tools/privoxy-log-parser.pl

   1 #!/usr/bin/perl
   2
   3 ################################################################################
   4 # privoxy-log-parser
   5 #
   6 # A parser for Privoxy log messages. For incomplete documentation run
   7 # perldoc privoxy-log-parser(.pl), for fancy screenshots see:
   8 #
   9 # http://www.fabiankeil.de/sourcecode/privoxy-log-parser/
  10 #
  11 # $Id: privoxy-log-parser.pl,v 1.89 2010/08/28 13:20:23 fabiankeil Exp $
  12 #
  13 # TODO:
  14 #       - LOG_LEVEL_CGI, LOG_LEVEL_ERROR, LOG_LEVEL_WRITE content highlighting
  15 #       - create fancy statistics
  16 #       - grep through Privoxy sources to find unsupported log messages
  17 #       - hunt down substitutions that match content from variables which
  18 #         can contain stuff like ()?'[]
  19 #       - replace $h{'foo'} with h('foo') where possible
  20 #       - hunt down XXX comments instead of just creating them
  21 #       - add example log lines for every regex and mark them up for
  22 #         regression testing
  23 #       - Handle incomplete input without Perl warning about undefined variables.
  24 #       - Use generic highlighting function that takes a regex and the
  25 #         hash key as input.
  26 #       - Add --compress and --decompress options.
  27 #
  28 # Copyright (c) 2007-2010 Fabian Keil <fk@fabiankeil.de>
  29 #
  30 # Permission to use, copy, modify, and distribute this software for any
  31 # purpose with or without fee is hereby granted, provided that the above
  32 # copyright notice and this permission notice appear in all copies.
  33 #
  34 # THE SOFTWARE IS PROVIDED "AS IS" AND THE AUTHOR DISCLAIMS ALL WARRANTIES
  35 # WITH REGARD TO THIS SOFTWARE INCLUDING ALL IMPLIED WARRANTIES OF
  36 # MERCHANTABILITY AND FITNESS. IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR
  37 # ANY SPECIAL, DIRECT, INDIRECT, OR CONSEQUENTIAL DAMAGES OR ANY DAMAGES
  38 # WHATSOEVER RESULTING FROM LOSS OF USE, DATA OR PROFITS, WHETHER IN AN
  39 # ACTION OF CONTRACT, NEGLIGENCE OR OTHER TORTIOUS ACTION, ARISING OUT OF
  40 # OR IN CONNECTION WITH THE USE OR PERFORMANCE OF THIS SOFTWARE.
  41 ################################################################################
  42
  43 use strict;
  44 use warnings;
  45 use Getopt::Long;
  46
  47 use constant {
  48     PRIVOXY_LOG_PARSER_VERSION => '0.6',
  49     # Feel free to mess with these ...
  50     DEFAULT_BACKGROUND => 'black',  # Choose registered colour (like 'black')
  51     DEFAULT_TEXT_COLOUR => 'white', # Choose registered colour (like 'black')
  52     HEADER_DEFAULT_COLOUR => 'yellow',
  53     REGISTER_HEADERS_WITH_THE_SAME_COLOUR => 1,
  54
  55     CLI_OPTION_DEFAULT_TO_HTML_OUTPUT => 0,
  56     CLI_OPTION_TITLE => 'Privoxy-Log-Parser in da house',
  57     CLI_OPTION_NO_EMBEDDED_CSS => 0,
  58     CLI_OPTION_NO_MSECS => 0,
  59     CLI_OPTION_NO_SYNTAX_HIGHLIGHTING => 0,
  60     CLI_OPTION_SHORTEN_THREAD_IDS => 0,
  61     CLI_OPTION_SHOW_INEFFECTIVE_FILTERS => 0,
  62     CLI_OPTION_ACCEPT_UNKNOWN_MESSAGES => 0,
  63     CLI_OPTION_STATISTICS => 0,
  64
  65     SUPPRESS_SUCCEEDED_FILTER_ADDITIONS => 1,
  66     SHOW_SCAN_INTRO => 0,
  67     SHOW_FILTER_READIN_IN => 0,
  68     SUPPRESS_EMPTY_LINES => 1,
  69     SUPPRESS_SUCCESSFUL_CONNECTIONS => 1,
  70     SUPPRESS_ACCEPTED_CONNECTIONS => 1,
  71     SUPPRESS_GIF_NOT_CHANGED => 1,
  72     SUPPRESS_NEED_TO_DE_CHUNK_FIRST => 1,
  73
  74     DEBUG_HEADER_REGISTERING => 0,
  75     DEBUG_HEADER_HIGHLIGHTING => 0,
  76     DEBUG_TICKS => 0,
  77     DEBUG_PAINT_IT => 0,
  78     DEBUG_SUPPRESS_LOG_MESSAGES => 0,
  79
  80     PUNISH_MISSING_LOG_KNOWLEDGE_WITH_DEATH => 0,
  81     PUNISH_MISSING_HIGHLIGHT_KNOWLEDGE_WITH_DEATH => 1,
  82
  83     LOG_UNPARSED_LINES_TO_EXTRA_FILE => 0,
  84     ERROR_LOG_FILE => '/var/log/privoxy-log-parser',
  85
  86     # You better leave these alone unless you know what you're doing.
  87     COLOUR_RESET      => "\033[0;0m",
  88     ESCAPE => "\033[",
  89 };
  90
  91 # For performance reasons, these are global.
  92
  93 my $t;
  94 my %req; # request data from previous lines
  95 my %h;
  96 my %thread_colours;
  97 my @all_colours;
  98 my @time_colours;
  99 my $thread_colour_index = 0;
 100 my $header_colour_index = 0;
 101 my $time_colour_index = 0;
 102 my %header_colours;
 103 my $no_special_header_highlighting;
 104 my %reason_colours;
 105 my %h_colours;
 106 my $header_highlight_regex = '';
 107
 108 my $html_output_mode;
 109 my $no_msecs_mode; # XXX: should probably be removed
 110 my $shorten_thread_ids;
 111 my $line_end;
 112
 113 sub prepare_our_stuff () {
 114
 115     # Syntax Higlight hash
 116     @all_colours = (
 117         'red', 'green', 'brown', 'blue', 'purple', 'cyan',
 118         'light_gray', 'light_red', 'light_green', 'yellow',
 119         'light_blue', 'pink', 'light_cyan', 'white'
 120     );
 121
 122     %h = (
 123         # LOG_LEVEL
 124         Info            => 'blue',
 125         Header          => 'green',
 126         Filter          => 'purple', # XXX: Used?
 127         'Re-Filter'     => 'purple',
 128         Connect         => 'brown',
 129         Request         => 'light_cyan',
 130         CGI             => 'light_green',
 131         Redirect        => 'cyan',
 132         Error           => 'light_red',
 133         Crunch          => 'cyan',
 134         'Fatal error'   => 'light_red',
 135         'Gif-Deanimate' => 'blue',
 136         Force           => 'red',
 137         Writing         => 'light_green',
 138         Received        => 'yellow',
 139         # ----------------------
 140         URL                  => 'yellow',
 141         path                 => 'brown',
 142         request_             => 'brown', # host+path but no protocol
 143         'ip-address'         => 'yellow',
 144         Number               => 'yellow',
 145         Standard             => 'reset',
 146         Truncation           => 'light_red',
 147         Status               => 'brown',
 148         Timestamp            => 'brown',
 149         Crunching            => 'light_red',
 150         crunched             => 'light_red',
 151         'Request-Line'       => 'pink',
 152         method               => 'purple',
 153         destination          => 'yellow',
 154         'http-version'       => 'pink',
 155         'crunch-pattern'     => 'pink',
 156         not                  => 'brown',
 157         file                 => 'brown',
 158         signal               => 'yellow',
 159         version              => 'green',
 160         'program-name'       => 'cyan',
 161         port                 => 'red',
 162         host                 => 'red',
 163         warning              => 'light_red',
 164         debug                => 'light_red',
 165         filter               => 'green',
 166         tag                  => 'green',
 167         tagger               => 'green',
 168         'status-message'     => 'light_cyan',
 169         'status-code'        => 'yellow',
 170         'invalid-request'    => 'light_red',
 171         'hits'               => 'yellow',
 172         error                => 'light_red',
 173         'rewritten-URL'      => 'light_red',
 174         'pcrs-delimiter'     => 'light_red',
 175         'ignored'            => 'light_red',
 176         'action-bits-update' => 'light_red',
 177         'configuration-line' => 'red',
 178         'content-type'       => 'yellow',
 179     );
 180
 181     %h_colours = %h;
 182
 183     # Header colours need their own hash so the keys can be accessed properly
 184     %header_colours = (
 185         # Prefilled with headers that should not appear with default header colours
 186         Cookie => 'light_red',
 187         'Set-Cookie' => 'light_red',
 188         Warning => 'light_red',
 189         Default => HEADER_DEFAULT_COLOUR,
 190     );
 191
 192     # Crunch reasons need their own hash as well
 193     %reason_colours = (
 194         'Unsupported HTTP feature'               => 'light_red',
 195         Blocked                                  => 'light_red',
 196         Untrusted                                => 'light_red',
 197         Redirected                               => 'green',
 198         'CGI Call'                               => 'white',
 199         'DNS failure'                            => 'red',
 200         'Forwarding failed'                      => 'light_red',
 201         'Connection failure'                     => 'light_red',
 202         'Out of memory (may mask other reasons)' => 'light_red',
 203         'No reason recorded'                     => 'light_red',
 204     );
 205
 206     @time_colours = ('white', 'light_gray');
 207
 208     # Translate highlight strings into highlight code
 209     prepare_highlight_hash(\%header_colours);
 210     prepare_highlight_hash(\%reason_colours);
 211     prepare_highlight_hash(\%h);
 212     prepare_colour_array(\@all_colours);
 213     prepare_colour_array(\@time_colours);
 214     init_css_colours();
 215
 216     init_stats();
 217 }
 218
 219 sub paint_it ($) {
 220 ###############################################################
 221 # Takes a colour string and returns an ANSI escape sequence
 222 # (unless --no-syntax-highlighting is used).
 223 # XXX: The Rolling Stones reference has to go.
 224 ###############################################################
 225
 226     my $colour = shift @_;
 227
 228     return "" if cli_option_is_set('no-syntax-highlighting');
 229
 230     my %light = (
 231         black       => 0,
 232         red         => 0,
 233         green       => 0,
 234         brown       => 0,
 235         blue        => 0,
 236         purple      => 0,
 237         cyan        => 0,
 238         light_gray  => 0,
 239         gray        => 0,
 240         dark_gray   => 1,
 241         light_red   => 1,
 242         light_green => 1,
 243         yellow      => 1,
 244         light_blue  => 1,
 245         pink        => 1,
 246         light_cyan  => 1,
 247         white       => 1,
 248     );
 249
 250     my %text = (
 251         black       => 30,
 252         red         => 31,
 253         green       => 32,
 254         brown       => 33,
 255         blue        => 34,
 256         purple      => 35,
 257         cyan        => 36,
 258         gray        => 37,
 259         light_gray  => 37,
 260         dark_gray   => 30,
 261         light_red   => 31,
 262         light_green => 32,
 263         yellow      => 33,
 264         light_blue  => 34,
 265         pink        => 35,
 266         light_cyan  => 36,
 267         white       => 37,
 268     );
 269
 270     my $bg_code = get_background();
 271     my $colour_code;
 272     our $default = default_colours();
 273
 274     if (defined($text{$colour})) {
 275         $colour_code  = ESCAPE;
 276         $colour_code .= $text{$colour};
 277         $colour_code .= ";";
 278         $colour_code .= $light{$colour} ? "1" : "2";
 279         $colour_code .= ";";
 280         $colour_code .= $bg_code;
 281         $colour_code .= "m";
 282         debug_message $colour . " is \'" . $colour_code . $colour . $default . "\'" if DEBUG_PAINT_IT;
 283
 284     } elsif ($colour =~ /reset/) {
 285
 286         $colour_code = default_colours();
 287
 288     } else {
 289
 290         die "What's $colour supposed to mean?\n";
 291     }
 292
 293     return $colour_code;
 294 }
 295
 296 sub get_semantic_html_markup ($) {
 297 ###############################################################
 298 # Takes a string and returns a span element
 299 ###############################################################
 300
 301     my $type = shift @_;
 302     my $code;
 303
 304     if ($type =~ /Standard/) {
 305         $code = '</span>';
 306     } else {
 307         $type = lc($type);
 308         $code = '<span title="' . $type . '" class="' . $type . '">';
 309     }
 310
 311     return $code;
 312 }
 313
 314 sub cli_option_is_set ($) {
 315
 316     our %cli_options;
 317     my $cli_option = shift;
 318
 319     die "Unknown CLI option: $cli_option" unless defined $cli_options{$cli_option};
 320
 321     return $cli_options{$cli_option};
 322 }
 323
 324 sub get_html_title () {
 325
 326     our %cli_options;
 327     return $cli_options{'title'};
 328
 329 }
 330
 331 sub init_css_colours() {
 332
 333     our %css_colours = (
 334         black       => "000",
 335         red         => "F00",
 336         green       => "0F0",
 337         brown       => "C90",
 338         blue        => "0F0",
 339         purple      => "F06", # XXX: wrong
 340         cyan        => "F09", # XXX: wrong
 341         light_gray  => "999",
 342         gray        => "333",
 343         dark_gray   => "222",
 344         light_red   => "F33",
 345         light_green => "33F",
 346         yellow      => "FF0",
 347         light_blue  => "30F",
 348         pink        => "F0F",
 349         light_cyan  => "66F",
 350         white       => "FFF",
 351     );
 352 }
 353
 354 sub get_css_colour ($) {
 355
 356    our %css_colours;
 357    my $colour = shift;
 358
 359    die "What's $colour supposed to mean?\n" unless defined($css_colours{$colour});
 360
 361    return '#' . $css_colours{$colour};
 362 }
 363
 364 sub get_css_line ($) {
 365
 366     my $class = shift;
 367     my $css_line;
 368
 369     $css_line .= '.' . lc($class) . ' {'; # XXX: lc() shouldn't be necessary
 370     die "What's $class supposed to mean?\n" unless defined($h_colours{$class});
 371     $css_line .= 'color:' . get_css_colour($h_colours{$class}) . ';';
 372     $css_line .= 'background-color:' . get_css_colour(DEFAULT_BACKGROUND) . ';';
 373     $css_line .= '}' . "\n";
 374
 375     return $css_line;
 376 }
 377
 378 sub get_css_line_for_colour ($) {
 379
 380     my $colour = shift;
 381     my $css_line;
 382
 383     $css_line .= '.' . lc($colour) . ' {'; # XXX: lc() shouldn't be necessary
 384     $css_line .= 'color:' . get_css_colour($colour) . ';';
 385     $css_line .= 'background-color:' . get_css_colour(DEFAULT_BACKGROUND) . ';';
 386     $css_line .= '}' . "\n";
 387
 388     return $css_line;
 389 }
 390
 391 # XXX: Wrong solution
 392 sub get_missing_css_lines () {
 393
 394     my $css_line;
 395
 396     $css_line .= '.' . 'default' . ' {';
 397     $css_line .= 'color:' . HEADER_DEFAULT_COLOUR . ';';
 398     $css_line .= 'background-color:' . get_css_colour(DEFAULT_BACKGROUND) . ';';
 399     $css_line .= '}' . "\n";
 400
 401     return $css_line;
 402 }
 403
 404 sub get_css () {
 405
 406     our %css_colours; #XXX: Wrong solution
 407
 408     my $css = '';
 409
 410     $css .= '.privoxy-log {';
 411     $css .= 'color:' . get_css_colour(DEFAULT_TEXT_COLOUR) . ';';
 412     $css .= 'background-color:' . get_css_colour(DEFAULT_BACKGROUND) . ';';
 413     $css .= '}' . "\n";
 414
 415     foreach my $key (keys %h_colours) {
 416
 417         next if ($h_colours{$key} =~ m/reset/); #XXX: Wrong solution.
 418         $css .= get_css_line($key);
 419
 420     }
 421
 422     foreach my $colour (keys %css_colours) {
 423
 424         $css .= get_css_line_for_colour($colour);
 425
 426     }
 427
 428     $css .= get_missing_css_lines(); #XXX: Wrong solution
 429
 430     return $css;
 431 }
 432
 433 sub print_intro () {
 434
 435     my $intro = '';
 436
 437     if (cli_option_is_set('html-output')) {
 438
 439         my $title = get_html_title();
 440
 441         $intro .= '<html><head>';
 442         $intro .= '<title>' . $title . '</title>';
 443         $intro .= '<style>' . get_css() . '</style>' unless cli_option_is_set('no-embedded-css');
 444         $intro .= '</head><body>';
 445         $intro .= '<h1>' . $title . '</h1><p class="privoxy-log">';
 446
 447         print $intro;
 448     }
 449 }
 450
 451 sub print_outro () {
 452
 453     my $outro = '';
 454
 455     if (cli_option_is_set('html-output')) {
 456
 457         $outro = '</p></body></html>';
 458         print $outro;
 459
 460     }
 461 }
 462
 463 sub get_line_end () {
 464     return cli_option_is_set('html-output') ? "<br>\n" : "\n";
 465 }
 466
 467 sub get_colour_html_markup ($) {
 468 ###############################################################
 469 # Takes a colour string a span element. XXX: WHAT?
 470 # XXX: This function shouldn't be necessary, the
 471 # markup should always be semantically correct.
 472 ###############################################################
 473
 474     my $type = shift @_;
 475     my $code;
 476
 477     if ($type =~ /Standard/) {
 478         $code = '</span>';
 479     } else {
 480         $code = '<span class="' . lc($type) . '">';
 481     }
 482
 483     return $code;
 484 }
 485
 486 sub default_colours () {
 487     # XXX: Properly
 488     our $bg_code;
 489     return reset_colours();
 490 }
 491
 492 sub show_colours () {
 493     # XXX: Implement
 494 }
 495
 496 sub reset_colours () {
 497     return ESCAPE . "0m";
 498 }
 499
 500 sub set_background ($){
 501
 502     my $colour = shift;
 503     our $bg_code;
 504     my %backgrounds = (
 505               black       => "40",
 506               red         => "41",
 507               green       => "42",
 508               brown       => "43",
 509               blue        => "44",
 510               magenta     => "45",
 511               cyan        => "46",
 512               white       => "47",
 513               default     => "49",
 514     );
 515
 516     if (defined($backgrounds{$colour})) {
 517         $bg_code = $backgrounds{$colour};
 518     } else {
 519         die "Invalid background colour: " . $colour;
 520     }
 521 }
 522
 523 sub get_background (){
 524     return our $bg_code;
 525 }
 526
 527 sub prepare_highlight_hash ($) {
 528     my $ref = shift;
 529
 530     foreach my $key (keys %$ref) {
 531         $$ref{$key} = $html_output_mode ?
 532             get_semantic_html_markup($key) :
 533             paint_it($$ref{$key});
 534     }
 535 }
 536
 537 sub prepare_colour_array ($) {
 538     my $ref = shift;
 539
 540     foreach my $i (0 ... @$ref - 1) {
 541         $$ref[$i] = $html_output_mode ?
 542             get_colour_html_markup($$ref[$i]) :
 543             paint_it($$ref[$i]);
 544     }
 545 }
 546
 547 sub found_unknown_content ($) {
 548
 549     my $unknown = shift;
 550     my $message;
 551
 552     return if cli_option_is_set('accept-unknown-messages');
 553
 554     return if ($unknown =~ /\[too long, truncated\]$/);
 555
 556     $message = "found_unknown_content: Don't know how to highlight: ";
 557     # Break line so the log file can later be parsed as Privoxy log file again
 558     $message .= '"' . $unknown . '"' . " in:\n";
 559     $message .= $req{$t}{'log-message'};
 560     debug_message($message);
 561     log_parse_error($req{$t}{'log-message'});
 562
 563     die "Unworthy content parser" if PUNISH_MISSING_LOG_KNOWLEDGE_WITH_DEATH;
 564 }
 565
 566 sub log_parse_error ($) {
 567
 568     my $message = shift;
 569
 570     if (LOG_UNPARSED_LINES_TO_EXTRA_FILE) {
 571         open(ERRORLOG, ">>" . ERROR_LOG_FILE) || die "Writing " . ERROR_LOG_FILE . " failed";
 572         print ERRORLOG $message;
 573         close(ERRORLOG);
 574     }
 575 }
 576
 577 sub debug_message (@) {
 578     my @message = @_;
 579
 580     print $h{'debug'} . "@message" . $h{'Standard'} . "\n";
 581 }
 582
 583 ################################################################################
 584 # highlighter functions that aren't loglevel-specific
 585 ################################################################################
 586
 587 sub h ($) {
 588
 589     # Get highlight marker
 590     my $highlight = shift; # XXX: Stupid name;
 591     my $result = '';
 592     my $message;
 593
 594     if (defined($highlight)) {
 595
 596         $result = $h{$highlight};
 597
 598     } else {
 599
 600         $message = "h: Don't recognize highlighter $highlight.";
 601         debug_message($message);
 602         log_parser_error($message);
 603         die "Unworthy highlighter function" if PUNISH_MISSING_HIGHLIGHT_KNOWLEDGE_WITH_DEATH;
 604     }
 605
 606     return $result;
 607 }
 608
 609 sub highlight_known_headers ($) {
 610
 611     my $content = shift;
 612
 613     debug_message("Searching $content for things to highlight.") if DEBUG_HEADER_HIGHLIGHTING;
 614
 615     if ($content =~ m/(?<=\s)($header_highlight_regex):/) {
 616         my $header = $1;
 617         $content =~ s@(?<=[\s|'])($header)(?=:)@$header_colours{$header}$1$h{'Standard'}@ig;
 618         debug_message("Highlighted '$header' in '$content'") if DEBUG_HEADER_HIGHLIGHTING;
 619     }
 620
 621     return $content;
 622 }
 623
 624 sub highlight_matched_request_line ($$) {
 625
 626     my $result = shift; # XXX: Stupid name;
 627     my $regex = shift;
 628     if ($result =~ m@(.*)($regex)(.*)@) {
 629         $result = $1 . highlight_request_line($2) . $3
 630     }
 631     return $result;
 632 }
 633
 634 sub highlight_request_line ($) {
 635
 636     my $rl = shift;
 637     my ($method, $url, $http_version);
 638
 639     #GET http://images.sourceforge.net/sfx/icon_warning.gif HTTP/1.1
 640     if ($rl =~ m/Invalid request/) {
 641
 642         $rl = h('invalid-request') . $rl . h('Standard');
 643
 644     } elsif ($rl =~ m/^([-\w]+) (.*) (HTTP\/\d\.\d)/) {
 645
 646         # XXX: might not match in case of HTTP method fuzzing.
 647         # XXX: save these: ($method, $path, $http_version) = ($1, $2, $3);
 648         $rl =~ s@^(\w+)@$h{'method'}$1$h{'Standard'}@;
 649         if ($rl =~ /http:\/\//) {
 650             $rl = highlight_matched_url($rl, '[^\s]*(?=\sHTTP)');
 651         } else {
 652             $rl = highlight_matched_pattern($rl, 'request_', '[^\s]*(?=\sHTTP)');
 653         }
 654
 655         $rl =~ s@(HTTP\/\d\.\d)$@$h{'http-version'}$1$h{'Standard'}@;
 656
 657     } elsif ($rl =~ m/\.\.\. \[too long, truncated\]$/) {
 658
 659         $rl =~ s@^(\w+)@$h{'method'}$1$h{'Standard'}@;
 660         $rl = highlight_matched_url($rl, '[^\s]*(?=\.\.\.)');
 661
 662     } elsif ($rl =~ m/^ $/) {
 663
 664         $rl = h('error') . "No request line specified!" . h('Standard');
 665
 666     } else {
 667
 668         debug_message ("Can't parse request line: $rl");
 669
 670     }
 671
 672     return $rl;
 673 }
 674
 675 sub highlight_response_line ($) {
 676
 677     my $rl = shift;
 678     my ($http_version, $status_code, $status_message);
 679
 680     #HTTP/1.1 200 OK
 681     #ICY 200 OK
 682
 683     # TODO: Mark different status codes differently
 684
 685     if ($rl =~ m/((?:HTTP\/\d\.\d|ICY)) (\d+) (.*)/) {
 686         ($http_version, $status_code, $status_message) = ($1, $2, $3);
 687     } else {
 688         debug_message ("Can't parse response line: $rl") and die 'Fix this';
 689     }
 690
 691     # Rebuild highlighted
 692     $rl= "";
 693     $rl .= h('http-version') . $http_version . h('Standard');
 694     $rl .= " ";
 695     $rl .= h('status-code') . $status_code . h('Standard');
 696     $rl .= " ";
 697     $rl .= h('status-message') . $status_message . h('Standard');
 698
 699     return $rl;
 700 }
 701
 702 sub highlight_matched_url ($$) {
 703
 704     my $result = shift; # XXX: Stupid name;
 705     my $regex = shift;
 706
 707     #print "Got $result, regex ($regex)\n";
 708
 709     if ($result =~ m@(.*?)($regex)(.*)@) {
 710         $result = $1 . highlight_url($2) . $3;
 711         #print "Now the result is $result\n";
 712     }
 713
 714     return $result;
 715 }
 716
 717 sub highlight_matched_host ($$) {
 718
 719     my ($result, $regex) = @_; # XXX: result ist stupid name;
 720
 721     if ($result =~ m@(.*?)($regex)(.*)@) {
 722         $result = $1 . $h{host} . $2 . $h{Standard} . $3;
 723     }
 724
 725     return $result;
 726 }
 727
 728 sub highlight_matched_pattern ($$$) {
 729
 730     my $result = shift; # XXX: Stupid name;
 731     my $key = shift;
 732     my $regex = shift;
 733
 734     die "Unknown key $key" unless defined $h{$key};
 735
 736     if ($result =~ m@(.*?)($regex)(.*)@) {
 737         $result = $1 . h($key) . $2 . h('Standard') . $3;
 738     }
 739
 740     return $result;
 741 }
 742
 743 sub highlight_matched_path ($$) {
 744
 745     my $result = shift; # XXX: Stupid name;
 746     my $regex = shift;
 747
 748     if ($result =~ m@(.*?)($regex)(.*)@) {
 749         $result = $1 . h('path') . $2 . h('Standard') . $3;
 750     }
 751
 752     return $result;
 753 }
 754
 755 sub highlight_url ($) {
 756
 757     my $url = shift;
 758
 759     if ($html_output_mode) {
 760
 761         $url = '<a href="' . $url . '">' . $url . '</a>';
 762
 763     } else {
 764
 765         $url = h('URL') . $url . h('Standard');
 766
 767     }
 768
 769     return $url;
 770 }
 771
 772 sub update_header_highlight_regex ($) {
 773
 774     my $header = shift;
 775     my $headers = join ('|', keys %header_colours);
 776
 777     $header_highlight_regex = qr/$headers/;
 778     print "Registering '$header'\n" if DEBUG_HEADER_HIGHLIGHTING;
 779 }
 780
 781 ################################################################################
 782 # loglevel-specific highlighter functions
 783 ################################################################################
 784
 785 sub handle_loglevel_header ($) {
 786
 787     my $c = shift;
 788
 789     if ($c =~ /^scan:/) {
 790
 791         if ($c =~ m/^scan: ([^: ]+):/) {
 792
 793             # Register new headers
 794             # scan: Accept: image/png,image/*;q=0.8,*/*;q=0.5
 795             my $header = $1;
 796             if (!defined($header_colours{$header}) and $header =~ /^[\d\w-]*$/) {
 797                 debug_message "Registering previously unknown header $1" if DEBUG_HEADER_REGISTERING;
 798
 799                 if (REGISTER_HEADERS_WITH_THE_SAME_COLOUR) {
 800                     $header_colours{$header} =  $header_colours{'Default'};
 801                 } else {
 802                     $header_colours{$header} = $all_colours[$header_colour_index % @all_colours];
 803                     $header_colour_index++;
 804                 }
 805                 update_header_highlight_regex($header);
 806             }
 807
 808         } elsif ($c =~ m/^(scan: )(\w+ .+ HTTP\/\d\.\d)/) {
 809
 810             # scan: HTTP/1.1 200 OK
 811             $c = $1 . highlight_request_line($2);
 812
 813         } elsif ($c =~ m/^(scan: )((?:HTTP\/\d\.\d|ICY) (\d+) (.*))/) {
 814
 815             # Server response line
 816             $req{$t}{'response_line'} = $2;
 817             $req{$t}{'status_code'} = $3;
 818             $req{$t}{'status_message'} = $4;
 819             $c = $1 . highlight_response_line($req{$t}{'response_line'});
 820         }
 821
 822     } elsif ($c =~ m/^Crunching (?:server|client) header: .* \(contains: ([^\)]*)\)/) {
 823
 824         # Crunching server header: Set-Cookie: trac_form_token=d5308c34e16d15e9e301a456; (contains: Cookie:)
 825         $c =~ s@(?<=contains: )($1)@$h{'crunch-pattern'}$1$h{'Standard'}@;
 826         $c =~ s@(Crunching)@$h{$1}$1$h{'Standard'}@;
 827
 828     } elsif ($c =~ m/^New host is: ([^\s]*)\./) {
 829
 830         # New host is: trac.vidalia-project.net. Crunching Referer: http://www.vidalia-project.net/!
 831         $c = highlight_matched_host($c, '(?<=New host is: )[^\s]+(?=\.)');
 832         $c = highlight_matched_url($c, '(?<=Crunching Referer: )[^\s!]+');
 833
 834     } elsif ($c =~ m/^Text mode enabled by force. (Take cover)!/) {
 835
 836         # Text mode enabled by force. Take cover!
 837         $c =~ s@($1)@$h{'warning'}$1$h{'Standard'}@;
 838
 839     } elsif ($c =~ m/^(New HTTP Request-Line: )(.*)/) {
 840
 841         # New HTTP Request-Line: GET http://www.privoxy.org/ HTTP/1.1
 842         $c = $1 . highlight_request_line($2);
 843
 844     } elsif ($c =~ m/^Adjust(ed)? Content-Length to \d+/) {
 845
 846         # Adjusted Content-Length to 2132
 847         # Adjust Content-Length to 33533
 848         $c =~ s@(?<=Content-Length to )(\d+)@$h{'Number'}$1$h{'Standard'}@;
 849         $c = highlight_known_headers($c);
 850
 851     } elsif ($c =~ m/^Destination extracted from "Host:" header. New request URL:/) {
 852
 853         # Destination extracted from "Host:" header. New request URL: http://www.cccmz.de/~ridcully/blog/
 854         $c = highlight_matched_url($c, '(?<=New request URL: ).*');
 855
 856     } elsif ($c =~ m/^Couldn\'t parse:/) {
 857
 858         # XXX: These should probable be logged with LOG_LEVEL_ERROR
 859         # Couldn't parse: If-Modified-Since: Wed, 21 Mar 2007 16:34:50 GMT (crunching!)
 860         # Couldn't parse: at, 24 Mar 2007 13:46:21 GMT in If-Modified-Since: Sat, 24 Mar 2007 13:46:21 GMT (crunching!)
 861         $c =~ s@^(Couldn\'t parse)@$h{'error'}$1$h{'Standard'}@;
 862
 863     } elsif ($c =~ /^Tagger \'([^\']*)\' added tag \'([^\']*)\'/ or
 864              $c =~ m/^Adding tag \'([^\']*)\' created by header tagger \'([^\']*)\'/) {
 865
 866         # Adding tag 'GET request' created by header tagger 'method-man' (XXX: no longer used)
 867         # Tagger 'revalidation' added tag 'REVALIDATION-REQUEST'. No action bit update necessary.
 868         # Tagger 'revalidation' added tag 'REVALIDATION-REQUEST'. Action bits updated accordingly.
 869
 870         # XXX: Save tag and tagger
 871
 872         $c =~ s@(?<=^Tagger \')([^\']*)@$h{'tagger'}$1$h{'Standard'}@;
 873         $c =~ s@(?<=added tag \')([^\']*)@$h{'tag'}$1$h{'Standard'}@;
 874         $c =~ s@(?<=Action bits )(updated)@$h{'action-bits-update'}$1$h{'Standard'}@;
 875         $no_special_header_highlighting = 1;
 876
 877     } elsif ($c =~ /^Tagger \'([^\']*)\' didn['']t add tag \'([^\']*)\'/) {
 878
 879         # Tagger 'revalidation' didn't add tag 'REVALIDATION-REQUEST'. Tag already present
 880         # XXX: Save tag and tagger
 881
 882         $c =~ s@(?<=^Tagger \')([^\']*)@$h{'tag'}$1$h{'Standard'}@;
 883         $c =~ s@(?<=didn['']t add tag \')([^\']*)@$h{'tagger'}$1$h{'Standard'}@;
 884
 885     } elsif ($c =~ m/^(?:scan:|Randomiz|addh:|Adding:|Removing:|Referer:|Modified:|Accept-Language header|[Cc]ookie)/
 886           or $c =~ m/^(Text mode is already enabled|Denied request with NULL byte|Replaced:|add-unique:)/
 887           or $c =~ m/^(Crunched (incoming|outgoing) cookie|Suppressed offer|Accepted the client)/
 888           or $c =~ m/^(addh-unique|Referer forged to)/
 889           or $c =~ m/^Downgraded answer to HTTP\/1.0/
 890           or $c =~ m/^Parameter: \+hide-referrer\{[^\}]*\} is a bad idea, but I don\'t care./
 891           or $c =~ m/^Referer (?:overwritten|replaced) with: Referer: / #XXX: should this be highlighted?
 892           or $c =~ m/^Referer crunched!/
 893           or $c =~ m/^crunched x-forwarded-for!/
 894           or $c =~ m/^crunched From!/
 895           or $c =~ m/^ modified$/
 896           or $c =~ m/^Content filtering is enabled. Crunching:/
 897           or $c =~ m/^force-text-mode overruled the client/
 898           or $c =~ m/^Server time in the future\./
 899           or $c =~ m/^content-disposition header crunched and replaced with:/i
 900           or $c =~ m/^Reducing white space in /
 901           or $c =~ m/^Ignoring single quote in /
 902           or $c =~ m/^Converting tab to space in /
 903           or $c =~ m/A HTTP\/1\.1 response without/
 904           or $c =~ m/Disabled filter mode on behalf of the client/
 905           or $c =~ m/Keeping the (?:server|client) header /
 906           or $c =~ m/Content modified with no Content-Length header set/
 907           or $c =~ m/^Appended client IP address to/
 908           or $c =~ m/^Removing 'Connection: close' to imply keep-alive./
 909           or $c =~ m/^keep-alive support is disabled/
 910           or $c =~ m/^Continue hack in da house/
 911             )
 912     {
 913         # XXX: Some of these may need highlighting
 914
 915         # Modified: User-Agent: Mozilla/5.0 (X11; U; SunOS i86pc; pl-PL; rv:1.8.1.1) Gecko/20070214 Firefox/2.0.0.1
 916         # Accept-Language header crunched and replaced with: Accept-Language: pl-pl
 917         # cookie 'Set-Cookie: eZSessionCookie=07bfec287c197440d299f81580593c3d; \
 918         #  expires=Thursday, 12-Apr-07 15:16:18 GMT; path=/' send by \
 919         #  http://wirres.net/article/articleview/4265/1/6/ appears to be using time format 1 (XXX: gone with the wind)
 920         # Cookie rewritten to a temporary one: Set-Cookie: NSC_gffe-iuuq-mc-wtfswfs=8efb33a53660;path=/
 921         # Text mode is already enabled
 922         # Denied request with NULL byte(s) turned into line break(s)
 923         # Replaced: 'Connection: Yo, home to Bel Air' with 'Connection: close'
 924         # addh-unique: Host: people.freebsd.org
 925         # Suppressed offer to compress content
 926         # Crunched incoming cookie -- yum!
 927         # Accepted the client's request to fetch without filtering.
 928         # Crunched outgoing cookie: Cookie: PREF=ID=6cf0abd347b30262:TM=1173357617:LM=1173357617:S=jZypyyJ7LPiwFi1_
 929         # addh-unique: Host: subkeys.pgp.net:11371
 930         # Referer forged to: Referer: http://10.0.0.1/
 931         # Downgraded answer to HTTP/1.0
 932         # Parameter: +hide-referrer{pille-palle} is a bad idea, but I don't care.
 933         # Referer overwritten with: Referer: pille-palle
 934         # Referer replaced with: Referer: pille-palle
 935         # crunched x-forwarded-for!
 936         # crunched From!
 937         #  modified # XXX: pretty stupid log message
 938         # Content filtering is enabled. Crunching: 'Range: 1234-5678' to prevent range-mismatch problems
 939         # force-text-mode overruled the client's request to fetch without filtering!
 940         # Server time in the future.
 941         # content-disposition header crunched and replaced with: content-disposition: filename=baz
 942         # Content-Disposition header crunched and replaced with: content-disposition: filename=baz
 943         # Reducing white space in 'X-LWS-Test: "This  is  quoted" this is not "this  is  " but " this again   is  not'
 944         # Ignoring single quote in 'X-LWS-Test: "This  is  quoted" this is not "this  is  " but "  this again   is  not'
 945         # Converting tab to space in 'X-LWS-Test:   "This  is  quoted" this   is  not "this  is  "  but  "\
 946         #  this again   is  not'
 947         # A HTTP/1.1 response without Connection header implies keep-alive.
 948         # Disabled filter mode on behalf of the client.
 949         # Keeping the server header 'Connection: keep-alive' around.
 950         # Keeping the client header 'Connection: close' around. The connection will not be kept alive.
 951         # Keeping the client header 'Connection: keep-alive' around. The connection will be kept alive if possible.
 952         # Content modified with no Content-Length header set. Creating a fake one for adjustment later on.
 953         # Appended client IP address to X-Forwarded-For: 10.0.0.2, 10.0.0.1
 954         # Removing 'Connection: close' to imply keep-alive.
 955         # keep-alive support is disabled. Crunching: Keep-Alive: 300.
 956         # Continue hack in da house.
 957
 958     } elsif ($c =~ m/^scanning headers for:/) {
 959
 960         return '' unless SHOW_SCAN_INTRO;
 961
 962     } elsif ($c =~ m/^[Cc]runch(ing|ed)|crumble crunched:/) {
 963         # crunched User-Agent!
 964         # Crunching: Content-Encoding: gzip
 965
 966         $c =~ s@(Crunching|crunched)@$h{$1}$1$h{'Standard'}@;
 967
 968     } elsif ($c =~ m/^Offending request data with NULL bytes turned into \'°\' characters:/) {
 969
 970         # Offending request data with NULL bytes turned into '°' characters: °°n°°(°°°
 971
 972         $c = h('warning') . $c . h('Standard');
 973
 974     } elsif ($c =~ m/^(Transforming \")(.*?)(\" to \")(.*?)(\")/) {
 975
 976         # Transforming "Proxy-Authenticate: Basic realm="Correos Proxy Server"" to\
 977         #  "Proxy-Authenticate: Basic realm="Correos Proxy Server""
 978
 979        $c =~ s@(?<=^Transforming \")(.*)(?=\" to)@$h{'Header'}$1$h{'Standard'}@;
 980        $c =~ s@(?<=to \")(.*)(?=\")@$h{'Header'}$1$h{'Standard'}@;
 981
 982     } elsif ($c =~ m/^Removing empty header/) {
 983
 984         # Removing empty header
 985         # Ignore for now
 986
 987     } elsif ($c =~ m/^Content-Type: .* not replaced/) {
 988
 989         # Content-Type: application/octet-stream not replaced. It doesn't look like text.\
 990         #  Enable force-text-mode if you know what you're doing.
 991         # XXX: Could highlight more here.
 992         $c =~ s@(?<=^Content-Type: )(.*)(?= not replaced)@$h{'content-type'}$1$h{'Standard'}@;
 993
 994     } elsif ($c =~ m/^(Server|Client) keep-alive timeout is/) {
 995
 996        # Server keep-alive timeout is 5. Sticking with 10.
 997        # Client keep-alive timeout is 20. Sticking with 10.
 998
 999        $c =~ s@(?<=timeout is )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1000        $c =~ s@(?<=Sticking with )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1001
1002     } elsif ($c =~ m/^Reducing keep-alive timeout/) {
1003
1004        # Reducing keep-alive timeout from 60 to 10.
1005
1006        $c =~ s@(?<= from )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1007        $c =~ s@(?<= to )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1008
1009     } else {
1010
1011         found_unknown_content($c);
1012     }
1013
1014     # Highlight headers
1015     unless ($c =~ m/^Transforming/) {
1016         $c = highlight_known_headers($c) unless $no_special_header_highlighting;
1017     }
1018
1019     return $c;
1020 }
1021
1022 sub handle_loglevel_re_filter ($) {
1023
1024     my $content = shift;
1025     my $c = $content;
1026     my $key;
1027
1028     if ($c =~ m/^(?:re_)?filtering ([^\s]+) \(size (\d+)\) with (?:filter )?\'?([^\s]+?)\'? produced (\d+) hits \(new size (\d+)\)/) {
1029
1030         # XXX: only the second version gets highlighted properly.
1031         # re_filtering www.lfk.de/favicon.ico (size 209) with filter untrackable-hulk produced 0 hits (new size 209).
1032         # filtering aci.blogg.de/ (size 37988) with 'blogg.de' produced 3 hits (new size 38057)
1033         $req{$t}{'content_source'} = $1;
1034         $req{$t}{'content_size'}   = $2;
1035         $req{$t}{'content_filter'} = $3;
1036         $req{$t}{'content_hits'}   = $4;
1037         $req{$t}{'new_content_size'} = $5;
1038         $req{$t}{'content_size_change'} = $req{$t}{'new_content_size'} - $req{$t}{'content_size'};
1039         #return '' if ($req{$t}{'content_hits'} == 0 && !cli_option_is_set('show-ineffective-filters'));
1040         if ($req{$t}{'content_hits'} == 0 and
1041             not (cli_option_is_set('show-ineffective-filters')
1042                  or ($req{$t}{'content_filter'} =~ m/^privoxy-filter-test$/))) {
1043                 return '';
1044         }
1045
1046         $c =~ s@(?<=\(size )(\d+)\)(?= with)@$h{'Number'}$1$h{'Standard'}@;
1047         $c =~ s@(?<=\(new size )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1048         $c =~ s@(?<=produced )(\d+)(?= hits)@$h{'Number'}$1$h{'Standard'}@;
1049
1050         $c =~ s@([^\s]+?)(\'? produced)@$h{'filter'}$1$h{'Standard'}$2@;
1051         $c = highlight_matched_host($c, '(?<=filtering )[^\s]+');
1052
1053         $c =~ s@\.$@ @;
1054         $c .= "(" . $h{'Number'};
1055         $c .= "+" if ($req{$t}{'content_size_change'} >= 0);
1056         $c .= $req{$t}{'content_size_change'} . $h{'Standard'} . ")";
1057         $content = $c;
1058
1059   } elsif ($c =~ /\.{3}$/
1060         and $c =~ m/^(?:re_)?filtering \'?(.*?)\'? \(size (\d*)\) with (?:filter )?\'?([^\s]*?)\'? ?\.{3}$/) {
1061
1062         # Used by Privoxy 3.0.5 and 3.0.6:
1063         # XXX: Fill in ...
1064         # Used by Privoxy 3.0.7:
1065         # filtering 'Connection: close' (size 17) with 'generic-content-ads' ...
1066
1067         $req{$t}{'filtered_header'} = $1;
1068         $req{$t}{'old_header_size'} = $2;
1069         $req{$t}{'header_filter_name'} = $3;
1070
1071         unless (cli_option_is_set('show-ineffective-filters') or
1072                 $req{$t}{'header_filter_name'} =~ m/^privoxy-filter-test$/) {
1073             return '';
1074         }
1075         $content =~ s@(?<=\(size )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1076         $content =~ s@($req{$t}{'header_filter_name'})@$h{'filter'}$1$h{'Standard'}@;
1077
1078     } elsif ($c =~ m/^ ?\.\.\. ?produced (\d*) hits \(new size (\d*)\)\./) {
1079
1080         # ...produced 0 hits (new size 23).
1081         #... produced 1 hits (new size 54).
1082
1083         $req{$t}{'header_filter_hits'} = $1;
1084         $req{$t}{'new_header_size'} = $2;
1085
1086         unless (cli_option_is_set('show-ineffective-filters') or
1087                 (defined($req{$t}{'header_filter_name'}) and
1088                  $req{$t}{'header_filter_name'} =~ m/^privoxy-filter-test$/)) {
1089
1090             if ($req{$t}{'header_filter_hits'} == 0 and
1091                 not (defined($req{$t}{'header_filter_name'}) and
1092                  $req{$t}{'header_filter_name'} =~ m/^privoxy-filter-test$/)) {
1093                 return '';
1094             }
1095             # Reformat including information from the intro
1096             $c = "'" . h('filter') . $req{$t}{'header_filter_name'} . h('Standard') . "'";
1097             $c .= " hit ";
1098             # XXX: Hide behind constant, it may be interesting if LOG_LEVEL_HEADER isn't enabled as well.
1099             # $c .= $req{$t}{'filtered_header'} . " ";
1100             $c .= h('Number') . $req{$t}{'header_filter_hits'}. h('Standard');
1101             $c .= ($req{$t}{'header_filter_hits'} == 1) ? " time, " : " times, ";
1102
1103             if ($req{$t}{'old_header_size'} !=  $req{$t}{'new_header_size'}) {
1104
1105                 $c .= "changing size from ";
1106                 $c .=  h('Number') . $req{$t}{'old_header_size'} . h('Standard');
1107                 $c .= " to ";
1108                 $c .= h('Number') . $req{$t}{'new_header_size'} . h('Standard');
1109                 $c .= ".";
1110
1111             } else {
1112
1113                 $c .= "keeping the size at " . $req{$t}{'old_header_size'};
1114
1115             }
1116
1117             # Highlight from last line (XXX: What?)
1118             # $c =~ s@(?<=produced )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1119             # $c =~ s@($req{$t}{'header_filter_name'})@$h{'filter'}$1$h{'Standard'}@;
1120
1121         } else {
1122
1123            # XXX: Untested
1124            $c =~ s@(?<=produced )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1125            $c =~ s@(?<=new size )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1126
1127         }
1128         $content = $c;
1129
1130     } elsif ($c =~ m/^(Tagger|Filter) ([^\s]*) has empty joblist. Nothing to do./) {
1131
1132         # Filter privoxy-filter-test has empty joblist. Nothing to do.
1133         # Tagger variable-test has empty joblist. Nothing to do.
1134
1135         $content =~ s@(?<=$1 )([^\s]*)@$h{'filter'}$1$h{'Standard'}@;
1136
1137     } elsif ($c =~ m/^De-chunking successful. Shrunk from (\d+) to (\d+)/) {
1138
1139         $req{$t}{'chunked-size'} = $1;
1140         $req{$t}{'dechunked-size'} = $2;
1141         $req{$t}{'dechunk-change'} = $req{$t}{'dechunked-size'} - $req{$t}{'chunked-size'};
1142
1143         $content .= " (" . h('Number') . $req{$t}{'dechunk-change'} . h('Standard') . ")";
1144
1145         $content =~ s@(?<=from )($req{$t}{'chunked-size'})@$h{'Number'}$1$h{'Standard'}@;
1146         $content =~ s@(?<=to )($req{$t}{'dechunked-size'})@$h{'Number'}$1$h{'Standard'}@;
1147
1148     } elsif ($c =~ m/^Decompression successful. Old size: (\d+), new size: (\d+)./) {
1149
1150         # Decompression successful. Old size: 670, new size: 1166.
1151
1152         $req{$t}{'size-compressed'} = $1;
1153         $req{$t}{'size-decompressed'} = $2;
1154         $req{$t}{'decompression-gain'} = $req{$t}{'size-decompressed'} - $req{$t}{'size-compressed'};
1155
1156         $content =~ s@(?<=Old size: )($req{$t}{'size-compressed'})@$h{'Number'}$1$h{'Standard'}@;
1157         $content =~ s@(?<=new size: )($req{$t}{'size-decompressed'})@$h{'Number'}$1$h{'Standard'}@;
1158
1159         # XXX: Create sub get_percentage()
1160         if ($req{$t}{'size-decompressed'}) {
1161             $req{$t}{'decompression-gain-percent'} =
1162                 $req{$t}{'decompression-gain'} / $req{$t}{'size-decompressed'} * 100;
1163
1164             $content .= " (saved: ";
1165             #$content .= h('Number') . $req{$t}{'decompression-gain'} . h('Standard');
1166             #$content .= "/";
1167             $content .= h('Number') . sprintf("%.2f%%", $req{$t}{'decompression-gain-percent'}) . h('Standard');
1168             $content .= ")";
1169         }
1170
1171     } elsif ($c =~ m/^(Need to de-chunk first)/) {
1172
1173         # Need to de-chunk first
1174         return '' if SUPPRESS_NEED_TO_DE_CHUNK_FIRST;
1175
1176     } elsif ($c =~ m/^(Adding (?:dynamic )?re_filter job)/) {
1177
1178         return ''  if (SUPPRESS_SUCCEEDED_FILTER_ADDITIONS && m/succeeded/);
1179
1180         # Adding re_filter job ...
1181         # Adding dynamic re_filter job s@^(?:\w*)\s+.*\s+HTTP/\d\.\d\s*@IP-ADDRESS: $origin@D\
1182         #  to filter client-ip-address succeeded.
1183
1184     } elsif ($c =~ m/^Reading in filter/) {
1185
1186         return '' unless SHOW_FILTER_READIN_IN;
1187
1188     } else {
1189
1190         found_unknown_content($content);
1191
1192     }
1193
1194     return $content;
1195 }
1196
1197 sub handle_loglevel_redirect ($) {
1198
1199     my $c = shift;
1200
1201     if ($c =~ m/^Decoding "([^""]*)"/) {
1202
1203          $req{$t}{'original-destination'} = $1;
1204          $c = highlight_matched_path($c, '(?<=Decoding ")[^"]*');
1205          $c =~ s@\"@@g;
1206
1207     } elsif ($c =~ m/^Checking/) {
1208
1209          # Checking /_ylt=A0geu.Z76BRGR9k/**http://search.yahoo.com/search?p=view+odb+presentation+on+freebsd\
1210          #  &ei=UTF-8&xargs=0&pstart=1&fr=moz2&b=11 for redirects.
1211
1212          # TODO: Change colour if really url-decoded
1213          $req{$t}{'decoded-original-destination'} = $1;
1214          $c = highlight_matched_path($c, '(?<=Checking ")[^"]*');
1215          $c =~ s@\"@@g;
1216
1217     } elsif ($c =~ m/^pcrs command "([^""]*)" changed /) {
1218
1219         # pcrs command "s@&from=rss@@" changed \
1220         #  "http://it.slashdot.org/article.pl?sid=07/03/02/1657247&from=rss"\
1221         #  to "http://it.slashdot.org/article.pl?sid=07/03/02/1657247" (1 hit).
1222         $c =~ s@(?<=pcrs command )"([^""]*)"@$h{'filter'}$1$h{'Standard'}@;
1223         $c = highlight_matched_url($c, '(?<=changed ")[^""]*');
1224         $c =~ s@(?<=changed )"([^""]*)"@$1@; # Remove quotes
1225         $c = highlight_matched_url($c, '(?<=to ")[^""]*');
1226         $c =~ s@(?<=to )"([^""]*)"@$1@; # Remove quotes
1227         $c =~ s@(\d+)(?= hits?)@$h{'hits'}$1$h{'Standard'}@;
1228
1229     } elsif ($c =~ m/^pcrs command "([^""]*)" didn\'t change/) {
1230
1231         # pcrs command "s@^http://([^.]+?)/?$@http://www.bing.com/search?q=$1@" didn't \
1232         #  change "http://www.example.org/".
1233         $c =~ s@(?<=pcrs command )"([^""]*)"@$h{'filter'}$1$h{'Standard'}@;
1234         $c = highlight_matched_url($c, '(?<=change ")[^""]*');
1235
1236     } elsif ($c =~ m/(^New URL is: )(.*)/) {
1237
1238         # New URL is: http://it.slashdot.org/article.pl?sid=07/03/04/1511210
1239         # XXX: Use URL highlighter
1240         # XXX: Save?
1241         $c = $1 . h('rewritten-URL') . $2 . h('Standard');
1242
1243     } elsif ($c =~ m/No pcrs command recognized, assuming that/) {
1244         # No pcrs command recognized, assuming that "http://config.privoxy.org/user-manual/favicon.png"\
1245         #  is already properly formatted.
1246         # XXX: assume the same?
1247         $c = highlight_matched_url($c, '(?<=assuming that \")[^"]*');
1248
1249     } else {
1250
1251         found_unknown_content($c);
1252
1253     }
1254
1255     return $c;
1256 }
1257
1258 sub handle_loglevel_gif_deanimate ($) {
1259
1260     my $content = shift;
1261
1262     if ($content =~ m/Success! GIF shrunk from (\d+) bytes to (\d+)\./) {
1263
1264         my $bytes_from = $1;
1265         my $bytes_to = $2;
1266         # Gif-Deanimate: Success! GIF shrunk from 205 bytes to 133.
1267         $content =~ s@$bytes_from@$h{'Number'}$bytes_from$h{'Standard'}@;
1268         # XXX: Do we need g in case of ($1 == $2)?
1269         $content =~ s@$bytes_to@$h{'Number'}$bytes_to$h{'Standard'}@;
1270
1271     } elsif ($content =~ m/GIF (not) changed/) {
1272
1273         # Gif-Deanimate: GIF not changed.
1274         return '' if SUPPRESS_GIF_NOT_CHANGED;
1275         $content =~ s@($1)@$h{'not'}$1$h{'Standard'}@;
1276
1277     } elsif ($content =~ m/^failed! \(gif parsing\)/) {
1278
1279         # failed! (gif parsing)
1280         # XXX: Replace this error message with something less stupid
1281         $content =~ s@(failed!)@$h{'error'}$1$h{'Standard'}@;
1282
1283     } elsif ($content =~ m/^Need to de-chunk first/) {
1284
1285         # Need to de-chunk first
1286         return '' if SUPPRESS_NEED_TO_DE_CHUNK_FIRST;
1287
1288     } elsif ($content =~ m/^(?:No GIF header found|failed while parsing)/) {
1289
1290         # No GIF header found (XXX: Did I ever commit this?)
1291         # failed while parsing 195 134747048 (XXX: never commited)
1292
1293         # Ignore these for now
1294
1295     } else {
1296
1297         found_unknown_content($content);
1298
1299     }
1300
1301     return $content;
1302 }
1303
1304 sub handle_loglevel_request ($) {
1305
1306     my $content = shift;
1307
1308     if ($content =~ m/crunch! /) {
1309
1310         # config.privoxy.org/send-stylesheet crunch! (CGI Call)
1311
1312         # Highlight crunch reasons
1313         foreach my $reason (keys %reason_colours) {
1314             $content =~ s@\(($reason)\)@$reason_colours{$reason}($1)$h{'Standard'}@g;
1315         }
1316         # Highlight request URL domain and ditch 'crunch!'
1317         $content = highlight_matched_pattern($content, 'request_', '[^ ]*(?= crunch!)');
1318         $content =~ s@ crunch!@@;
1319
1320     } elsif ($content =~ m/\[too long, truncated\]$/) {
1321
1322         # config.privoxy.org/edit-actions-submit?f=3&v=1176116716&s=7&Submit=Submit[...]&filter... [too long, truncated]
1323         $content = highlight_matched_pattern($content, 'request_', '^.*(?=\.\.\. \[too long, truncated\]$)');
1324
1325     } elsif ($content =~ m/(.*)/) { # XXX: Pretty stupid
1326
1327         # trac.vidalia-project.net/wiki/Volunteer?format=txt
1328         $content = h('request_') . $content . h('Standard');
1329
1330     } else {  # XXX: Nop
1331
1332         found_unknown_content($content);
1333
1334     }
1335
1336     return $content;
1337 }
1338
1339 sub handle_loglevel_crunch ($) {
1340
1341     my $content = shift;
1342
1343     # Highlight crunch reason
1344     foreach my $reason (keys %reason_colours) {
1345         $content =~ s@($reason)@$reason_colours{$reason}$1$h{'Standard'}@g;
1346     }
1347
1348     if ($content =~ m/\[too long, truncated\]$/) {
1349
1350         # Blocked: config.privoxy.org/edit-actions-submit?f=3&v=1176116716&s=7&Submit=Submit\
1351         #  [...]&filter... [too long, truncated]
1352         $content = highlight_matched_pattern($content, 'request_', '^.*(?=\.\.\. \[too long, truncated\]$)');
1353
1354     } else {
1355
1356         # Blocked: http://ads.example.org/
1357         $content = highlight_matched_pattern($content, 'request_', '(?<=: ).*');
1358     }
1359
1360     return $content;
1361 }
1362
1363 sub handle_loglevel_connect ($) {
1364
1365     my $c = shift;
1366
1367     if ($c =~ m/^via [^\s]+ to: [^\s]+/) {
1368
1369         # Connect: via 10.0.0.1:8123 to: www.example.org.noconnect
1370
1371         $c = highlight_matched_host($c, '(?<=via )[^\s]+');
1372         $c = highlight_matched_host($c, '(?<=to: )[^\s]+');
1373
1374     } elsif ($c =~ m/^connect to: .* failed: .*/) {
1375
1376         # connect to: www.example.org.noconnect failed: Operation not permitted
1377
1378         $c = highlight_matched_host($c, '(?<=connect to: )[^\s]+');
1379
1380         $c =~ s@(?<=failed: )(.*)@$h{'error'}$1$h{'Standard'}@;
1381
1382     } elsif ($c =~ m/^to ([^\s]*)( successful)?$/) {
1383
1384         # Connect: to www.nzherald.co.nz successful
1385         # Connect: to archiv.radiotux.de
1386
1387         return '' if SUPPRESS_SUCCESSFUL_CONNECTIONS;
1388         $c = highlight_matched_host($c, '(?<=to )[^\s]+');
1389
1390     } elsif ($c =~ m/^to ([^\s]*)$/) {
1391
1392         # Connect: to lists.sourceforge.net:443
1393
1394         $c = highlight_matched_host($c, '(?<=to )[^\s]+');
1395
1396     } elsif ($c =~ m/^accepted connection from .*/ or
1397              $c =~ m/^OK/) {
1398
1399         # accepted connection from 10.0.0.1
1400         # Privoxy 3.0.6 and earlier just say:
1401         # OK
1402         return '' if SUPPRESS_ACCEPTED_CONNECTIONS;
1403         $c = highlight_matched_host($c, '(?<=connection from ).*');
1404
1405     } elsif ($c =~ m/^write header to: .* failed:/) {
1406
1407         # write header to: 10.0.0.1 failed: Broken pipe
1408
1409         $c = highlight_matched_host($c, '(?<=write header to: )[^\s]*');
1410         $c =~ s@(?<=failed: )(.*)@$h{'Error'}$1$h{'Standard'}@;
1411
1412     } elsif ($c =~ m/^write header to client failed:/) {
1413
1414         # write header to client failed: Broken pipe
1415         # XXX: Stil in use?
1416         $c =~ s@(?<=failed: )(.*)@$h{'Error'}$1$h{'Standard'}@;
1417
1418     } elsif ($c =~ m/^socks4_connect:/) {
1419
1420         # socks4_connect: SOCKS request rejected or failed.
1421         $c =~ s@(?<=socks4_connect: )(.*)@$h{'Error'}$1$h{'Standard'}@;
1422
1423     } elsif ($c =~ m/^Listening for new connections/ or
1424              $c =~ m/^accept connection/) {
1425         # XXX: Highlight?
1426         # Privoxy versions above 3.0.6 say:
1427         # Listening for new connections ...
1428         # earlier versions say:
1429         # accept connection ...
1430         return '';
1431
1432     } elsif ($c =~ m/^accept failed:/) {
1433
1434         $c =~ s@(?<=accept failed: )(.*)@$h{'Error'}$1$h{'Standard'}@;
1435
1436     } elsif ($c =~ m/^Overriding forwarding settings/) {
1437
1438         # Overriding forwarding settings based on 'forward 10.0.0.1:8123'
1439         $c =~ s@(?<=based on \')(.*)(?=\')@$h{'configuration-line'}$1$h{'Standard'}@;
1440
1441     } elsif ($c =~ m/^Denying suspicious CONNECT request from/) {
1442
1443         # Denying suspicious CONNECT request from 10.0.0.1
1444         $c = highlight_matched_host($c, '(?<=from )[^\s]+'); # XXX: not an URL
1445
1446     } elsif ($c =~ m/^socks5_connect:/) {
1447
1448         $c =~ s@(?<=socks5_connect: )(.*)@$h{'error'}$1$h{'Standard'}@;
1449
1450     } elsif ($c =~ m/^Created new connection to/) {
1451
1452         # Created new connection to www.privoxy.org:80 on socket 11.
1453         $c = highlight_matched_host($c, '(?<=connection to )[^\s]+');
1454         $c =~ s@(?<=on socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1455
1456     } elsif ($c =~ m/^Found reusable socket/) {
1457
1458         # Found reusable socket 9 for www.privoxy.org:80 in slot 0.
1459         # 3.0.15 and later:
1460         # Found reusable socket 8 for www.privoxy.org:80 in slot 2.\
1461         #  Timestamp made 0 seconds ago. Timeout: 1. Latency: 0.
1462         $c =~ s@(?<=Found reusable socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1463         $c = highlight_matched_host($c, '(?<=for )[^\s]+');
1464         $c =~ s@(?<=in slot )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1465         $c =~ s@(?<=made )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1466         $c =~ s@(?<=Timeout: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1467         $c =~ s@(?<=Latency: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1468
1469     } elsif ($c =~ m/^Marking open socket/) {
1470
1471         # Marking open socket 9 for www.privoxy.org:80 in slot 0 as unused.
1472         $c =~ s@(?<=Marking open socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1473         $c = highlight_matched_host($c, '(?<=for )[^\s]+');
1474         $c =~ s@(?<=in slot )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1475
1476     } elsif ($c =~ m/^No reusable/) {
1477
1478         # No reusable socket for addons.mozilla.org:443 found. Opening a new one.
1479         $c = highlight_matched_host($c, '(?<=for )[^\s]+');
1480
1481     } elsif ($c =~ m/^(Remembering|Forgetting) socket/) {
1482
1483         # Remembering socket 13 for www.privoxy.org:80 in slot 0.
1484         # Forgetting socket 38 for www.privoxy.org:80 in slot 5.
1485
1486         $c =~ s@(?<=socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1487         $c = highlight_matched_host($c, '(?<=for )[^\s]+');
1488         $c =~ s@(?<=in slot )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1489
1490     } elsif ($c =~ m/^Socket/) {
1491
1492         # Socket 16 already forgotten or never remembered.
1493         $c =~ s@(?<=Socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1494
1495     } elsif ($c =~ m/^The connection to/) {
1496
1497         # The connection to www.privoxy.org:80 in slot 6 timed out. Closing socket 19. Timeout is: 61.
1498         # 3.0.15 and later:
1499         # The connection to 1.bp.blogspot.com:80 in slot 0 timed out. Closing socket 5.\
1500         #  Timeout is: 1. Assumed latency: 4.
1501         # The connection to 10.0.0.1:80 in slot 0 is no longer usable. Closing socket 4.
1502         $c = highlight_matched_host($c, '(?<=connection to )[^\s]+');
1503         $c =~ s@(?<=in slot )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1504         $c =~ s@(?<=Closing socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1505         $c =~ s@(?<=Timeout is: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1506         $c =~ s@(?<=Assumed latency: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1507
1508     } elsif ($c =~ m/^Stopped waiting for the request line./) {
1509
1510         # Stopped waiting for the request line. Timeout: 121.
1511         $c =~ s@(?<=Timeout: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1512
1513     } elsif ($c =~ m/^Waiting for \d/) {
1514
1515         # Waiting for 1 connections to timeout.
1516         $c =~ s@(?<=^Waiting for )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1517
1518     } elsif ($c =~ m/^Initialized/) {
1519
1520         # Initialized 20 socket slots.
1521         $c =~ s@(?<=Initialized )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1522
1523     } elsif ($c =~ m/^Done reading from server/) {
1524
1525         # Done reading from server. Expected content length: 24892. \
1526         #  Actual content length: 24892. Most recently received: 4412.
1527         # 3.0.15 and later:
1528         # Done reading from server. Expected content length: 24892. \
1529         #  Actual content length: 24892. Bytes most recently read: 4412.
1530         # Done reading from server. Content length: 6018 as expected. \
1531         #  Bytes most recently read: 294.
1532         $c =~ s@(?<=ontent length: )(\d+)@$h{'Number'}$1$h{'Standard'}@g;
1533         $c =~ s@(?<=received: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1534         $c =~ s@(?<=read: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1535
1536     } elsif ($c =~ m/^Continuing buffering headers/) {
1537
1538         # Continuing buffering headers. byte_count: 19. header_offset: 517. len: 536.
1539         $c =~ s@(?<=byte_count: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1540         $c =~ s@(?<=header_offset: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1541         $c =~ s@(?<=len: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1542         # 3.0.15 and later:
1543         # Continuing buffering headers. Bytes most recently read: %d.
1544         $c =~ s@(?<=read: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1545
1546     } elsif ($c =~ m/^Received \d+ bytes while/) {
1547
1548         # Received 206 bytes while expecting 12103.
1549         $c =~ s@(?<=Received )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1550         $c =~ s@(?<=expecting )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1551
1552     } elsif ($c =~ m/^(Rejecting c|C)onnection from/) {
1553
1554         # Connection from 81.163.28.218 dropped due to ACL
1555         # Rejecting connection from 178.63.152.227. Maximum number of connections reached.
1556         $c =~ s@(?<=onnection from )((?:\d+\.?){3}\d+)@$h{'Number'}$1$h{'Standard'}@;
1557
1558     } elsif ($c =~ m/^(?:Reusing|Closing) server socket \d./ or
1559              $c =~ m/^No additional client request/) {
1560
1561         # Reusing server socket 4. Opened for 10.0.0.1.
1562         # Closing server socket 2. Opened for 10.0.0.1.
1563         # No additional client request received in time. \
1564         #  Closing server socket 4, initially opened for 10.0.0.1.
1565         # No additional client request received in time on socket 29.
1566
1567         $c =~ s@(?<= socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1568         $c = highlight_matched_host($c, '(?<=for )[^\s]+(?=\.$)');
1569
1570     } elsif ($c =~ m/^Connected to /) {
1571
1572         # Connected to tor-jail[10.0.0.2]:9050.
1573
1574         $c = highlight_matched_host($c, '(?<=\[)[^\]]+');
1575         $c = highlight_matched_host($c, '(?<=Connected to )[^\[\s]+');
1576         $c =~ s@(?<=\]:)(\d+)@$h{'Number'}$1$h{'Standard'}@;
1577
1578     } elsif ($c =~ m/^Could not connect to /) {
1579
1580         # Could not connect to [10.0.0.1]:80.
1581
1582         $c = highlight_matched_host($c, '(?<=\[)[^\]]+');
1583         $c =~ s@(?<=\]:)(\d+)@$h{'Number'}$1$h{'Standard'}@;
1584
1585     } elsif ($c =~ m/^Waiting for the next client request/ or
1586              $c =~ m/^The connection on server socket/ or
1587              $c =~ m/^Client request arrived in time or the client closed the connection/) {
1588
1589         # Waiting for the next client request on socket 3. Keeping the server \
1590         #  socket 12 to a.fsdn.com open.
1591         # The connection on server socket 6 to upload.wikimedia.org isn't reusable. Closing.
1592         # Client request arrived in time or the client closed the connection on socket 12.
1593
1594         $c =~ s@(?<=on socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1595         $c =~ s@(?<=server socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1596         $c = highlight_matched_host($c, '(?<=to )[^\s]+');
1597
1598     } elsif ($c =~ m/^Marking the server socket/) {
1599
1600         # Marking the server socket 7 tainted.
1601
1602         $c =~ s@(?<=server socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1603
1604     } elsif ($c =~ m/^Reduced expected bytes to /) {
1605
1606         # Reduced expected bytes to 0 to account for the 1542 ones we already got.
1607         $c =~ s@(?<=bytes to )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1608         $c =~ s@(?<=for the )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1609
1610     } elsif ($c =~ m/^The client closed socket /) {
1611
1612         # The client closed socket 2 while the server socket 4 is still open.
1613         $c =~ s@(?<=closed socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1614         $c =~ s@(?<=server socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1615
1616     } elsif ($c =~ m/^Expected client content length set /) {
1617
1618         # Expected client content length set to 667325411 after reading 4999 bytes.
1619         $c =~ s@(?<=set to )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1620         $c =~ s@(?<=reading )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1621
1622     } elsif ($c =~ m/^Waiting for up to /) {
1623
1624         # Waiting for up to 4999 bytes from the client.
1625         $c =~ s@(?<=up to )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1626
1627     } elsif ($c =~ m/^Looks like we / or
1628              $c =~ m/^Unsetting keep-alive flag/ or
1629              $c =~ m/^No connections to wait/ or
1630              $c =~ m/^Complete client request received/ or
1631              $c =~ m/^Possible pipeline attempt detected./ or
1632              $c =~ m/^POST request detected. The connection will not be kept alive./ or
1633              $c =~ m/^The server still wants to talk, but the client hung up on us./ or
1634              $c =~ m/^The server didn't specify how long the connection will stay open/ or
1635              $c =~ m/^There might be a request body. The connection will not be kept alive/ or
1636              $c =~ m/^Stopping to watch the client socket. There's already another request waiting./ or
1637              $c =~ m/^Done reading from the client\.$/) {
1638
1639         # Looks like we reached the end of the last chunk. We better stop reading.
1640         # Looks like we read the end of the last chunk together with the server \
1641         #  headers. We better stop reading.
1642         # Looks like we got the last chunk together with the server headers. \
1643         #  We better stop reading.
1644         # Unsetting keep-alive flag.
1645         # No connections to wait for left.
1646         # Client request arrived in time or the client closed the connection.
1647         # Complete client request received
1648         # Possible pipeline attempt detected. The connection will not be \
1649         #  kept alive and we will only serve the first request.
1650         # POST request detected. The connection will not be kept alive.
1651         # The server still wants to talk, but the client hung up on us.
1652         # The server didn't specify how long the connection will stay open. Assume it's only a second.
1653         # There might be a request body. The connection will not be kept alive.
1654         # Stopping to watch the client socket. There's already another request waiting.
1655         # Done reading from the client\.
1656
1657     } else {
1658
1659         found_unknown_content($c);
1660
1661     }
1662
1663     return $c;
1664 }
1665
1666
1667 sub handle_loglevel_info ($) {
1668
1669     my $c = shift;
1670
1671     if ($c =~ m/^Rewrite detected:/) {
1672
1673         # Rewrite detected: GET http://10.0.0.2:88/blah.txt HTTP/1.1
1674         $c = highlight_matched_request_line($c, '(?<=^Rewrite detected: ).*');
1675
1676     } elsif ($c =~ m/^Decompress(ing deflated|ion didn)/ or
1677              $c =~ m/^Compressed content detected/ or
1678              $c =~ m/^Tagger/
1679             ) {
1680         # Decompressing deflated iob: 117
1681         # Decompression didn't result in any content.
1682         # Compressed content detected, content filtering disabled. Consider recompiling Privoxy\
1683         #  with zlib support or enable the prevent-compression action.
1684         # Tagger 'complete-url' created empty tag. Ignored.
1685
1686         # Ignored for now
1687
1688     } elsif ($c =~ m/^(Re)?loading configuration file /) {
1689
1690         # loading configuration file '/usr/local/etc/privoxy/config':
1691         # Reloading configuration file '/usr/local/etc/privoxy/config'
1692         $c =~ s@(?<=loading configuration file \')([^\']*)@$h{'file'}$1$h{'Standard'}@;
1693
1694     } elsif ($c =~ m/^Loading (actions|filter) file: /) {
1695
1696         # Loading actions file: /usr/local/etc/privoxy/default.action
1697         # Loading filter file: /usr/local/etc/privoxy/default.filter
1698         $c =~ s@(?<= file: )(.*)$@$h{'file'}$1$h{'Standard'}@;
1699
1700     } elsif ($c =~ m/^exiting by signal/) {
1701
1702         # exiting by signal 15 .. bye
1703         $c =~ s@(?<=exiting by signal )(\d+)@$h{'signal'}$1$h{'Standard'}@;
1704
1705     } elsif ($c =~ m/^Privoxy version/) {
1706
1707         # Privoxy version 3.0.7
1708         $c =~ s@(?<=^Privoxy version )(\d+\.\d+\.\d+)$@$h{'version'}$1$h{'Standard'}@;
1709
1710     } elsif ($c =~ m/^Program name: /) {
1711
1712         # Program name: /usr/local/sbin/privoxy
1713         $c =~ s@(?<=Program name: )(.*)@$h{'program-name'}$1$h{'Standard'}@;
1714
1715     } elsif ($c =~ m/^Listening on port /) {
1716
1717         # Listening on port 8118 on IP address 10.0.0.1
1718         $c =~ s@(?<=Listening on port )(\d+)@$h{'port'}$1$h{'Standard'}@;
1719         $c =~ s@(?<=on IP address )(.*)@$h{'ip-address'}$1$h{'Standard'}@;
1720
1721     } elsif ($c =~ m/^\(Re-\)Open(?:ing)? logfile/) {
1722
1723         # (Re-)Open logfile /var/log/privoxy/privoxy.log
1724         $c =~ s@(?<=Open logfile )(.*)@$h{'file'}$1$h{'Standard'}@;
1725
1726     } elsif ($c =~ m/^(Request from|Malformed server response detected)/) {
1727
1728         # Request from 10.0.0.1 denied. limit-connect{,} doesn't allow CONNECT requests to port 443.
1729         # Request from 10.0.0.1 marked for blocking. limit-connect{,} doesn't allow CONNECT requests to port 443.
1730         # Malformed server response detected. Downgrading to HTTP/1.0 impossible.
1731
1732         $c =~ s@(?<=Request from )([^\s]*)@$h{'ip-address'}$1$h{'Standard'}@;
1733         $c =~ s@(denied|blocking)@$h{'warning'}$1$h{'Standard'}@;
1734         $c =~ s@(CONNECT)@$h{'method'}$1$h{'Standard'}@;
1735         $c =~ s@(?<=to port )(\d+)@$h{'port'}$1$h{'Standard'}@;
1736
1737     } elsif ($c =~ m/^Status code/) {
1738
1739         # Status code 304 implies no body.
1740         $c =~ s@(?<=Status code )(\d+)@$h{'status-code'}$1$h{'Standard'}@;
1741
1742     } elsif ($c =~ m/^Method/) {
1743
1744         # Method HEAD implies no body.
1745         $c =~ s@(?<=Method )([^\s]+)@$h{'method'}$1$h{'Standard'}@;
1746
1747     } elsif ($c =~ m/^Buffer limit reached while extending /) {
1748
1749         # Buffer limit reached while extending the buffer (iob). Needed: 4197470. Limit: 4194304
1750         $c =~ s@(?<=Needed: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1751         $c =~ s@(?<=Limit: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1752
1753     } elsif ($c =~ m/^No logfile configured/ or
1754              $c =~ m/^Malformerd HTTP headers detected and MS IIS5 hack enabled/ or
1755              $c =~ m/^Invalid \"chunked\" transfer/ or
1756              $c =~ m/^Support for/ or
1757              $c =~ m/^Flushing header and buffers/ or
1758              $c =~ m/^Can not resolve/
1759              ) {
1760
1761         # No logfile configured. Please enable it before reporting any problems.
1762         # Malformerd HTTP headers detected and MS IIS5 hack enabled. Expect an invalid \
1763         #  response or even no response at all.
1764         # No logfile configured. Logging disabled.
1765         # Invalid "chunked" transfer encoding detected and ignored.
1766         # Support for 'Connection: keep-alive' is experimental, incomplete and\
1767         #  known not to work properly in some situations.
1768         # Flushing header and buffers. Stepping back from filtering.
1769         # Can not resolve doesnotexist: hostname nor servname provided, or not known
1770
1771     } else {
1772
1773         found_unknown_content($c);
1774
1775     }
1776
1777     return $c;
1778 }
1779
1780 sub handle_loglevel_cgi ($) {
1781
1782     my $c = shift;
1783
1784     if ($c =~ m/^Granting access to/) {
1785
1786         #Granting access to http://config.privoxy.org/send-stylesheet, referrer http://p.p/ is trustworthy.
1787
1788     } elsif ($c =~ m/^Substituting: s(.)/) {
1789
1790         # Substituting: s/@else-not-FEATURE_ZLIB@.*@endif-FEATURE_ZLIB@//sigTU
1791         # XXX: prone to span several lines
1792
1793         my $delimiter = $1;
1794         #$c =~ s@(?<=failed: )(.*)@$h{'error'}$1$h{'Standard'}@;
1795         $c =~ s@(?!<=\\)($delimiter)@$h{'pcrs-delimiter'}$1$h{'Standard'}@g; # XXX: Too aggressive
1796         #$c =~ s@(?!<=\\)($1)@$h{'pcrs-delimiter'}$1$h{'Standard'}@g;
1797     }
1798
1799     return $c;
1800 }
1801
1802 sub handle_loglevel_force ($) {
1803
1804     my $c = shift;
1805
1806     if ($c =~ m/^Ignored force prefix in request:/) {
1807
1808         # Ignored force prefix in request: "GET http://10.0.0.1/PRIVOXY-FORCE/block HTTP/1.1"
1809         $c =~ s@^(Ignored)@$h{'ignored'}$1$h{'Standard'}@;
1810         $c = highlight_matched_request_line($c, '(?<=request: ")[^"]*');
1811
1812     } elsif ($c =~ m/^Enforcing request:/) {
1813
1814         # Enforcing request: "GET http://10.0.0.1/block HTTP/1.1".
1815         $c = highlight_matched_request_line($c, '(?<=request: ")[^"]*');
1816
1817     } else {
1818
1819         found_unknown_content($c);
1820
1821     }
1822
1823     return $c;
1824 }
1825
1826 sub handle_loglevel_error ($) {
1827
1828     my $c = shift;
1829
1830     if ($c =~ m/^Empty server or forwarder response received on socket \d+./) {
1831
1832         # Empty server or forwarder response received on socket 4.
1833         # Empty server or forwarder response received on socket 3. \
1834         #  Closing client socket 15 without sending data.
1835         $c =~ s@(?<=on socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1836         $c =~ s@(?<=client socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1837     }
1838     # XXX: There are probably more messages that deserve highlighting.
1839
1840     return $c;
1841 }
1842
1843
1844 sub handle_loglevel_ignore ($) {
1845     return shift;
1846 }
1847
1848 sub gather_loglevel_request_stats ($$) {
1849     my $c = shift;
1850     my $thread = shift;
1851     our %stats;
1852
1853     $stats{requests}++;
1854 }
1855
1856 sub gather_loglevel_crunch_stats ($$) {
1857     my $c = shift;
1858     my $thread = shift;
1859     our %stats;
1860
1861     $stats{requests}++;
1862     $stats{crunches}++;
1863 }
1864
1865
1866 sub gather_loglevel_error_stats ($$) {
1867
1868     my $c = shift;
1869     my $thread = shift;
1870     our %stats;
1871     our %thread_data;
1872
1873     if ($c =~ m/^Empty server or forwarder response received on socket \d+./) {
1874
1875         # Empty server or forwarder response received on socket 4.
1876         $stats{'empty-responses'}++;
1877         if ($thread_data{$thread}{'new_connection'}) {
1878             $stats{'empty-responses-on-new-connections'}++;
1879         } else {
1880             $stats{'empty-responses-on-reused-connections'}++;
1881         }
1882     }
1883 }
1884
1885 sub gather_loglevel_connect_stats ($$) {
1886
1887     my ($c, $thread) = @_;
1888     our %thread_data;
1889     our %stats;
1890
1891     if ($c =~ m/^via ([^\s]+) to: [^\s]+/) {
1892
1893         # Connect: via 10.0.0.1:8123 to: www.example.org.noconnect
1894         $thread_data{$thread}{'forwarder'} = $1; # XXX: is this missue?
1895
1896     } elsif ($c =~ m/^to ([^\s]*)$/) {
1897
1898         # Connect: to lists.sourceforge.net:443
1899
1900         $thread_data{$thread}{'forwarder'} = 'direct connection';
1901
1902     } elsif ($c =~ m/^Created new connection to/) {
1903
1904         # Created new connection to www.privoxy.org:80 on socket 11.
1905
1906         $thread_data{$thread}{'new_connection'} = 1;
1907
1908     } elsif ($c =~ m/^Reusing server socket \d./ or
1909              $c =~ m/^Found reusable socket/) {
1910
1911         # Reusing server socket 4. Opened for 10.0.0.1.
1912         # Found reusable socket 9 for www.privoxy.org:80 in slot 0.
1913
1914         $thread_data{$thread}{'new_connection'} = 0;
1915         $stats{'reused-connections'}++;
1916     }
1917 }
1918
1919 sub gather_loglevel_header_stats ($$) {
1920
1921     my ($c, $thread) = @_;
1922     our %stats;
1923
1924     if ($c =~ m/^A HTTP\/1\.1 response without/ or
1925         $c =~ m/^Keeping the server header 'Connection: keep-alive' around./)
1926     {
1927         # A HTTP/1.1 response without Connection header implies keep-alive.
1928         # Keeping the server header 'Connection: keep-alive' around.
1929         $stats{'server-keep-alive'}++;
1930
1931     } elsif ($c =~ m/^scan: ((\w+) (.+) (HTTP\/\d\.\d))/) {
1932
1933         # scan: HTTP/1.1 200 OK
1934         $stats{'method'}{$2}++;
1935         $stats{'ressource'}{$3}++;
1936         $stats{'http-version'}{$4}++;
1937     }
1938 }
1939
1940 sub init_stats () {
1941     our %stats = (
1942         requests => 0,
1943         crunches => 0,
1944         'server-keep-alive' => 0,
1945         'reused-connections' => 0,
1946         'empty-responses' => 0,
1947         'empty-responses-on-new-connections' => 0,
1948         'empty-responses-on-reused-connections' => 0,
1949         );
1950 }
1951
1952 sub get_percentage ($$) {
1953     my $big = shift;
1954     my $small = shift;
1955     return "NaN" if ($big eq 0);
1956     return sprintf("%.2f%%", $small / $big * 100);
1957 }
1958
1959 sub print_stats () {
1960
1961     our %stats;
1962     my $new_connections = $stats{requests} - $stats{crunches} - $stats{'reused-connections'};
1963     my $outgoing_requests = $stats{requests} - $stats{crunches};
1964
1965     if ($stats{requests} eq 0) {
1966         print "No requests yet.\n";
1967         return;
1968     }
1969
1970     print "Client requests total: " . $stats{requests} . "\n";
1971     print "Crunches: " . $stats{crunches} . " (" .
1972         get_percentage($stats{requests}, $stats{crunches}) . ")\n";
1973     print "Outgoing requests: " . $outgoing_requests . " (" .
1974         get_percentage($stats{requests}, $outgoing_requests) . ")\n";
1975     print "Server keep-alive offers: " . $stats{'server-keep-alive'} . " (" .
1976         get_percentage($stats{requests}, $stats{'server-keep-alive'}) . ")\n";
1977     print "New outgoing connections: " . $new_connections . " (" .
1978         get_percentage($stats{requests}, $new_connections) . ")\n";
1979     print "Reused connections: " . $stats{'reused-connections'} . " (" .
1980         get_percentage($stats{requests}, $stats{'reused-connections'}) . ")\n";
1981     print "Empty responses: " . $stats{'empty-responses'} . " (" .
1982         get_percentage($stats{requests}, $stats{'empty-responses'}) . ")\n";
1983     print "Empty responses on new connections: "
1984          . $stats{'empty-responses-on-new-connections'} . " (" .
1985         get_percentage($stats{requests}, $stats{'empty-responses-on-new-connections'})
1986         . ")\n";
1987     print "Empty responses on reused connections: " .
1988         $stats{'empty-responses-on-reused-connections'} . " (" .
1989         get_percentage($stats{requests}, $stats{'empty-responses-on-reused-connections'}) .
1990         ")\n";
1991
1992     if ($stats{method} eq 0) {
1993         print "No response lines parsed yet yet.\n";
1994         return;
1995     }
1996     print "Method distribution:\n";
1997     foreach my $method (sort {$stats{'method'}{$b} <=> $stats{'method'}{$a}} keys %{$stats{'method'}}) {
1998         printf "%8d : %-8s\n", $stats{'method'}{$method}, $method;
1999     }
2000     print "Client HTTP versions:\n";
2001     foreach my $http_version (sort {$stats{'http-version'}{$b} <=> $stats{'http-version'}{$a}} keys %{$stats{'http-version'}}) {
2002         printf "%d : %s\n",  $stats{'http-version'}{$http_version}, $http_version;
2003     }
2004     print "Requested ressources:\n";
2005     foreach my $ressource (sort {$stats{'ressource'}{$b} <=> $stats{'ressource'}{$a}} keys %{$stats{'ressource'}}) {
2006         printf "%d : %s\n", $stats{'ressource'}{$ressource}, $ressource;
2007     }
2008 }
2009
2010
2011 ################################################################################
2012 # Functions that actually print stuff
2013 ################################################################################
2014
2015 sub print_clf_message () {
2016
2017     our ($ip, $timestamp, $request_line, $status_code, $size);
2018     my $output = '';
2019
2020     return if DEBUG_SUPPRESS_LOG_MESSAGES;
2021
2022     # Rebuild highlighted
2023     $output .= $h{'Number'} . $ip . $h{'Standard'};
2024     $output .= " - - ";
2025     $output .= "[" . $h{'Timestamp'} . $timestamp . $h{'Standard'} . "]";
2026     $output .= " ";
2027     $output .= "\"" . highlight_request_line("$request_line") . "\"";
2028     $output .= " ";
2029     $output .= $h{'Status'} . $status_code . $h{'Standard'};
2030     $output .= " ";
2031     $output .= $h{'Number'} . $size . $h{'Standard'};
2032     $output .= $line_end;
2033
2034     print $output;
2035 }
2036
2037 sub print_non_clf_message ($) {
2038
2039     my $content = shift;
2040     my $msec_string = "." . $req{$t}{'msecs'} unless $no_msecs_mode;
2041     my $line_start = $html_output_mode ? '' : $h{"Standard"};
2042
2043     return if DEBUG_SUPPRESS_LOG_MESSAGES;
2044
2045     print $line_start
2046         . $time_colours[$time_colour_index % 2]
2047         . $req{$t}{'time-stamp'}
2048         . $msec_string
2049         . $h{Standard} . " "
2050         . $thread_colours{$t}
2051         . $t
2052         . $h{Standard}
2053         . " "
2054         . $h{$req{$t}{'log-level'}}
2055         . $req{$t}{'log-level'}
2056         . $h{Standard}
2057         . ": "
2058         . $content
2059         . $line_end;
2060 }
2061
2062 sub shorten_thread_id ($) {
2063
2064     my $thread_id = shift;
2065
2066     our %short_thread_ids;
2067     our $max_threadid;
2068
2069     unless (defined $short_thread_ids{$thread_id}) {
2070         $short_thread_ids{$thread_id} = sprintf "%.3d", $max_threadid++;
2071     }
2072
2073     return $short_thread_ids{$thread_id}
2074 }
2075
2076 sub parse_loop () {
2077
2078     my ($day, $time_stamp, $thread, $log_level, $content, $c, $msecs);
2079     my $last_msecs  = 0;
2080     my $last_thread = 0;
2081     my $last_timestamp = 0;
2082     my $filters_that_did_nothing;
2083     my $key;
2084     my $time_colour;
2085     $time_colour = paint_it('white');
2086
2087     my %log_level_handlers = (
2088         'Re-Filter'         => \&handle_loglevel_re_filter,
2089         'Header'            => \&handle_loglevel_header,
2090         'Connect'           => \&handle_loglevel_connect,
2091         'Redirect'          => \&handle_loglevel_redirect,
2092         'Request'           => \&handle_loglevel_request,
2093         'Crunch'            => \&handle_loglevel_crunch,
2094         'Gif-Deanimate'     => \&handle_loglevel_gif_deanimate,
2095         'Info'              => \&handle_loglevel_info,
2096         'CGI'               => \&handle_loglevel_cgi,
2097         'Force'             => \&handle_loglevel_force,
2098         'Error'             => \&handle_loglevel_error,
2099         'Fatal error'       => \&handle_loglevel_ignore,
2100         'Writing'           => \&handle_loglevel_ignore,
2101         'Received'          => \&handle_loglevel_ignore,
2102         'Unknown log level' => \&handle_loglevel_ignore,
2103     );
2104
2105     while (<>) {
2106
2107         if (m/^(\w{3} \d{2}) (\d\d:\d\d:\d\d)\.?(\d+)? (?:Privoxy\()?([^\)\s]*)[\)]? ([\w -]*): (.*?)\r?$/) {
2108             $thread = $t = ($shorten_thread_ids) ? shorten_thread_id($4) : $4;
2109             $req{$t}{'day'} = $day = $1;
2110             $req{$t}{'time-stamp'} = $time_stamp = $2;
2111             $req{$t}{'msecs'} = $msecs = $3 ? $3 : 0; # Only the cool kids have micro second resolution;
2112             $req{$t}{'log-level'} = $log_level = $5;
2113             $req{$t}{'content'} = $content = $c = $6;
2114             $req{$t}{'log-message'} = $_;
2115             $no_special_header_highlighting = 0;
2116
2117             if (defined($log_level_handlers{$log_level})) {
2118
2119                 $content = $log_level_handlers{$log_level}($content);
2120
2121             } else {
2122
2123                 die "No handler found for log level \"$log_level\"\n";
2124             }
2125
2126             # Highlight Truncations
2127             if (length($_) > 4000) {
2128                 $content =~ s@(too long, truncated)]$@$h{'Truncation'}$1$h{'Standard'}]@g;
2129             }
2130
2131             next unless $content;
2132
2133             # Register threads to keep the colour constant
2134             if (!defined($thread_colours{$thread})) {
2135                 $thread_colours{$thread} = $all_colours[$thread_colour_index % @all_colours];
2136                 $thread_colour_index++;
2137             }
2138
2139             # Switch timestamp colour if timestamps differ
2140             if (($msecs ne $last_msecs) || ($time_stamp ne $last_timestamp)) {
2141                debug_message("Tick tack!") if DEBUG_TICKS;
2142                $time_colour = $time_colours[$time_colour_index % 2];
2143                $time_colour_index++;
2144                $last_msecs = $msecs;
2145                $last_timestamp = $time_stamp;
2146             }
2147
2148             $last_thread = $thread;
2149
2150             print_non_clf_message($content);
2151
2152         } elsif (m/^((?:\d+\.\d+\.\d+\.\d+|[:\d]+)) - - \[(.*)\] "(.*)" (\d+) (\d+)/) {
2153
2154             # LOG_LEVEL_CLF lines look like this
2155             # 61.152.239.32 - - [04/Mar/2007:18:28:23 +0100] "GET \
2156             #  http://ad.yieldmanager.com/imp?z=1&Z=120x600&s=109339&u=http%3A%2F%2Fwww.365loan.co.uk%2F&r=1\
2157             #  HTTP/1.1" 403 1730
2158             our ($ip, $timestamp, $request_line, $status_code, $size) = ($1, $2, $3, $4, $5);
2159
2160             print_clf_message();
2161
2162         } else {
2163
2164             # Some Privoxy log messages span more than one line,
2165             # usually to dump lots of content that doesn't need any syntax highlighting.
2166             # XXX: add mechanism to forward these lines to the right handler anyway.
2167             chomp();
2168             unless (DEBUG_SUPPRESS_LOG_MESSAGES or (SUPPRESS_EMPTY_LINES and m/^\s+$/)) {
2169                 print and print get_line_end(); # unless (SUPPRESS_EMPTY_LINES and m/^\s+$/);
2170             }
2171         }
2172     }
2173 }
2174
2175 sub stats_loop () {
2176
2177     my ($day, $time_stamp, $msecs, $thread, $log_level, $content);
2178     my %log_level_handlers = (
2179          'Re-Filter'         => \&handle_loglevel_ignore,
2180          'Header'            => \&gather_loglevel_header_stats,
2181          'Connect'           => \&gather_loglevel_connect_stats,
2182          'Redirect'          => \&handle_loglevel_ignore,
2183          'Request'           => \&gather_loglevel_request_stats,
2184          'Crunch'            => \&gather_loglevel_crunch_stats,
2185          'Gif-Deanimate'     => \&handle_loglevel_ignore,
2186          'Info'              => \&handle_loglevel_ignore,
2187          'CGI'               => \&handle_loglevel_ignore,
2188          'Force'             => \&handle_loglevel_ignore,
2189          'Error'             => \&gather_loglevel_error_stats,
2190          'Fatal error'       => \&handle_loglevel_ignore,
2191          'Writing'           => \&handle_loglevel_ignore,
2192          'Unknown log level' => \&handle_loglevel_ignore
2193     );
2194
2195     while (<>) {
2196         if (m/^(\w{3} \d{2}) (\d\d:\d\d:\d\d)\.?(\d+)? (?:Privoxy\()?([^\)\s]*)[\)]? ([\w -]*): (.*?)\r?$/) {
2197             $day = $1;
2198             $time_stamp = $2;
2199             $msecs = $3 ? $3 : 0;
2200             $thread = $4;
2201             $log_level = $5;
2202             $content = $6;
2203
2204             if (defined($log_level_handlers{$log_level})) {
2205
2206                 $content = $log_level_handlers{$log_level}($content, $thread);
2207
2208             } else {
2209
2210                 die "No handler found for log level \"$log_level\"\n";
2211
2212             }
2213         }
2214     }
2215
2216     print_stats();
2217
2218 }
2219
2220 sub VersionMessage {
2221     my $version_message;
2222
2223     $version_message .= 'Privoxy-Log-Parser ' . PRIVOXY_LOG_PARSER_VERSION  . "\n";
2224     $version_message .= 'Copyright (C) 2007-2010 Fabian Keil <fk@fabiankeil.de>' . "\n";
2225     $version_message .= 'http://www.fabiankeil.de/sourcecode/privoxy-log-parser/' . "\n";
2226
2227     print $version_message;
2228 }
2229
2230 sub get_cli_options () {
2231
2232     our %cli_options = (
2233         'html-output'              => CLI_OPTION_DEFAULT_TO_HTML_OUTPUT,
2234         'title'                    => CLI_OPTION_TITLE,
2235         'no-syntax-highlighting'   => CLI_OPTION_NO_SYNTAX_HIGHLIGHTING,
2236         'no-embedded-css'          => CLI_OPTION_NO_EMBEDDED_CSS,
2237         'no-msecs'                 => CLI_OPTION_NO_MSECS,
2238         'shorten-thread-ids'       => CLI_OPTION_SHORTEN_THREAD_IDS,
2239         'show-ineffective-filters' => CLI_OPTION_SHOW_INEFFECTIVE_FILTERS,
2240         'accept-unknown-messages'  => CLI_OPTION_ACCEPT_UNKNOWN_MESSAGES,
2241         'statistics'               => CLI_OPTION_STATISTICS,
2242     );
2243
2244     GetOptions (
2245         'html-output'              => \$cli_options{'html-output'},
2246         'title'                    => \$cli_options{'title'},
2247         'no-syntax-highlighting'   => \$cli_options{'no-syntax-highlighting'},
2248         'no-embedded-css'          => \$cli_options{'no-embedded-css'},
2249         'no-msecs'                 => \$cli_options{'no-msecs'},
2250         'shorten-thread-ids'       => \$cli_options{'shorten-thread-ids'},
2251         'show-ineffective-filters' => \$cli_options{'show-ineffective-filters'},
2252         'accept-unknown-messages'  => \$cli_options{'accept-unknown-messages'},
2253         'statistics'               => \$cli_options{'statistics'},
2254         'version'                  => sub { VersionMessage && exit(0) },
2255         'help'                     => \&help,
2256    ) or exit(1);
2257
2258    $html_output_mode = cli_option_is_set('html-output');
2259    $no_msecs_mode = cli_option_is_set('no-msecs');
2260    $shorten_thread_ids = cli_option_is_set('shorten-thread-ids');
2261    $line_end = get_line_end();
2262 }
2263
2264 sub help () {
2265
2266     our %cli_options;
2267
2268     VersionMessage();
2269
2270     print << "    EOF"
2271
2272 Options and their default values if they have any:
2273     [--accept-unknown-messages]
2274     [--html-output]
2275     [--no-embedded-css]
2276     [--no-msecs]
2277     [--no-syntax-highlighting]
2278     [--shorten-thread-ids]
2279     [--show-ineffective-filters]
2280     [--statistics]
2281     [--title $cli_options{'title'}]
2282     [--version]
2283 see "perldoc $0" for more information
2284     EOF
2285     ;
2286     exit(0);
2287 }
2288
2289 ################################################################################
2290 # main
2291 ################################################################################
2292 sub main () {
2293
2294     get_cli_options();
2295     set_background(DEFAULT_BACKGROUND);
2296     prepare_our_stuff();
2297
2298     print_intro();
2299
2300     if (cli_option_is_set('statistics')) {
2301         stats_loop();
2302     } else {
2303         parse_loop();
2304     }
2305
2306     print_outro();
2307 }
2308
2309 main();
2310
2311 =head1 NAME
2312
2313 B<privoxy-log-parser> - A parser and syntax-highlighter for Privoxy log messages
2314
2315 =head1 SYNOPSIS
2316
2317 B<privoxy-log-parser> [B<--accept-unknown-messages>] [B<--html-output>]
2318 [B<--no-msecs>] [B<--no-syntax-higlighting>] [B<--statistics>]
2319 [B<--shorten-thread-ids>] [B<--show-ineffective-filters>] [B<--version>]
2320
2321 =head1 DESCRIPTION
2322
2323 B<privoxy-log-parser> reads Privoxy log messages and
2324
2325 - syntax-highlights recognized lines,
2326
2327 - reformats some of them for easier comprehension,
2328
2329 - filters out less useful messages, and
2330
2331 - (in some cases) calculates additional information,
2332   like the compression ratio or how a filter affected
2333   the content size.
2334
2335 With B<privoxy-log-parser> you should be able to increase Privoxy's log level
2336 without getting confused by the resulting amount of output. For example for
2337 "debug 64" B<privoxy-log-parser> will (by default) only show messages that
2338 affect the content. If a filter doesn't cause any hits, B<privoxy-log-parser>
2339 will hide the "filter foo caused 0 hits" message.
2340
2341 =head1 OPTIONS
2342
2343 [B<--accept-unknown-messages>] Don't print warnings in case of unknown messages,
2344 just don't highlight them.
2345
2346 [B<--html-output>] Use HTML and CSS for the syntax highlighting. If this option is
2347 omitted, ANSI escape sequences are used unless B<--no-syntax-highlighting> is active.
2348 This option is only intended to make embedding log excerpts in web pages easier.
2349 It does not escape any input!
2350
2351 [B<--no-msecs>] Don't expect milisecond resolution
2352
2353 [B<--no-syntax-highlighting>] Disable syntax-highlighting. Useful when
2354 the filtered output is piped into less in which case the ANSI control
2355 codes don't work, or if the terminal itself doesn't support the control
2356 codes.
2357
2358 [B<--shorten-thread-ids>] Shorten the thread ids to a three-digit decimal number.
2359 Note that the mapping from thread ids to shortened ids is created at run-time
2360 and thus varies with the input.
2361
2362 [B<--show-ineffective-filters>] Don't suppress log lines for filters
2363 that didn't modify the content.
2364
2365 [B<--statistics>] Gather various statistics instead of syntax highlighting
2366 log messages. This is an experimental feature, if the results look wrong
2367 they very well might be. Also note that the results are pretty much guaranteed
2368 to be incorrect if Privoxy and Privoxy-Log-Parser aren't in sync.
2369
2370 [B<--version>] Print version and exit.
2371
2372 =head1 EXAMPLES
2373
2374 To monitor a log file:
2375
2376 tail -F /usr/jails/privoxy-jail/var/log/privoxy/privoxy.log | B<privoxy-log-parser>
2377
2378 Replace '-F' with '-f' if your tail implementation lacks '-F' support
2379 or if the log won't get rotated anyway. The log file location depends
2380 on your system (Doh!).
2381
2382 To monitor Privoxy without having it write to a log file:
2383
2384 privoxy --no-daemon /usr/jails/privoxy-jail/usr/local/etc/privoxy/config 2>&1 | B<privoxy-log-parser>
2385
2386 Again, the config file location depends on your system. Output redirection
2387 depends on your shell, the above works with bourne shells.
2388
2389 To read a processed Privoxy log file from top to bottom, letting the content
2390 scroll by slightly faster than you can read:
2391
2392 B<privoxy-log-parser> < /usr/jails/privoxy-jail/var/log/privoxy/privoxy.log
2393
2394 This is probably only useful to fill screens in the background of haxor movies.
2395
2396 =head1 CAVEATS
2397
2398 Syntax highlighting with ANSI escape sequences will look strange
2399 if your background color isn't black.
2400
2401 Some messages aren't recognized yet and will not be fully highlighted.
2402
2403 B<privoxy-log-parser> is developed with Privoxy 3.0.7 or later in mind,
2404 using earlier Privoxy versions will probably result in an increased amount
2405 of unrecognized log lines.
2406
2407 Privoxy's log files tend to be rather large. If you use HTML
2408 highlighting some browsers can't handle them, get confused and
2409 will eventually crash because of segmentation faults or unexpected
2410 exceptions. This is a problem in the browser and not B<privoxy-log-parser>'s
2411 fault.
2412
2413 =head1 BUGS
2414
2415 Many settings can't be controlled through command line options yet.
2416
2417 =head1 SEE ALSO
2418
2419 privoxy(1)
2420
2421 =head1 AUTHOR
2422
2423 Fabian Keil <fk@fabiankeil.de>
2424
2425 =cut