tools/privoxy-log-parser.pl

   1 #!/usr/bin/perl
   2
   3 ################################################################################
   4 # privoxy-log-parser
   5 #
   6 # A parser for Privoxy log messages. For incomplete documentation run
   7 # perldoc privoxy-log-parser(.pl), for fancy screenshots see:
   8 #
   9 # http://www.fabiankeil.de/sourcecode/privoxy-log-parser/
  10 #
  11 # $Id: privoxy-log-parser.pl,v 1.86 2010/07/26 11:28:52 fabiankeil Exp $
  12 #
  13 # TODO:
  14 #       - LOG_LEVEL_CGI, LOG_LEVEL_ERROR, LOG_LEVEL_WRITE content highlighting
  15 #       - create fancy statistics
  16 #       - grep through Privoxy sources to find unsupported log messages
  17 #       - hunt down substitutions that match content from variables which
  18 #         can contain stuff like ()?'[]
  19 #       - replace $h{'foo'} with h('foo') where possible
  20 #       - hunt down XXX comments instead of just creating them
  21 #       - add example log lines for every regex and mark them up for
  22 #         regression testing
  23 #       - Handle incomplete input without Perl warning about undefined variables.
  24 #       - Use generic highlighting function that takes a regex and the
  25 #         hash key as input.
  26 #
  27 # Copyright (c) 2007-2010 Fabian Keil <fk@fabiankeil.de>
  28 #
  29 # Permission to use, copy, modify, and distribute this software for any
  30 # purpose with or without fee is hereby granted, provided that the above
  31 # copyright notice and this permission notice appear in all copies.
  32 #
  33 # THE SOFTWARE IS PROVIDED "AS IS" AND THE AUTHOR DISCLAIMS ALL WARRANTIES
  34 # WITH REGARD TO THIS SOFTWARE INCLUDING ALL IMPLIED WARRANTIES OF
  35 # MERCHANTABILITY AND FITNESS. IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR
  36 # ANY SPECIAL, DIRECT, INDIRECT, OR CONSEQUENTIAL DAMAGES OR ANY DAMAGES
  37 # WHATSOEVER RESULTING FROM LOSS OF USE, DATA OR PROFITS, WHETHER IN AN
  38 # ACTION OF CONTRACT, NEGLIGENCE OR OTHER TORTIOUS ACTION, ARISING OUT OF
  39 # OR IN CONNECTION WITH THE USE OR PERFORMANCE OF THIS SOFTWARE.
  40 ################################################################################
  41
  42 use strict;
  43 use warnings;
  44 use Getopt::Long;
  45
  46 use constant {
  47     PRIVOXY_LOG_PARSER_VERSION => '0.6',
  48     # Feel free to mess with these ...
  49     DEFAULT_BACKGROUND => 'black',  # Choose registered colour (like 'black')
  50     DEFAULT_TEXT_COLOUR => 'white', # Choose registered colour (like 'black')
  51     HEADER_DEFAULT_COLOUR => 'yellow',
  52     REGISTER_HEADERS_WITH_THE_SAME_COLOUR => 1,
  53
  54     CLI_OPTION_DEFAULT_TO_HTML_OUTPUT => 0,
  55     CLI_OPTION_TITLE => 'Privoxy-Log-Parser in da house',
  56     CLI_OPTION_NO_EMBEDDED_CSS => 0,
  57     CLI_OPTION_NO_MSECS => 0,
  58     CLI_OPTION_NO_SYNTAX_HIGHLIGHTING => 0,
  59     CLI_OPTION_SHORTEN_THREAD_IDS => 0,
  60     CLI_OPTION_SHOW_INEFFECTIVE_FILTERS => 0,
  61     CLI_OPTION_ACCEPT_UNKNOWN_MESSAGES => 0,
  62     CLI_OPTION_STATISTICS => 0,
  63
  64     SUPPRESS_SUCCEEDED_FILTER_ADDITIONS => 1,
  65     SHOW_SCAN_INTRO => 0,
  66     SHOW_FILTER_READIN_IN => 0,
  67     SUPPRESS_EMPTY_LINES => 1,
  68     SUPPRESS_SUCCESSFUL_CONNECTIONS => 1,
  69     SUPPRESS_ACCEPTED_CONNECTIONS => 1,
  70     SUPPRESS_GIF_NOT_CHANGED => 1,
  71     SUPPRESS_NEED_TO_DE_CHUNK_FIRST => 1,
  72
  73     DEBUG_HEADER_REGISTERING => 0,
  74     DEBUG_HEADER_HIGHLIGHTING => 0,
  75     DEBUG_TICKS => 0,
  76     DEBUG_PAINT_IT => 0,
  77     DEBUG_SUPPRESS_LOG_MESSAGES => 0,
  78
  79     PUNISH_MISSING_LOG_KNOWLEDGE_WITH_DEATH => 0,
  80     PUNISH_MISSING_HIGHLIGHT_KNOWLEDGE_WITH_DEATH => 1,
  81
  82     LOG_UNPARSED_LINES_TO_EXTRA_FILE => 0,
  83     ERROR_LOG_FILE => '/var/log/privoxy-log-parser',
  84
  85     # You better leave these alone unless you know what you're doing.
  86     COLOUR_RESET      => "\033[0;0m",
  87     ESCAPE => "\033[",
  88 };
  89
  90 # For performance reasons, these are global.
  91
  92 my $t;
  93 my %req; # request data from previous lines
  94 my %h;
  95 my %thread_colours;
  96 my @all_colours;
  97 my @time_colours;
  98 my $thread_colour_index = 0;
  99 my $header_colour_index = 0;
 100 my $time_colour_index = 0;
 101 my %header_colours;
 102 my $no_special_header_highlighting;
 103 my %reason_colours;
 104 my %h_colours;
 105 my $header_highlight_regex = '';
 106
 107 my $html_output_mode;
 108 my $no_msecs_mode; # XXX: should probably be removed
 109 my $shorten_thread_ids;
 110 my $line_end;
 111
 112 sub prepare_our_stuff () {
 113
 114     # Syntax Higlight hash
 115     @all_colours = (
 116         'red', 'green', 'brown', 'blue', 'purple', 'cyan',
 117         'light_gray', 'light_red', 'light_green', 'yellow',
 118         'light_blue', 'pink', 'light_cyan', 'white'
 119     );
 120
 121     %h = (
 122         # LOG_LEVEL
 123         Info            => 'blue',
 124         Header          => 'green',
 125         Filter          => 'purple', # XXX: Used?
 126         'Re-Filter'     => 'purple',
 127         Connect         => 'brown',
 128         Request         => 'light_cyan',
 129         CGI             => 'light_green',
 130         Redirect        => 'cyan',
 131         Error           => 'light_red',
 132         Crunch          => 'cyan',
 133         'Fatal error'   => 'light_red',
 134         'Gif-Deanimate' => 'blue',
 135         Force           => 'red',
 136         Writing         => 'light_green',
 137         Received        => 'yellow',
 138         # ----------------------
 139         URL                  => 'yellow',
 140         path                 => 'brown',
 141         request_             => 'brown', # host+path but no protocol
 142         'ip-address'         => 'yellow',
 143         Number               => 'yellow',
 144         Standard             => 'reset',
 145         Truncation           => 'light_red',
 146         Status               => 'brown',
 147         Timestamp            => 'brown',
 148         Crunching            => 'light_red',
 149         crunched             => 'light_red',
 150         'Request-Line'       => 'pink',
 151         method               => 'purple',
 152         destination          => 'yellow',
 153         'http-version'       => 'pink',
 154         'crunch-pattern'     => 'pink',
 155         not                  => 'brown',
 156         file                 => 'brown',
 157         signal               => 'yellow',
 158         version              => 'green',
 159         'program-name'       => 'cyan',
 160         port                 => 'red',
 161         host                 => 'red',
 162         warning              => 'light_red',
 163         debug                => 'light_red',
 164         filter               => 'green',
 165         tag                  => 'green',
 166         tagger               => 'green',
 167         'status-message'     => 'light_cyan',
 168         'status-code'        => 'yellow',
 169         'invalid-request'    => 'light_red',
 170         'hits'               => 'yellow',
 171         error                => 'light_red',
 172         'rewritten-URL'      => 'light_red',
 173         'pcrs-delimiter'     => 'light_red',
 174         'ignored'            => 'light_red',
 175         'action-bits-update' => 'light_red',
 176         'configuration-line' => 'red',
 177         'content-type'       => 'yellow',
 178     );
 179
 180     %h_colours = %h;
 181
 182     # Header colours need their own hash so the keys can be accessed properly
 183     %header_colours = (
 184         # Prefilled with headers that should not appear with default header colours
 185         Cookie => 'light_red',
 186         'Set-Cookie' => 'light_red',
 187         Warning => 'light_red',
 188         Default => HEADER_DEFAULT_COLOUR,
 189     );
 190
 191     # Crunch reasons need their own hash as well
 192     %reason_colours = (
 193         'Unsupported HTTP feature'               => 'light_red',
 194         Blocked                                  => 'light_red',
 195         Untrusted                                => 'light_red',
 196         Redirected                               => 'green',
 197         'CGI Call'                               => 'white',
 198         'DNS failure'                            => 'red',
 199         'Forwarding failed'                      => 'light_red',
 200         'Connection failure'                     => 'light_red',
 201         'Out of memory (may mask other reasons)' => 'light_red',
 202         'No reason recorded'                     => 'light_red',
 203     );
 204
 205     @time_colours = ('white', 'light_gray');
 206
 207     # Translate highlight strings into highlight code
 208     prepare_highlight_hash(\%header_colours);
 209     prepare_highlight_hash(\%reason_colours);
 210     prepare_highlight_hash(\%h);
 211     prepare_colour_array(\@all_colours);
 212     prepare_colour_array(\@time_colours);
 213     init_css_colours();
 214
 215     init_stats();
 216 }
 217
 218 sub paint_it ($) {
 219 ###############################################################
 220 # Takes a colour string and returns an ANSI escape sequence
 221 # (unless --no-syntax-highlighting is used).
 222 # XXX: The Rolling Stones reference has to go.
 223 ###############################################################
 224
 225     my $colour = shift @_;
 226
 227     return "" if cli_option_is_set('no-syntax-highlighting');
 228
 229     my %light = (
 230         black       => 0,
 231         red         => 0,
 232         green       => 0,
 233         brown       => 0,
 234         blue        => 0,
 235         purple      => 0,
 236         cyan        => 0,
 237         light_gray  => 0,
 238         gray        => 0,
 239         dark_gray   => 1,
 240         light_red   => 1,
 241         light_green => 1,
 242         yellow      => 1,
 243         light_blue  => 1,
 244         pink        => 1,
 245         light_cyan  => 1,
 246         white       => 1,
 247     );
 248
 249     my %text = (
 250         black       => 30,
 251         red         => 31,
 252         green       => 32,
 253         brown       => 33,
 254         blue        => 34,
 255         purple      => 35,
 256         cyan        => 36,
 257         gray        => 37,
 258         light_gray  => 37,
 259         dark_gray   => 30,
 260         light_red   => 31,
 261         light_green => 32,
 262         yellow      => 33,
 263         light_blue  => 34,
 264         pink        => 35,
 265         light_cyan  => 36,
 266         white       => 37,
 267     );
 268
 269     my $bg_code = get_background();
 270     my $colour_code;
 271     our $default = default_colours();
 272
 273     if (defined($text{$colour})) {
 274         $colour_code  = ESCAPE;
 275         $colour_code .= $text{$colour};
 276         $colour_code .= ";";
 277         $colour_code .= $light{$colour} ? "1" : "2";
 278         $colour_code .= ";";
 279         $colour_code .= $bg_code;
 280         $colour_code .= "m";
 281         debug_message $colour . " is \'" . $colour_code . $colour . $default . "\'" if DEBUG_PAINT_IT;
 282
 283     } elsif ($colour =~ /reset/) {
 284
 285         $colour_code = default_colours();
 286
 287     } else {
 288
 289         die "What's $colour supposed to mean?\n";
 290     }
 291
 292     return $colour_code;
 293 }
 294
 295 sub get_semantic_html_markup ($) {
 296 ###############################################################
 297 # Takes a string and returns a span element
 298 ###############################################################
 299
 300     my $type = shift @_;
 301     my $code;
 302
 303     if ($type =~ /Standard/) {
 304         $code = '</span>';
 305     } else {
 306         $type = lc($type);
 307         $code = '<span title="' . $type . '" class="' . $type . '">';
 308     }
 309
 310     return $code;
 311 }
 312
 313 sub cli_option_is_set ($) {
 314
 315     our %cli_options;
 316     my $cli_option = shift;
 317
 318     die "Unknown CLI option: $cli_option" unless defined $cli_options{$cli_option};
 319
 320     return $cli_options{$cli_option};
 321 }
 322
 323 sub get_html_title () {
 324
 325     our %cli_options;
 326     return $cli_options{'title'};
 327
 328 }
 329
 330 sub init_css_colours() {
 331
 332     our %css_colours = (
 333         black       => "000",
 334         red         => "F00",
 335         green       => "0F0",
 336         brown       => "C90",
 337         blue        => "0F0",
 338         purple      => "F06", # XXX: wrong
 339         cyan        => "F09", # XXX: wrong
 340         light_gray  => "999",
 341         gray        => "333",
 342         dark_gray   => "222",
 343         light_red   => "F33",
 344         light_green => "33F",
 345         yellow      => "FF0",
 346         light_blue  => "30F",
 347         pink        => "F0F",
 348         light_cyan  => "66F",
 349         white       => "FFF",
 350     );
 351 }
 352
 353 sub get_css_colour ($) {
 354
 355    our %css_colours;
 356    my $colour = shift;
 357
 358    die "What's $colour supposed to mean?\n" unless defined($css_colours{$colour});
 359
 360    return '#' . $css_colours{$colour};
 361 }
 362
 363 sub get_css_line ($) {
 364
 365     my $class = shift;
 366     my $css_line;
 367
 368     $css_line .= '.' . lc($class) . ' {'; # XXX: lc() shouldn't be necessary
 369     die "What's $class supposed to mean?\n" unless defined($h_colours{$class});
 370     $css_line .= 'color:' . get_css_colour($h_colours{$class}) . ';';
 371     $css_line .= 'background-color:' . get_css_colour(DEFAULT_BACKGROUND) . ';';
 372     $css_line .= '}' . "\n";
 373
 374     return $css_line;
 375 }
 376
 377 sub get_css_line_for_colour ($) {
 378
 379     my $colour = shift;
 380     my $css_line;
 381
 382     $css_line .= '.' . lc($colour) . ' {'; # XXX: lc() shouldn't be necessary
 383     $css_line .= 'color:' . get_css_colour($colour) . ';';
 384     $css_line .= 'background-color:' . get_css_colour(DEFAULT_BACKGROUND) . ';';
 385     $css_line .= '}' . "\n";
 386
 387     return $css_line;
 388 }
 389
 390 # XXX: Wrong solution
 391 sub get_missing_css_lines () {
 392
 393     my $css_line;
 394
 395     $css_line .= '.' . 'default' . ' {';
 396     $css_line .= 'color:' . HEADER_DEFAULT_COLOUR . ';';
 397     $css_line .= 'background-color:' . get_css_colour(DEFAULT_BACKGROUND) . ';';
 398     $css_line .= '}' . "\n";
 399
 400     return $css_line;
 401 }
 402
 403 sub get_css () {
 404
 405     our %css_colours; #XXX: Wrong solution
 406
 407     my $css = '';
 408
 409     $css .= '.privoxy-log {';
 410     $css .= 'color:' . get_css_colour(DEFAULT_TEXT_COLOUR) . ';';
 411     $css .= 'background-color:' . get_css_colour(DEFAULT_BACKGROUND) . ';';
 412     $css .= '}' . "\n";
 413
 414     foreach my $key (keys %h_colours) {
 415
 416         next if ($h_colours{$key} =~ m/reset/); #XXX: Wrong solution.
 417         $css .= get_css_line($key);
 418
 419     }
 420
 421     foreach my $colour (keys %css_colours) {
 422
 423         $css .= get_css_line_for_colour($colour);
 424
 425     }
 426
 427     $css .= get_missing_css_lines(); #XXX: Wrong solution
 428
 429     return $css;
 430 }
 431
 432 sub print_intro () {
 433
 434     my $intro = '';
 435
 436     if (cli_option_is_set('html-output')) {
 437
 438         my $title = get_html_title();
 439
 440         $intro .= '<html><head>';
 441         $intro .= '<title>' . $title . '</title>';
 442         $intro .= '<style>' . get_css() . '</style>' unless cli_option_is_set('no-embedded-css');
 443         $intro .= '</head><body>';
 444         $intro .= '<h1>' . $title . '</h1><p class="privoxy-log">';
 445
 446         print $intro;
 447     }
 448 }
 449
 450 sub print_outro () {
 451
 452     my $outro = '';
 453
 454     if (cli_option_is_set('html-output')) {
 455
 456         $outro = '</p></body></html>';
 457         print $outro;
 458
 459     }
 460 }
 461
 462 sub get_line_end () {
 463     return cli_option_is_set('html-output') ? "<br>\n" : "\n";
 464 }
 465
 466 sub get_colour_html_markup ($) {
 467 ###############################################################
 468 # Takes a colour string a span element. XXX: WHAT?
 469 # XXX: This function shouldn't be necessary, the
 470 # markup should always be semantically correct.
 471 ###############################################################
 472
 473     my $type = shift @_;
 474     my $code;
 475
 476     if ($type =~ /Standard/) {
 477         $code = '</span>';
 478     } else {
 479         $code = '<span class="' . lc($type) . '">';
 480     }
 481
 482     return $code;
 483 }
 484
 485 sub default_colours () {
 486     # XXX: Properly
 487     our $bg_code;
 488     return reset_colours();
 489 }
 490
 491 sub show_colours () {
 492     # XXX: Implement
 493 }
 494
 495 sub reset_colours () {
 496     return ESCAPE . "0m";
 497 }
 498
 499 sub set_background ($){
 500
 501     my $colour = shift;
 502     our $bg_code;
 503     my %backgrounds = (
 504               black       => "40",
 505               red         => "41",
 506               green       => "42",
 507               brown       => "43",
 508               blue        => "44",
 509               magenta     => "45",
 510               cyan        => "46",
 511               white       => "47",
 512               default     => "49",
 513     );
 514
 515     if (defined($backgrounds{$colour})) {
 516         $bg_code = $backgrounds{$colour};
 517     } else {
 518         die "Invalid background colour: " . $colour;
 519     }
 520 }
 521
 522 sub get_background (){
 523     return our $bg_code;
 524 }
 525
 526 sub prepare_highlight_hash ($) {
 527     my $ref = shift;
 528
 529     foreach my $key (keys %$ref) {
 530         $$ref{$key} = $html_output_mode ?
 531             get_semantic_html_markup($key) :
 532             paint_it($$ref{$key});
 533     }
 534 }
 535
 536 sub prepare_colour_array ($) {
 537     my $ref = shift;
 538
 539     foreach my $i (0 ... @$ref - 1) {
 540         $$ref[$i] = $html_output_mode ?
 541             get_colour_html_markup($$ref[$i]) :
 542             paint_it($$ref[$i]);
 543     }
 544 }
 545
 546 sub found_unknown_content ($) {
 547
 548     my $unknown = shift;
 549     my $message;
 550
 551     return if cli_option_is_set('accept-unknown-messages');
 552
 553     return if ($unknown =~ /\[too long, truncated\]$/);
 554
 555     $message = "found_unknown_content: Don't know how to highlight: ";
 556     # Break line so the log file can later be parsed as Privoxy log file again
 557     $message .= '"' . $unknown . '"' . " in:\n";
 558     $message .= $req{$t}{'log-message'};
 559     debug_message($message);
 560     log_parse_error($req{$t}{'log-message'});
 561
 562     die "Unworthy content parser" if PUNISH_MISSING_LOG_KNOWLEDGE_WITH_DEATH;
 563 }
 564
 565 sub log_parse_error ($) {
 566
 567     my $message = shift;
 568
 569     if (LOG_UNPARSED_LINES_TO_EXTRA_FILE) {
 570         open(ERRORLOG, ">>" . ERROR_LOG_FILE) || die "Writing " . ERROR_LOG_FILE . " failed";
 571         print ERRORLOG $message;
 572         close(ERRORLOG);
 573     }
 574 }
 575
 576 sub debug_message (@) {
 577     my @message = @_;
 578
 579     print $h{'debug'} . "@message" . $h{'Standard'} . "\n";
 580 }
 581
 582 ################################################################################
 583 # highlighter functions that aren't loglevel-specific
 584 ################################################################################
 585
 586 sub h ($) {
 587
 588     # Get highlight marker
 589     my $highlight = shift; # XXX: Stupid name;
 590     my $result = '';
 591     my $message;
 592
 593     if (defined($highlight)) {
 594
 595         $result = $h{$highlight};
 596
 597     } else {
 598
 599         $message = "h: Don't recognize highlighter $highlight.";
 600         debug_message($message);
 601         log_parser_error($message);
 602         die "Unworthy highlighter function" if PUNISH_MISSING_HIGHLIGHT_KNOWLEDGE_WITH_DEATH;
 603     }
 604
 605     return $result;
 606 }
 607
 608 sub highlight_known_headers ($) {
 609
 610     my $content = shift;
 611
 612     debug_message("Searching $content for things to highlight.") if DEBUG_HEADER_HIGHLIGHTING;
 613
 614     if ($content =~ m/(?<=\s)($header_highlight_regex):/) {
 615         my $header = $1;
 616         $content =~ s@(?<=[\s|'])($header)(?=:)@$header_colours{$header}$1$h{'Standard'}@ig;
 617         debug_message("Highlighted '$header' in '$content'") if DEBUG_HEADER_HIGHLIGHTING;
 618     }
 619
 620     return $content;
 621 }
 622
 623 sub highlight_matched_request_line ($$) {
 624
 625     my $result = shift; # XXX: Stupid name;
 626     my $regex = shift;
 627     if ($result =~ m@(.*)($regex)(.*)@) {
 628         $result = $1 . highlight_request_line($2) . $3
 629     }
 630     return $result;
 631 }
 632
 633 sub highlight_request_line ($) {
 634
 635     my $rl = shift;
 636     my ($method, $url, $http_version);
 637
 638     #GET http://images.sourceforge.net/sfx/icon_warning.gif HTTP/1.1
 639     if ($rl =~ m/Invalid request/) {
 640
 641         $rl = h('invalid-request') . $rl . h('Standard');
 642
 643     } elsif ($rl =~ m/^([-\w]+) (.*) (HTTP\/\d\.\d)/) {
 644
 645         # XXX: might not match in case of HTTP method fuzzing.
 646         # XXX: save these: ($method, $path, $http_version) = ($1, $2, $3);
 647         $rl =~ s@^(\w+)@$h{'method'}$1$h{'Standard'}@;
 648         if ($rl =~ /http:\/\//) {
 649             $rl = highlight_matched_url($rl, '[^\s]*(?=\sHTTP)');
 650         } else {
 651             $rl = highlight_matched_pattern($rl, 'request_', '[^\s]*(?=\sHTTP)');
 652         }
 653
 654         $rl =~ s@(HTTP\/\d\.\d)$@$h{'http-version'}$1$h{'Standard'}@;
 655
 656     } elsif ($rl =~ m/\.\.\. \[too long, truncated\]$/) {
 657
 658         $rl =~ s@^(\w+)@$h{'method'}$1$h{'Standard'}@;
 659         $rl = highlight_matched_url($rl, '[^\s]*(?=\.\.\.)');
 660
 661     } elsif ($rl =~ m/^ $/) {
 662
 663         $rl = h('error') . "No request line specified!" . h('Standard');
 664
 665     } else {
 666
 667         debug_message ("Can't parse request line: $rl");
 668
 669     }
 670
 671     return $rl;
 672 }
 673
 674 sub highlight_response_line ($) {
 675
 676     my $rl = shift;
 677     my ($http_version, $status_code, $status_message);
 678
 679     #HTTP/1.1 200 OK
 680     #ICY 200 OK
 681
 682     # TODO: Mark different status codes differently
 683
 684     if ($rl =~ m/((?:HTTP\/\d\.\d|ICY)) (\d+) (.*)/) {
 685         ($http_version, $status_code, $status_message) = ($1, $2, $3);
 686     } else {
 687         debug_message ("Can't parse response line: $rl") and die 'Fix this';
 688     }
 689
 690     # Rebuild highlighted
 691     $rl= "";
 692     $rl .= h('http-version') . $http_version . h('Standard');
 693     $rl .= " ";
 694     $rl .= h('status-code') . $status_code . h('Standard');
 695     $rl .= " ";
 696     $rl .= h('status-message') . $status_message . h('Standard');
 697
 698     return $rl;
 699 }
 700
 701 sub highlight_matched_url ($$) {
 702
 703     my $result = shift; # XXX: Stupid name;
 704     my $regex = shift;
 705
 706     #print "Got $result, regex ($regex)\n";
 707
 708     if ($result =~ m@(.*?)($regex)(.*)@) {
 709         $result = $1 . highlight_url($2) . $3;
 710         #print "Now the result is $result\n";
 711     }
 712
 713     return $result;
 714 }
 715
 716 sub highlight_matched_host ($$) {
 717
 718     my ($result, $regex) = @_; # XXX: result ist stupid name;
 719
 720     if ($result =~ m@(.*?)($regex)(.*)@) {
 721         $result = $1 . $h{host} . $2 . $h{Standard} . $3;
 722     }
 723
 724     return $result;
 725 }
 726
 727 sub highlight_matched_pattern ($$$) {
 728
 729     my $result = shift; # XXX: Stupid name;
 730     my $key = shift;
 731     my $regex = shift;
 732
 733     die "Unknown key $key" unless defined $h{$key};
 734
 735     if ($result =~ m@(.*?)($regex)(.*)@) {
 736         $result = $1 . h($key) . $2 . h('Standard') . $3;
 737     }
 738
 739     return $result;
 740 }
 741
 742 sub highlight_matched_path ($$) {
 743
 744     my $result = shift; # XXX: Stupid name;
 745     my $regex = shift;
 746
 747     if ($result =~ m@(.*?)($regex)(.*)@) {
 748         $result = $1 . h('path') . $2 . h('Standard') . $3;
 749     }
 750
 751     return $result;
 752 }
 753
 754 sub highlight_url ($) {
 755
 756     my $url = shift;
 757
 758     if ($html_output_mode) {
 759
 760         $url = '<a href="' . $url . '">' . $url . '</a>';
 761
 762     } else {
 763
 764         $url = h('URL') . $url . h('Standard');
 765
 766     }
 767
 768     return $url;
 769 }
 770
 771 sub update_header_highlight_regex ($) {
 772
 773     my $header = shift;
 774     my $headers = join ('|', keys %header_colours);
 775
 776     $header_highlight_regex = qr/$headers/;
 777     print "Registering '$header'\n" if DEBUG_HEADER_HIGHLIGHTING;
 778 }
 779
 780 ################################################################################
 781 # loglevel-specific highlighter functions
 782 ################################################################################
 783
 784 sub handle_loglevel_header ($) {
 785
 786     my $c = shift;
 787
 788     if ($c =~ /^scan:/) {
 789
 790         if ($c =~ m/^scan: ([^: ]+):/) {
 791
 792             # Register new headers
 793             # scan: Accept: image/png,image/*;q=0.8,*/*;q=0.5
 794             my $header = $1;
 795             if (!defined($header_colours{$header}) and $header =~ /^[\d\w-]*$/) {
 796                 debug_message "Registering previously unknown header $1" if DEBUG_HEADER_REGISTERING;
 797
 798                 if (REGISTER_HEADERS_WITH_THE_SAME_COLOUR) {
 799                     $header_colours{$header} =  $header_colours{'Default'};
 800                 } else {
 801                     $header_colours{$header} = $all_colours[$header_colour_index % @all_colours];
 802                     $header_colour_index++;
 803                 }
 804                 update_header_highlight_regex($header);
 805             }
 806
 807         } elsif ($c =~ m/^scan: ((\w+) (.+) (HTTP\/\d\.\d))/) {
 808
 809             # Client request line
 810             # Save for statistics (XXX: Not implemented yet)
 811             $req{$t}{'method'} = $2;
 812             $req{$t}{'destination'} = $3;
 813             $req{$t}{'http-version'} = $4;
 814
 815             $c = highlight_request_line($1);
 816
 817         } elsif ($c =~ m/^(scan: )((?:HTTP\/\d\.\d|ICY) (\d+) (.*))/) {
 818
 819             # Server response line
 820             $req{$t}{'response_line'} = $2;
 821             $req{$t}{'status_code'} = $3;
 822             $req{$t}{'status_message'} = $4;
 823             $c = $1 . highlight_response_line($req{$t}{'response_line'});
 824         }
 825
 826     } elsif ($c =~ m/^Crunching (?:server|client) header: .* \(contains: ([^\)]*)\)/) {
 827
 828         # Crunching server header: Set-Cookie: trac_form_token=d5308c34e16d15e9e301a456; (contains: Cookie:)
 829         $c =~ s@(?<=contains: )($1)@$h{'crunch-pattern'}$1$h{'Standard'}@;
 830         $c =~ s@(Crunching)@$h{$1}$1$h{'Standard'}@;
 831
 832     } elsif ($c =~ m/^New host is: ([^\s]*)\./) {
 833
 834         # New host is: trac.vidalia-project.net. Crunching Referer: http://www.vidalia-project.net/!
 835         $c = highlight_matched_host($c, '(?<=New host is: )[^\s]+(?=\.)');
 836         $c = highlight_matched_url($c, '(?<=Crunching Referer: )[^\s!]+');
 837
 838     } elsif ($c =~ m/^Text mode enabled by force. (Take cover)!/) {
 839
 840         # Text mode enabled by force. Take cover!
 841         $c =~ s@($1)@$h{'warning'}$1$h{'Standard'}@;
 842
 843     } elsif ($c =~ m/^(New HTTP Request-Line: )(.*)/) {
 844
 845         # New HTTP Request-Line: GET http://www.privoxy.org/ HTTP/1.1
 846         $c = $1 . highlight_request_line($2);
 847
 848     } elsif ($c =~ m/^Adjust(ed)? Content-Length to \d+/) {
 849
 850         # Adjusted Content-Length to 2132
 851         # Adjust Content-Length to 33533
 852         $c =~ s@(?<=Content-Length to )(\d+)@$h{'Number'}$1$h{'Standard'}@;
 853         $c = highlight_known_headers($c);
 854
 855     } elsif ($c =~ m/^Destination extracted from "Host:" header. New request URL:/) {
 856
 857         # Destination extracted from "Host:" header. New request URL: http://www.cccmz.de/~ridcully/blog/
 858         $c = highlight_matched_url($c, '(?<=New request URL: ).*');
 859
 860     } elsif ($c =~ m/^Couldn\'t parse:/) {
 861
 862         # XXX: These should probable be logged with LOG_LEVEL_ERROR
 863         # Couldn't parse: If-Modified-Since: Wed, 21 Mar 2007 16:34:50 GMT (crunching!)
 864         # Couldn't parse: at, 24 Mar 2007 13:46:21 GMT in If-Modified-Since: Sat, 24 Mar 2007 13:46:21 GMT (crunching!)
 865         $c =~ s@^(Couldn\'t parse)@$h{'error'}$1$h{'Standard'}@;
 866
 867     } elsif ($c =~ /^Tagger \'([^\']*)\' added tag \'([^\']*)\'/ or
 868              $c =~ m/^Adding tag \'([^\']*)\' created by header tagger \'([^\']*)\'/) {
 869
 870         # Adding tag 'GET request' created by header tagger 'method-man' (XXX: no longer used)
 871         # Tagger 'revalidation' added tag 'REVALIDATION-REQUEST'. No action bit update necessary.
 872         # Tagger 'revalidation' added tag 'REVALIDATION-REQUEST'. Action bits updated accordingly.
 873
 874         # XXX: Save tag and tagger
 875
 876         $c =~ s@(?<=^Tagger \')([^\']*)@$h{'tagger'}$1$h{'Standard'}@;
 877         $c =~ s@(?<=added tag \')([^\']*)@$h{'tag'}$1$h{'Standard'}@;
 878         $c =~ s@(?<=Action bits )(updated)@$h{'action-bits-update'}$1$h{'Standard'}@;
 879         $no_special_header_highlighting = 1;
 880
 881     } elsif ($c =~ /^Tagger \'([^\']*)\' didn['']t add tag \'([^\']*)\'/) {
 882
 883         # Tagger 'revalidation' didn't add tag 'REVALIDATION-REQUEST'. Tag already present
 884         # XXX: Save tag and tagger
 885
 886         $c =~ s@(?<=^Tagger \')([^\']*)@$h{'tag'}$1$h{'Standard'}@;
 887         $c =~ s@(?<=didn['']t add tag \')([^\']*)@$h{'tagger'}$1$h{'Standard'}@;
 888
 889     } elsif ($c =~ m/^(?:scan:|Randomiz|addh:|Adding:|Removing:|Referer:|Modified:|Accept-Language header|[Cc]ookie)/
 890           or $c =~ m/^(Text mode is already enabled|Denied request with NULL byte|Replaced:|add-unique:)/
 891           or $c =~ m/^(Crunched (incoming|outgoing) cookie|Suppressed offer|Accepted the client)/
 892           or $c =~ m/^(addh-unique|Referer forged to)/
 893           or $c =~ m/^Downgraded answer to HTTP\/1.0/
 894           or $c =~ m/^Parameter: \+hide-referrer\{[^\}]*\} is a bad idea, but I don\'t care./
 895           or $c =~ m/^Referer (?:overwritten|replaced) with: Referer: / #XXX: should this be highlighted?
 896           or $c =~ m/^Referer crunched!/
 897           or $c =~ m/^crunched x-forwarded-for!/
 898           or $c =~ m/^crunched From!/
 899           or $c =~ m/^ modified$/
 900           or $c =~ m/^Content filtering is enabled. Crunching:/
 901           or $c =~ m/^force-text-mode overruled the client/
 902           or $c =~ m/^Server time in the future\./
 903           or $c =~ m/^content-disposition header crunched and replaced with:/i
 904           or $c =~ m/^Reducing white space in /
 905           or $c =~ m/^Ignoring single quote in /
 906           or $c =~ m/^Converting tab to space in /
 907           or $c =~ m/A HTTP\/1\.1 response without/
 908           or $c =~ m/Disabled filter mode on behalf of the client/
 909           or $c =~ m/Keeping the (?:server|client) header /
 910           or $c =~ m/Content modified with no Content-Length header set/
 911           or $c =~ m/^Appended client IP address to/
 912           or $c =~ m/^Removing 'Connection: close' to imply keep-alive./
 913           or $c =~ m/^keep-alive support is disabled/
 914           or $c =~ m/^Continue hack in da house/
 915             )
 916     {
 917         # XXX: Some of these may need highlighting
 918
 919         # Modified: User-Agent: Mozilla/5.0 (X11; U; SunOS i86pc; pl-PL; rv:1.8.1.1) Gecko/20070214 Firefox/2.0.0.1
 920         # Accept-Language header crunched and replaced with: Accept-Language: pl-pl
 921         # cookie 'Set-Cookie: eZSessionCookie=07bfec287c197440d299f81580593c3d; \
 922         #  expires=Thursday, 12-Apr-07 15:16:18 GMT; path=/' send by \
 923         #  http://wirres.net/article/articleview/4265/1/6/ appears to be using time format 1 (XXX: gone with the wind)
 924         # Cookie rewritten to a temporary one: Set-Cookie: NSC_gffe-iuuq-mc-wtfswfs=8efb33a53660;path=/
 925         # Text mode is already enabled
 926         # Denied request with NULL byte(s) turned into line break(s)
 927         # Replaced: 'Connection: Yo, home to Bel Air' with 'Connection: close'
 928         # addh-unique: Host: people.freebsd.org
 929         # Suppressed offer to compress content
 930         # Crunched incoming cookie -- yum!
 931         # Accepted the client's request to fetch without filtering.
 932         # Crunched outgoing cookie: Cookie: PREF=ID=6cf0abd347b30262:TM=1173357617:LM=1173357617:S=jZypyyJ7LPiwFi1_
 933         # addh-unique: Host: subkeys.pgp.net:11371
 934         # Referer forged to: Referer: http://10.0.0.1/
 935         # Downgraded answer to HTTP/1.0
 936         # Parameter: +hide-referrer{pille-palle} is a bad idea, but I don't care.
 937         # Referer overwritten with: Referer: pille-palle
 938         # Referer replaced with: Referer: pille-palle
 939         # crunched x-forwarded-for!
 940         # crunched From!
 941         #  modified # XXX: pretty stupid log message
 942         # Content filtering is enabled. Crunching: 'Range: 1234-5678' to prevent range-mismatch problems
 943         # force-text-mode overruled the client's request to fetch without filtering!
 944         # Server time in the future.
 945         # content-disposition header crunched and replaced with: content-disposition: filename=baz
 946         # Content-Disposition header crunched and replaced with: content-disposition: filename=baz
 947         # Reducing white space in 'X-LWS-Test: "This  is  quoted" this is not "this  is  " but " this again   is  not'
 948         # Ignoring single quote in 'X-LWS-Test: "This  is  quoted" this is not "this  is  " but "  this again   is  not'
 949         # Converting tab to space in 'X-LWS-Test:   "This  is  quoted" this   is  not "this  is  "  but  "\
 950         #  this again   is  not'
 951         # A HTTP/1.1 response without Connection header implies keep-alive.
 952         # Disabled filter mode on behalf of the client.
 953         # Keeping the server header 'Connection: keep-alive' around.
 954         # Keeping the client header 'Connection: close' around. The connection will not be kept alive.
 955         # Keeping the client header 'Connection: keep-alive' around. The connection will be kept alive if possible.
 956         # Content modified with no Content-Length header set. Creating a fake one for adjustment later on.
 957         # Appended client IP address to X-Forwarded-For: 10.0.0.2, 10.0.0.1
 958         # Removing 'Connection: close' to imply keep-alive.
 959         # keep-alive support is disabled. Crunching: Keep-Alive: 300.
 960         # Continue hack in da house.
 961
 962     } elsif ($c =~ m/^scanning headers for:/) {
 963
 964         return '' unless SHOW_SCAN_INTRO;
 965
 966     } elsif ($c =~ m/^[Cc]runch(ing|ed)|crumble crunched:/) {
 967         # crunched User-Agent!
 968         # Crunching: Content-Encoding: gzip
 969
 970         $c =~ s@(Crunching|crunched)@$h{$1}$1$h{'Standard'}@;
 971
 972     } elsif ($c =~ m/^Offending request data with NULL bytes turned into \'°\' characters:/) {
 973
 974         # Offending request data with NULL bytes turned into '°' characters: °°n°°(°°°
 975
 976         $c = h('warning') . $c . h('Standard');
 977
 978     } elsif ($c =~ m/^(Transforming \")(.*?)(\" to \")(.*?)(\")/) {
 979
 980         # Transforming "Proxy-Authenticate: Basic realm="Correos Proxy Server"" to\
 981         #  "Proxy-Authenticate: Basic realm="Correos Proxy Server""
 982
 983        $c =~ s@(?<=^Transforming \")(.*)(?=\" to)@$h{'Header'}$1$h{'Standard'}@;
 984        $c =~ s@(?<=to \")(.*)(?=\")@$h{'Header'}$1$h{'Standard'}@;
 985
 986     } elsif ($c =~ m/^Removing empty header/) {
 987
 988         # Removing empty header
 989         # Ignore for now
 990
 991     } elsif ($c =~ m/^Content-Type: .* not replaced/) {
 992
 993         # Content-Type: application/octet-stream not replaced. It doesn't look like text.\
 994         #  Enable force-text-mode if you know what you're doing.
 995         # XXX: Could highlight more here.
 996         $c =~ s@(?<=^Content-Type: )(.*)(?= not replaced)@$h{'content-type'}$1$h{'Standard'}@;
 997
 998     } elsif ($c =~ m/^(Server|Client) keep-alive timeout is/) {
 999
1000        # Server keep-alive timeout is 5. Sticking with 10.
1001        # Client keep-alive timeout is 20. Sticking with 10.
1002
1003        $c =~ s@(?<=timeout is )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1004        $c =~ s@(?<=Sticking with )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1005
1006     } elsif ($c =~ m/^Reducing keep-alive timeout/) {
1007
1008        # Reducing keep-alive timeout from 60 to 10.
1009
1010        $c =~ s@(?<= from )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1011        $c =~ s@(?<= to )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1012
1013     } else {
1014
1015         found_unknown_content($c);
1016     }
1017
1018     # Highlight headers
1019     unless ($c =~ m/^Transforming/) {
1020         $c = highlight_known_headers($c) unless $no_special_header_highlighting;
1021     }
1022
1023     return $c;
1024 }
1025
1026 sub handle_loglevel_re_filter ($) {
1027
1028     my $content = shift;
1029     my $c = $content;
1030     my $key;
1031
1032     if ($c =~ m/^(?:re_)?filtering ([^\s]+) \(size (\d+)\) with (?:filter )?\'?([^\s]+?)\'? produced (\d+) hits \(new size (\d+)\)/) {
1033
1034         # XXX: only the second version gets highlighted properly.
1035         # re_filtering www.lfk.de/favicon.ico (size 209) with filter untrackable-hulk produced 0 hits (new size 209).
1036         # filtering aci.blogg.de/ (size 37988) with 'blogg.de' produced 3 hits (new size 38057)
1037         $req{$t}{'content_source'} = $1;
1038         $req{$t}{'content_size'}   = $2;
1039         $req{$t}{'content_filter'} = $3;
1040         $req{$t}{'content_hits'}   = $4;
1041         $req{$t}{'new_content_size'} = $5;
1042         $req{$t}{'content_size_change'} = $req{$t}{'new_content_size'} - $req{$t}{'content_size'};
1043         #return '' if ($req{$t}{'content_hits'} == 0 && !cli_option_is_set('show-ineffective-filters'));
1044         if ($req{$t}{'content_hits'} == 0 and
1045             not (cli_option_is_set('show-ineffective-filters')
1046                  or ($req{$t}{'content_filter'} =~ m/^privoxy-filter-test$/))) {
1047                 return '';
1048         }
1049
1050         $c =~ s@(?<=\(size )(\d+)\)(?= with)@$h{'Number'}$1$h{'Standard'}@;
1051         $c =~ s@(?<=\(new size )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1052         $c =~ s@(?<=produced )(\d+)(?= hits)@$h{'Number'}$1$h{'Standard'}@;
1053
1054         $c =~ s@([^\s]+?)(\'? produced)@$h{'filter'}$1$h{'Standard'}$2@;
1055         $c = highlight_matched_host($c, '(?<=filtering )[^\s]+');
1056
1057         $c =~ s@\.$@ @;
1058         $c .= "(" . $h{'Number'};
1059         $c .= "+" if ($req{$t}{'content_size_change'} >= 0);
1060         $c .= $req{$t}{'content_size_change'} . $h{'Standard'} . ")";
1061         $content = $c;
1062
1063   } elsif ($c =~ /\.{3}$/
1064         and $c =~ m/^(?:re_)?filtering \'?(.*?)\'? \(size (\d*)\) with (?:filter )?\'?([^\s]*?)\'? ?\.{3}$/) {
1065
1066         # Used by Privoxy 3.0.5 and 3.0.6:
1067         # XXX: Fill in ...
1068         # Used by Privoxy 3.0.7:
1069         # filtering 'Connection: close' (size 17) with 'generic-content-ads' ...
1070
1071         $req{$t}{'filtered_header'} = $1;
1072         $req{$t}{'old_header_size'} = $2;
1073         $req{$t}{'header_filter_name'} = $3;
1074
1075         unless (cli_option_is_set('show-ineffective-filters') or
1076                 $req{$t}{'header_filter_name'} =~ m/^privoxy-filter-test$/) {
1077             return '';
1078         }
1079         $content =~ s@(?<=\(size )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1080         $content =~ s@($req{$t}{'header_filter_name'})@$h{'filter'}$1$h{'Standard'}@;
1081
1082     } elsif ($c =~ m/^ ?\.\.\. ?produced (\d*) hits \(new size (\d*)\)\./) {
1083
1084         # ...produced 0 hits (new size 23).
1085         #... produced 1 hits (new size 54).
1086
1087         $req{$t}{'header_filter_hits'} = $1;
1088         $req{$t}{'new_header_size'} = $2;
1089
1090         unless (cli_option_is_set('show-ineffective-filters') or
1091                 (defined($req{$t}{'header_filter_name'}) and
1092                  $req{$t}{'header_filter_name'} =~ m/^privoxy-filter-test$/)) {
1093
1094             if ($req{$t}{'header_filter_hits'} == 0 and
1095                 not (defined($req{$t}{'header_filter_name'}) and
1096                  $req{$t}{'header_filter_name'} =~ m/^privoxy-filter-test$/)) {
1097                 return '';
1098             }
1099             # Reformat including information from the intro
1100             $c = "'" . h('filter') . $req{$t}{'header_filter_name'} . h('Standard') . "'";
1101             $c .= " hit ";
1102             # XXX: Hide behind constant, it may be interesting if LOG_LEVEL_HEADER isn't enabled as well.
1103             # $c .= $req{$t}{'filtered_header'} . " ";
1104             $c .= h('Number') . $req{$t}{'header_filter_hits'}. h('Standard');
1105             $c .= ($req{$t}{'header_filter_hits'} == 1) ? " time, " : " times, ";
1106
1107             if ($req{$t}{'old_header_size'} !=  $req{$t}{'new_header_size'}) {
1108
1109                 $c .= "changing size from ";
1110                 $c .=  h('Number') . $req{$t}{'old_header_size'} . h('Standard');
1111                 $c .= " to ";
1112                 $c .= h('Number') . $req{$t}{'new_header_size'} . h('Standard');
1113                 $c .= ".";
1114
1115             } else {
1116
1117                 $c .= "keeping the size at " . $req{$t}{'old_header_size'};
1118
1119             }
1120
1121             # Highlight from last line (XXX: What?)
1122             # $c =~ s@(?<=produced )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1123             # $c =~ s@($req{$t}{'header_filter_name'})@$h{'filter'}$1$h{'Standard'}@;
1124
1125         } else {
1126
1127            # XXX: Untested
1128            $c =~ s@(?<=produced )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1129            $c =~ s@(?<=new size )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1130
1131         }
1132         $content = $c;
1133
1134     } elsif ($c =~ m/^(Tagger|Filter) ([^\s]*) has empty joblist. Nothing to do./) {
1135
1136         # Filter privoxy-filter-test has empty joblist. Nothing to do.
1137         # Tagger variable-test has empty joblist. Nothing to do.
1138
1139         $content =~ s@(?<=$1 )([^\s]*)@$h{'filter'}$1$h{'Standard'}@;
1140
1141     } elsif ($c =~ m/^De-chunking successful. Shrunk from (\d+) to (\d+)/) {
1142
1143         $req{$t}{'chunked-size'} = $1;
1144         $req{$t}{'dechunked-size'} = $2;
1145         $req{$t}{'dechunk-change'} = $req{$t}{'dechunked-size'} - $req{$t}{'chunked-size'};
1146
1147         $content .= " (" . h('Number') . $req{$t}{'dechunk-change'} . h('Standard') . ")";
1148
1149         $content =~ s@(?<=from )($req{$t}{'chunked-size'})@$h{'Number'}$1$h{'Standard'}@;
1150         $content =~ s@(?<=to )($req{$t}{'dechunked-size'})@$h{'Number'}$1$h{'Standard'}@;
1151
1152     } elsif ($c =~ m/^Decompression successful. Old size: (\d+), new size: (\d+)./) {
1153
1154         # Decompression successful. Old size: 670, new size: 1166.
1155
1156         $req{$t}{'size-compressed'} = $1;
1157         $req{$t}{'size-decompressed'} = $2;
1158         $req{$t}{'decompression-gain'} = $req{$t}{'size-decompressed'} - $req{$t}{'size-compressed'};
1159
1160         $content =~ s@(?<=Old size: )($req{$t}{'size-compressed'})@$h{'Number'}$1$h{'Standard'}@;
1161         $content =~ s@(?<=new size: )($req{$t}{'size-decompressed'})@$h{'Number'}$1$h{'Standard'}@;
1162
1163         # XXX: Create sub get_percentage()
1164         if ($req{$t}{'size-decompressed'}) {
1165             $req{$t}{'decompression-gain-percent'} =
1166                 $req{$t}{'decompression-gain'} / $req{$t}{'size-decompressed'} * 100;
1167
1168             $content .= " (saved: ";
1169             #$content .= h('Number') . $req{$t}{'decompression-gain'} . h('Standard');
1170             #$content .= "/";
1171             $content .= h('Number') . sprintf("%.2f%%", $req{$t}{'decompression-gain-percent'}) . h('Standard');
1172             $content .= ")";
1173         }
1174
1175     } elsif ($c =~ m/^(Need to de-chunk first)/) {
1176
1177         # Need to de-chunk first
1178         return '' if SUPPRESS_NEED_TO_DE_CHUNK_FIRST;
1179
1180     } elsif ($c =~ m/^(Adding (?:dynamic )?re_filter job)/) {
1181
1182         return ''  if (SUPPRESS_SUCCEEDED_FILTER_ADDITIONS && m/succeeded/);
1183
1184         # Adding re_filter job ...
1185         # Adding dynamic re_filter job s@^(?:\w*)\s+.*\s+HTTP/\d\.\d\s*@IP-ADDRESS: $origin@D\
1186         #  to filter client-ip-address succeeded.
1187
1188     } elsif ($c =~ m/^Reading in filter/) {
1189
1190         return '' unless SHOW_FILTER_READIN_IN;
1191
1192     } else {
1193
1194         found_unknown_content($content);
1195
1196     }
1197
1198     return $content;
1199 }
1200
1201 sub handle_loglevel_redirect ($) {
1202
1203     my $c = shift;
1204
1205     if ($c =~ m/^Decoding "([^""]*)"/) {
1206
1207          $req{$t}{'original-destination'} = $1;
1208          $c = highlight_matched_path($c, '(?<=Decoding ")[^"]*');
1209          $c =~ s@\"@@g;
1210
1211     } elsif ($c =~ m/^Checking/) {
1212
1213          # Checking /_ylt=A0geu.Z76BRGR9k/**http://search.yahoo.com/search?p=view+odb+presentation+on+freebsd\
1214          #  &ei=UTF-8&xargs=0&pstart=1&fr=moz2&b=11 for redirects.
1215
1216          # TODO: Change colour if really url-decoded
1217          $req{$t}{'decoded-original-destination'} = $1;
1218          $c = highlight_matched_path($c, '(?<=Checking ")[^"]*');
1219          $c =~ s@\"@@g;
1220
1221     } elsif ($c =~ m/^pcrs command "([^""]*)" changed /) {
1222
1223         # pcrs command "s@&from=rss@@" changed \
1224         #  "http://it.slashdot.org/article.pl?sid=07/03/02/1657247&from=rss"\
1225         #  to "http://it.slashdot.org/article.pl?sid=07/03/02/1657247" (1 hit).
1226         $c =~ s@(?<=pcrs command )"([^""]*)"@$h{'filter'}$1$h{'Standard'}@;
1227         $c = highlight_matched_url($c, '(?<=changed ")[^""]*');
1228         $c =~ s@(?<=changed )"([^""]*)"@$1@; # Remove quotes
1229         $c = highlight_matched_url($c, '(?<=to ")[^""]*');
1230         $c =~ s@(?<=to )"([^""]*)"@$1@; # Remove quotes
1231         $c =~ s@(\d+)(?= hits?)@$h{'hits'}$1$h{'Standard'}@;
1232
1233     } elsif ($c =~ m/^pcrs command "([^""]*)" didn\'t change/) {
1234
1235         # pcrs command "s@^http://([^.]+?)/?$@http://www.bing.com/search?q=$1@" didn't \
1236         #  change "http://www.example.org/".
1237         $c =~ s@(?<=pcrs command )"([^""]*)"@$h{'filter'}$1$h{'Standard'}@;
1238         $c = highlight_matched_url($c, '(?<=change ")[^""]*');
1239
1240     } elsif ($c =~ m/(^New URL is: )(.*)/) {
1241
1242         # New URL is: http://it.slashdot.org/article.pl?sid=07/03/04/1511210
1243         # XXX: Use URL highlighter
1244         # XXX: Save?
1245         $c = $1 . h('rewritten-URL') . $2 . h('Standard');
1246
1247     } elsif ($c =~ m/No pcrs command recognized, assuming that/) {
1248         # No pcrs command recognized, assuming that "http://config.privoxy.org/user-manual/favicon.png"\
1249         #  is already properly formatted.
1250         # XXX: assume the same?
1251         $c = highlight_matched_url($c, '(?<=assuming that \")[^"]*');
1252
1253     } else {
1254
1255         found_unknown_content($c);
1256
1257     }
1258
1259     return $c;
1260 }
1261
1262 sub handle_loglevel_gif_deanimate ($) {
1263
1264     my $content = shift;
1265
1266     if ($content =~ m/Success! GIF shrunk from (\d+) bytes to (\d+)\./) {
1267
1268         my $bytes_from = $1;
1269         my $bytes_to = $2;
1270         # Gif-Deanimate: Success! GIF shrunk from 205 bytes to 133.
1271         $content =~ s@$bytes_from@$h{'Number'}$bytes_from$h{'Standard'}@;
1272         # XXX: Do we need g in case of ($1 == $2)?
1273         $content =~ s@$bytes_to@$h{'Number'}$bytes_to$h{'Standard'}@;
1274
1275     } elsif ($content =~ m/GIF (not) changed/) {
1276
1277         # Gif-Deanimate: GIF not changed.
1278         return '' if SUPPRESS_GIF_NOT_CHANGED;
1279         $content =~ s@($1)@$h{'not'}$1$h{'Standard'}@;
1280
1281     } elsif ($content =~ m/^failed! \(gif parsing\)/) {
1282
1283         # failed! (gif parsing)
1284         # XXX: Replace this error message with something less stupid
1285         $content =~ s@(failed!)@$h{'error'}$1$h{'Standard'}@;
1286
1287     } elsif ($content =~ m/^Need to de-chunk first/) {
1288
1289         # Need to de-chunk first
1290         return '' if SUPPRESS_NEED_TO_DE_CHUNK_FIRST;
1291
1292     } elsif ($content =~ m/^(?:No GIF header found|failed while parsing)/) {
1293
1294         # No GIF header found (XXX: Did I ever commit this?)
1295         # failed while parsing 195 134747048 (XXX: never commited)
1296
1297         # Ignore these for now
1298
1299     } else {
1300
1301         found_unknown_content($content);
1302
1303     }
1304
1305     return $content;
1306 }
1307
1308 sub handle_loglevel_request ($) {
1309
1310     my $content = shift;
1311
1312     if ($content =~ m/crunch! /) {
1313
1314         # config.privoxy.org/send-stylesheet crunch! (CGI Call)
1315
1316         # Highlight crunch reasons
1317         foreach my $reason (keys %reason_colours) {
1318             $content =~ s@\(($reason)\)@$reason_colours{$reason}($1)$h{'Standard'}@g;
1319         }
1320         # Highlight request URL domain and ditch 'crunch!'
1321         $content = highlight_matched_pattern($content, 'request_', '[^ ]*(?= crunch!)');
1322         $content =~ s@ crunch!@@;
1323
1324     } elsif ($content =~ m/\[too long, truncated\]$/) {
1325
1326         # config.privoxy.org/edit-actions-submit?f=3&v=1176116716&s=7&Submit=Submit[...]&filter... [too long, truncated]
1327         $content = highlight_matched_pattern($content, 'request_', '^.*(?=\.\.\. \[too long, truncated\]$)');
1328
1329     } elsif ($content =~ m/(.*)/) { # XXX: Pretty stupid
1330
1331         # trac.vidalia-project.net/wiki/Volunteer?format=txt
1332         $content = h('request_') . $content . h('Standard');
1333
1334     } else {  # XXX: Nop
1335
1336         found_unknown_content($content);
1337
1338     }
1339
1340     return $content;
1341 }
1342
1343 sub handle_loglevel_crunch ($) {
1344
1345     my $content = shift;
1346
1347     # Highlight crunch reason
1348     foreach my $reason (keys %reason_colours) {
1349         $content =~ s@($reason)@$reason_colours{$reason}$1$h{'Standard'}@g;
1350     }
1351
1352     if ($content =~ m/\[too long, truncated\]$/) {
1353
1354         # Blocked: config.privoxy.org/edit-actions-submit?f=3&v=1176116716&s=7&Submit=Submit\
1355         #  [...]&filter... [too long, truncated]
1356         $content = highlight_matched_pattern($content, 'request_', '^.*(?=\.\.\. \[too long, truncated\]$)');
1357
1358     } else {
1359
1360         # Blocked: http://ads.example.org/
1361         $content = highlight_matched_pattern($content, 'request_', '(?<=: ).*');
1362     }
1363
1364     return $content;
1365 }
1366
1367 sub handle_loglevel_connect ($) {
1368
1369     my $c = shift;
1370
1371     if ($c =~ m/^via [^\s]+ to: [^\s]+/) {
1372
1373         # Connect: via 10.0.0.1:8123 to: www.example.org.noconnect
1374
1375         $c = highlight_matched_host($c, '(?<=via )[^\s]+');
1376         $c = highlight_matched_host($c, '(?<=to: )[^\s]+');
1377
1378     } elsif ($c =~ m/^connect to: .* failed: .*/) {
1379
1380         # connect to: www.example.org.noconnect failed: Operation not permitted
1381
1382         $c = highlight_matched_host($c, '(?<=connect to: )[^\s]+');
1383
1384         $c =~ s@(?<=failed: )(.*)@$h{'error'}$1$h{'Standard'}@;
1385
1386     } elsif ($c =~ m/^to ([^\s]*)( successful)?$/) {
1387
1388         # Connect: to www.nzherald.co.nz successful
1389         # Connect: to archiv.radiotux.de
1390
1391         return '' if SUPPRESS_SUCCESSFUL_CONNECTIONS;
1392         $c = highlight_matched_host($c, '(?<=to )[^\s]+');
1393
1394     } elsif ($c =~ m/^to ([^\s]*)$/) {
1395
1396         # Connect: to lists.sourceforge.net:443
1397
1398         $c = highlight_matched_host($c, '(?<=to )[^\s]+');
1399
1400     } elsif ($c =~ m/^accepted connection from .*/ or
1401              $c =~ m/^OK/) {
1402
1403         # accepted connection from 10.0.0.1
1404         # Privoxy 3.0.6 and earlier just say:
1405         # OK
1406         return '' if SUPPRESS_ACCEPTED_CONNECTIONS;
1407         $c = highlight_matched_host($c, '(?<=connection from ).*');
1408
1409     } elsif ($c =~ m/^write header to: .* failed:/) {
1410
1411         # write header to: 10.0.0.1 failed: Broken pipe
1412
1413         $c = highlight_matched_host($c, '(?<=write header to: )[^\s]*');
1414         $c =~ s@(?<=failed: )(.*)@$h{'Error'}$1$h{'Standard'}@;
1415
1416     } elsif ($c =~ m/^write header to client failed:/) {
1417
1418         # write header to client failed: Broken pipe
1419         # XXX: Stil in use?
1420         $c =~ s@(?<=failed: )(.*)@$h{'Error'}$1$h{'Standard'}@;
1421
1422     } elsif ($c =~ m/^socks4_connect:/) {
1423
1424         # socks4_connect: SOCKS request rejected or failed.
1425         $c =~ s@(?<=socks4_connect: )(.*)@$h{'Error'}$1$h{'Standard'}@;
1426
1427     } elsif ($c =~ m/^Listening for new connections/ or
1428              $c =~ m/^accept connection/) {
1429         # XXX: Highlight?
1430         # Privoxy versions above 3.0.6 say:
1431         # Listening for new connections ...
1432         # earlier versions say:
1433         # accept connection ...
1434         return '';
1435
1436     } elsif ($c =~ m/^accept failed:/) {
1437
1438         $c =~ s@(?<=accept failed: )(.*)@$h{'Error'}$1$h{'Standard'}@;
1439
1440     } elsif ($c =~ m/^Overriding forwarding settings/) {
1441
1442         # Overriding forwarding settings based on 'forward 10.0.0.1:8123'
1443         $c =~ s@(?<=based on \')(.*)(?=\')@$h{'configuration-line'}$1$h{'Standard'}@;
1444
1445     } elsif ($c =~ m/^Denying suspicious CONNECT request from/) {
1446
1447         # Denying suspicious CONNECT request from 10.0.0.1
1448         $c = highlight_matched_host($c, '(?<=from )[^\s]+'); # XXX: not an URL
1449
1450     } elsif ($c =~ m/^socks5_connect:/) {
1451
1452         $c =~ s@(?<=socks5_connect: )(.*)@$h{'error'}$1$h{'Standard'}@;
1453
1454     } elsif ($c =~ m/^Created new connection to/) {
1455
1456         # Created new connection to www.privoxy.org:80 on socket 11.
1457         $c = highlight_matched_host($c, '(?<=connection to )[^\s]+');
1458         $c =~ s@(?<=on socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1459
1460     } elsif ($c =~ m/^Found reusable socket/) {
1461
1462         # Found reusable socket 9 for www.privoxy.org:80 in slot 0.
1463         # 3.0.15 and later:
1464         # Found reusable socket 8 for www.privoxy.org:80 in slot 2.\
1465         #  Timestamp made 0 seconds ago. Timeout: 1. Latency: 0.
1466         $c =~ s@(?<=Found reusable socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1467         $c = highlight_matched_host($c, '(?<=for )[^\s]+');
1468         $c =~ s@(?<=in slot )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1469         $c =~ s@(?<=made )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1470         $c =~ s@(?<=Timeout: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1471         $c =~ s@(?<=Latency: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1472
1473     } elsif ($c =~ m/^Marking open socket/) {
1474
1475         # Marking open socket 9 for www.privoxy.org:80 in slot 0 as unused.
1476         $c =~ s@(?<=Marking open socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1477         $c = highlight_matched_host($c, '(?<=for )[^\s]+');
1478         $c =~ s@(?<=in slot )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1479
1480     } elsif ($c =~ m/^No reusable/) {
1481
1482         # No reusable socket for addons.mozilla.org:443 found. Opening a new one.
1483         $c = highlight_matched_host($c, '(?<=for )[^\s]+');
1484
1485     } elsif ($c =~ m/^(Remembering|Forgetting) socket/) {
1486
1487         # Remembering socket 13 for www.privoxy.org:80 in slot 0.
1488         # Forgetting socket 38 for www.privoxy.org:80 in slot 5.
1489
1490         $c =~ s@(?<=socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1491         $c = highlight_matched_host($c, '(?<=for )[^\s]+');
1492         $c =~ s@(?<=in slot )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1493
1494     } elsif ($c =~ m/^Socket/) {
1495
1496         # Socket 16 already forgotten or never remembered.
1497         $c =~ s@(?<=Socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1498
1499     } elsif ($c =~ m/^The connection to/) {
1500
1501         # The connection to www.privoxy.org:80 in slot 6 timed out. Closing socket 19. Timeout is: 61.
1502         # 3.0.15 and later:
1503         # The connection to 1.bp.blogspot.com:80 in slot 0 timed out. Closing socket 5.\
1504         #  Timeout is: 1. Assumed latency: 4.
1505         # The connection to 10.0.0.1:80 in slot 0 is no longer usable. Closing socket 4.
1506         $c = highlight_matched_host($c, '(?<=connection to )[^\s]+');
1507         $c =~ s@(?<=in slot )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1508         $c =~ s@(?<=Closing socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1509         $c =~ s@(?<=Timeout is: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1510         $c =~ s@(?<=Assumed latency: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1511
1512     } elsif ($c =~ m/^Stopped waiting for the request line./) {
1513
1514         # Stopped waiting for the request line. Timeout: 121.
1515         $c =~ s@(?<=Timeout: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1516
1517     } elsif ($c =~ m/^Waiting for \d/) {
1518
1519         # Waiting for 1 connections to timeout.
1520         $c =~ s@(?<=^Waiting for )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1521
1522     } elsif ($c =~ m/^Initialized/) {
1523
1524         # Initialized 20 socket slots.
1525         $c =~ s@(?<=Initialized )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1526
1527     } elsif ($c =~ m/^Done reading from server/) {
1528
1529         # Done reading from server. Expected content length: 24892. \
1530         #  Actual content length: 24892. Most recently received: 4412.
1531         # 3.0.15 and later:
1532         # Done reading from server. Expected content length: 24892. \
1533         #  Actual content length: 24892. Bytes most recently read: 4412.
1534         # Done reading from server. Content length: 6018 as expected. \
1535         #  Bytes most recently read: 294.
1536         $c =~ s@(?<=ontent length: )(\d+)@$h{'Number'}$1$h{'Standard'}@g;
1537         $c =~ s@(?<=received: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1538         $c =~ s@(?<=read: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1539
1540     } elsif ($c =~ m/^Continuing buffering headers/) {
1541
1542         # Continuing buffering headers. byte_count: 19. header_offset: 517. len: 536.
1543         $c =~ s@(?<=byte_count: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1544         $c =~ s@(?<=header_offset: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1545         $c =~ s@(?<=len: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1546         # 3.0.15 and later:
1547         # Continuing buffering headers. Bytes most recently read: %d.
1548         $c =~ s@(?<=read: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1549
1550     } elsif ($c =~ m/^Received \d+ bytes while/) {
1551
1552         # Received 206 bytes while expecting 12103.
1553         $c =~ s@(?<=Received )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1554         $c =~ s@(?<=expecting )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1555
1556     } elsif ($c =~ m/^(Rejecting c|C)onnection from/) {
1557
1558         # Connection from 81.163.28.218 dropped due to ACL
1559         # Rejecting connection from 178.63.152.227. Maximum number of connections reached.
1560         $c =~ s@(?<=onnection from )((?:\d+\.?){3}\d+)@$h{'Number'}$1$h{'Standard'}@;
1561
1562     } elsif ($c =~ m/^(?:Reusing|Closing) server socket \d./ or
1563              $c =~ m/^No additional client request/) {
1564
1565         # Reusing server socket 4. Opened for 10.0.0.1.
1566         # Closing server socket 2. Opened for 10.0.0.1.
1567         # No additional client request received in time. \
1568         #  Closing server socket 4, initially opened for 10.0.0.1.
1569         # No additional client request received in time on socket 29.
1570
1571         $c =~ s@(?<= socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1572         $c = highlight_matched_host($c, '(?<=for )[^\s]+(?=\.$)');
1573
1574     } elsif ($c =~ m/^Connected to /) {
1575
1576         # Connected to tor-jail[10.0.0.2]:9050.
1577
1578         $c = highlight_matched_host($c, '(?<=\[)[^\]]+');
1579         $c = highlight_matched_host($c, '(?<=Connected to )[^\[\s]+');
1580         $c =~ s@(?<=\]:)(\d+)@$h{'Number'}$1$h{'Standard'}@;
1581
1582     } elsif ($c =~ m/^Could not connect to /) {
1583
1584         # Could not connect to [10.0.0.1]:80.
1585
1586         $c = highlight_matched_host($c, '(?<=\[)[^\]]+');
1587         $c =~ s@(?<=\]:)(\d+)@$h{'Number'}$1$h{'Standard'}@;
1588
1589     } elsif ($c =~ m/^Waiting for the next client request/ or
1590              $c =~ m/^The connection on server socket/ or
1591              $c =~ m/^Client request arrived in time or the client closed the connection/) {
1592
1593         # Waiting for the next client request on socket 3. Keeping the server \
1594         #  socket 12 to a.fsdn.com open.
1595         # The connection on server socket 6 to upload.wikimedia.org isn't reusable. Closing.
1596         # Client request arrived in time or the client closed the connection on socket 12.
1597
1598         $c =~ s@(?<=on socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1599         $c =~ s@(?<=server socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1600         $c = highlight_matched_host($c, '(?<=to )[^\s]+');
1601
1602     } elsif ($c =~ m/^Marking the server socket/) {
1603
1604         # Marking the server socket 7 tainted.
1605
1606         $c =~ s@(?<=server socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1607
1608     } elsif ($c =~ m/^Reduced expected bytes to /) {
1609
1610         # Reduced expected bytes to 0 to account for the 1542 ones we already got.
1611         $c =~ s@(?<=bytes to )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1612         $c =~ s@(?<=for the )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1613
1614     } elsif ($c =~ m/^The client closed socket /) {
1615
1616         # The client closed socket 2 while the server socket 4 is still open.
1617         $c =~ s@(?<=closed socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1618         $c =~ s@(?<=server socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1619
1620     } elsif ($c =~ m/^Expected client content length set /) {
1621
1622         # Expected client content length set to 667325411 after reading 4999 bytes.
1623         $c =~ s@(?<=set to )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1624         $c =~ s@(?<=reading )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1625
1626     } elsif ($c =~ m/^Waiting for up to /) {
1627
1628         # Waiting for up to 4999 bytes from the client.
1629         $c =~ s@(?<=up to )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1630
1631     } elsif ($c =~ m/^Looks like we / or
1632              $c =~ m/^Unsetting keep-alive flag/ or
1633              $c =~ m/^No connections to wait/ or
1634              $c =~ m/^Complete client request received/ or
1635              $c =~ m/^Possible pipeline attempt detected./ or
1636              $c =~ m/^POST request detected. The connection will not be kept alive./ or
1637              $c =~ m/^The server still wants to talk, but the client hung up on us./ or
1638              $c =~ m/^The server didn't specify how long the connection will stay open/ or
1639              $c =~ m/^There might be a request body. The connection will not be kept alive/ or
1640              $c =~ m/^Stopping to watch the client socket. There's already another request waiting./ or
1641              $c =~ m/^Done reading from the client\.$/) {
1642
1643         # Looks like we reached the end of the last chunk. We better stop reading.
1644         # Looks like we read the end of the last chunk together with the server \
1645         #  headers. We better stop reading.
1646         # Looks like we got the last chunk together with the server headers. \
1647         #  We better stop reading.
1648         # Unsetting keep-alive flag.
1649         # No connections to wait for left.
1650         # Client request arrived in time or the client closed the connection.
1651         # Complete client request received
1652         # Possible pipeline attempt detected. The connection will not be \
1653         #  kept alive and we will only serve the first request.
1654         # POST request detected. The connection will not be kept alive.
1655         # The server still wants to talk, but the client hung up on us.
1656         # The server didn't specify how long the connection will stay open. Assume it's only a second.
1657         # There might be a request body. The connection will not be kept alive.
1658         # Stopping to watch the client socket. There's already another request waiting.
1659         # Done reading from the client\.
1660
1661     } else {
1662
1663         found_unknown_content($c);
1664
1665     }
1666
1667     return $c;
1668 }
1669
1670
1671 sub handle_loglevel_info ($) {
1672
1673     my $c = shift;
1674
1675     if ($c =~ m/^Rewrite detected:/) {
1676
1677         # Rewrite detected: GET http://10.0.0.2:88/blah.txt HTTP/1.1
1678         $c = highlight_matched_request_line($c, '(?<=^Rewrite detected: ).*');
1679
1680     } elsif ($c =~ m/^Decompress(ing deflated|ion didn)/ or
1681              $c =~ m/^Compressed content detected/ or
1682              $c =~ m/^Tagger/
1683             ) {
1684         # Decompressing deflated iob: 117
1685         # Decompression didn't result in any content.
1686         # Compressed content detected, content filtering disabled. Consider recompiling Privoxy\
1687         #  with zlib support or enable the prevent-compression action.
1688         # Tagger 'complete-url' created empty tag. Ignored.
1689
1690         # Ignored for now
1691
1692     } elsif ($c =~ m/^(Re)?loading configuration file /) {
1693
1694         # loading configuration file '/usr/local/etc/privoxy/config':
1695         # Reloading configuration file '/usr/local/etc/privoxy/config'
1696         $c =~ s@(?<=loading configuration file \')([^\']*)@$h{'file'}$1$h{'Standard'}@;
1697
1698     } elsif ($c =~ m/^Loading (actions|filter) file: /) {
1699
1700         # Loading actions file: /usr/local/etc/privoxy/default.action
1701         # Loading filter file: /usr/local/etc/privoxy/default.filter
1702         $c =~ s@(?<= file: )(.*)$@$h{'file'}$1$h{'Standard'}@;
1703
1704     } elsif ($c =~ m/^exiting by signal/) {
1705
1706         # exiting by signal 15 .. bye
1707         $c =~ s@(?<=exiting by signal )(\d+)@$h{'signal'}$1$h{'Standard'}@;
1708
1709     } elsif ($c =~ m/^Privoxy version/) {
1710
1711         # Privoxy version 3.0.7
1712         $c =~ s@(?<=^Privoxy version )(\d+\.\d+\.\d+)$@$h{'version'}$1$h{'Standard'}@;
1713
1714     } elsif ($c =~ m/^Program name: /) {
1715
1716         # Program name: /usr/local/sbin/privoxy
1717         $c =~ s@(?<=Program name: )(.*)@$h{'program-name'}$1$h{'Standard'}@;
1718
1719     } elsif ($c =~ m/^Listening on port /) {
1720
1721         # Listening on port 8118 on IP address 10.0.0.1
1722         $c =~ s@(?<=Listening on port )(\d+)@$h{'port'}$1$h{'Standard'}@;
1723         $c =~ s@(?<=on IP address )(.*)@$h{'ip-address'}$1$h{'Standard'}@;
1724
1725     } elsif ($c =~ m/^\(Re-\)Open(?:ing)? logfile/) {
1726
1727         # (Re-)Open logfile /var/log/privoxy/privoxy.log
1728         $c =~ s@(?<=Open logfile )(.*)@$h{'file'}$1$h{'Standard'}@;
1729
1730     } elsif ($c =~ m/^(Request from|Malformed server response detected)/) {
1731
1732         # Request from 10.0.0.1 denied. limit-connect{,} doesn't allow CONNECT requests to port 443.
1733         # Request from 10.0.0.1 marked for blocking. limit-connect{,} doesn't allow CONNECT requests to port 443.
1734         # Malformed server response detected. Downgrading to HTTP/1.0 impossible.
1735
1736         $c =~ s@(?<=Request from )([^\s]*)@$h{'ip-address'}$1$h{'Standard'}@;
1737         $c =~ s@(denied|blocking)@$h{'warning'}$1$h{'Standard'}@;
1738         $c =~ s@(CONNECT)@$h{'method'}$1$h{'Standard'}@;
1739         $c =~ s@(?<=to port )(\d+)@$h{'port'}$1$h{'Standard'}@;
1740
1741     } elsif ($c =~ m/^Status code/) {
1742
1743         # Status code 304 implies no body.
1744         $c =~ s@(?<=Status code )(\d+)@$h{'status-code'}$1$h{'Standard'}@;
1745
1746     } elsif ($c =~ m/^Method/) {
1747
1748         # Method HEAD implies no body.
1749         $c =~ s@(?<=Method )([^\s]+)@$h{'method'}$1$h{'Standard'}@;
1750
1751     } elsif ($c =~ m/^Buffer limit reached while extending /) {
1752
1753         # Buffer limit reached while extending the buffer (iob). Needed: 4197470. Limit: 4194304
1754         $c =~ s@(?<=Needed: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1755         $c =~ s@(?<=Limit: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1756
1757     } elsif ($c =~ m/^No logfile configured/ or
1758              $c =~ m/^Malformerd HTTP headers detected and MS IIS5 hack enabled/ or
1759              $c =~ m/^Invalid \"chunked\" transfer/ or
1760              $c =~ m/^Support for/ or
1761              $c =~ m/^Flushing header and buffers/ or
1762              $c =~ m/^Can not resolve/
1763              ) {
1764
1765         # No logfile configured. Please enable it before reporting any problems.
1766         # Malformerd HTTP headers detected and MS IIS5 hack enabled. Expect an invalid \
1767         #  response or even no response at all.
1768         # No logfile configured. Logging disabled.
1769         # Invalid "chunked" transfer encoding detected and ignored.
1770         # Support for 'Connection: keep-alive' is experimental, incomplete and\
1771         #  known not to work properly in some situations.
1772         # Flushing header and buffers. Stepping back from filtering.
1773         # Can not resolve doesnotexist: hostname nor servname provided, or not known
1774
1775     } else {
1776
1777         found_unknown_content($c);
1778
1779     }
1780
1781     return $c;
1782 }
1783
1784 sub handle_loglevel_cgi ($) {
1785
1786     my $c = shift;
1787
1788     if ($c =~ m/^Granting access to/) {
1789
1790         #Granting access to http://config.privoxy.org/send-stylesheet, referrer http://p.p/ is trustworthy.
1791
1792     } elsif ($c =~ m/^Substituting: s(.)/) {
1793
1794         # Substituting: s/@else-not-FEATURE_ZLIB@.*@endif-FEATURE_ZLIB@//sigTU
1795         # XXX: prone to span several lines
1796
1797         my $delimiter = $1;
1798         #$c =~ s@(?<=failed: )(.*)@$h{'error'}$1$h{'Standard'}@;
1799         $c =~ s@(?!<=\\)($delimiter)@$h{'pcrs-delimiter'}$1$h{'Standard'}@g; # XXX: Too aggressive
1800         #$c =~ s@(?!<=\\)($1)@$h{'pcrs-delimiter'}$1$h{'Standard'}@g;
1801     }
1802
1803     return $c;
1804 }
1805
1806 sub handle_loglevel_force ($) {
1807
1808     my $c = shift;
1809
1810     if ($c =~ m/^Ignored force prefix in request:/) {
1811
1812         # Ignored force prefix in request: "GET http://10.0.0.1/PRIVOXY-FORCE/block HTTP/1.1"
1813         $c =~ s@^(Ignored)@$h{'ignored'}$1$h{'Standard'}@;
1814         $c = highlight_matched_request_line($c, '(?<=request: ")[^"]*');
1815
1816     } elsif ($c =~ m/^Enforcing request:/) {
1817
1818         # Enforcing request: "GET http://10.0.0.1/block HTTP/1.1".
1819         $c = highlight_matched_request_line($c, '(?<=request: ")[^"]*');
1820
1821     } else {
1822
1823         found_unknown_content($c);
1824
1825     }
1826
1827     return $c;
1828 }
1829
1830 sub handle_loglevel_error ($) {
1831
1832     my $c = shift;
1833
1834     if ($c =~ m/^Empty server or forwarder response received on socket \d+./) {
1835
1836         # Empty server or forwarder response received on socket 4.
1837         # Empty server or forwarder response received on socket 3. \
1838         #  Closing client socket 15 without sending data.
1839         $c =~ s@(?<=on socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1840         $c =~ s@(?<=client socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1841     }
1842     # XXX: There are probably more messages that deserve highlighting.
1843
1844     return $c;
1845 }
1846
1847
1848 sub handle_loglevel_ignore ($) {
1849     return shift;
1850 }
1851
1852 sub gather_loglevel_request_stats ($$) {
1853     my $c = shift;
1854     my $thread = shift;
1855     our %stats;
1856
1857     $stats{requests}++;
1858 }
1859
1860 sub gather_loglevel_crunch_stats ($$) {
1861     my $c = shift;
1862     my $thread = shift;
1863     our %stats;
1864
1865     $stats{requests}++;
1866     $stats{crunches}++;
1867 }
1868
1869
1870 sub gather_loglevel_error_stats ($$) {
1871
1872     my $c = shift;
1873     my $thread = shift;
1874     our %stats;
1875     our %thread_data;
1876
1877     if ($c =~ m/^Empty server or forwarder response received on socket \d+./) {
1878
1879         # Empty server or forwarder response received on socket 4.
1880         $stats{'empty-responses'}++;
1881         if ($thread_data{$thread}{'new_connection'}) {
1882             $stats{'empty-responses-on-new-connections'}++;
1883         } else {
1884             $stats{'empty-responses-on-reused-connections'}++;
1885         }
1886     }
1887 }
1888
1889 sub gather_loglevel_connect_stats ($$) {
1890
1891     my ($c, $thread) = @_;
1892     our %thread_data;
1893     our %stats;
1894
1895     if ($c =~ m/^via ([^\s]+) to: [^\s]+/) {
1896
1897         # Connect: via 10.0.0.1:8123 to: www.example.org.noconnect
1898         $thread_data{$thread}{'forwarder'} = $1; # XXX: is this missue?
1899
1900     } elsif ($c =~ m/^to ([^\s]*)$/) {
1901
1902         # Connect: to lists.sourceforge.net:443
1903
1904         $thread_data{$thread}{'forwarder'} = 'direct connection';
1905
1906     } elsif ($c =~ m/^Created new connection to/) {
1907
1908         # Created new connection to www.privoxy.org:80 on socket 11.
1909
1910         $thread_data{$thread}{'new_connection'} = 1;
1911
1912     } elsif ($c =~ m/^Reusing server socket \d./ or
1913              $c =~ m/^Found reusable socket/) {
1914
1915         # Reusing server socket 4. Opened for 10.0.0.1.
1916         # Found reusable socket 9 for www.privoxy.org:80 in slot 0.
1917
1918         $thread_data{$thread}{'new_connection'} = 0;
1919         $stats{'reused-connections'}++;
1920     }
1921 }
1922
1923 sub gather_loglevel_header_stats ($$) {
1924
1925     my ($c, $thread) = @_;
1926     our %stats;
1927
1928     if ($c =~ m/^A HTTP\/1\.1 response without/ or
1929         $c =~ m/^Keeping the server header 'Connection: keep-alive' around./)
1930     {
1931         # A HTTP/1.1 response without Connection header implies keep-alive.
1932         # Keeping the server header 'Connection: keep-alive' around.
1933         $stats{'server-keep-alive'}++;
1934     }
1935 }
1936
1937 sub init_stats () {
1938     our %stats = (
1939         requests => 0,
1940         crunches => 0,
1941         'server-keep-alive' => 0,
1942         'reused-connections' => 0,
1943         'empty-responses' => 0,
1944         'empty-responses-on-new-connections' => 0,
1945         'empty-responses-on-reused-connections' => 0,
1946         );
1947 }
1948
1949 sub get_percentage ($$) {
1950     my $big = shift;
1951     my $small = shift;
1952     return "NaN" if ($big eq 0);
1953     return sprintf("%.2f%%", $small / $big * 100);
1954 }
1955
1956 sub print_stats () {
1957
1958     our %stats;
1959     my $new_connections = $stats{requests} - $stats{crunches} - $stats{'reused-connections'};
1960     my $outgoing_requests = $stats{requests} - $stats{crunches};
1961
1962     if ($stats{requests} eq 0) {
1963         print "No requests yet.\n";
1964         return;
1965     }
1966
1967     print "Client requests total: " . $stats{requests} . "\n";
1968     print "Crunches: " . $stats{crunches} . " (" .
1969         get_percentage($stats{requests}, $stats{crunches}) . ")\n";
1970     print "Outgoing requests: " . $outgoing_requests . " (" .
1971         get_percentage($stats{requests}, $outgoing_requests) . ")\n";
1972     print "Server keep-alive offers: " . $stats{'server-keep-alive'} . " (" .
1973         get_percentage($stats{requests}, $stats{'server-keep-alive'}) . ")\n";
1974     print "New outgoing connections: " . $new_connections . " (" .
1975         get_percentage($stats{requests}, $new_connections) . ")\n";
1976     print "Reused connections: " . $stats{'reused-connections'} . " (" .
1977         get_percentage($stats{requests}, $stats{'reused-connections'}) . ")\n";
1978     print "Empty responses: " . $stats{'empty-responses'} . " (" .
1979         get_percentage($stats{requests}, $stats{'empty-responses'}) . ")\n";
1980     print "Empty responses on new connections: "
1981          . $stats{'empty-responses-on-new-connections'} . " (" .
1982         get_percentage($stats{requests}, $stats{'empty-responses-on-new-connections'})
1983         . ")\n";
1984     print "Empty responses on reused connections: " .
1985         $stats{'empty-responses-on-reused-connections'} . " (" .
1986         get_percentage($stats{requests}, $stats{'empty-responses-on-reused-connections'}) .
1987         ")\n";
1988 }
1989
1990
1991 ################################################################################
1992 # Functions that actually print stuff
1993 ################################################################################
1994
1995 sub print_clf_message () {
1996
1997     our ($ip, $timestamp, $request_line, $status_code, $size);
1998     my $output = '';
1999
2000     return if DEBUG_SUPPRESS_LOG_MESSAGES;
2001
2002     # Rebuild highlighted
2003     $output .= $h{'Number'} . $ip . $h{'Standard'};
2004     $output .= " - - ";
2005     $output .= "[" . $h{'Timestamp'} . $timestamp . $h{'Standard'} . "]";
2006     $output .= " ";
2007     $output .= "\"" . highlight_request_line("$request_line") . "\"";
2008     $output .= " ";
2009     $output .= $h{'Status'} . $status_code . $h{'Standard'};
2010     $output .= " ";
2011     $output .= $h{'Number'} . $size . $h{'Standard'};
2012     $output .= $line_end;
2013
2014     print $output;
2015 }
2016
2017 sub print_non_clf_message ($) {
2018
2019     my $content = shift;
2020     my $msec_string = "." . $req{$t}{'msecs'} unless $no_msecs_mode;
2021     my $line_start = $html_output_mode ? '' : $h{"Standard"};
2022
2023     return if DEBUG_SUPPRESS_LOG_MESSAGES;
2024
2025     print $line_start
2026         . $time_colours[$time_colour_index % 2]
2027         . $req{$t}{'time-stamp'}
2028         . $msec_string
2029         . $h{Standard} . " "
2030         . $thread_colours{$t}
2031         . $t
2032         . $h{Standard}
2033         . " "
2034         . $h{$req{$t}{'log-level'}}
2035         . $req{$t}{'log-level'}
2036         . $h{Standard}
2037         . ": "
2038         . $content
2039         . $line_end;
2040 }
2041
2042 sub shorten_thread_id ($) {
2043
2044     my $thread_id = shift;
2045
2046     our %short_thread_ids;
2047     our $max_threadid;
2048
2049     unless (defined $short_thread_ids{$thread_id}) {
2050         $short_thread_ids{$thread_id} = sprintf "%.3d", $max_threadid++;
2051     }
2052
2053     return $short_thread_ids{$thread_id}
2054 }
2055
2056 sub parse_loop () {
2057
2058     my ($day, $time_stamp, $thread, $log_level, $content, $c, $msecs);
2059     my $last_msecs  = 0;
2060     my $last_thread = 0;
2061     my $last_timestamp = 0;
2062     my $filters_that_did_nothing;
2063     my $key;
2064     my $time_colour;
2065     $time_colour = paint_it('white');
2066
2067     my %log_level_handlers = (
2068         'Re-Filter'         => \&handle_loglevel_re_filter,
2069         'Header'            => \&handle_loglevel_header,
2070         'Connect'           => \&handle_loglevel_connect,
2071         'Redirect'          => \&handle_loglevel_redirect,
2072         'Request'           => \&handle_loglevel_request,
2073         'Crunch'            => \&handle_loglevel_crunch,
2074         'Gif-Deanimate'     => \&handle_loglevel_gif_deanimate,
2075         'Info'              => \&handle_loglevel_info,
2076         'CGI'               => \&handle_loglevel_cgi,
2077         'Force'             => \&handle_loglevel_force,
2078         'Error'             => \&handle_loglevel_error,
2079         'Fatal error'       => \&handle_loglevel_ignore,
2080         'Writing'           => \&handle_loglevel_ignore,
2081         'Received'          => \&handle_loglevel_ignore,
2082         'Unknown log level' => \&handle_loglevel_ignore,
2083     );
2084
2085     while (<>) {
2086
2087         if (m/^(\w{3} \d{2}) (\d\d:\d\d:\d\d)\.?(\d+)? (?:Privoxy\()?([^\)\s]*)[\)]? ([\w -]*): (.*?)\r?$/) {
2088             $thread = $t = ($shorten_thread_ids) ? shorten_thread_id($4) : $4;
2089             $req{$t}{'day'} = $day = $1;
2090             $req{$t}{'time-stamp'} = $time_stamp = $2;
2091             $req{$t}{'msecs'} = $msecs = $3 ? $3 : 0; # Only the cool kids have micro second resolution;
2092             $req{$t}{'log-level'} = $log_level = $5;
2093             $req{$t}{'content'} = $content = $c = $6;
2094             $req{$t}{'log-message'} = $_;
2095             $no_special_header_highlighting = 0;
2096
2097             if (defined($log_level_handlers{$log_level})) {
2098
2099                 $content = $log_level_handlers{$log_level}($content);
2100
2101             } else {
2102
2103                 die "No handler found for log level \"$log_level\"\n";
2104             }
2105
2106             # Highlight Truncations
2107             if (length($_) > 4000) {
2108                 $content =~ s@(too long, truncated)]$@$h{'Truncation'}$1$h{'Standard'}]@g;
2109             }
2110
2111             next unless $content;
2112
2113             # Register threads to keep the colour constant
2114             if (!defined($thread_colours{$thread})) {
2115                 $thread_colours{$thread} = $all_colours[$thread_colour_index % @all_colours];
2116                 $thread_colour_index++;
2117             }
2118
2119             # Switch timestamp colour if timestamps differ
2120             if (($msecs ne $last_msecs) || ($time_stamp ne $last_timestamp)) {
2121                debug_message("Tick tack!") if DEBUG_TICKS;
2122                $time_colour = $time_colours[$time_colour_index % 2];
2123                $time_colour_index++;
2124                $last_msecs = $msecs;
2125                $last_timestamp = $time_stamp;
2126             }
2127
2128             $last_thread = $thread;
2129
2130             print_non_clf_message($content);
2131
2132         } elsif (m/^((?:\d+\.\d+\.\d+\.\d+|[:\d]+)) - - \[(.*)\] "(.*)" (\d+) (\d+)/) {
2133
2134             # LOG_LEVEL_CLF lines look like this
2135             # 61.152.239.32 - - [04/Mar/2007:18:28:23 +0100] "GET \
2136             #  http://ad.yieldmanager.com/imp?z=1&Z=120x600&s=109339&u=http%3A%2F%2Fwww.365loan.co.uk%2F&r=1\
2137             #  HTTP/1.1" 403 1730
2138             our ($ip, $timestamp, $request_line, $status_code, $size) = ($1, $2, $3, $4, $5);
2139
2140             print_clf_message();
2141
2142         } else {
2143
2144             # Some Privoxy log messages span more than one line,
2145             # usually to dump lots of content that doesn't need any syntax highlighting.
2146             # XXX: add mechanism to forward these lines to the right handler anyway.
2147             chomp();
2148             unless (DEBUG_SUPPRESS_LOG_MESSAGES or (SUPPRESS_EMPTY_LINES and m/^\s+$/)) {
2149                 print and print get_line_end(); # unless (SUPPRESS_EMPTY_LINES and m/^\s+$/);
2150             }
2151         }
2152     }
2153 }
2154
2155 sub stats_loop () {
2156
2157     my ($day, $time_stamp, $msecs, $thread, $log_level, $content);
2158     my %log_level_handlers = (
2159          'Re-Filter'         => \&handle_loglevel_ignore,
2160          'Header'            => \&gather_loglevel_header_stats,
2161          'Connect'           => \&gather_loglevel_connect_stats,
2162          'Redirect'          => \&handle_loglevel_ignore,
2163          'Request'           => \&gather_loglevel_request_stats,
2164          'Crunch'            => \&gather_loglevel_crunch_stats,
2165          'Gif-Deanimate'     => \&handle_loglevel_ignore,
2166          'Info'              => \&handle_loglevel_ignore,
2167          'CGI'               => \&handle_loglevel_ignore,
2168          'Force'             => \&handle_loglevel_ignore,
2169          'Error'             => \&gather_loglevel_error_stats,
2170          'Fatal error'       => \&handle_loglevel_ignore,
2171          'Writing'           => \&handle_loglevel_ignore,
2172          'Unknown log level' => \&handle_loglevel_ignore
2173     );
2174
2175     while (<>) {
2176         if (m/^(\w{3} \d{2}) (\d\d:\d\d:\d\d)\.?(\d+)? (?:Privoxy\()?([^\)\s]*)[\)]? ([\w -]*): (.*?)\r?$/) {
2177             $day = $1;
2178             $time_stamp = $2;
2179             $msecs = $3 ? $3 : 0;
2180             $thread = $4;
2181             $log_level = $5;
2182             $content = $6;
2183
2184             if (defined($log_level_handlers{$log_level})) {
2185
2186                 $content = $log_level_handlers{$log_level}($content, $thread);
2187
2188             } else {
2189
2190                 die "No handler found for log level \"$log_level\"\n";
2191
2192             }
2193         }
2194     }
2195
2196     print_stats();
2197
2198 }
2199
2200 sub VersionMessage {
2201     my $version_message;
2202
2203     $version_message .= 'Privoxy-Log-Parser ' . PRIVOXY_LOG_PARSER_VERSION  . "\n";
2204     $version_message .= 'Copyright (C) 2007-2010 Fabian Keil <fk@fabiankeil.de>' . "\n";
2205     $version_message .= 'http://www.fabiankeil.de/sourcecode/privoxy-log-parser/' . "\n";
2206
2207     print $version_message;
2208 }
2209
2210 sub get_cli_options () {
2211
2212     our %cli_options = (
2213         'html-output'              => CLI_OPTION_DEFAULT_TO_HTML_OUTPUT,
2214         'title'                    => CLI_OPTION_TITLE,
2215         'no-syntax-highlighting'   => CLI_OPTION_NO_SYNTAX_HIGHLIGHTING,
2216         'no-embedded-css'          => CLI_OPTION_NO_EMBEDDED_CSS,
2217         'no-msecs'                 => CLI_OPTION_NO_MSECS,
2218         'shorten-thread-ids'       => CLI_OPTION_SHORTEN_THREAD_IDS,
2219         'show-ineffective-filters' => CLI_OPTION_SHOW_INEFFECTIVE_FILTERS,
2220         'accept-unknown-messages'  => CLI_OPTION_ACCEPT_UNKNOWN_MESSAGES,
2221         'statistics'               => CLI_OPTION_STATISTICS,
2222     );
2223
2224     GetOptions (
2225         'html-output'              => \$cli_options{'html-output'},
2226         'title'                    => \$cli_options{'title'},
2227         'no-syntax-highlighting'   => \$cli_options{'no-syntax-highlighting'},
2228         'no-embedded-css'          => \$cli_options{'no-embedded-css'},
2229         'no-msecs'                 => \$cli_options{'no-msecs'},
2230         'shorten-thread-ids'       => \$cli_options{'shorten-thread-ids'},
2231         'show-ineffective-filters' => \$cli_options{'show-ineffective-filters'},
2232         'accept-unknown-messages'  => \$cli_options{'accept-unknown-messages'},
2233         'statistics'               => \$cli_options{'statistics'},
2234         'version'                  => sub { VersionMessage && exit(0) },
2235         'help'                     => \&help,
2236    ) or exit(1);
2237
2238    $html_output_mode = cli_option_is_set('html-output');
2239    $no_msecs_mode = cli_option_is_set('no-msecs');
2240    $shorten_thread_ids = cli_option_is_set('shorten-thread-ids');
2241    $line_end = get_line_end();
2242 }
2243
2244 sub help () {
2245
2246     our %cli_options;
2247
2248     VersionMessage();
2249
2250     print << "    EOF"
2251
2252 Options and their default values if they have any:
2253     [--accept-unknown-messages]
2254     [--html-output]
2255     [--no-embedded-css]
2256     [--no-msecs]
2257     [--no-syntax-highlighting]
2258     [--shorten-thread-ids]
2259     [--show-ineffective-filters]
2260     [--statistics]
2261     [--title $cli_options{'title'}]
2262     [--version]
2263 see "perldoc $0" for more information
2264     EOF
2265     ;
2266     exit(0);
2267 }
2268
2269 ################################################################################
2270 # main
2271 ################################################################################
2272 sub main () {
2273
2274     get_cli_options();
2275     set_background(DEFAULT_BACKGROUND);
2276     prepare_our_stuff();
2277
2278     print_intro();
2279
2280     if (cli_option_is_set('statistics')) {
2281         stats_loop();
2282     } else {
2283         parse_loop();
2284     }
2285
2286     print_outro();
2287 }
2288
2289 main();
2290
2291 =head1 NAME
2292
2293 B<privoxy-log-parser> - A parser and syntax-highlighter for Privoxy log messages
2294
2295 =head1 SYNOPSIS
2296
2297 B<privoxy-log-parser> [B<--accept-unknown-messages>] [B<--html-output>]
2298 [B<--no-msecs>] [B<--no-syntax-higlighting>] [B<--statistics>]
2299 [B<--shorten-thread-ids>] [B<--show-ineffective-filters>] [B<--version>]
2300
2301 =head1 DESCRIPTION
2302
2303 B<privoxy-log-parser> reads Privoxy log messages and
2304
2305 - syntax-highlights recognized lines,
2306
2307 - reformats some of them for easier comprehension,
2308
2309 - filters out less useful messages, and
2310
2311 - (in some cases) calculates additional information,
2312   like the compression ratio or how a filter affected
2313   the content size.
2314
2315 With B<privoxy-log-parser> you should be able to increase Privoxy's log level
2316 without getting confused by the resulting amount of output. For example for
2317 "debug 64" B<privoxy-log-parser> will (by default) only show messages that
2318 affect the content. If a filter doesn't cause any hits, B<privoxy-log-parser>
2319 will hide the "filter foo caused 0 hits" message.
2320
2321 =head1 OPTIONS
2322
2323 [B<--accept-unknown-messages>] Don't print warnings in case of unknown messages,
2324 just don't highlight them.
2325
2326 [B<--html-output>] Use HTML and CSS for the syntax highlighting. If this option is
2327 omitted, ANSI escape sequences are used unless B<--no-syntax-highlighting> is active.
2328 This option is only intended to make embedding log excerpts in web pages easier.
2329 It does not escape any input!
2330
2331 [B<--no-msecs>] Don't expect milisecond resolution
2332
2333 [B<--no-syntax-highlighting>] Disable syntax-highlighting. Useful when
2334 the filtered output is piped into less in which case the ANSI control
2335 codes don't work, or if the terminal itself doesn't support the control
2336 codes.
2337
2338 [B<--shorten-thread-ids>] Shorten the thread ids to a three-digit decimal number.
2339 Note that the mapping from thread ids to shortened ids is created at run-time
2340 and thus varies with the input.
2341
2342 [B<--show-ineffective-filters>] Don't suppress log lines for filters
2343 that didn't modify the content.
2344
2345 [B<--statistics>] Gather various statistics instead of syntax highlighting
2346 log messages. This is an experimental feature, if the results look wrong
2347 they very well might be. Also note that the results are pretty much guaranteed
2348 to be incorrect if Privoxy and Privoxy-Log-Parser aren't in sync.
2349
2350 [B<--version>] Print version and exit.
2351
2352 =head1 EXAMPLES
2353
2354 To monitor a log file:
2355
2356 tail -F /usr/jails/privoxy-jail/var/log/privoxy/privoxy.log | B<privoxy-log-parser>
2357
2358 Replace '-F' with '-f' if your tail implementation lacks '-F' support
2359 or if the log won't get rotated anyway. The log file location depends
2360 on your system (Doh!).
2361
2362 To monitor Privoxy without having it write to a log file:
2363
2364 privoxy --no-daemon /usr/jails/privoxy-jail/usr/local/etc/privoxy/config 2>&1 | B<privoxy-log-parser>
2365
2366 Again, the config file location depends on your system. Output redirection
2367 depends on your shell, the above works with bourne shells.
2368
2369 To read a processed Privoxy log file from top to bottom, letting the content
2370 scroll by slightly faster than you can read:
2371
2372 B<privoxy-log-parser> < /usr/jails/privoxy-jail/var/log/privoxy/privoxy.log
2373
2374 This is probably only useful to fill screens in the background of haxor movies.
2375
2376 =head1 CAVEATS
2377
2378 Syntax highlighting with ANSI escape sequences will look strange
2379 if your background color isn't black.
2380
2381 Some messages aren't recognized yet and will not be fully highlighted.
2382
2383 B<privoxy-log-parser> is developed with Privoxy 3.0.7 or later in mind,
2384 using earlier Privoxy versions will probably result in an increased amount
2385 of unrecognized log lines.
2386
2387 Privoxy's log files tend to be rather large. If you use HTML
2388 highlighting some browsers can't handle them, get confused and
2389 will eventually crash because of segmentation faults or unexpected
2390 exceptions. This is a problem in the browser and not B<privoxy-log-parser>'s
2391 fault.
2392
2393 =head1 BUGS
2394
2395 Many settings can't be controlled through command line options yet.
2396
2397 =head1 SEE ALSO
2398
2399 privoxy(1)
2400
2401 =head1 AUTHOR
2402
2403 Fabian Keil <fk@fabiankeil.de>
2404
2405 =cut