tools/privoxy-log-parser.pl

   1 #!/usr/bin/perl
   2
   3 ################################################################################
   4 # privoxy-log-parser
   5 #
   6 # A parser for Privoxy log messages. For incomplete documentation run
   7 # perldoc privoxy-log-parser(.pl), for fancy screenshots see:
   8 #
   9 # https://www.fabiankeil.de/sourcecode/privoxy-log-parser/
  10 #
  11 # TODO:
  12 #       - LOG_LEVEL_CGI, LOG_LEVEL_ERROR, LOG_LEVEL_WRITE content highlighting
  13 #       - create fancy statistics
  14 #       - grep through Privoxy sources to find unsupported log messages
  15 #       - hunt down substitutions that match content from variables which
  16 #         can contain stuff like ()?'[]
  17 #       - replace $h{'foo'} with h('foo') where possible
  18 #       - hunt down XXX comments instead of just creating them
  19 #       - add example log lines for every regex and mark them up for
  20 #         regression testing
  21 #       - Handle incomplete input without Perl warning about undefined variables.
  22 #       - Use generic highlighting function that takes a regex and the
  23 #         hash key as input.
  24 #       - Add --compress and --decompress options.
  25 #
  26 # Copyright (c) 2007-2024 Fabian Keil <fk@fabiankeil.de>
  27 #
  28 # Permission to use, copy, modify, and distribute this software for any
  29 # purpose with or without fee is hereby granted, provided that the above
  30 # copyright notice and this permission notice appear in all copies.
  31 #
  32 # THE SOFTWARE IS PROVIDED "AS IS" AND THE AUTHOR DISCLAIMS ALL WARRANTIES
  33 # WITH REGARD TO THIS SOFTWARE INCLUDING ALL IMPLIED WARRANTIES OF
  34 # MERCHANTABILITY AND FITNESS. IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR
  35 # ANY SPECIAL, DIRECT, INDIRECT, OR CONSEQUENTIAL DAMAGES OR ANY DAMAGES
  36 # WHATSOEVER RESULTING FROM LOSS OF USE, DATA OR PROFITS, WHETHER IN AN
  37 # ACTION OF CONTRACT, NEGLIGENCE OR OTHER TORTIOUS ACTION, ARISING OUT OF
  38 # OR IN CONNECTION WITH THE USE OR PERFORMANCE OF THIS SOFTWARE.
  39 ################################################################################
  40
  41 use strict;
  42 use warnings;
  43 use Getopt::Long;
  44
  45 use constant {
  46     PRIVOXY_LOG_PARSER_VERSION => '0.9.5',
  47     # Feel free to mess with these ...
  48     DEFAULT_BACKGROUND => 'black',  # Choose registered colour (like 'black')
  49     DEFAULT_TEXT_COLOUR => 'white', # Choose registered colour (like 'black')
  50     HEADER_DEFAULT_COLOUR => 'yellow',
  51     REGISTER_HEADERS_WITH_THE_SAME_COLOUR => 1,
  52
  53     CLI_OPTION_DETECT_INACTIVITY => 0,
  54     CLI_OPTION_DEFAULT_TO_HTML_OUTPUT => 0,
  55     CLI_OPTION_TITLE => 'Privoxy-Log-Parser in da house',
  56     CLI_OPTION_INACTIVITY_THRESHOLD => 100,
  57     CLI_OPTION_KEEP_DATE => 0,
  58     CLI_OPTION_NO_EMBEDDED_CSS => 0,
  59     CLI_OPTION_NO_MSECS => 0,
  60     CLI_OPTION_NO_SYNTAX_HIGHLIGHTING => 0,
  61     CLI_OPTION_SHORTEN_THREAD_IDS => 0,
  62     CLI_OPTION_SHOW_INEFFECTIVE_FILTERS => 0,
  63     CLI_OPTION_STATISTICS => 0,
  64     CLI_OPTION_STRICT_CHECKS => 0,
  65     CLI_OPTION_UNBREAK_LINES_ONLY => 0,
  66     CLI_OPTION_URL_STATISTICS_THRESHOLD => 0,
  67     CLI_OPTION_PASSED_REQUEST_STATISTICS_THRESHOLD => 0,
  68     CLI_OPTION_HOST_STATISTICS_THRESHOLD => 0,
  69     CLI_OPTION_SHOW_COMPLETE_REQUEST_DISTRIBUTION => 0,
  70
  71     SUPPRESS_SUCCEEDED_FILTER_ADDITIONS => 1,
  72     SHOW_SCAN_INTRO => 0,
  73     SHOW_FILTER_READIN_IN => 0,
  74     SUPPRESS_EMPTY_LINES => 1,
  75     SUPPRESS_SUCCESSFUL_CONNECTIONS => 1,
  76     SUPPRESS_GIF_NOT_CHANGED => 1,
  77     SUPPRESS_NEED_TO_DE_CHUNK_FIRST => 1,
  78
  79     DEBUG_HEADER_REGISTERING => 0,
  80     DEBUG_HEADER_HIGHLIGHTING => 0,
  81     DEBUG_TICKS => 0,
  82     DEBUG_PAINT_IT => 0,
  83     DEBUG_SUPPRESS_LOG_MESSAGES => 0,
  84
  85     PUNISH_MISSING_LOG_KNOWLEDGE_WITH_DEATH => 0,
  86     PUNISH_MISSING_HIGHLIGHT_KNOWLEDGE_WITH_DEATH => 1,
  87
  88     LOG_UNPARSED_LINES_TO_EXTRA_FILE => 0,
  89     ERROR_LOG_FILE => '/var/log/privoxy-log-parser',
  90
  91     # You better leave these alone unless you know what you're doing.
  92     COLOUR_RESET      => "\033[0;0m",
  93     ESCAPE => "\033[",
  94 };
  95
  96 # For performance reasons, these are global.
  97
  98 my $t;
  99 my %req; # request data from previous lines
 100 my %h;
 101 my %thread_colours;
 102 my @all_colours;
 103 my @time_colours;
 104 my $thread_colour_index = 0;
 105 my $header_colour_index = 0;
 106 my $time_colour_index = 0;
 107 my %header_colours;
 108 my $no_special_header_highlighting;
 109 my %reason_colours;
 110 my %h_colours;
 111 my $header_highlight_regex = '';
 112
 113 my $html_output_mode;
 114 my $keep_date_mode;
 115 my $no_msecs_mode; # XXX: should probably be removed
 116 my $shorten_thread_ids;
 117 my $line_end;
 118
 119 sub prepare_our_stuff() {
 120
 121     # Syntax Higlight hash
 122     @all_colours = (
 123         'red', 'green', 'brown', 'blue', 'purple', 'cyan',
 124         'light_gray', 'light_red', 'light_green', 'yellow',
 125         'light_blue', 'pink', 'light_cyan', 'white'
 126     );
 127
 128     %h = (
 129         # LOG_LEVEL
 130         Info            => 'blue',
 131         Header          => 'green',
 132         Filter          => 'purple', # XXX: Used?
 133         'Re-Filter'     => 'purple',
 134         Connect         => 'brown',
 135         Request         => 'light_cyan',
 136         Tagging         => 'purple',
 137         CGI             => 'light_green',
 138         Redirect        => 'cyan',
 139         Error           => 'light_red',
 140         Crunch          => 'cyan',
 141         'Fatal error'   => 'light_red',
 142         'Gif-Deanimate' => 'blue',
 143         Force           => 'red',
 144         Writing         => 'light_green',
 145         Received        => 'yellow',
 146         Actions         => 'yellow',
 147         # ----------------------
 148         URL                  => 'yellow',
 149         path                 => 'brown',
 150         request_             => 'brown', # host+path but no protocol
 151         'ip-address'         => 'yellow',
 152         Number               => 'yellow',
 153         Standard             => 'reset',
 154         Truncation           => 'light_red',
 155         Status               => 'brown',
 156         Timestamp            => 'brown',
 157         Crunching            => 'light_red',
 158         crunched             => 'light_red',
 159         'Request-Line'       => 'pink',
 160         method               => 'purple',
 161         destination          => 'yellow',
 162         'http-version'       => 'pink',
 163         'crunch-pattern'     => 'pink',
 164         not                  => 'brown',
 165         file                 => 'brown',
 166         signal               => 'yellow',
 167         version              => 'green',
 168         'program-name'       => 'cyan',
 169         port                 => 'red',
 170         host                 => 'red',
 171         warning              => 'light_red',
 172         debug                => 'light_red',
 173         filter               => 'green',
 174         tag                  => 'green',
 175         tagger               => 'green',
 176         'status-message'     => 'light_cyan',
 177         'status-code'        => 'yellow',
 178         'invalid-request'    => 'light_red',
 179         'hits'               => 'yellow',
 180         error                => 'light_red',
 181         'rewritten-URL'      => 'light_red',
 182         'pcrs-delimiter'     => 'light_red',
 183         'ignored'            => 'light_red',
 184         'action-bits-update' => 'light_red',
 185         'http-downgrade'     => 'light_red',
 186         'configuration-line' => 'red',
 187         'content-type'       => 'yellow',
 188         'HOST'               => HEADER_DEFAULT_COLOUR,
 189         'tls-version'        => 'pink',
 190         'cipher-suite'       => 'light_cyan',
 191     );
 192
 193     %h_colours = %h;
 194
 195     # Header colours need their own hash so the keys can be accessed properly
 196     %header_colours = (
 197         # Prefilled with headers that should not appear with default header colours
 198         Cookie => 'light_red',
 199         'Set-Cookie' => 'light_red',
 200         Warning => 'light_red',
 201         Default => HEADER_DEFAULT_COLOUR,
 202     );
 203
 204     # Crunch reasons need their own hash as well
 205     %reason_colours = (
 206         'Unsupported HTTP feature'               => 'light_red',
 207         Blocked                                  => 'light_red',
 208         Untrusted                                => 'light_red',
 209         Redirected                               => 'green',
 210         'CGI Call'                               => 'white',
 211         'DNS failure'                            => 'red',
 212         'Forwarding failed'                      => 'light_red',
 213         'Connection failure'                     => 'light_red',
 214         'Out of memory (may mask other reasons)' => 'light_red',
 215         'No reason recorded'                     => 'light_red',
 216     );
 217
 218     @time_colours = ('white', 'light_gray');
 219
 220     # Translate highlight strings into highlight code
 221     prepare_highlight_hash(\%header_colours);
 222     prepare_highlight_hash(\%reason_colours);
 223     prepare_highlight_hash(\%h);
 224     prepare_colour_array(\@all_colours);
 225     prepare_colour_array(\@time_colours);
 226     init_css_colours();
 227
 228     init_stats();
 229 }
 230
 231 sub paint_it($) {
 232 ###############################################################
 233 # Takes a colour string and returns an ANSI escape sequence
 234 # (unless --no-syntax-highlighting is used).
 235 # XXX: The Rolling Stones reference has to go.
 236 ###############################################################
 237
 238     my $colour = shift;
 239
 240     return "" if cli_option_is_set('no-syntax-highlighting');
 241
 242     my %light = (
 243         black       => 0,
 244         red         => 0,
 245         green       => 0,
 246         brown       => 0,
 247         blue        => 0,
 248         purple      => 0,
 249         cyan        => 0,
 250         light_gray  => 0,
 251         gray        => 0,
 252         dark_gray   => 1,
 253         light_red   => 1,
 254         light_green => 1,
 255         yellow      => 1,
 256         light_blue  => 1,
 257         pink        => 1,
 258         light_cyan  => 1,
 259         white       => 1,
 260     );
 261
 262     my %text = (
 263         black       => 30,
 264         red         => 31,
 265         green       => 32,
 266         brown       => 33,
 267         blue        => 34,
 268         purple      => 35,
 269         cyan        => 36,
 270         gray        => 37,
 271         light_gray  => 37,
 272         dark_gray   => 30,
 273         light_red   => 31,
 274         light_green => 32,
 275         yellow      => 33,
 276         light_blue  => 34,
 277         pink        => 35,
 278         light_cyan  => 36,
 279         white       => 37,
 280     );
 281
 282     my $bg_code = get_background();
 283     my $colour_code;
 284     our $default = default_colours();
 285
 286     if (defined($text{$colour})) {
 287         $colour_code  = ESCAPE;
 288         $colour_code .= $text{$colour};
 289         $colour_code .= ";";
 290         $colour_code .= $light{$colour} ? "1" : "2";
 291         $colour_code .= ";";
 292         $colour_code .= $bg_code;
 293         $colour_code .= "m";
 294         debug_message $colour . " is \'" . $colour_code . $colour . $default . "\'" if DEBUG_PAINT_IT;
 295
 296     } elsif ($colour =~ /reset/) {
 297
 298         $colour_code = default_colours();
 299
 300     } else {
 301
 302         die "What's $colour supposed to mean?\n";
 303     }
 304
 305     return $colour_code;
 306 }
 307
 308 sub get_semantic_html_markup($) {
 309 ###############################################################
 310 # Takes a string and returns a span element
 311 ###############################################################
 312
 313     my $type = shift;
 314     my $code;
 315
 316     if ($type =~ /Standard/) {
 317         $code = '</span>';
 318     } else {
 319         $type = lc($type);
 320         $code = '<span title="' . $type . '" class="' . $type . '">';
 321     }
 322
 323     return $code;
 324 }
 325
 326 sub cli_option_is_set($) {
 327
 328     our %cli_options;
 329     my $cli_option = shift;
 330
 331     die "Unknown CLI option: $cli_option" unless defined $cli_options{$cli_option};
 332
 333     return $cli_options{$cli_option};
 334 }
 335
 336 sub get_html_title() {
 337
 338     our %cli_options;
 339     return $cli_options{'title'};
 340
 341 }
 342
 343 sub init_css_colours() {
 344
 345     our %css_colours = (
 346         black       => "000",
 347         red         => "F00",
 348         green       => "0F0",
 349         brown       => "C90",
 350         blue        => "0F0",
 351         purple      => "F06", # XXX: wrong
 352         cyan        => "F09", # XXX: wrong
 353         light_gray  => "999",
 354         gray        => "333",
 355         dark_gray   => "222",
 356         light_red   => "F33",
 357         light_green => "33F",
 358         yellow      => "FF0",
 359         light_blue  => "30F",
 360         pink        => "F0F",
 361         light_cyan  => "66F",
 362         white       => "FFF",
 363     );
 364 }
 365
 366 sub get_css_colour($) {
 367
 368    our %css_colours;
 369    my $colour = shift;
 370
 371    die "What's $colour supposed to mean?\n" unless defined($css_colours{$colour});
 372
 373    return '#' . $css_colours{$colour};
 374 }
 375
 376 sub get_css_line($) {
 377
 378     my $class = shift;
 379     my $css_line;
 380
 381     $css_line .= '.' . lc($class) . ' {'; # XXX: lc() shouldn't be necessary
 382     die "What's $class supposed to mean?\n" unless defined($h_colours{$class});
 383     $css_line .= 'color:' . get_css_colour($h_colours{$class}) . ';';
 384     $css_line .= 'background-color:' . get_css_colour(DEFAULT_BACKGROUND) . ';';
 385     $css_line .= '}' . "\n";
 386
 387     return $css_line;
 388 }
 389
 390 sub get_css_line_for_colour($) {
 391
 392     my $colour = shift;
 393     my $css_line;
 394
 395     $css_line .= '.' . lc($colour) . ' {'; # XXX: lc() shouldn't be necessary
 396     $css_line .= 'color:' . get_css_colour($colour) . ';';
 397     $css_line .= 'background-color:' . get_css_colour(DEFAULT_BACKGROUND) . ';';
 398     $css_line .= '}' . "\n";
 399
 400     return $css_line;
 401 }
 402
 403 # XXX: Wrong solution
 404 sub get_missing_css_lines() {
 405
 406     my $css_line;
 407
 408     $css_line .= '.' . 'default' . ' {';
 409     $css_line .= 'color:' . HEADER_DEFAULT_COLOUR . ';';
 410     $css_line .= 'background-color:' . get_css_colour(DEFAULT_BACKGROUND) . ';';
 411     $css_line .= '}' . "\n";
 412
 413     return $css_line;
 414 }
 415
 416 sub get_css() {
 417
 418     our %css_colours; #XXX: Wrong solution
 419
 420     my $css = '';
 421
 422     $css .= '.privoxy-log {';
 423     $css .= 'color:' . get_css_colour(DEFAULT_TEXT_COLOUR) . ';';
 424     $css .= 'background-color:' . get_css_colour(DEFAULT_BACKGROUND) . ';';
 425     $css .= '}' . "\n";
 426
 427     foreach my $key (keys %h_colours) {
 428
 429         next if ($h_colours{$key} =~ m/reset/); #XXX: Wrong solution.
 430         $css .= get_css_line($key);
 431
 432     }
 433
 434     foreach my $colour (keys %css_colours) {
 435
 436         $css .= get_css_line_for_colour($colour);
 437
 438     }
 439
 440     $css .= get_missing_css_lines(); #XXX: Wrong solution
 441
 442     return $css;
 443 }
 444
 445 sub print_intro() {
 446
 447     my $intro = '';
 448
 449     if (cli_option_is_set('html-output')) {
 450
 451         my $title = get_html_title();
 452
 453         $intro .= '<html><head>';
 454         $intro .= '<title>' . $title . '</title>';
 455         $intro .= '<style>' . get_css() . '</style>' unless cli_option_is_set('no-embedded-css');
 456         $intro .= '</head><body>';
 457         $intro .= '<h1>' . $title . '</h1><p class="privoxy-log">';
 458
 459         print $intro;
 460     }
 461 }
 462
 463 sub print_outro() {
 464
 465     my $outro = '';
 466
 467     if (cli_option_is_set('html-output')) {
 468
 469         $outro = '</p></body></html>';
 470         print $outro;
 471
 472     }
 473 }
 474
 475 sub get_line_end() {
 476     return cli_option_is_set('html-output') ? "<br>\n" : "\n";
 477 }
 478
 479 sub get_colour_html_markup($) {
 480 ###############################################################
 481 # Takes a colour string a span element. XXX: WHAT?
 482 # XXX: This function shouldn't be necessary, the
 483 # markup should always be semantically correct.
 484 ###############################################################
 485
 486     my $type = shift;
 487     my $code;
 488
 489     if ($type =~ /Standard/) {
 490         $code = '</span>';
 491     } else {
 492         $code = '<span class="' . lc($type) . '">';
 493     }
 494
 495     return $code;
 496 }
 497
 498 sub default_colours() {
 499     # XXX: Properly
 500     our $bg_code;
 501     return reset_colours();
 502 }
 503
 504 sub show_colours() {
 505     # XXX: Implement
 506 }
 507
 508 sub reset_colours() {
 509     return ESCAPE . "0m";
 510 }
 511
 512 sub set_background($) {
 513
 514     my $colour = shift;
 515     our $bg_code;
 516     my %backgrounds = (
 517               black       => "40",
 518               red         => "41",
 519               green       => "42",
 520               brown       => "43",
 521               blue        => "44",
 522               magenta     => "45",
 523               cyan        => "46",
 524               white       => "47",
 525               default     => "49",
 526     );
 527
 528     if (defined($backgrounds{$colour})) {
 529         $bg_code = $backgrounds{$colour};
 530     } else {
 531         die "Invalid background colour: " . $colour;
 532     }
 533 }
 534
 535 sub get_background() {
 536     return our $bg_code;
 537 }
 538
 539 sub prepare_highlight_hash($) {
 540     my $ref = shift;
 541
 542     foreach my $key (keys %$ref) {
 543         $$ref{$key} = $html_output_mode ?
 544             get_semantic_html_markup($key) :
 545             paint_it($$ref{$key});
 546     }
 547 }
 548
 549 sub prepare_colour_array($) {
 550     my $ref = shift;
 551
 552     foreach my $i (0 ... @$ref - 1) {
 553         $$ref[$i] = $html_output_mode ?
 554             get_colour_html_markup($$ref[$i]) :
 555             paint_it($$ref[$i]);
 556     }
 557 }
 558
 559 sub found_unknown_content($) {
 560
 561     my $unknown = shift;
 562     my $message;
 563
 564     return unless cli_option_is_set('strict-checks');
 565
 566     return if ($unknown =~ /\[too long, truncated\]$/);
 567
 568     $message = "found_unknown_content: Don't know how to highlight: ";
 569     # Break line so the log file can later be parsed as Privoxy log file again
 570     $message .= '"' . $unknown . '"' . " in:\n";
 571     $message .= $req{$t}{'log-message'};
 572     debug_message($message);
 573     log_parse_error($req{$t}{'log-message'});
 574
 575     die "Unworthy content parser" if PUNISH_MISSING_LOG_KNOWLEDGE_WITH_DEATH;
 576 }
 577
 578 sub log_parse_error($) {
 579
 580     my $message = shift;
 581
 582     if (LOG_UNPARSED_LINES_TO_EXTRA_FILE) {
 583         open(my $errorlog_fd, ">>", ERROR_LOG_FILE) || die "Writing " . ERROR_LOG_FILE . " failed";
 584         print $errorlog_fd $message;
 585         close($errorlog_fd);
 586     }
 587 }
 588
 589 sub debug_message(@) {
 590     my @message = @_;
 591
 592     print $h{'debug'} . "@message" . $h{'Standard'} . "\n";
 593 }
 594
 595 ################################################################################
 596 # highlighter functions that aren't loglevel-specific
 597 ################################################################################
 598
 599 sub h($) {
 600
 601     # Get highlight marker
 602     my $highlight = shift; # XXX: Stupid name;
 603     my $result = '';
 604     my $message;
 605
 606     if (defined($highlight)) {
 607
 608         $result = $h{$highlight};
 609
 610     } else {
 611
 612         $message = "h: Don't recognize highlighter $highlight.";
 613         debug_message($message);
 614         log_parser_error($message);
 615         die "Unworthy highlighter function" if PUNISH_MISSING_HIGHLIGHT_KNOWLEDGE_WITH_DEATH;
 616     }
 617
 618     return $result;
 619 }
 620
 621 sub highlight_known_headers($) {
 622
 623     my $content = shift;
 624
 625     debug_message("Searching $content for things to highlight.") if DEBUG_HEADER_HIGHLIGHTING;
 626
 627     if ($content =~ m/(?<=\s)($header_highlight_regex):/) {
 628         my $header = $1;
 629         $content =~ s@(?<=[\s|'])($header)(?=:)@$header_colours{$header}$1$h{'Standard'}@ig;
 630         debug_message("Highlighted '$header' in '$content'") if DEBUG_HEADER_HIGHLIGHTING;
 631     }
 632
 633     return $content;
 634 }
 635
 636 sub highlight_matched_request_line($$) {
 637
 638     my $result = shift; # XXX: Stupid name;
 639     my $regex = shift;
 640     if ($result =~ m@(.*)($regex)(.*)@) {
 641         $result = $1 . highlight_request_line($2) . $3
 642     }
 643     return $result;
 644 }
 645
 646 sub highlight_request_line($) {
 647
 648     my $rl = shift;
 649     my ($method, $url, $http_version);
 650
 651     #GET http://images.sourceforge.net/sfx/icon_warning.gif HTTP/1.1
 652     if ($rl =~ m/Invalid request/ or $rl =~ m/Failed reading chunked client body/) {
 653
 654         $rl = h('invalid-request') . $rl . h('Standard');
 655
 656     } elsif ($rl =~ m/^([-\w]+) (.*) (HTTP\/\d+\.\d+)/) {
 657
 658         # XXX: might not match in case of HTTP method fuzzing.
 659         # XXX: save these: ($method, $path, $http_version) = ($1, $2, $3);
 660         $rl =~ s@^(\w+)@$h{'method'}$1$h{'Standard'}@;
 661         if ($rl =~ /http:\/\//) {
 662             $rl = highlight_matched_url($rl, '[^\s]*(?=\sHTTP)');
 663         } else {
 664             $rl = highlight_matched_pattern($rl, 'request_', '[^\s]*(?=\sHTTP)');
 665         }
 666
 667         $rl =~ s@(HTTP\/\d\.\d)$@$h{'http-version'}$1$h{'Standard'}@;
 668
 669     } elsif ($rl =~ m/\.\.\. \[too long, truncated\]$/) {
 670
 671         $rl =~ s@^(\w+)@$h{'method'}$1$h{'Standard'}@;
 672         $rl = highlight_matched_url($rl, '[^\s]*(?=\.\.\.)');
 673
 674     } elsif ($rl =~ m/^ $/) {
 675
 676         $rl = h('error') . "No request line specified!" . h('Standard');
 677
 678     } else {
 679
 680         debug_message ("Can't parse request line: $rl");
 681
 682     }
 683
 684     return $rl;
 685 }
 686
 687 sub highlight_response_line($) {
 688
 689     my $rl = shift;
 690     my ($http_version, $status_code, $status_message);
 691
 692     #HTTP/1.1 200 OK
 693     #ICY 200 OK
 694
 695     # TODO: Mark different status codes differently
 696
 697     if ($rl =~ m/((?:HTTP\/\d\.\d|ICY)) (\d+) (.*)/) {
 698         ($http_version, $status_code, $status_message) = ($1, $2, $3);
 699     } else {
 700         debug_message ("Can't parse response line: $rl") and die 'Fix this';
 701     }
 702
 703     # Rebuild highlighted
 704     $rl= "";
 705     $rl .= h('http-version') . $http_version . h('Standard');
 706     $rl .= " ";
 707     $rl .= h('status-code') . $status_code . h('Standard');
 708     $rl .= " ";
 709     $rl .= h('status-message') . $status_message . h('Standard');
 710
 711     return $rl;
 712 }
 713
 714 sub highlight_matched_url($$) {
 715
 716     my $result = shift; # XXX: Stupid name;
 717     my $regex = shift;
 718
 719     #print "Got $result, regex ($regex)\n";
 720
 721     if ($result =~ m@(.*?)($regex)(.*)@) {
 722         $result = $1 . highlight_url($2) . $3;
 723         #print "Now the result is $result\n";
 724     }
 725
 726     return $result;
 727 }
 728
 729 sub highlight_matched_host($$) {
 730
 731     my ($result, $regex) = @_; # XXX: result ist stupid name;
 732
 733     if ($result =~ m@(.*?)($regex)(.*)@) {
 734         $result = $1 . $h{host} . $2 . $h{Standard} . $3;
 735     }
 736
 737     return $result;
 738 }
 739
 740 sub highlight_matched_pattern($$$) {
 741
 742     my $result = shift; # XXX: Stupid name;
 743     my $key = shift;
 744     my $regex = shift;
 745
 746     die "Unknown key $key" unless defined $h{$key};
 747
 748     if ($result =~ m@(.*?)($regex)(.*)@) {
 749         $result = $1 . h($key) . $2 . h('Standard') . $3;
 750     }
 751
 752     return $result;
 753 }
 754
 755 sub highlight_matched_path($$) {
 756
 757     my $result = shift; # XXX: Stupid name;
 758     my $regex = shift;
 759
 760     if ($result =~ m@(.*?)($regex)(.*)@) {
 761         $result = $1 . h('path') . $2 . h('Standard') . $3;
 762     }
 763
 764     return $result;
 765 }
 766
 767 sub highlight_url($) {
 768
 769     my $url = shift;
 770
 771     if ($html_output_mode) {
 772
 773         $url = '<a href="' . $url . '">' . $url . '</a>';
 774
 775     } else {
 776
 777         $url = h('URL') . $url . h('Standard');
 778
 779     }
 780
 781     return $url;
 782 }
 783
 784 sub update_header_highlight_regex($) {
 785
 786     my $header = shift;
 787     my $headers = join ('|', keys %header_colours);
 788
 789     $header_highlight_regex = qr/$headers/;
 790     print "Registering '$header'\n" if DEBUG_HEADER_HIGHLIGHTING;
 791 }
 792
 793 ################################################################################
 794 # loglevel-specific highlighter functions
 795 ################################################################################
 796
 797 sub handle_loglevel_header($) {
 798
 799     my $c = shift;
 800
 801     if ($c =~ /^scan:/) {
 802
 803         if ($c =~ m/^scan: ([^: ]+):/) {
 804
 805             # Register new headers
 806             # scan: Accept: image/png,image/*;q=0.8,*/*;q=0.5
 807             my $header = $1;
 808             if (!defined($header_colours{$header}) and $header =~ /^[\d\w-]*$/) {
 809                 debug_message "Registering previously unknown header $1" if DEBUG_HEADER_REGISTERING;
 810
 811                 if (REGISTER_HEADERS_WITH_THE_SAME_COLOUR) {
 812                     $header_colours{$header} =  $header_colours{'Default'};
 813                 } else {
 814                     $header_colours{$header} = $all_colours[$header_colour_index % @all_colours];
 815                     $header_colour_index++;
 816                 }
 817                 update_header_highlight_regex($header);
 818             }
 819
 820         } elsif ($c =~ m/^(scan: )(\w+ .+ HTTP\/\d\.\d)/) {
 821
 822             # scan: GET http://p.p/ HTTP/1.1
 823             $c = $1 . highlight_request_line($2);
 824
 825         } elsif ($c =~ m/^(scan: )((?:HTTP\/\d\.\d|ICY) (\d+) (.*))/) {
 826
 827             # scan: HTTP/1.1 200 OK
 828             $req{$t}{'response_line'} = $2;
 829             $req{$t}{'status_code'} = $3;
 830             $req{$t}{'status_message'} = $4;
 831             $c = $1 . highlight_response_line($req{$t}{'response_line'});
 832         }
 833
 834     } elsif ($c =~ m/^Crunching (?:server|client) header: .* \(contains: ([^\)]*)\)/) {
 835
 836         # Crunching server header: Set-Cookie: trac_form_token=d5308c34e16d15e9e301a456; (contains: Cookie:)
 837         $c =~ s@(?<=contains: )($1)@$h{'crunch-pattern'}$1$h{'Standard'}@;
 838         $c =~ s@(Crunching)@$h{$1}$1$h{'Standard'}@;
 839
 840     } elsif ($c =~ m/^New host is: ([^\s]*)\./) {
 841
 842         # New host is: trac.vidalia-project.net. Crunching Referer: http://www.vidalia-project.net/!
 843         $c = highlight_matched_host($c, '(?<=New host is: )[^\s]+(?=\.)');
 844         $c = highlight_matched_url($c, '(?<=Crunching Referer: )[^\s!]+');
 845
 846     } elsif ($c =~ m/^Text mode enabled by force. (Take cover)!/) {
 847
 848         # Text mode enabled by force. Take cover!
 849         $c =~ s@($1)@$h{'warning'}$1$h{'Standard'}@;
 850
 851     } elsif ($c =~ m/^(New HTTP Request-Line: )(.*)/) {
 852
 853         # New HTTP Request-Line: GET http://www.privoxy.org/ HTTP/1.1
 854         $c = $1 . highlight_request_line($2);
 855
 856     } elsif ($c =~ m/^Adjust(ed)? Content-Length to \d+/) {
 857
 858         # Adjusted Content-Length to 2132
 859         # Adjust Content-Length to 33533
 860         $c =~ s@(?<=Content-Length to )(\d+)@$h{'Number'}$1$h{'Standard'}@;
 861         $c = highlight_known_headers($c);
 862
 863     } elsif ($c =~ m/^Destination extracted from "Host:" header. New request URL:/) {
 864
 865         # Destination extracted from "Host:" header. New request URL: http://www.cccmz.de/~ridcully/blog/
 866         $c = highlight_matched_url($c, '(?<=New request URL: ).*');
 867
 868     } elsif ($c =~ m/^Couldn\'t parse:/) {
 869
 870         # XXX: These should probable be logged with LOG_LEVEL_ERROR
 871         # Couldn't parse: If-Modified-Since: Wed, 21 Mar 2007 16:34:50 GMT (crunching!)
 872         # Couldn't parse: at, 24 Mar 2007 13:46:21 GMT in If-Modified-Since: Sat, 24 Mar 2007 13:46:21 GMT (crunching!)
 873         $c =~ s@^(Couldn\'t parse)@$h{'error'}$1$h{'Standard'}@;
 874
 875     } elsif ($c =~ /^Tagger \'([^\']*)\' added tag \'([^\']*)\'/ or
 876              $c =~ m/^Adding tag \'([^\']*)\' created by header tagger \'([^\']*)\'/) {
 877
 878         # Adding tag 'GET request' created by header tagger 'method-man' (XXX: no longer used)
 879         # Tagger 'revalidation' added tag 'REVALIDATION-REQUEST'. No action bit update necessary.
 880         # Tagger 'revalidation' added tag 'REVALIDATION-REQUEST'. Action bits updated accordingly.
 881
 882         # XXX: Save tag and tagger
 883
 884         $c =~ s@(?<=^Tagger \')([^\']*)@$h{'tagger'}$1$h{'Standard'}@;
 885         $c =~ s@(?<=added tag \')([^\']*)@$h{'tag'}$1$h{'Standard'}@;
 886         $c =~ s@(?<=Action bits )(updated)@$h{'action-bits-update'}$1$h{'Standard'}@;
 887         $no_special_header_highlighting = 1;
 888
 889     } elsif ($c =~ /^Tagger \'([^\']*)\' didn['']t add tag \'([^\']*)\'/) {
 890
 891         # Tagger 'revalidation' didn't add tag 'REVALIDATION-REQUEST'. Tag already present
 892         # XXX: Save tag and tagger
 893
 894         $c =~ s@(?<=^Tagger \')([^\']*)@$h{'tag'}$1$h{'Standard'}@;
 895         $c =~ s@(?<=didn['']t add tag \')([^\']*)@$h{'tagger'}$1$h{'Standard'}@;
 896
 897     } elsif ($c =~ m/^(?:scan:|Randomiz|addh:|Adding:|Removing:|Referer:|Modified:|Accept-Language header|[Cc]ookie)/
 898           or $c =~ m/^(Text mode is already enabled|Denied request with NULL byte|Replaced:|add-unique:)/
 899           or $c =~ m/^(Crunched (incoming|outgoing) cookie|Suppressed offer|Accepted the client)/
 900           or $c =~ m/^(addh-unique|Referer forged to)/
 901           or $c =~ m/^Downgraded answer to HTTP\/1.0/
 902           or $c =~ m/^Parameter: \+hide-referrer\{[^\}]*\} is a bad idea, but I don\'t care./
 903           or $c =~ m/^Referer (?:overwritten|replaced) with: Referer: / #XXX: should this be highlighted?
 904           or $c =~ m/^Referer crunched!/
 905           or $c =~ m/^crunched x-forwarded-for!/
 906           or $c =~ m/^crunched From!/
 907           or $c =~ m/^ modified$/
 908           or $c =~ m/^Content filtering is enabled. Crunching:/
 909           or $c =~ m/^force-text-mode overruled the client/
 910           or $c =~ m/^Server time in the future\./
 911           or $c =~ m/^content-disposition header crunched and replaced with:/i
 912           or $c =~ m/^Reducing white space in /
 913           or $c =~ m/^Ignoring single quote in /
 914           or $c =~ m/^Converting tab to space in /
 915           or $c =~ m/A HTTP\/1\.1 response without/
 916           or $c =~ m/Disabled filter mode on behalf of the client/
 917           or $c =~ m/Keeping the (?:server|client) header /
 918           or $c =~ m/Content modified with no Content-Length header set/
 919           or $c =~ m/^Appended client IP address to/
 920           or $c =~ m/^Removing 'Connection: close' to imply keep-alive./
 921           or $c =~ m/^keep-alive support is disabled/
 922           or $c =~ m/^Continue hack in da house/
 923           or $c =~ m/^Merged multiple header lines to:/
 924           or $c =~ m/^Added header: /
 925           or $c =~ m/^Enlisting (?:sorted|left-over) header/
 926           or $c =~ m/^Multiple Content-Type headers detected. Removing and ignoring: Content-Type:/
 927             )
 928     {
 929         # XXX: Some of these may need highlighting
 930
 931         # Modified: User-Agent: Mozilla/5.0 (X11; U; SunOS i86pc; pl-PL; rv:1.8.1.1) Gecko/20070214 Firefox/2.0.0.1
 932         # Accept-Language header crunched and replaced with: Accept-Language: pl-pl
 933         # cookie 'Set-Cookie: eZSessionCookie=07bfec287c197440d299f81580593c3d; \
 934         #  expires=Thursday, 12-Apr-07 15:16:18 GMT; path=/' send by \
 935         #  http://wirres.net/article/articleview/4265/1/6/ appears to be using time format 1 (XXX: gone with the wind)
 936         # Cookie rewritten to a temporary one: Set-Cookie: NSC_gffe-iuuq-mc-wtfswfs=8efb33a53660;path=/
 937         # Text mode is already enabled
 938         # Denied request with NULL byte(s) turned into line break(s)
 939         # Replaced: 'Connection: Yo, home to Bel Air' with 'Connection: close'
 940         # addh-unique: Host: people.freebsd.org
 941         # Suppressed offer to compress content
 942         # Crunched incoming cookie -- yum!
 943         # Accepted the client's request to fetch without filtering.
 944         # Crunched outgoing cookie: Cookie: PREF=ID=6cf0abd347b30262:TM=1173357617:LM=1173357617:S=jZypyyJ7LPiwFi1_
 945         # addh-unique: Host: subkeys.pgp.net:11371
 946         # Referer forged to: Referer: http://10.0.0.1/
 947         # Downgraded answer to HTTP/1.0
 948         # Parameter: +hide-referrer{pille-palle} is a bad idea, but I don't care.
 949         # Referer overwritten with: Referer: pille-palle
 950         # Referer replaced with: Referer: pille-palle
 951         # crunched x-forwarded-for!
 952         # crunched From!
 953         #  modified # XXX: pretty stupid log message
 954         # Content filtering is enabled. Crunching: 'Range: 1234-5678' to prevent range-mismatch problems
 955         # force-text-mode overruled the client's request to fetch without filtering!
 956         # Server time in the future.
 957         # content-disposition header crunched and replaced with: content-disposition: filename=baz
 958         # Content-Disposition header crunched and replaced with: content-disposition: filename=baz
 959         # Reducing white space in 'X-LWS-Test: "This  is  quoted" this is not "this  is  " but " this again   is  not'
 960         # Ignoring single quote in 'X-LWS-Test: "This  is  quoted" this is not "this  is  " but "  this again   is  not'
 961         # Converting tab to space in 'X-LWS-Test:   "This  is  quoted" this   is  not "this  is  "  but  "\
 962         #  this again   is  not'
 963         # A HTTP/1.1 response without Connection header implies keep-alive.
 964         # Disabled filter mode on behalf of the client.
 965         # Keeping the server header 'Connection: keep-alive' around.
 966         # Keeping the client header 'Connection: close' around. The connection will not be kept alive.
 967         # Keeping the client header 'Connection: keep-alive' around. The connection will be kept alive if possible.
 968         # Content modified with no Content-Length header set. Creating a fake one for adjustment later on.
 969         # Appended client IP address to X-Forwarded-For: 10.0.0.2, 10.0.0.1
 970         # Removing 'Connection: close' to imply keep-alive.
 971         # keep-alive support is disabled. Crunching: Keep-Alive: 300.
 972         # Continue hack in da house.
 973         # Merged multiple header lines to: 'X-FORWARDED-PROTO: http X-HOST: 127.0.0.1'
 974         # Added header: Content-Encoding: deflate
 975         # Enlisting sorted header User-Agent: Mozilla/5.0 (X11; SunOS i86pc; rv:10.0.3) Gecko/20100101 Firefox/10.0.3
 976         # Enlisting left-over header Connection: close
 977         # Multiple Content-Type headers detected. Removing and ignoring: Content-Type: text/html
 978
 979     } elsif ($c =~ m/^scanning headers for:/) {
 980
 981         return '' unless SHOW_SCAN_INTRO;
 982
 983     } elsif ($c =~ m/^[Cc]runch(ing|ed)|crumble crunched:/) {
 984         # crunched User-Agent!
 985         # Crunching: Content-Encoding: gzip
 986
 987         $c =~ s@(Crunching|crunched)@$h{$1}$1$h{'Standard'}@;
 988
 989     } elsif ($c =~ m/^Offending request data with NULL bytes turned into \'°\' characters:/) {
 990
 991         # Offending request data with NULL bytes turned into '°' characters: °°n°°(°°°
 992
 993         $c = h('warning') . $c . h('Standard');
 994
 995     } elsif ($c =~ m/^(Transforming \")(.*?)(\" to \")(.*?)(\")/) {
 996
 997         # Transforming "Proxy-Authenticate: Basic realm="Correos Proxy Server"" to\
 998         #  "Proxy-Authenticate: Basic realm="Correos Proxy Server""
 999
1000        $c =~ s@(?<=^Transforming \")(.*)(?=\" to)@$h{'Header'}$1$h{'Standard'}@;
1001        $c =~ s@(?<=to \")(.*)(?=\")@$h{'Header'}$1$h{'Standard'}@;
1002
1003     } elsif ($c =~ m/^Removing empty header/) {
1004
1005         # Removing empty header
1006         # Ignore for now
1007
1008     } elsif ($c =~ m/^Content-Type: .* not replaced/) {
1009
1010         # Content-Type: application/octet-stream not replaced. It doesn't look like text.\
1011         #  Enable force-text-mode if you know what you're doing.
1012         # XXX: Could highlight more here.
1013         $c =~ s@(?<=^Content-Type: )(.*)(?= not replaced)@$h{'content-type'}$1$h{'Standard'}@;
1014
1015     } elsif ($c =~ m/^(Server|Client) keep-alive timeout is/) {
1016
1017        # Server keep-alive timeout is 5. Sticking with 10.
1018        # Client keep-alive timeout is 20. Sticking with 10.
1019
1020        $c =~ s@(?<=timeout is )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1021        $c =~ s@(?<=Sticking with )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1022
1023     } elsif ($c =~ m/^Reducing keep-alive timeout/) {
1024
1025        # Reducing keep-alive timeout from 60 to 10.
1026
1027        $c =~ s@(?<= from )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1028        $c =~ s@(?<= to )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1029
1030     } elsif ($c =~ m/^Killed all-caps Host header line: HOST:/) {
1031
1032        # Killed all-caps Host header line: HOST: bestproxydb.com
1033        $c = highlight_matched_host($c, '(?<=HOST: )[^\s]+');
1034        $c = highlight_matched_pattern($c, 'HOST', 'HOST');
1035
1036     } else {
1037
1038         found_unknown_content($c);
1039     }
1040
1041     # Highlight headers
1042     unless ($c =~ m/^Transforming/) {
1043         $c = highlight_known_headers($c) unless $no_special_header_highlighting;
1044     }
1045
1046     return $c;
1047 }
1048
1049 sub handle_loglevel_re_filter($) {
1050
1051     my $content = shift;
1052     my $c = $content;
1053     my $key;
1054
1055     if ($c =~ m/^(?:re_)?filtering ([^\s]+) \(size (\d+)\) with (?:filter )?\'?([^\s]+?)\'? produced (\d+) hits \(new size (\d+)\)/) {
1056
1057         # XXX: only the second version gets highlighted properly.
1058         # re_filtering www.lfk.de/favicon.ico (size 209) with filter untrackable-hulk produced 0 hits (new size 209).
1059         # filtering aci.blogg.de/ (size 37988) with 'blogg.de' produced 3 hits (new size 38057)
1060         $req{$t}{'content_source'} = $1;
1061         $req{$t}{'content_size'}   = $2;
1062         $req{$t}{'content_filter'} = $3;
1063         $req{$t}{'content_hits'}   = $4;
1064         $req{$t}{'new_content_size'} = $5;
1065         $req{$t}{'content_size_change'} = $req{$t}{'new_content_size'} - $req{$t}{'content_size'};
1066         #return '' if ($req{$t}{'content_hits'} == 0 && !cli_option_is_set('show-ineffective-filters'));
1067         if ($req{$t}{'content_hits'} == 0 and
1068             not (cli_option_is_set('show-ineffective-filters')
1069                  or ($req{$t}{'content_filter'} =~ m/^privoxy-filter-test$/))) {
1070                 return '';
1071         }
1072
1073         $c =~ s@(?<=\(size )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1074         $c =~ s@(?<=\(new size )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1075         $c =~ s@(?<=produced )(\d+)(?= hits)@$h{'Number'}$1$h{'Standard'}@;
1076
1077         $c =~ s@([^\s]+?)(\'? produced)@$h{'filter'}$1$h{'Standard'}$2@;
1078         $c = highlight_matched_host($c, '(?<=filtering )[^\s]+');
1079
1080         $c =~ s@\.$@ @;
1081         $c .= "(" . $h{'Number'};
1082         $c .= "+" if ($req{$t}{'content_size_change'} >= 0);
1083         $c .= $req{$t}{'content_size_change'} . $h{'Standard'} . ")";
1084         $content = $c;
1085
1086     } elsif ($c =~ m/^filtering request body from client /) {
1087
1088         # filtering request body from client 127.0.0.1 (size 958) with 'null-filter' produced 0 hits (new size 958).
1089
1090         $c =~ s@(?<=from client )([^\s]+)@$h{'ip-address'}$1$h{'Standard'}@;
1091         $c =~ s@(?<=\(size )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1092         $c =~ s@([^\s]+?)(\'? produced)@$h{'filter'}$1$h{'Standard'}$2@;
1093         $c =~ s@(?<=\(new size )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1094         $c =~ s@(?<=produced )(\d+)(?= hits)@$h{'Number'}$1$h{'Standard'}@;
1095         $content = $c;
1096
1097   } elsif ($c =~ /\.{3}$/
1098         and $c =~ m/^(?:re_)?filtering \'?(.*?)\'? \(size (\d*)\) with (?:filter )?\'?([^\s]*?)\'? ?\.{3}$/) {
1099
1100         # Used by Privoxy 3.0.5 and 3.0.6:
1101         # XXX: Fill in ...
1102         # Used by Privoxy 3.0.7:
1103         # filtering 'Connection: close' (size 17) with 'generic-content-ads' ...
1104
1105         $req{$t}{'filtered_header'} = $1;
1106         $req{$t}{'old_header_size'} = $2;
1107         $req{$t}{'header_filter_name'} = $3;
1108
1109         unless (cli_option_is_set('show-ineffective-filters') or
1110                 $req{$t}{'header_filter_name'} =~ m/^privoxy-filter-test$/) {
1111             return '';
1112         }
1113         $content =~ s@(?<=\(size )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1114         $content =~ s@($req{$t}{'header_filter_name'})@$h{'filter'}$1$h{'Standard'}@;
1115
1116     } elsif ($c =~ m/^ ?\.\.\. ?produced (\d*) hits \(new size (\d*)\)\./) {
1117
1118         # ...produced 0 hits (new size 23).
1119         #... produced 1 hits (new size 54).
1120
1121         $req{$t}{'header_filter_hits'} = $1;
1122         $req{$t}{'new_header_size'} = $2;
1123
1124         unless (cli_option_is_set('show-ineffective-filters') or
1125                 (defined($req{$t}{'header_filter_name'}) and
1126                  $req{$t}{'header_filter_name'} =~ m/^privoxy-filter-test$/)) {
1127
1128             if ($req{$t}{'header_filter_hits'} == 0 and
1129                 not (defined($req{$t}{'header_filter_name'}) and
1130                  $req{$t}{'header_filter_name'} =~ m/^privoxy-filter-test$/)) {
1131                 return '';
1132             }
1133             # Reformat including information from the intro
1134             $c = "'" . h('filter') . $req{$t}{'header_filter_name'} . h('Standard') . "'";
1135             $c .= " hit ";
1136             # XXX: Hide behind constant, it may be interesting if LOG_LEVEL_HEADER isn't enabled as well.
1137             # $c .= $req{$t}{'filtered_header'} . " ";
1138             $c .= h('Number') . $req{$t}{'header_filter_hits'}. h('Standard');
1139             $c .= ($req{$t}{'header_filter_hits'} == 1) ? " time, " : " times, ";
1140
1141             if ($req{$t}{'old_header_size'} !=  $req{$t}{'new_header_size'}) {
1142
1143                 $c .= "changing size from ";
1144                 $c .=  h('Number') . $req{$t}{'old_header_size'} . h('Standard');
1145                 $c .= " to ";
1146                 $c .= h('Number') . $req{$t}{'new_header_size'} . h('Standard');
1147                 $c .= ".";
1148
1149             } else {
1150
1151                 $c .= "keeping the size at " . $req{$t}{'old_header_size'};
1152
1153             }
1154
1155             # Highlight from last line (XXX: What?)
1156             # $c =~ s@(?<=produced )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1157             # $c =~ s@($req{$t}{'header_filter_name'})@$h{'filter'}$1$h{'Standard'}@;
1158
1159         } else {
1160
1161            # XXX: Untested
1162            $c =~ s@(?<=produced )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1163            $c =~ s@(?<=new size )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1164
1165         }
1166         $content = $c;
1167
1168     } elsif ($c =~ m/^(Tagger|Filter) ([^\s]*) has empty joblist. Nothing to do./) {
1169
1170         # Filter privoxy-filter-test has empty joblist. Nothing to do.
1171         # Tagger variable-test has empty joblist. Nothing to do.
1172
1173         $content =~ s@(?<=$1 )([^\s]*)@$h{'filter'}$1$h{'Standard'}@;
1174
1175     } elsif ($c =~ m/^De-chunking successful. Shrunk from (\d+) to (\d+)/) {
1176
1177         $req{$t}{'chunked-size'} = $1;
1178         $req{$t}{'dechunked-size'} = $2;
1179         $req{$t}{'dechunk-change'} = $req{$t}{'dechunked-size'} - $req{$t}{'chunked-size'};
1180
1181         $content .= " (" . h('Number') . $req{$t}{'dechunk-change'} . h('Standard') . ")";
1182
1183         $content =~ s@(?<=from )($req{$t}{'chunked-size'})@$h{'Number'}$1$h{'Standard'}@;
1184         $content =~ s@(?<=to )($req{$t}{'dechunked-size'})@$h{'Number'}$1$h{'Standard'}@;
1185
1186     } elsif ($c =~ m/^Decompression successful. Old size: (\d+), new size: (\d+)./) {
1187
1188         # Decompression successful. Old size: 670, new size: 1166.
1189
1190         $req{$t}{'size-compressed'} = $1;
1191         $req{$t}{'size-decompressed'} = $2;
1192         $req{$t}{'decompression-gain'} = $req{$t}{'size-decompressed'} - $req{$t}{'size-compressed'};
1193
1194         $content =~ s@(?<=Old size: )($req{$t}{'size-compressed'})@$h{'Number'}$1$h{'Standard'}@;
1195         $content =~ s@(?<=new size: )($req{$t}{'size-decompressed'})@$h{'Number'}$1$h{'Standard'}@;
1196
1197         # XXX: Create sub get_percentage()
1198         if ($req{$t}{'size-decompressed'}) {
1199             $req{$t}{'decompression-gain-percent'} =
1200                 $req{$t}{'decompression-gain'} / $req{$t}{'size-decompressed'} * 100;
1201
1202             $content .= " (saved: ";
1203             #$content .= h('Number') . $req{$t}{'decompression-gain'} . h('Standard');
1204             #$content .= "/";
1205             $content .= h('Number') . sprintf("%.2f%%", $req{$t}{'decompression-gain-percent'}) . h('Standard');
1206             $content .= ")";
1207         }
1208
1209     } elsif ($c =~ m/^(Need to de-chunk first)/) {
1210
1211         # Need to de-chunk first
1212         return '' if SUPPRESS_NEED_TO_DE_CHUNK_FIRST;
1213
1214     } elsif ($c =~ m/^(Adding (?:dynamic )?re_filter job)/) {
1215
1216         return ''  if (SUPPRESS_SUCCEEDED_FILTER_ADDITIONS && m/succeeded/);
1217
1218         # Adding re_filter job ...
1219         # Adding dynamic re_filter job s@^(?:\w*)\s+.*\s+HTTP/\d\.\d\s*@IP-ADDRESS: $origin@D\
1220         #  to filter client-ip-address succeeded.
1221
1222     } elsif ($c =~ m/^Compressed content from /) {
1223
1224         # Compressed content from 29258 to 8630 bytes. Compression level: 3
1225         $content =~ s@(?<=from )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1226         $content =~ s@(?<=to )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1227         $content =~ s@(?<=level: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1228
1229     } elsif ($c =~ m/^Reading in filter/) {
1230
1231         return '' unless SHOW_FILTER_READIN_IN;
1232
1233     } elsif ($c =~ m/^Decompression didn't result/) {
1234
1235         # Decompression didn't result in any content.
1236
1237         # Nothing to highlight.
1238
1239     } else {
1240
1241         found_unknown_content($content);
1242
1243     }
1244
1245     return $content;
1246 }
1247
1248 sub handle_loglevel_tagging($) {
1249
1250     my $c = shift;
1251
1252     if ($c =~ /^Tagger \'([^\']*)\' added tag \'([^\']*)\'/ or
1253         $c =~ m/^Adding tag \'([^\']*)\' created by header tagger \'([^\']*)\'/) {
1254
1255         # Adding tag 'GET request' created by header tagger 'method-man' (XXX: no longer used)
1256         # Tagger 'revalidation' added tag 'REVALIDATION-REQUEST'. No action bit update necessary.
1257         # Tagger 'revalidation' added tag 'REVALIDATION-REQUEST'. Action bits updated accordingly.
1258
1259         # XXX: Save tag and tagger
1260
1261         $c =~ s@(?<=^Tagger \')([^\']*)@$h{'tagger'}$1$h{'Standard'}@;
1262         $c =~ s@(?<=added tag \')([^\']*)@$h{'tag'}$1$h{'Standard'}@;
1263         $c =~ s@(?<=Action bits )(updated)@$h{'action-bits-update'}$1$h{'Standard'}@;
1264
1265     } elsif ($c =~ /^Enlisting tag/) {
1266
1267         # Enlisting tag 'forward-directly' for client 127.0.0.1.
1268
1269         $c =~ s@(?<=tag \')([^\']*)@$h{'tag'}$1$h{'Standard'}@;
1270         $c = highlight_matched_host($c, '[^\s]+(?=\.$)');
1271
1272     } elsif ($c =~ /^Tag/) {
1273
1274         # Tag 'change-tor-socks-port' for client 127.0.0.1 expired 1 seconds ago. Deleting it.
1275
1276         $c =~ s@(?<=Tag \')([^\']*)@$h{'tag'}$1$h{'Standard'}@;
1277         $c =~ s@(?<=expired )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1278         $c = highlight_matched_host($c, '(?<=client )[^\s]+');
1279
1280     } elsif ($c =~ /^Evaluating/) {
1281
1282         # Evaluating tag 'change-tor-socks-port' for client 127.0.0.1. End of life 1613162302.
1283
1284         $c =~ s@(?<=tag \')([^\']*)@$h{'tag'}$1$h{'Standard'}@;
1285         $c = highlight_matched_host($c, '(?<=client )[^\s]+(?=\.)');
1286         $c =~ s@(?<=life )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1287
1288     } elsif ($c =~ /^Client tag/) {
1289
1290         # Client tag 'forward-directly' matches
1291
1292         $c =~ s@(?<=tag \')([^\']*)@$h{'tag'}$1$h{'Standard'}@;
1293
1294     }
1295
1296     return $c;
1297 }
1298
1299 sub handle_loglevel_redirect($) {
1300
1301     my $c = shift;
1302
1303     if ($c =~ m/^Decoding "([^""]*)"/) {
1304
1305          $req{$t}{'original-destination'} = $1;
1306          $c = highlight_matched_path($c, '(?<=Decoding ")[^"]*');
1307          $c =~ s@\"@@g;
1308
1309     } elsif ($c =~ m/^Checking/) {
1310
1311          # Checking /_ylt=A0geu.Z76BRGR9k/**http://search.yahoo.com/search?p=view+odb+presentation+on+freebsd\
1312          #  &ei=UTF-8&xargs=0&pstart=1&fr=moz2&b=11 for redirects.
1313
1314          # TODO: Change colour if really url-decoded
1315          $req{$t}{'decoded-original-destination'} = $1;
1316          $c = highlight_matched_path($c, '(?<=Checking ")[^"]*');
1317          $c =~ s@\"@@g;
1318
1319     } elsif ($c =~ m/^pcrs command "([^""]*)" changed /) {
1320
1321         # pcrs command "s@&from=rss@@" changed \
1322         #  "http://it.slashdot.org/article.pl?sid=07/03/02/1657247&from=rss"\
1323         #  to "http://it.slashdot.org/article.pl?sid=07/03/02/1657247" (1 hit).
1324         $c =~ s@(?<=pcrs command )"([^""]*)"@$h{'filter'}$1$h{'Standard'}@;
1325         $c = highlight_matched_url($c, '(?<=changed ")[^""]*');
1326         $c =~ s@(?<=changed )"([^""]*)"@$1@; # Remove quotes
1327         $c = highlight_matched_url($c, '(?<=to ")[^""]*');
1328         $c =~ s@(?<=to )"([^""]*)"@$1@; # Remove quotes
1329         $c =~ s@(\d+)(?= hits?)@$h{'hits'}$1$h{'Standard'}@;
1330
1331     } elsif ($c =~ m/^pcrs command "([^""]*)" didn\'t change/) {
1332
1333         # pcrs command "s@^http://([^.]+?)/?$@http://www.bing.com/search?q=$1@" didn't \
1334         #  change "http://www.example.org/".
1335         $c =~ s@(?<=pcrs command )"([^""]*)"@$h{'filter'}$1$h{'Standard'}@;
1336         $c = highlight_matched_url($c, '(?<=change ")[^""]*');
1337
1338     } elsif ($c =~ m/(^New URL is: )(.*)/) {
1339
1340         # New URL is: http://it.slashdot.org/article.pl?sid=07/03/04/1511210
1341         # XXX: Use URL highlighter
1342         # XXX: Save?
1343         $c = $1 . h('rewritten-URL') . $2 . h('Standard');
1344
1345     } elsif ($c =~ m/No pcrs command recognized, assuming that/) {
1346         # No pcrs command recognized, assuming that "http://config.privoxy.org/user-manual/favicon.png"\
1347         #  is already properly formatted.
1348         # XXX: assume the same?
1349         $c = highlight_matched_url($c, '(?<=assuming that \")[^"]*');
1350
1351     } elsif ($c =~ m/^Percent-encoding redirect/) {
1352
1353         # Percent-encoding redirect URL: http://www.example.org/\x02
1354         $c = highlight_matched_url($c, '(?<=redirect URL: ).*');
1355
1356     } elsif ($c =~ m/^Rewrite detected:/) {
1357
1358         # Rewrite detected: GET http://10.0.0.2:88/blah.txt HTTP/1.1
1359         # Rewrite detected: GET https://www.electrobsd.org/CommonJS/ajax/libs/jquery/3.4.1/jquery.min.js HTTP/1.1
1360         $c = highlight_matched_request_line($c, '(?<=^Rewrite detected: ).*');
1361
1362     } elsif ($c =~ m/^Rewritten request line results in downgrade to http/) {
1363
1364         # Rewritten request line results in downgrade to http
1365         $c =~ s@(downgrade)@$h{'http-downgrade'}$1$h{'Standard'}@;
1366
1367     } else {
1368
1369         found_unknown_content($c);
1370
1371     }
1372
1373     return $c;
1374 }
1375
1376 sub handle_loglevel_gif_deanimate($) {
1377
1378     my $content = shift;
1379
1380     if ($content =~ m/Success! GIF shrunk from (\d+) bytes to (\d+)\./) {
1381
1382         my $bytes_from = $1;
1383         my $bytes_to = $2;
1384         # Gif-Deanimate: Success! GIF shrunk from 205 bytes to 133.
1385         $content =~ s@$bytes_from@$h{'Number'}$bytes_from$h{'Standard'}@;
1386         # XXX: Do we need g in case of ($1 == $2)?
1387         $content =~ s@$bytes_to@$h{'Number'}$bytes_to$h{'Standard'}@;
1388
1389     } elsif ($content =~ m/GIF (not) changed/) {
1390
1391         # Gif-Deanimate: GIF not changed.
1392         return '' if SUPPRESS_GIF_NOT_CHANGED;
1393         $content =~ s@($1)@$h{'not'}$1$h{'Standard'}@;
1394
1395     } elsif ($content =~ m/^failed! \(gif parsing\)/) {
1396
1397         # failed! (gif parsing)
1398         # XXX: Replace this error message with something less stupid
1399         $content =~ s@(failed!)@$h{'error'}$1$h{'Standard'}@;
1400
1401     } elsif ($content =~ m/^Need to de-chunk first/) {
1402
1403         # Need to de-chunk first
1404         return '' if SUPPRESS_NEED_TO_DE_CHUNK_FIRST;
1405
1406     } elsif ($content =~ m/^(?:No GIF header found|failed while parsing)/) {
1407
1408         # No GIF header found (XXX: Did I ever commit this?)
1409         # failed while parsing 195 134747048 (XXX: never committed)
1410
1411         # Ignore these for now
1412
1413     } else {
1414
1415         found_unknown_content($content);
1416
1417     }
1418
1419     return $content;
1420 }
1421
1422 sub handle_loglevel_request($) {
1423
1424     my $content = shift;
1425
1426     if ($content =~ m/crunch! /) {
1427
1428         # config.privoxy.org/send-stylesheet crunch! (CGI Call)
1429
1430         # Highlight crunch reasons
1431         foreach my $reason (keys %reason_colours) {
1432             $content =~ s@\(($reason)\)@$reason_colours{$reason}($1)$h{'Standard'}@g;
1433         }
1434         # Highlight request URL domain and ditch 'crunch!'
1435         $content = highlight_matched_pattern($content, 'request_', '[^ ]*(?= crunch!)');
1436         $content =~ s@ crunch!@@;
1437
1438     } elsif ($content =~ m/\[too long, truncated\]$/) {
1439
1440         # config.privoxy.org/edit-actions-submit?f=3&v=1176116716&s=7&Submit=Submit[...]&filter... [too long, truncated]
1441         $content = highlight_matched_pattern($content, 'request_', '^.*(?=\.\.\. \[too long, truncated\]$)');
1442
1443     } elsif ($content =~ m/(.*)/) { # XXX: Pretty stupid
1444
1445         # trac.vidalia-project.net/wiki/Volunteer?format=txt
1446         $content = h('request_') . $content . h('Standard');
1447
1448     } else {  # XXX: Nop
1449
1450         found_unknown_content($content);
1451
1452     }
1453
1454     return $content;
1455 }
1456
1457 sub handle_loglevel_crunch($) {
1458
1459     my $content = shift;
1460
1461     # Highlight crunch reason
1462     foreach my $reason (keys %reason_colours) {
1463         # Crunch: Blocked: https://capture.condenastdigital.com/track?_o=cne&[...]&dim2=%7B%22adBlocked%[...]
1464         $content =~ s@($reason)@$reason_colours{$reason}$1$h{'Standard'}@;
1465     }
1466
1467     if ($content =~ m/\[too long, truncated\]$/) {
1468
1469         # Blocked: config.privoxy.org/edit-actions-submit?f=3&v=1176116716&s=7&Submit=Submit\
1470         #  [...]&filter... [too long, truncated]
1471         $content = highlight_matched_pattern($content, 'request_', '^.*(?=\.\.\. \[too long, truncated\]$)');
1472
1473     } elsif ($content =~ m/Certificate error:/) {
1474
1475         # Certificate error: ASN date error, current date after: https://expired.badssl.com/
1476         $content = highlight_matched_pattern($content, 'request_', 'https://.*');
1477
1478     } else {
1479
1480         # Blocked: http://ads.example.org/
1481         $content = highlight_matched_pattern($content, 'request_', '(?<=: ).*');
1482     }
1483
1484     return $content;
1485 }
1486
1487 sub handle_loglevel_connect($) {
1488
1489     my $c = shift;
1490
1491     if ($c =~ m/^via [^\s]+ to: [^\s]+/) {
1492
1493         # Connect: via 10.0.0.1:8123 to: www.example.org.noconnect
1494
1495         $c = highlight_matched_host($c, '(?<=via )[^\s]+');
1496         $c = highlight_matched_host($c, '(?<=to: )[^\s]+');
1497
1498     } elsif ($c =~ m/^connect to: .* failed: .*/) {
1499
1500         # connect to: www.example.org.noconnect failed: Operation not permitted
1501
1502         $c = highlight_matched_host($c, '(?<=connect to: )[^\s]+');
1503
1504         $c =~ s@(?<=failed: )(.*)@$h{'error'}$1$h{'Standard'}@;
1505
1506     } elsif ($c =~ m/^to ([^\s]*)( successful)?$/) {
1507
1508         # Connect: to www.nzherald.co.nz successful
1509         # Connect: to archiv.radiotux.de
1510
1511         return '' if SUPPRESS_SUCCESSFUL_CONNECTIONS;
1512         $c = highlight_matched_host($c, '(?<=to )[^\s]+');
1513
1514     } elsif ($c =~ m/^to ([^\s]*)$/) {
1515
1516         # Connect: to lists.sourceforge.net:443
1517
1518         $c = highlight_matched_host($c, '(?<=to )[^\s]+');
1519
1520     } elsif ($c =~ m/^[Aa]ccepted connection from .*/ or
1521              $c =~ m/^OK/) {
1522
1523         # Privoxy 3.0.20:
1524         # Accepted connection from 10.0.0.1 on socket 5
1525         # Privoxy between 3.0.20 and 3.0.6:
1526         # accepted connection from 10.0.0.1( on socket 5)?
1527         # Privoxy 3.0.6 and earlier just say:
1528         # OK
1529         $c = highlight_matched_host($c, '(?<=connection from )[^ ]*');
1530         $c = highlight_matched_pattern($c, 'Number', '(?<=socket )\d+');
1531
1532     } elsif ($c =~ m/^Closing client socket/) {
1533
1534         # Closing client socket 5. Keep-alive: 0, Socket alive: 1. Data available: 0.
1535         # Privoxy 3.0.20 and later
1536         # Closing client socket 8. Keep-alive: 1. Socket alive: 0. Data available: 0. \
1537         #  Configuration file change detected: 0. Requests received: 11.
1538
1539         $c = highlight_matched_pattern($c, 'Number', '(?<=socket )\d+');
1540         $c = highlight_matched_pattern($c, 'Number', '(?<=Keep-alive: )\d+');
1541         $c = highlight_matched_pattern($c, 'Number', '(?<=Socket alive: )\d+');
1542         $c = highlight_matched_pattern($c, 'Number', '(?<=available: )\d+');
1543         $c = highlight_matched_pattern($c, 'Number', '(?<=detected: )\d+');
1544         $c = highlight_matched_pattern($c, 'Number', '(?<=received: )\d+');
1545
1546     } elsif ($c =~ m/^write header to: .* failed:/) {
1547
1548         # write header to: 10.0.0.1 failed: Broken pipe
1549
1550         $c = highlight_matched_host($c, '(?<=write header to: )[^\s]*');
1551         $c =~ s@(?<=failed: )(.*)@$h{'Error'}$1$h{'Standard'}@;
1552
1553     } elsif ($c =~ m/^write header to client failed:/) {
1554
1555         # write header to client failed: Broken pipe
1556         # XXX: Stil in use?
1557         $c =~ s@(?<=failed: )(.*)@$h{'Error'}$1$h{'Standard'}@;
1558
1559     } elsif ($c =~ m/^socks4_connect:/) {
1560
1561         # socks4_connect: SOCKS request rejected or failed.
1562         $c =~ s@(?<=socks4_connect: )(.*)@$h{'Error'}$1$h{'Standard'}@;
1563
1564     } elsif ($c =~ m/^Listening for new connections/ or
1565              $c =~ m/^accept connection/) {
1566         # XXX: Highlight?
1567         # Privoxy versions above 3.0.6 say:
1568         # Listening for new connections ...
1569         # earlier versions say:
1570         # accept connection ...
1571         return '';
1572
1573     } elsif ($c =~ m/^accept failed:/) {
1574
1575         $c =~ s@(?<=accept failed: )(.*)@$h{'Error'}$1$h{'Standard'}@;
1576
1577     } elsif ($c =~ m/^Failed to accept\(\) incoming connection:/) {
1578
1579         # Failed to accept() incoming connection: Software caused connection abort
1580         $c =~ s@(?<=connection: )(.*)@$h{'Error'}$1$h{'Standard'}@;
1581
1582     } elsif ($c =~ m/^Overriding forwarding settings/) {
1583
1584         # Overriding forwarding settings based on 'forward 10.0.0.1:8123'
1585         $c =~ s@(?<=based on \')(.*)(?=\')@$h{'configuration-line'}$1$h{'Standard'}@;
1586
1587     } elsif ($c =~ m/^Denying suspicious CONNECT request from/) {
1588
1589         # Denying suspicious CONNECT request from 10.0.0.1
1590         $c = highlight_matched_host($c, '(?<=from )[^\s]+'); # XXX: not an URL
1591
1592     } elsif ($c =~ m/^socks5_connect:/) {
1593
1594         $c =~ s@(?<=socks5_connect: )(.*)@$h{'error'}$1$h{'Standard'}@;
1595
1596     } elsif ($c =~ m/^Created new connection to/) {
1597
1598         # Created new connection to www.privoxy.org:80 on socket 11.
1599         $c = highlight_matched_host($c, '(?<=connection to )[^\s]+');
1600         $c =~ s@(?<=on socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1601
1602     } elsif ($c =~ m/^Found reusable socket/) {
1603
1604         # Found reusable socket 9 for www.privoxy.org:80 in slot 0.
1605         # 3.0.15 and later:
1606         # Found reusable socket 8 for www.privoxy.org:80 in slot 2.\
1607         #  Timestamp made 0 seconds ago. Timeout: 1. Latency: 0.
1608         $c =~ s@(?<=Found reusable socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1609         $c = highlight_matched_host($c, '(?<=for )[^\s]+');
1610         $c =~ s@(?<=in slot )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1611         $c =~ s@(?<=made )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1612         $c =~ s@(?<=Timeout: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1613         $c =~ s@(?<=Latency: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1614
1615     } elsif ($c =~ m/^Marking open socket/) {
1616
1617         # Marking open socket 9 for www.privoxy.org:80 in slot 0 as unused.
1618         $c =~ s@(?<=Marking open socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1619         $c = highlight_matched_host($c, '(?<=for )[^\s]+');
1620         $c =~ s@(?<=in slot )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1621
1622     } elsif ($c =~ m/^No reusable/) {
1623
1624         # No reusable socket for addons.mozilla.org:443 found. Opening a new one.
1625         $c = highlight_matched_host($c, '(?<=for )[^\s]+');
1626
1627     } elsif ($c =~ m/^(Remembering|Forgetting) socket/) {
1628
1629         # Remembering socket 13 for www.privoxy.org:80 in slot 0.
1630         # Forgetting socket 38 for www.privoxy.org:80 in slot 5.
1631
1632         $c =~ s@(?<=socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1633         $c = highlight_matched_host($c, '(?<=for )[^\s]+');
1634         $c =~ s@(?<=in slot )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1635
1636     } elsif ($c =~ m/^Socket \d+ (already|closed)/) {
1637
1638         # Socket 16 already forgotten or never remembered.
1639         # Socket 9 closed while waiting for client headers
1640         $c =~ s@(?<=Socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1641
1642     } elsif ($c =~ m/^The connection to/) {
1643
1644         # The connection to www.privoxy.org:80 in slot 6 timed out. Closing socket 19. Timeout is: 61.
1645         # 3.0.15 and later:
1646         # The connection to 1.bp.blogspot.com:80 in slot 0 timed out. Closing socket 5.\
1647         #  Timeout is: 1. Assumed latency: 4.
1648         # The connection to 10.0.0.1:80 in slot 0 is no longer usable. Closing socket 4.
1649         $c = highlight_matched_host($c, '(?<=connection to )[^\s]+');
1650         $c =~ s@(?<=in slot )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1651         $c =~ s@(?<=Closing socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1652         $c =~ s@(?<=Timeout is: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1653         $c =~ s@(?<=Assumed latency: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1654
1655     } elsif ($c =~ m/^Stopped waiting for the request line/ or
1656              $c =~ m/^No request line on socket \d+ received in time/ or
1657              $c =~ m/^The client side of the connection on socket \d/) {
1658
1659         # Stopped waiting for the request line. Timeout: 121.
1660         # Privoxy 3.0.19 and later:
1661         # No request line on socket 5 received in time. Timeout: 1.
1662         # The client side of the connection on socket 5 got closed \
1663         #  without sending a complete request line.
1664         $c =~ s@(?<=Timeout: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1665         $c =~ s@(?<=socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1666
1667     } elsif ($c =~ m/^Waiting for \d/) {
1668
1669         # Waiting for 1 connections to timeout.
1670         $c =~ s@(?<=^Waiting for )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1671
1672     } elsif ($c =~ m/^Initialized/) {
1673
1674         # Initialized 20 socket slots.
1675         $c =~ s@(?<=Initialized )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1676
1677     } elsif ($c =~ m/^Done reading from server/) {
1678
1679         # Done reading from server. Expected content length: 24892. \
1680         #  Actual content length: 24892. Most recently received: 4412.
1681         # 3.0.15 and later:
1682         # Done reading from server. Expected content length: 24892. \
1683         #  Actual content length: 24892. Bytes most recently read: 4412.
1684         # Done reading from server. Content length: 6018 as expected. \
1685         #  Bytes most recently read: 294.
1686         $c =~ s@(?<=ontent length: )(\d+)@$h{'Number'}$1$h{'Standard'}@g;
1687         $c =~ s@(?<=received: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1688         $c =~ s@(?<=read: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1689
1690     } elsif ($c =~ m/^Continuing buffering (?:server )?headers/) {
1691
1692         # Continuing buffering headers. byte_count: 19. header_offset: 517. len: 536.
1693         $c =~ s@(?<=byte_count: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1694         $c =~ s@(?<=header_offset: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1695         $c =~ s@(?<=len: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1696         # 3.0.15 up to 3.0.19:
1697         # Continuing buffering headers. Bytes most recently read: 498.
1698         $c =~ s@(?<=read: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1699         # 3.0.20 and later:
1700         # Continuing buffering server headers from socket 5. Bytes most recently read: 498.
1701         $c =~ s@(?<=socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1702
1703     } elsif ($c =~ m/^Received \d+ bytes while/) {
1704
1705         # Received 206 bytes while expecting 12103.
1706         $c =~ s@(?<=Received )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1707         $c =~ s@(?<=expecting )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1708
1709     } elsif ($c =~ m/^(Rejecting c|C)onnection from/) {
1710
1711         # Connection from 81.163.28.218 dropped due to ACL
1712         # Rejecting connection from 178.63.152.227. Maximum number of connections reached.
1713         # Connection from 192.168.2.1 on 127.0.1.1:8118 (socket 3) dropped due to ACL
1714         $c = highlight_matched_host($c, '(?<=onnection from )[\d.:]+');
1715         $c = highlight_matched_host($c, '(?<=on )[\d.:]+');
1716         $c =~ s@(?<=socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1717
1718     } elsif ($c =~ m/^(?:Reusing|Closing) server socket / or
1719              $c =~ m/^No additional client request/) {
1720
1721         # Reusing server socket 4. Opened for 10.0.0.1.
1722         # Closing server socket 2. Opened for 10.0.0.1.
1723         # No additional client request received in time. \
1724         #  Closing server socket 4, initially opened for 10.0.0.1.
1725         # No additional client request received in time on socket 29.
1726         # Privoxy 3.0.20 and later
1727         # Reusing server socket 7 connected to www.privoxy.org. Total requests: 2.
1728         # Closing server socket 6 connected to d.asset.soup.io. Keep-alive: 0.\
1729         #  Tainted: 1. Socket alive: 1. Timeout: 60. Configuration file change detected: 0.
1730         # Reusing server socket 35 connected to nl.wikipedia.org. Requests already sent: 5.
1731
1732         $c =~ s@(?<= socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1733         $c = highlight_matched_host($c, '(?<=for )[^\s]+(?=\.)');
1734         $c = highlight_matched_host($c, '(?<=connected to )[^\s]+(?=\.)');
1735         for my $number_pattern ('requests', 'Keep-alive', 'Tainted', ' alive', 'Timeout', 'detected') {
1736             $c = highlight_matched_pattern($c, 'Number', '(?<='. $number_pattern . ': )\d+');
1737         }
1738         $c =~ s@(?<=already sent: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1739
1740     } elsif ($c =~ m/^Connected to /) {
1741
1742         # Connected to tor-jail[10.0.0.2]:9050.
1743
1744         $c = highlight_matched_host($c, '(?<=\[)[^\]]+');
1745         $c = highlight_matched_host($c, '(?<=Connected to )[^\[\s]+');
1746         $c =~ s@(?<=\]:)(\d+)@$h{'Number'}$1$h{'Standard'}@;
1747
1748     } elsif ($c =~ m/^Could not connect to /) {
1749
1750         # Could not connect to [10.0.0.1]:80.
1751
1752         $c = highlight_matched_host($c, '(?<=\[)[^\]]+');
1753         $c =~ s@(?<=\]:)(\d+)@$h{'Number'}$1$h{'Standard'}@;
1754
1755     } elsif ($c =~ m/^Waiting for the next client request/ or
1756              $c =~ m/^The connection on server socket/ or
1757              $c =~ m/^Client request (?:\d+ )?(?:arrived in time|has been pipelined) /) {
1758
1759         # Waiting for the next client request on socket 3. Keeping the server \
1760         #  socket 12 to a.fsdn.com open.
1761         # The connection on server socket 6 to upload.wikimedia.org isn't reusable. Closing.
1762         # Privoxy 3.0.20 and later:
1763         # Client request 4 arrived in time on socket 7.
1764         # Used by Privoxy 3.0.18 and 3.0.19:
1765         # Client request arrived in time on socket 21.
1766         # Used by earlier version:
1767         # Client request arrived in time or the client closed the connection on socket 12.
1768         # Client request 8 has been pipelined on socket 7 and the socket is still alive.
1769
1770         $c =~ s@(?<=request )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1771         $c =~ s@(?<=on socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1772         $c =~ s@(?<=server socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1773         $c = highlight_matched_host($c, '(?<=to )[^\s]+');
1774
1775     } elsif ($c =~ m/^Marking the server socket/) {
1776
1777         # Marking the server socket 7 tainted.
1778
1779         $c =~ s@(?<=server socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1780
1781     } elsif ($c =~ m/^Reduced expected bytes to /) {
1782
1783         # Reduced expected bytes to 0 to account for the 1542 ones we already got.
1784         $c =~ s@(?<=bytes to )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1785         $c =~ s@(?<=for the )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1786
1787     } elsif ($c =~ m/^The client closed socket /) {
1788
1789         # The client closed socket 2 while the server socket 4 is still open.
1790         $c =~ s@(?<=closed socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1791         $c =~ s@(?<=server socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1792
1793     } elsif ($c =~ m/^Expected client content length set /) {
1794
1795         # Expected client content length set to 667325411 after reading 4999 bytes.
1796         $c =~ s@(?<=set to )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1797         $c =~ s@(?<=reading )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1798
1799     } elsif ($c =~ m/^Reducing expected bytes to /) {
1800
1801         # Reducing expected bytes to 0. Marking the server socket tainted after throwing 4 bytes away.
1802         $c =~ s@(?<=bytes to )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1803         $c =~ s@(?<=after throwing )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1804
1805     } elsif ($c =~ m/^Waiting for up to /) {
1806
1807         # Waiting for up to 4999 bytes from the client.
1808         $c =~ s@(?<=up to )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1809
1810     } elsif ($c =~ m/^Optimistically sending /) {
1811
1812         # Optimistically sending 318 bytes of client headers intended for www.privoxy.org
1813         # Optimistically sending 318 bytes of client headers intended for www.privoxy.org.
1814         $c =~ s@(?<=sending )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1815         if ($c =~ /\.$/) {
1816             $c = highlight_matched_host($c, '[^\s]+(?=\.)');
1817         } else {
1818             $c = highlight_matched_host($c, '(?<=for )[^\s]+');
1819         }
1820
1821     } elsif ($c =~ m/^Stopping to watch the client socket/) {
1822
1823         # Stopping to watch the client socket. There's already another request waiting.
1824         # Privoxy 3.0.20 and later:
1825         # Stopping to watch the client socket 5. There's already another request waiting.
1826         $c =~ s@(?<=client socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1827
1828     } elsif ($c =~ m/^Drained \d+ bytes before closing/) {
1829
1830         # Drained 180 bytes before closing socket 6
1831         $c =~ s@(?<=Drained )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1832         $c =~ s@(?<=socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1833
1834     } elsif ($c =~ m/^Tainting client socket/ or
1835              $c =~ m/^Failed to shutdown socket/) {
1836
1837         # Tainting client socket 7 due to unread data.
1838         # Failed to shutdown socket 11: Connection reset by peer
1839
1840         $c =~ s@(?<=socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1841
1842     } elsif ($c =~ m/^Shifting \d+ pipelined bytes/) {
1843
1844         # Shifting 360 pipelined bytes by 360 bytes
1845         $c =~ s@(?<=Shifting )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1846         $c =~ s@(?<=by )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1847
1848     } elsif ($c =~ m/^Flushed (\d+) bytes of request body while expecting (\d+)/) {
1849
1850         # Flushed 30 bytes of request body while expecting 30
1851         $c =~ s@(?<=Flushed )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1852         $c =~ s@(?<=expecting )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1853
1854     } elsif ($c =~ m/^Performing the TLS\/SSL handshake with client. Hash of host:/) {
1855
1856         # Performing the TLS/SSL handshake with client. Hash of host: bab5296b25e256c7b06b92b17b56bcae
1857         $c = highlight_matched_host($c, '(?<=Hash of host: ).+');
1858
1859     } elsif ($c =~ m/^Forwarding \d+ bytes of encrypted POST data/) {
1860
1861         # Forwarding 1954 bytes of encrypted POST data
1862         $c =~ s@(?<=Forwarding )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1863
1864     } elsif ($c =~ m/^Forwarded the last \d+ bytes/) {
1865
1866         # Forwarded the last 1954 bytes
1867         $c =~ s@(?<=the last )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1868
1869     } elsif ($c =~ m/^Waiting for the next client connection. Currently active threads:/) {
1870
1871         # Waiting for the next client connection. Currently active threads: 30
1872         $c =~ s@(?<=threads: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1873
1874     } elsif ($c =~ m/^Data arrived in time on client socket/) {
1875
1876         # Data arrived in time on client socket 6. Requests so far: 3
1877         $c =~ s@(?<=client socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1878         $c =~ s@(?<=Requests so far: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1879
1880     } elsif ($c =~ m/^Dropping the client connection on socket/) {
1881
1882         # Dropping the client connection on socket 71. The server connection has not been established yet.
1883         # Dropping the client connection on socket 23 with server socket 24 connected to \
1884         #  www.reddit.com. The forwarder has changed.
1885         $c =~ s@(?<=on socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1886         $c =~ s@(?<=server socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1887         $c = highlight_matched_host($c, '(?<=connected to )[^ ]+(?=\.)');
1888
1889     } elsif ($c =~ m/^The client socket \d+ has become unusable while the server/) {
1890
1891         # The client socket 16 has become unusable while the server socket 24 is still open.
1892         $c =~ s@(?<=client socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1893         $c =~ s@(?<=server socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1894
1895     } elsif ($c =~ m/^The last \d+ bytes of the request body have been read/) {
1896
1897         # The last 12078 bytes of the request body have been read
1898         $c =~ s@(?<=The last )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1899
1900     } elsif ($c =~ m/^Flushed \d+ bytes of request body/) {
1901
1902         # Flushed 3153 bytes of request body
1903         $c =~ s@(?<=Flushed )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1904
1905     } elsif ($c =~ m/^Complete client request followed by/) {
1906
1907         # Complete client request followed by 59 bytes of pipelined data received.
1908         $c =~ s@(?<=followed by )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1909
1910     } elsif ($c =~ m/^The peer notified us that the connection on socket/) {
1911
1912         # The peer notified us that the connection on socket 11 is going to be closed
1913         $c =~ s@(?<=socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1914
1915     } elsif ($c =~ m/^Client socket \d is no longer usable/) {
1916
1917         # Client socket 7 is no longer usable. The server socket has been closed.
1918         $c =~ s@(?<=socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1919
1920     } elsif ($c =~ m/^Socket timeout \d+ reached/) {
1921
1922         # Socket timeout 3 reached: http://127.0.0.1:20000/no-filter/chunked-content/36
1923         $c =~ s@(?<=timeout )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1924         $c = highlight_matched_url($c, "(?<=reached: ).*")
1925
1926     } elsif ($c =~ m/^Prepared to read up to /) {
1927
1928         # Prepared to read up to 157 bytes of encrypted request body from the client.
1929         $c =~ s@(?<=up to )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1930
1931     } elsif ($c =~ m/^Forwarding \d+ bytes /) {
1932
1933         # Forwarding 157 bytes of encrypted request body.
1934         $c =~ s@(?<=Forwarding )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1935
1936     } elsif ($c =~ m/^Buffering encrypted client body/) {
1937
1938         # Buffering encrypted client body. Prepared to read up to 2236 bytes.
1939         $c =~ s@(?<=up to )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1940
1941     } elsif ($c =~ m/^The last \d+ bytes of the encrypted request body have been read/) {
1942
1943         # The last 6945 bytes of the encrypted request body have been read.
1944         $c =~ s@(?<=The last )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1945
1946     } elsif ($c =~ m/^Reducing the chunk offset from/) {
1947
1948         # Reducing the chunk offset from 1096654 to 32704 after discarding 1063950 bytes to make room in the buffer.
1949         # Reducing the chunk offset from 16219 to 128 after flushing 16091 bytes.
1950         $c =~ s@(?<=\d to )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1951         $c =~ s@(?<=offset from )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1952         $c =~ s@(?<=after discarding )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1953         $c =~ s@(?<=after flushing )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1954
1955     } elsif ($c =~ m/^Client socket \d+ is no longer usable/) {
1956
1957         # Client socket 21 is no longer usable. The server socket has been closed.
1958         $c =~ s@(?<=Client socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1959
1960     } elsif ($c =~ m/^(Client|Server) successfully connected over/) {
1961
1962         # Server successfully connected over TLSv1.3 (TLS_AES_256_GCM_SHA384).
1963         # Client successfully connected over TLSv1.3 (TLS_AES_128_GCM_SHA256).
1964         $c =~ s@(?<=connected over )(TLSv\d\.\d)@$h{'tls-version'}$1$h{'Standard'}@;
1965         $c =~ s@(?<=\()([^)]+)@$h{'cipher-suite'}$1$h{'Standard'}@;
1966
1967     } elsif ($c =~ m/^Couldn't deliver the error message for/) {
1968
1969         # Couldn't deliver the error message for https://m.media-amazon.com/[...] through client socket 18 using TLS/SSL
1970         $c = highlight_matched_url($c, "(?<=error message for )[^ ]*");
1971         $c =~ s@(?<=client socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1972
1973     } elsif ($c =~ m/^Keeping chunk offset at/) {
1974
1975         # Keeping chunk offset at 0 despite flushing 31 bytes.
1976         $c =~ s@(?<=offset at )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1977         $c =~ s@(?<=flushing )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1978
1979     } elsif ($c =~ m/^Looks like we / or
1980              $c =~ m/^Unsetting keep-alive flag/ or
1981              $c =~ m/^No connections to wait/ or
1982              $c =~ m/^Complete client request received/ or
1983              $c =~ m/^Possible pipeline attempt detected./ or
1984              $c =~ m/^POST request detected. The connection will not be kept alive./ or
1985              $c =~ m/^The server still wants to talk, but the client hung up on us./ or
1986              $c =~ m/^The server didn't specify how long the connection will stay open/ or
1987              $c =~ m/^There might be a request body. The connection will not be kept alive/ or
1988              $c =~ m/^There better be a request body./ or
1989              $c =~ m/^Done reading from the client\.$/) {
1990
1991         # Looks like we reached the end of the last chunk. We better stop reading.
1992         # Looks like we read the end of the last chunk together with the server \
1993         #  headers. We better stop reading.
1994         # Looks like we got the last chunk together with the server headers. \
1995         #  We better stop reading.
1996         # Unsetting keep-alive flag.
1997         # No connections to wait for left.
1998         # Client request arrived in time or the client closed the connection.
1999         # Complete client request received
2000         # Possible pipeline attempt detected. The connection will not be \
2001         #  kept alive and we will only serve the first request.
2002         # POST request detected. The connection will not be kept alive.
2003         # The server still wants to talk, but the client hung up on us.
2004         # The server didn't specify how long the connection will stay open. Assume it's only a second.
2005         # There might be a request body. The connection will not be kept alive.
2006         # Privoxy 3.0.20 and later
2007         # There better be a request body.
2008         # Done reading from the client.
2009
2010     } else {
2011
2012         found_unknown_content($c);
2013
2014     }
2015
2016     return $c;
2017 }
2018
2019
2020 sub handle_loglevel_info($) {
2021
2022     my $c = shift;
2023
2024     if ($c =~ m/^Rewrite detected:/) {
2025
2026         # Rewrite detected: GET http://10.0.0.2:88/blah.txt HTTP/1.1
2027         $c = highlight_matched_request_line($c, '(?<=^Rewrite detected: ).*');
2028
2029     } elsif ($c =~ m/^Decompress(ing deflated|ion didn)/ or
2030              $c =~ m/^Compressed content detected/ or
2031              $c =~ m/^SDCH-compressed content detected/ or
2032              $c =~ m/^Tagger/
2033             ) {
2034         # Decompressing deflated iob: 117
2035         # Decompression didn't result in any content.
2036         # Compressed content detected, content filtering disabled. Consider recompiling Privoxy\
2037         #  with zlib support or enable the prevent-compression action.
2038         # SDCH-compressed content detected, content filtering disabled.\
2039         #  Consider suppressing SDCH offers made by the client.
2040         # Tagger 'complete-url' created empty tag. Ignored.
2041
2042         # Ignored for now
2043
2044     } elsif ($c =~ m/^(Re)?loading configuration file /) {
2045
2046         # loading configuration file '/usr/local/etc/privoxy/config':
2047         # Reloading configuration file '/usr/local/etc/privoxy/config'
2048         $c =~ s@(?<=loading configuration file \')([^\']*)@$h{'file'}$1$h{'Standard'}@;
2049
2050     } elsif ($c =~ m/^Loading (actions|filter|trust) file: /) {
2051
2052         # Loading actions file: /usr/local/etc/privoxy/default.action
2053         # Loading filter file: /usr/local/etc/privoxy/default.filter
2054         # Loading trust file: /usr/local/etc/privoxy/trust
2055
2056         $c =~ s@(?<= file: )(.*)$@$h{'file'}$1$h{'Standard'}@;
2057
2058     } elsif ($c =~ m/^exiting by signal/) {
2059
2060         # exiting by signal 15 .. bye
2061         $c =~ s@(?<=exiting by signal )(\d+)@$h{'signal'}$1$h{'Standard'}@;
2062
2063     } elsif ($c =~ m/^Privoxy version/) {
2064
2065         # Privoxy version 3.0.7
2066         $c =~ s@(?<=^Privoxy version )(\d+\.\d+\.\d+)$@$h{'version'}$1$h{'Standard'}@;
2067
2068     } elsif ($c =~ m/^Program name: /) {
2069
2070         # Program name: /usr/local/sbin/privoxy
2071         $c =~ s@(?<=Program name: )(.*)@$h{'program-name'}$1$h{'Standard'}@;
2072
2073     } elsif ($c =~ m/^Listening on port /) {
2074
2075         # Listening on port 8118 on IP address 10.0.0.1
2076         $c =~ s@(?<=Listening on port )(\d+)@$h{'port'}$1$h{'Standard'}@;
2077         $c =~ s@(?<=on IP address )(.*)@$h{'ip-address'}$1$h{'Standard'}@;
2078
2079     } elsif ($c =~ m/^\(Re-\)Open(?:ing)? logfile/) {
2080
2081         # (Re-)Open logfile /var/log/privoxy/privoxy.log
2082         $c =~ s@(?<=Open logfile )(.*)@$h{'file'}$1$h{'Standard'}@;
2083
2084     } elsif ($c =~ m/^(Request from|Malformed server response detected)/) {
2085
2086         # Request from 10.0.0.1 denied. limit-connect{,} doesn't allow CONNECT requests to port 443.
2087         # Request from 10.0.0.1 marked for blocking. limit-connect{,} doesn't allow CONNECT requests to port 443.
2088         # 3.0.18 and later:
2089         # Request from 10.0.0.1 marked for blocking. limit-connect{0} doesn't allow CONNECT requests to www.example.org:443
2090         # Malformed server response detected. Downgrading to HTTP/1.0 impossible.
2091
2092         $c =~ s@(?<=Request from )([^\s]*)@$h{'ip-address'}$1$h{'Standard'}@;
2093         $c =~ s@(denied|blocking)@$h{'warning'}$1$h{'Standard'}@;
2094         $c =~ s@(CONNECT)@$h{'method'}$1$h{'Standard'}@;
2095         $c =~ s@(?<=to port )(\d+)@$h{'port'}$1$h{'Standard'}@;
2096         $c =~ s@(?<=to )([^\s]+)@$h{'request_'}$1$h{'Standard'}@;
2097
2098     } elsif ($c =~ m/^Status code/) {
2099
2100         # Status code 304 implies no body.
2101         $c =~ s@(?<=Status code )(\d+)@$h{'status-code'}$1$h{'Standard'}@;
2102
2103     } elsif ($c =~ m/^Method/) {
2104
2105         # Method HEAD implies no body.
2106         $c =~ s@(?<=Method )([^\s]+)@$h{'method'}$1$h{'Standard'}@;
2107
2108     } elsif ($c =~ m/^Buffer limit reached while extending /) {
2109
2110         # Buffer limit reached while extending the buffer (iob). Needed: 4197470. Limit: 4194304
2111         $c =~ s@(?<=Needed: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
2112         $c =~ s@(?<=Limit: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
2113
2114     } elsif ($c =~ m/^File modification detected: /) {
2115
2116         # File modification detected: /usr/local/etc/privoxy/user-agent.action
2117         $c =~ s@(?<= detected: )(.*)$@$h{'file'}$1$h{'Standard'}@;
2118
2119     } elsif ($c =~ m/^No logfile configured/ or
2120              $c =~ m/^Malformerd HTTP headers detected and MS IIS5 hack enabled/ or
2121              $c =~ m/^Invalid \"chunked\" transfer/ or
2122              $c =~ m/^Support for/ or
2123              $c =~ m/^Flushing header and buffers/ or
2124              $c =~ m/^Can not resolve/
2125              ) {
2126
2127         # No logfile configured. Please enable it before reporting any problems.
2128         # Malformerd HTTP headers detected and MS IIS5 hack enabled. Expect an invalid \
2129         #  response or even no response at all.
2130         # No logfile configured. Logging disabled.
2131         # Invalid "chunked" transfer encoding detected and ignored.
2132         # Support for 'Connection: keep-alive' is experimental, incomplete and\
2133         #  known not to work properly in some situations.
2134         # Flushing header and buffers. Stepping back from filtering.
2135         # Can not resolve doesnotexist: hostname nor servname provided, or not known
2136
2137     } else {
2138
2139         found_unknown_content($c);
2140
2141     }
2142
2143     return $c;
2144 }
2145
2146 sub handle_loglevel_cgi($) {
2147
2148     my $c = shift;
2149
2150     if ($c =~ m/^Granting access to/) {
2151
2152         #Granting access to http://config.privoxy.org/send-stylesheet, referrer http://p.p/ is trustworthy.
2153
2154     } elsif ($c =~ m/^Substituting: s(.)/) {
2155
2156         # Substituting: s/@else-not-FEATURE_ZLIB@.*@endif-FEATURE_ZLIB@//sigTU
2157         # XXX: prone to span several lines
2158
2159         my $delimiter = $1;
2160         #$c =~ s@(?<=failed: )(.*)@$h{'error'}$1$h{'Standard'}@;
2161         $c =~ s@(?!<=\\)($delimiter)@$h{'pcrs-delimiter'}$1$h{'Standard'}@g; # XXX: Too aggressive
2162         #$c =~ s@(?!<=\\)($1)@$h{'pcrs-delimiter'}$1$h{'Standard'}@g;
2163     }
2164
2165     return $c;
2166 }
2167
2168 sub handle_loglevel_force($) {
2169
2170     my $c = shift;
2171
2172     if ($c =~ m/^Ignored force prefix in request:/) {
2173
2174         # Ignored force prefix in request: "GET http://10.0.0.1/PRIVOXY-FORCE/block HTTP/1.1"
2175         $c =~ s@^(Ignored)@$h{'ignored'}$1$h{'Standard'}@;
2176         $c = highlight_matched_request_line($c, '(?<=request: ")[^"]*');
2177
2178     } elsif ($c =~ m/^Enforcing request:/) {
2179
2180         # Enforcing request: "GET http://10.0.0.1/block HTTP/1.1".
2181         $c = highlight_matched_request_line($c, '(?<=request: ")[^"]*');
2182
2183     } else {
2184
2185         found_unknown_content($c);
2186
2187     }
2188
2189     return $c;
2190 }
2191
2192 sub handle_loglevel_error($) {
2193
2194     my $c = shift;
2195
2196     if ($c =~ m/^(?:Empty|No) server or forwarder response received on socket \d+\./) {
2197
2198         # Empty server or forwarder response received on socket 4.
2199         # Empty server or forwarder response received on socket 3. \
2200         #  Closing client socket 15 without sending data.
2201         # Used by Privoxy 3.0.18 and later:
2202         # No server or forwarder response received on socket 8. \
2203         #  Closing client socket 10 without sending data.
2204
2205         $c =~ s@(?<=on socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
2206         $c =~ s@(?<=client socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
2207
2208     } elsif ($c =~ m/^Didn't receive data in time:/) {
2209
2210         # Didn't receive data in time: a.fsdn.com:443
2211         $c =~ s@(?<=in time: )(.*)@$h{'destination'}$1$h{'Standard'}@;
2212
2213     } elsif ($c =~ m/^Sending data on socket \d+ over TLS/) {
2214
2215         # Sending data on socket 33 over TLS/SSL failed: no TLS/SSL errors detected
2216         $c =~ s@(?<=on socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
2217
2218     } elsif ($c =~ m/^Chunk size \d+ exceeds buffered data left/) {
2219
2220         # Chunk size 291 exceeds buffered data left. Already digested 69894 of 69957 buffered bytes.
2221         $c =~ s@(?<=size )(\d+)@$h{'Number'}$1$h{'Standard'}@;
2222         $c =~ s@(?<=digested )(\d+)@$h{'Number'}$1$h{'Standard'}@;
2223         $c =~ s@(?<=of )(\d+)@$h{'Number'}$1$h{'Standard'}@;
2224
2225     } elsif ($c =~ m/^The socks connection timed out after/) {
2226
2227         # The socks connection timed out after 60 seconds.
2228         $c =~ s@(?<=after )(\d+)@$h{'Number'}$1$h{'Standard'}@;
2229     }
2230
2231     # XXX: There are probably more messages that deserve highlighting.
2232
2233     return $c;
2234 }
2235
2236 sub handle_loglevel_received($) {
2237
2238     my $c = shift;
2239
2240     if ($c =~ m/^TLS from socket/) {
2241         # TLS from socket 3: \x16\xda\xe2\xa2;\x0d\x0a
2242
2243         $c =~ s@(?<=TLS from socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
2244
2245     } elsif ($c =~ m/^from socket/) {
2246         # from socket 3: HEAD http://p.p/ HTTP/1.1\x0d\x0aHost: p.p\x0d\x0aUser-Agent: curl/7.85.0\x0d\x0aAccept: */*\x0d\x0aProxy-Connection: Keep-Alive\x0d\x0a\x0d\x0a
2247
2248         $c =~ s@(?<=from socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
2249     }
2250
2251     return $c;
2252 }
2253
2254 sub handle_loglevel_writing($) {
2255
2256     my $c = shift;
2257
2258     if ($c =~ m/^to socket/) {
2259         # to socket 11: HTTP/1.1 200 Connection established\x0d\x0a\x0d\x0a
2260
2261         $c =~ s@(?<=to socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
2262
2263     } elsif ($c =~ m/^TLS on socket /) {
2264         # TLS on socket 9: o~\xfcS[\xfa\x8f\xd6\x96\xe6_\xc7$\x1b[...]
2265
2266         $c =~ s@(?<=TLS on socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
2267     }
2268
2269     return $c;
2270 }
2271
2272 sub handle_loglevel_ignore($) {
2273     return shift;
2274 }
2275
2276 sub gather_loglevel_clf_stats($) {
2277
2278     my $content = shift;
2279     my ($method, $resource, $http_version, $status_code, $size);
2280     our %stats;
2281     our %cli_options;
2282
2283     # +0200] "GET https://www.youtube.com/watch?v=JmcA9LIIXWw HTTP/1.1" 200 68004
2284     # +0200] "VERSION-CONTROL http://p.p/ HTTP/1.1" 200 2787
2285     $content =~ m/^[+-]\d{4}\] "([^ ]+) (.+) (HTTP\/\d\.\d)" (\d+) (\d+)/;
2286     $method       = $1;
2287     $resource     = $2;
2288     $http_version = $3;
2289     $status_code  = $4;
2290     $size         = $5;
2291
2292     $stats{requests_clf}++;
2293
2294     unless (defined $method) {
2295         # +0200] "Invalid request" 400 0
2296         return if ($content =~ m/^[+-]\d{4}\] "Invalid request"/);
2297         # +0100] "Failed reading chunked client body" 400 0
2298         return if ($content =~ m/^[+-]\d{4}\] "Failed reading chunked client body"/);
2299         # +0100] "GET https://securepubads.g.doubleclick.net/gampad/ads?gd[...]... [too long, truncated]
2300         if ($content =~ m/\[too long, truncated\]$/) {
2301             print("Skipped LOG_LEVEL_CLF message that got truncated by Privoxy. Statistics will be inprecise.\n");
2302         } else {
2303             print("Failed to parse: $content\n");
2304         }
2305         return;
2306     }
2307     $stats{'method'}{$method}++;
2308     if ($cli_options{'url-statistics-threshold'} != 0) {
2309         $stats{'resource'}{$resource}++;
2310     }
2311     $stats{'http-version'}{$http_version}++;
2312
2313     if ($cli_options{'host-statistics-threshold'} != 0) {
2314         $resource =~ m@(?:https?://)?([^/]+)/?@;
2315         $stats{'hosts'}{$1}++;
2316     }
2317     $stats{'content-size-total'} += $size;
2318     $stats{'status-code'}{$status_code}++;
2319 }
2320
2321 sub gather_loglevel_request_stats($$) {
2322     my $request_url = shift;
2323     my $thread = shift;
2324     our %stats;
2325     our %cli_options;
2326
2327     $stats{requests}++;
2328     if ($cli_options{'passed-request-statistics-threshold'} != 0) {
2329         # If the request get blocked we'll decrement
2330         # in gather_loglevel_crunch_stats()
2331         chomp $request_url;
2332         $stats{'passed-request-url'}{$request_url}++;
2333     }
2334 }
2335
2336 sub gather_loglevel_crunch_stats($$) {
2337     my $c = shift;
2338     my $thread = shift;
2339     our %stats;
2340     our %cli_options;
2341
2342     $stats{crunches}++;
2343
2344     if ($c =~ m/^Redirected:/) {
2345         # Redirected: http://www.example.org/http://p.p/
2346         $stats{'fast-redirections'}++;
2347
2348     } elsif ($c =~ m/^Blocked:/) {
2349         # Blocked: blogger.googleusercontent.com:443
2350         $stats{'blocked'}++;
2351
2352     } elsif ($c =~ m/^Connection timeout:/) {
2353         # Connection timeout: http://c.tile.openstreetmap.org/18/136116/87842.png
2354         $stats{'connection-timeout'}++;
2355
2356     } elsif ($c =~ m/^Connection failure:/) {
2357         # Connection failure: http://127.0.0.1:8080/
2358         $stats{'connection-failure'}++;
2359     }
2360     if ($cli_options{'passed-request-statistics-threshold'} != 0) {
2361         $c =~ m/^[^:]+: (.*)/;
2362         if ($stats{'passed-request-url'}{$1}) {
2363             $stats{'passed-request-url'}{$1}-- ;
2364             if ($stats{'passed-request-url'}{$1} == 0) {
2365                 delete($stats{'passed-request-url'}{$1});
2366             }
2367         }
2368     }
2369 }
2370
2371
2372 sub gather_loglevel_error_stats($$) {
2373
2374     my $c = shift;
2375     my $thread = shift;
2376     our %stats;
2377     our %thread_data;
2378
2379     if ($c =~ m/^Empty server or forwarder response received on socket \d+./) {
2380
2381         # Empty server or forwarder response received on socket 4.
2382         $stats{'empty-responses'}++;
2383         if ($thread_data{$thread}{'new_connection'}) {
2384             $stats{'empty-responses-on-new-connections'}++;
2385         } else {
2386             $stats{'empty-responses-on-reused-connections'}++;
2387         }
2388     }
2389 }
2390
2391 sub gather_loglevel_connect_stats($$) {
2392
2393     my ($c, $thread) = @_;
2394     our %thread_data;
2395     our %stats;
2396
2397     if ($c =~ m/^via ([^\s]+) to: [^\s]+/) {
2398
2399         # Connect: via 10.0.0.1:8123 to: www.example.org.noconnect
2400         $thread_data{$thread}{'forwarder'} = $1; # XXX: is this missue?
2401
2402     } elsif ($c =~ m/^to ([^\s]*)$/) {
2403
2404         # Connect: to lists.sourceforge.net:443
2405
2406         $thread_data{$thread}{'forwarder'} = 'direct connection';
2407
2408     } elsif ($c =~ m/^Created new connection to/) {
2409
2410         # Created new connection to www.privoxy.org:80 on socket 11.
2411
2412         $thread_data{$thread}{'new_connection'} = 1;
2413
2414     } elsif ($c =~ m/^Reusing server socket \d./ or
2415              $c =~ m/^Found reusable socket/) {
2416
2417         # Reusing server socket 4. Opened for 10.0.0.1.
2418         # Found reusable socket 9 for www.privoxy.org:80 in slot 0.
2419
2420         $thread_data{$thread}{'new_connection'} = 0;
2421         $stats{'reused-connections'}++;
2422
2423     } elsif ($c =~ m/^Closing client socket \d+. .* Requests received: (\d+)\.$/) {
2424
2425         # Closing client socket 12. Keep-alive: 1. Socket alive: 1. Data available: 0. \
2426         #  Configuration file change detected: 0. Requests received: 14.
2427
2428         $stats{'client-requests-on-connection'}{$1}++;
2429         $stats{'closed-client-connections'}++;
2430     }
2431 }
2432
2433 sub gather_loglevel_header_stats($$) {
2434
2435     my ($c, $thread) = @_;
2436     our %stats;
2437     our %cli_options;
2438
2439     if ($c =~ m/^A HTTP\/1\.1 response without/ or
2440         $c =~ m/^Keeping the server header 'Connection: keep-alive' around./)
2441     {
2442         # A HTTP/1.1 response without Connection header implies keep-alive.
2443         # Keeping the server header 'Connection: keep-alive' around.
2444         $stats{'server-keep-alive'}++;
2445     }
2446 }
2447
2448 sub init_stats() {
2449     our %stats = (
2450         requests => 0,
2451         requests_clf => 0,
2452         crunches => 0,
2453         'server-keep-alive' => 0,
2454         'reused-connections' => 0,
2455         'empty-responses' => 0,
2456         'empty-responses-on-new-connections' => 0,
2457         'empty-responses-on-reused-connections' => 0,
2458         'fast-redirections' => 0,
2459         'blocked' => 0,
2460         'connection-failure' => 0,
2461         'connection-timeout' => 0,
2462         'reused-connections' => 0,
2463         'server-keep-alive' => 0,
2464         'closed-client-connections' => 0,
2465         'content-size-total' => 0,
2466         );
2467         $stats{'client-requests-on-connection'}{1} = 0;
2468 }
2469
2470 sub get_percentage($$) {
2471     my $big = shift;
2472     my $small = shift;
2473
2474     # If small is 0 the percentage is always 0%.
2475     # Make sure it works even if big is 0 as well.
2476     return "0.00%" if ($small eq 0);
2477
2478     # Prevent division by zero.
2479     # XXX: Is this still supposed to be reachable?
2480     return "NaN" if ($big eq 0);
2481
2482     return sprintf("%.2f%%", $small / $big * 100);
2483 }
2484
2485 sub print_stats() {
2486
2487     our %stats;
2488     our %cli_options;
2489     my $new_connections = $stats{requests} - $stats{crunches} - $stats{'reused-connections'};
2490     my $client_requests_checksum = 0;
2491     my $requests_total;
2492
2493     if ($stats{requests_clf} && $stats{requests}
2494         && $stats{requests_clf} != $stats{requests}) {
2495         print "Inconsistent request counts: " . $stats{requests} . "/" . $stats{requests_clf} . "\n";
2496     }
2497
2498     # To get the total number of requests we can use either the number
2499     # of Common-Log-Format lines or the number of "Request:" messages.
2500     # We prefer the number of CLF lines if available because using
2501     # it works when analysing old log files from Privoxy versions before 3.0.29.
2502     # In Privoxy 3.0.28 and earlier "Request:" messages excluded
2503     # crunched messages.
2504     $requests_total = $stats{requests_clf} ? $stats{requests_clf} : $stats{requests};
2505
2506     if ($requests_total eq 0) {
2507         print "No requests yet.\n";
2508         return;
2509     }
2510
2511     print "Client requests total: " . $requests_total . "\n";
2512     if ($stats{crunches}) {
2513         my $outgoing_requests = $requests_total - $stats{crunches};
2514         print "Crunches: " . $stats{crunches} . " (" .
2515             get_percentage($requests_total, $stats{crunches}) . ")\n";
2516         print "Blocks: " . $stats{'blocked'} . " (" .
2517             get_percentage($requests_total, $stats{'blocked'}) . ")\n";
2518         print "Fast redirections: " . $stats{'fast-redirections'} . " (" .
2519             get_percentage($requests_total, $stats{'fast-redirections'}) . ")\n";
2520         print "Connection timeouts: " . $stats{'connection-timeout'} . " (" .
2521             get_percentage($requests_total, $stats{'connection-timeout'}) . ")\n";
2522         print "Connection failures: " . $stats{'connection-failure'} . " (" .
2523             get_percentage($requests_total, $stats{'connection-failure'}) . ")\n";
2524         print "Outgoing requests: " . $outgoing_requests . " (" .
2525             get_percentage($requests_total, $outgoing_requests) . ")\n";
2526     } else {
2527         print "No crunches detected. Is 'debug 1024' enabled?\n";
2528     }
2529
2530     print "Server keep-alive offers: " . $stats{'server-keep-alive'} . " (" .
2531         get_percentage($requests_total, $stats{'server-keep-alive'}) . ")\n";
2532     print "New outgoing connections: " . $new_connections . " (" .
2533         get_percentage($requests_total, $new_connections) . ")\n";
2534     print "Reused server connections: " . $stats{'reused-connections'} . " (" .
2535         get_percentage($requests_total, $stats{'reused-connections'}) .
2536         "; server offers accepted: " .
2537         get_percentage($stats{'server-keep-alive'}, $stats{'reused-connections'}) . ")\n";
2538     print "Empty responses: " . $stats{'empty-responses'} . " (" .
2539         get_percentage($requests_total, $stats{'empty-responses'}) . ")\n";
2540     print "Empty responses on new connections: "
2541          . $stats{'empty-responses-on-new-connections'} . " (" .
2542         get_percentage($requests_total, $stats{'empty-responses-on-new-connections'})
2543         . ")\n";
2544     print "Empty responses on reused connections: " .
2545         $stats{'empty-responses-on-reused-connections'} . " (" .
2546         get_percentage($requests_total, $stats{'empty-responses-on-reused-connections'}) .
2547         ")\n";
2548     print "Client connections: " .  $stats{'closed-client-connections'} . "\n";
2549     if ($stats{'content-size-total'}) {
2550         print "Bytes of content transferred to the client: " .  $stats{'content-size-total'} . "\n";
2551     }
2552     my $lines_printed = 0;
2553     print "Client requests per connection distribution:\n";
2554     foreach my $client_requests (sort {
2555         $stats{'client-requests-on-connection'}{$b} <=> $stats{'client-requests-on-connection'}{$a}}
2556                                   keys %{$stats{'client-requests-on-connection'}
2557                                   })
2558     {
2559         my $count = $stats{'client-requests-on-connection'}{$client_requests};
2560         $client_requests_checksum += $count * $client_requests;
2561         if ($cli_options{'show-complete-request-distribution'} or ($lines_printed < 10)) {
2562             printf "%8d: %d\n", $count, $client_requests;
2563             $lines_printed++;
2564         }
2565     }
2566     unless ($cli_options{'show-complete-request-distribution'}) {
2567         printf "Enable --show-complete-request-distribution to get less common numbers as well.\n";
2568     }
2569     # Due to log rotation we may not have a complete picture for all the requests
2570     printf "Improperly accounted requests: ~%d\n", abs($requests_total - $client_requests_checksum);
2571
2572     if (exists $stats{method}) {
2573         print "Method distribution:\n";
2574         foreach my $method (sort {$stats{'method'}{$b} <=> $stats{'method'}{$a}} keys %{$stats{'method'}}) {
2575             printf "%8d : %-8s\n", $stats{'method'}{$method}, $method;
2576         }
2577     } else {
2578         print "Method distribution unknown. No CLF message parsed yet. Is 'debug 512' enabled?\n";
2579     }
2580     if (exists $stats{'http-version'}) {
2581         print "Client HTTP versions:\n";
2582         foreach my $http_version (sort {$stats{'http-version'}{$b} <=> $stats{'http-version'}{$a}} keys %{$stats{'http-version'}}) {
2583             printf "%8d : %-8s\n",  $stats{'http-version'}{$http_version}, $http_version;
2584         }
2585     } else {
2586         print "HTTP version distribution unknown. No CLF message parsed yet. Is 'debug 512' enabled?\n";
2587     }
2588     if (exists $stats{'status-code'}) {
2589         print "HTTP status codes according to 'debug 512' (status codes sent by the server may differ):\n";
2590         foreach my $status_code (sort {$stats{'status-code'}{$b} <=> $stats{'status-code'}{$a}} keys %{$stats{'status-code'}}) {
2591             printf "%8d : %-8d\n",  $stats{'status-code'}{$status_code}, $status_code;
2592         }
2593     } else {
2594         print "Status code distribution unknown. No CLF message parsed yet. Is 'debug 512' enabled?\n";
2595     }
2596
2597     if ($cli_options{'url-statistics-threshold'} == 0) {
2598         print "URL statistics are disabled. Increase --url-statistics-threshold to enable them.\n";
2599     } else {
2600         print "Requested URLs:\n";
2601         foreach my $resource (sort {$stats{'resource'}{$b} <=> $stats{'resource'}{$a}} keys %{$stats{'resource'}}) {
2602             if ($stats{'resource'}{$resource} < $cli_options{'url-statistics-threshold'}) {
2603                 print "Skipped statistics for URLs below the treshold.\n";
2604                 last;
2605             }
2606             printf "%d : %s\n", $stats{'resource'}{$resource}, $resource;
2607         }
2608     }
2609
2610     if ($cli_options{'passed-request-statistics-threshold'} == 0) {
2611         print "Passed request statistics are disabled. Increase --passed-request-statistics-threshold to enable them.\n";
2612     } else {
2613         print "Requested requests that were passed:\n";
2614         foreach my $passed_url (sort {$stats{'passed-request-url'}{$b} <=> $stats{'passed-request-url'}{$a}}
2615                                 keys %{$stats{'passed-request-url'}}) {
2616             if ($stats{'passed-request-url'}{$passed_url} < $cli_options{'passed-request-statistics-threshold'}) {
2617                 print "Skipped statistics for passed URLs below the treshold.\n";
2618                 last;
2619             }
2620             printf "%d : %s\n", $stats{'passed-request-url'}{$passed_url}, $passed_url;
2621         }
2622     }
2623     if ($cli_options{'host-statistics-threshold'} == 0) {
2624         print "Host statistics are disabled. Increase --host-statistics-threshold to enable them.\n";
2625     } else {
2626         print "Requested Hosts:\n";
2627         foreach my $host (sort {$stats{'hosts'}{$b} <=> $stats{'hosts'}{$a}} keys %{$stats{'hosts'}}) {
2628             if ($stats{'hosts'}{$host} < $cli_options{'host-statistics-threshold'}) {
2629                 print "Skipped statistics for Hosts below the treshold.\n";
2630                 last;
2631             }
2632             printf "%d : %s\n", $stats{'hosts'}{$host}, $host;
2633         }
2634     }
2635 }
2636
2637
2638 ################################################################################
2639 # Functions that actually print stuff
2640 ################################################################################
2641
2642 sub print_clf_message() {
2643
2644     our ($ip, $timestamp, $request_line, $status_code, $size);
2645     my $output = '';
2646
2647     return if DEBUG_SUPPRESS_LOG_MESSAGES;
2648
2649     # Rebuild highlighted
2650     $output .= $h{'Number'} . $ip . $h{'Standard'};
2651     $output .= " - - ";
2652     $output .= "[" . $h{'Timestamp'} . $timestamp . $h{'Standard'} . "]";
2653     $output .= " ";
2654     $output .= "\"" . highlight_request_line("$request_line") . "\"";
2655     $output .= " ";
2656     $output .= $h{'Status'} . $status_code . $h{'Standard'};
2657     $output .= " ";
2658     $output .= $h{'Number'} . $size . $h{'Standard'};
2659     $output .= $line_end;
2660
2661     print $output;
2662 }
2663
2664 sub print_non_clf_message($) {
2665
2666     my $content = shift;
2667     my $date_string = $keep_date_mode ? $req{$t}{'day'} . ' ' : '';
2668     my $msec_string = $no_msecs_mode ? '' : '.' . $req{$t}{'msecs'};
2669     my $line_start = $html_output_mode ? '' : $h{"Standard"};
2670
2671     return if DEBUG_SUPPRESS_LOG_MESSAGES;
2672
2673     print $line_start
2674         . $date_string
2675         . $time_colours[$time_colour_index % 2]
2676         . $req{$t}{'time-stamp'}
2677         . $msec_string
2678         . $h{Standard} . " "
2679         . $thread_colours{$t}
2680         . $t
2681         . $h{Standard}
2682         . " "
2683         . $h{$req{$t}{'log-level'}}
2684         . $req{$t}{'log-level'}
2685         . $h{Standard}
2686         . ": "
2687         . $content
2688         . $line_end;
2689 }
2690
2691 sub shorten_thread_id($) {
2692
2693     my $thread_id = shift;
2694
2695     our %short_thread_ids;
2696     our $max_threadid;
2697
2698     unless (defined $short_thread_ids{$thread_id}) {
2699         $short_thread_ids{$thread_id} = sprintf "%.3d", $max_threadid++;
2700     }
2701
2702     return $short_thread_ids{$thread_id}
2703 }
2704
2705 sub parse_loop() {
2706
2707     my ($day, $time_stamp, $thread, $log_level, $content, $c, $msecs);
2708     my $last_msecs  = 0;
2709     my $last_thread = 0;
2710     my $last_timestamp = 0;
2711     my $filters_that_did_nothing;
2712     my $key;
2713     my $time_colour;
2714     $time_colour = paint_it('white');
2715
2716     my %log_level_handlers = (
2717         'Re-Filter'         => \&handle_loglevel_re_filter,
2718         'Header'            => \&handle_loglevel_header,
2719         'Connect'           => \&handle_loglevel_connect,
2720         'Redirect'          => \&handle_loglevel_redirect,
2721         'Request'           => \&handle_loglevel_request,
2722         'Crunch'            => \&handle_loglevel_crunch,
2723         'Gif-Deanimate'     => \&handle_loglevel_gif_deanimate,
2724         'Info'              => \&handle_loglevel_info,
2725         'CGI'               => \&handle_loglevel_cgi,
2726         'Force'             => \&handle_loglevel_force,
2727         'Error'             => \&handle_loglevel_error,
2728         'Fatal error'       => \&handle_loglevel_ignore,
2729         'Writing'           => \&handle_loglevel_writing,
2730         'Received'          => \&handle_loglevel_received,
2731         'Tagging'           => \&handle_loglevel_tagging,
2732         'Actions'           => \&handle_loglevel_ignore,
2733         'Unknown log level' => \&handle_loglevel_ignore,
2734     );
2735
2736     while (<>) {
2737
2738         if (m/^(\d{4}-\d{2}-\d{2}|\w{3} \d{2}) (\d\d:\d\d:\d\d)\.?(\d+)? (?:Privoxy\()?([^\)\s]*)[\)]? ([\w -]*): (.*?)\r?$/) {
2739             $thread = $t = ($shorten_thread_ids) ? shorten_thread_id($4) : $4;
2740             $req{$t}{'day'} = $day = $1;
2741             $req{$t}{'time-stamp'} = $time_stamp = $2;
2742             $req{$t}{'msecs'} = $msecs = $3 ? $3 : 0; # Only the cool kids have micro second resolution;
2743             $req{$t}{'log-level'} = $log_level = $5;
2744             $req{$t}{'content'} = $content = $c = $6;
2745             $req{$t}{'log-message'} = $_;
2746             $no_special_header_highlighting = 0;
2747
2748             if (defined($log_level_handlers{$log_level})) {
2749
2750                 $content = $log_level_handlers{$log_level}($content);
2751
2752             } else {
2753
2754                 die "No handler found for log level \"$log_level\"\n";
2755             }
2756
2757             # Highlight Truncations
2758             if (length($_) > 4000) {
2759                 $content =~ s@(too long, truncated)]$@$h{'Truncation'}$1$h{'Standard'}]@g;
2760             }
2761
2762             next unless $content;
2763
2764             # Register threads to keep the colour constant
2765             if (!defined($thread_colours{$thread})) {
2766                 $thread_colours{$thread} = $all_colours[$thread_colour_index % @all_colours];
2767                 $thread_colour_index++;
2768             }
2769
2770             # Switch timestamp colour if timestamps differ
2771             if (($msecs ne $last_msecs) || ($time_stamp ne $last_timestamp)) {
2772                debug_message("Tick tack!") if DEBUG_TICKS;
2773                $time_colour = $time_colours[$time_colour_index % 2];
2774                $time_colour_index++;
2775                $last_msecs = $msecs;
2776                $last_timestamp = $time_stamp;
2777             }
2778
2779             $last_thread = $thread;
2780
2781             print_non_clf_message($content);
2782
2783         } elsif (m/^((?:\d+\.\d+\.\d+\.\d+|[:\d]+)) - - \[(.*)\] "(.*)" (\d+) (\d+)/) {
2784
2785             # LOG_LEVEL_CLF lines look like this
2786             # 61.152.239.32 - - [04/Mar/2007:18:28:23 +0100] "GET \
2787             #  http://ad.yieldmanager.com/imp?z=1&Z=120x600&s=109339&u=http%3A%2F%2Fwww.365loan.co.uk%2F&r=1\
2788             #  HTTP/1.1" 403 1730
2789             our ($ip, $timestamp, $request_line, $status_code, $size) = ($1, $2, $3, $4, $5);
2790
2791             print_clf_message();
2792
2793         } else {
2794
2795             # Some Privoxy log messages span more than one line,
2796             # usually to dump lots of content that doesn't need any syntax highlighting.
2797             # XXX: add mechanism to forward these lines to the right handler anyway.
2798             chomp();
2799             unless (DEBUG_SUPPRESS_LOG_MESSAGES or (SUPPRESS_EMPTY_LINES and m/^\s+$/)) {
2800                 print and print get_line_end(); # unless (SUPPRESS_EMPTY_LINES and m/^\s+$/);
2801             }
2802         }
2803     }
2804 }
2805
2806 sub stats_loop() {
2807
2808     my ($day, $time_stamp, $thread, $log_level, $content);
2809     my $strict_checks = cli_option_is_set('strict-checks');
2810     my %log_level_handlers = (
2811          'Connect:'           => \&gather_loglevel_connect_stats,
2812          'Crunch:'            => \&gather_loglevel_crunch_stats,
2813          'Error:'             => \&gather_loglevel_error_stats,
2814          'Header:'            => \&gather_loglevel_header_stats,
2815          'Request:'           => \&gather_loglevel_request_stats,
2816     );
2817     my %ignored_log_levels = (
2818          'Actions:'           => \&handle_loglevel_ignore,
2819          'CGI:'               => \&handle_loglevel_ignore,
2820          'Fatal error:'       => \&handle_loglevel_ignore,
2821          'Force:'             => \&handle_loglevel_ignore,
2822          'Gif-Deanimate:'     => \&handle_loglevel_ignore,
2823          'Info:'              => \&handle_loglevel_ignore,
2824          'Re-Filter:'         => \&handle_loglevel_ignore,
2825          'Received:'          => \&handle_loglevel_ignore,
2826          'Redirect:'          => \&handle_loglevel_ignore,
2827          'Unknown log level:' => \&handle_loglevel_ignore,
2828          'Writing:'           => \&handle_loglevel_ignore,
2829          'Tagging:'           => \&handle_loglevel_ignore,
2830     );
2831
2832     while (<>) {
2833         (undef, $time_stamp, $thread, $log_level, $content) = split(/ /, $_, 5);
2834
2835
2836         next if (not defined($log_level));
2837
2838         if ($time_stamp eq "-") {
2839
2840             gather_loglevel_clf_stats($content);
2841
2842         } elsif (defined($log_level_handlers{$log_level})) {
2843
2844             $content = $log_level_handlers{$log_level}($content, $thread);
2845
2846         } elsif ($strict_checks and not defined($ignored_log_levels{$log_level})) {
2847
2848             die "No handler found for: $_";
2849         }
2850     }
2851
2852     print_stats();
2853
2854 }
2855
2856 # Convert a timestamp like 18:07:28.733 into milliseconds
2857 sub time_stamp_to_msecs($) {
2858     my $time_stamp = shift;
2859
2860     if ($time_stamp =~ /(\d\d):(\d\d):(\d\d)\.(\d{3})/) {
2861         my ($hours, $minutes, $seconds, $msecs) = ($1, $2, $3, $4);
2862
2863         $msecs += $seconds * 1000;
2864         $msecs += $minutes * 1000 * 60;
2865         $msecs += $hours   * 1000 * 60 * 60;
2866
2867         return $msecs;
2868     }
2869     return undef;
2870 }
2871
2872 sub inactivity_detection_loop() {
2873
2874     our %cli_options;
2875     my ($date, $time_stamp, $thread, $log_level, $content);
2876     my ($msecs, $previous_msecs, $inactivity);
2877     my $inactivity_threshold = $cli_options{'inactivity-threshold'};
2878     my $previous_date;
2879     my $log_messages_out_of_order = 0;
2880
2881     while (<>) {
2882         ($date, $time_stamp, $thread, $log_level, $content) = split(/ /, $_, 5);
2883
2884         next if (not defined($log_level));
2885         next if ($time_stamp eq "-");
2886         $msecs = time_stamp_to_msecs($time_stamp);
2887         unless (defined $msecs) {
2888             print "Failed to convert $time_stamp into milliseconds\n";
2889             print "$_";
2890             next;
2891         }
2892         unless (defined $previous_msecs) {
2893             $previous_msecs = $msecs;
2894             $previous_date = $date;
2895             print "$_";
2896             next;
2897         }
2898         $inactivity = $msecs - $previous_msecs;
2899         if ($inactivity < 0) {
2900             # This can happen if there's a high load in which case
2901             # a Privoxy thread may be moved off schedule between
2902             # getting the timestamp for the log message and actually
2903             # writing it.
2904             $log_messages_out_of_order++;
2905         }
2906         if ($inactivity > $inactivity_threshold) {
2907             if ($previous_date eq $date) {
2908                 print "Detected inactivity: $inactivity msecs\n";
2909             } else {
2910                 # While we could include the date in the timestamp
2911                 # we currently don't.
2912                 print "Detected date change. Timestamp difference ignored.\n";
2913             }
2914         }
2915         print "$_";
2916         $previous_msecs = $msecs;
2917         $previous_date = $date;
2918     }
2919     if ($log_messages_out_of_order) {
2920         print "At least $log_messages_out_of_order messages were written out of the chronological order.\n";
2921         print "This can result in false positives. Consider sorting the log first.\n";
2922     }
2923 }
2924
2925 sub unbreak_lines_only_loop() {
2926     my $log_messages_reached = 0;
2927     while (<>) {
2928         chomp;
2929
2930             # Log level other than LOG_LEVEL_CLF?
2931         if (m/^(\d{4}-\d{2}-\d{2}|\w{3} \d{2}) (\d\d:\d\d:\d\d)\.?(\d+)? (?:Privoxy\()?([^\)\s]*)[\)]? ([\w -]*): (.*?)\r?$/ or
2932             # LOG_LEVEL_CLF?
2933             m/^((?:\d+\.\d+\.\d+\.\d+)) - - \[(.*)\] "(.*)" (\d+) (\d+)/) {
2934             $log_messages_reached = 1;
2935             print "\n";
2936
2937         } else {
2938             # Wrapped message
2939             $_ = "\n". $_  if /^(?:\d+\.\d+\.\d+\.\d+)/;
2940             $_ = " " . $_;
2941         }
2942         s@<BR>$@@;
2943         print;
2944         print "\n" unless $log_messages_reached;
2945     }
2946     print "\n";
2947 }
2948
2949 sub VersionMessage {
2950     my $version_message;
2951
2952     $version_message .= 'Privoxy-Log-Parser ' . PRIVOXY_LOG_PARSER_VERSION  . "\n";
2953     $version_message .= 'https://www.fabiankeil.de/sourcecode/privoxy-log-parser/' . "\n";
2954
2955     print $version_message;
2956 }
2957
2958 sub get_cli_options() {
2959
2960     our %cli_options = (
2961         'detect-inactivity'        => CLI_OPTION_DETECT_INACTIVITY,
2962         'inactivity-threshold'     => CLI_OPTION_INACTIVITY_THRESHOLD,
2963         'html-output'              => CLI_OPTION_DEFAULT_TO_HTML_OUTPUT,
2964         'title'                    => CLI_OPTION_TITLE,
2965         'keep-date'                => CLI_OPTION_KEEP_DATE,
2966         'no-syntax-highlighting'   => CLI_OPTION_NO_SYNTAX_HIGHLIGHTING,
2967         'no-embedded-css'          => CLI_OPTION_NO_EMBEDDED_CSS,
2968         'no-msecs'                 => CLI_OPTION_NO_MSECS,
2969         'shorten-thread-ids'       => CLI_OPTION_SHORTEN_THREAD_IDS,
2970         'show-ineffective-filters' => CLI_OPTION_SHOW_INEFFECTIVE_FILTERS,
2971         'statistics'               => CLI_OPTION_STATISTICS,
2972         'strict-checks'            => CLI_OPTION_STRICT_CHECKS,
2973         'url-statistics-threshold' => CLI_OPTION_URL_STATISTICS_THRESHOLD,
2974         'unbreak-lines-only'       => CLI_OPTION_UNBREAK_LINES_ONLY,
2975         'host-statistics-threshold'=> CLI_OPTION_HOST_STATISTICS_THRESHOLD,
2976         'passed-request-statistics-threshold' => CLI_OPTION_PASSED_REQUEST_STATISTICS_THRESHOLD,
2977         'show-complete-request-distribution' => CLI_OPTION_SHOW_COMPLETE_REQUEST_DISTRIBUTION,
2978     );
2979
2980     GetOptions (
2981         'detect-inactivity'        => \$cli_options{'detect-inactivity'},
2982         'inactivity-threshold=i'   => \$cli_options{'inactivity-threshold'},
2983         'html-output'              => \$cli_options{'html-output'},
2984         'title'                    => \$cli_options{'title'},
2985         'keep-date'                => \$cli_options{'keep-date'},
2986         'no-syntax-highlighting'   => \$cli_options{'no-syntax-highlighting'},
2987         'no-embedded-css'          => \$cli_options{'no-embedded-css'},
2988         'no-msecs'                 => \$cli_options{'no-msecs'},
2989         'shorten-thread-ids'       => \$cli_options{'shorten-thread-ids'},
2990         'show-ineffective-filters' => \$cli_options{'show-ineffective-filters'},
2991         'statistics'               => \$cli_options{'statistics'},
2992         'strict-checks'            => \$cli_options{'strict-checks'},
2993         'unbreak-lines-only'       => \$cli_options{'unbreak-lines-only'},
2994         'url-statistics-threshold=i'=> \$cli_options{'url-statistics-threshold'},
2995         'host-statistics-threshold=i'=> \$cli_options{'host-statistics-threshold'},
2996         'passed-request-statistics-threshold=i' => \$cli_options{'passed-request-statistics-threshold'},
2997         'show-complete-request-distribution' => \$cli_options{'show-complete-request-distribution'},
2998         'version'                  => sub { VersionMessage && exit(0) },
2999         'help'                     => \&help,
3000    ) or exit(1);
3001
3002    $html_output_mode = cli_option_is_set('html-output');
3003    $no_msecs_mode = cli_option_is_set('no-msecs');
3004    $keep_date_mode = cli_option_is_set('keep-date');
3005    $shorten_thread_ids = cli_option_is_set('shorten-thread-ids');
3006    $line_end = get_line_end();
3007 }
3008
3009 sub help() {
3010
3011     our %cli_options;
3012
3013     VersionMessage();
3014
3015     print << "    EOF"
3016
3017 Options and their default values if they have any:
3018     [--detect-innactivity]
3019     [--inactivity-threshold $cli_options{'inactivity-threshold'}]
3020     [--host-statistics-threshold $cli_options{'host-statistics-threshold'}]
3021     [--html-output]
3022     [--no-embedded-css]
3023     [--no-msecs]
3024     [--no-syntax-highlighting]
3025     [--shorten-thread-ids]
3026     [--show-ineffective-filters]
3027     [--show-complete-request-distribution]
3028     [--statistics]
3029     [--unbreak-lines-only]
3030     [--url-statistics-threshold $cli_options{'url-statistics-threshold'}]
3031     [--passed-request-statistics-threshold $cli_options{'passed-request-statistics-threshold'}]
3032     [--title $cli_options{'title'}]
3033     [--version]
3034 see "perldoc $0" for more information
3035     EOF
3036     ;
3037     exit(0);
3038 }
3039
3040 ################################################################################
3041 # main
3042 ################################################################################
3043 sub main() {
3044
3045     get_cli_options();
3046     set_background(DEFAULT_BACKGROUND);
3047     prepare_our_stuff();
3048
3049     # XXX: should explicitly reject incompatible argument combinations
3050     if (cli_option_is_set('unbreak-lines-only')) {
3051         unbreak_lines_only_loop();
3052     } elsif (cli_option_is_set('statistics')) {
3053         stats_loop();
3054     } elsif (cli_option_is_set('detect-inactivity')) {
3055         inactivity_detection_loop();
3056     } else {
3057         print_intro();
3058         parse_loop();
3059         print_outro();
3060     }
3061 }
3062
3063 main();
3064
3065 =head1 NAME
3066
3067 B<privoxy-log-parser> - A parser and syntax-highlighter for Privoxy log messages
3068
3069 =head1 SYNOPSIS
3070
3071 B<privoxy-log-parser> [B<--detect-inactivity>] [B<--inactivity-threshold msecs>]
3072 [B<--html-output>]
3073 [B<--no-msecs>] [B<--no-syntax-higlighting>] [B<--statistics>]
3074 [B<--shorten-thread-ids>] [B<--show-ineffective-filters>]
3075 [B<--url-statistics-threshold>] [B<--version>]
3076
3077 =head1 DESCRIPTION
3078
3079 B<privoxy-log-parser> reads Privoxy log messages and
3080
3081 - syntax-highlights recognized lines,
3082
3083 - reformats some of them for easier comprehension,
3084
3085 - filters out less useful messages, and
3086
3087 - (in some cases) calculates additional information,
3088   like the compression ratio or how a filter affected
3089   the content size.
3090
3091 With B<privoxy-log-parser> you should be able to increase Privoxy's log level
3092 without getting confused by the resulting amount of output. For example for
3093 "debug 64" B<privoxy-log-parser> will (by default) only show messages that
3094 affect the content. If a filter doesn't cause any hits, B<privoxy-log-parser>
3095 will hide the "filter foo caused 0 hits" message.
3096
3097 =head1 OPTIONS
3098
3099 [B<--detect-inactivity>] Instead of syntax highlighting, detect periods
3100 of log inactivity of more than the amount of milliseconds specified with
3101 the B<--inactivity-threshold> option. Mainly useful for debugging.
3102
3103 [B<--host-statistics-threshold>] Only show the request count for a host
3104 if it's above or equal to the given threshold. If the threshold is 0, host
3105 statistics are disabled.
3106
3107 [B<--html-output>] Use HTML and CSS when syntax highlighting. If this option is
3108 omitted, ANSI escape sequences are used unless B<--no-syntax-highlighting> is active.
3109 This option is only intended to make embedding log excerpts in web pages easier.
3110 It does not escape any input!
3111
3112 [B<--inactivity-threshold msecs>] Specifies the number of milliseconds between
3113 log messages to consider inactivity when running in [B<--detect-inactivity>]
3114 mode.
3115
3116 [B<--keep-date>] Don't remove the date when printing highlighted log messages.
3117 Useful when parsing multiple log files at once.
3118
3119 [B<--no-msecs>] Don't expect millisecond resolution
3120
3121 [B<--no-syntax-highlighting>] Disable syntax-highlighting. Useful when
3122 the filtered output is piped into less in which case the ANSI control
3123 codes don't work, or if the terminal itself doesn't support the control
3124 codes.
3125
3126 [B<--passed-request-statistics-threshold>] Only show the request count for
3127 a passed requests if it's above or equal to the given threshold. If the
3128 threshold is 0, passed request statistics are disabled.
3129
3130 [B<--shorten-thread-ids>] Shorten the thread ids to a three-digit decimal number.
3131 Note that the mapping from thread ids to shortened ids is created at run-time
3132 and thus varies with the input.
3133
3134 [B<--show-ineffective-filters>] Don't suppress log lines for filters
3135 that didn't modify the content.
3136
3137 [B<--show-complete-request-distribution>] Show the complete client request
3138 distribution in the B<--statistics> output. Without this option only the
3139 ten most common numbers are shown.
3140
3141 [B<--statistics>] Gather various statistics instead of syntax highlighting
3142 log messages. This is an experimental feature, if the results look wrong
3143 they very well might be. Also note that the results are pretty much guaranteed
3144 to be incorrect if Privoxy and Privoxy-Log-Parser aren't in sync.
3145
3146 [B<--strict-checks>] When generating statistics, look more careful at the
3147 input data and abort if it is unexpected, even if it doesn't affect the
3148 results. Significantly slows the parsing down and is not expected to catch
3149 any problems that matter.
3150 When highlighting, print warnings in case of unknown messages which can't be
3151 properly highlighted.
3152
3153 [B<--unbreak-lines-only>] Tries to fix lines that got messed up by a broken or
3154 interestingly configured mail client and thus are no longer recognized properly.
3155 Only fixes some breakage, but may be good enough or at least better than nothing.
3156 Doesn't do anything else, so you probably want to pipe the output into
3157 B<privoxy-log-parser> again.
3158
3159 [B<--url-statistics-threshold>] Only show the request count for a resource
3160 if it's above or equal to the given threshold. If the threshold is 0, URL
3161 statistics are disabled.
3162
3163 [B<--version>] Print version and exit.
3164
3165 =head1 EXAMPLES
3166
3167 To monitor a log file:
3168
3169 tail -F /usr/jails/privoxy-jail/var/log/privoxy/privoxy.log | B<privoxy-log-parser>
3170
3171 Replace '-F' with '-f' if your tail implementation lacks '-F' support
3172 or if the log won't get rotated anyway. The log file location depends
3173 on your system (Doh!).
3174
3175 To monitor Privoxy without having it write to a log file:
3176
3177 privoxy --no-daemon /usr/jails/privoxy-jail/usr/local/etc/privoxy/config 2>&1 | B<privoxy-log-parser>
3178
3179 Again, the config file location depends on your system. Output redirection
3180 depends on your shell, the above works with bourne shells.
3181
3182 To read a processed Privoxy log file from top to bottom, letting the content
3183 scroll by slightly faster than you can read:
3184
3185 B<privoxy-log-parser> < /usr/jails/privoxy-jail/var/log/privoxy/privoxy.log
3186
3187 This is probably only useful to fill screens in the background of haxor movies.
3188
3189 =head1 CAVEATS
3190
3191 Syntax highlighting with ANSI escape sequences will look strange
3192 if your background color isn't black.
3193
3194 Some messages aren't recognized yet and will not be fully highlighted.
3195
3196 B<privoxy-log-parser> is developed with Privoxy 3.0.7 or later in mind,
3197 using earlier Privoxy versions will probably result in an increased amount
3198 of unrecognized log lines.
3199
3200 Privoxy's log files tend to be rather large. If you use HTML
3201 highlighting some browsers can't handle them, get confused and
3202 will eventually crash because of segmentation faults or unexpected
3203 exceptions. This is a problem in the browser and not B<privoxy-log-parser>'s
3204 fault.
3205
3206 =head1 BUGS
3207
3208 Many settings can't be controlled through command line options yet.
3209
3210 =head1 SEE ALSO
3211
3212 privoxy(8)
3213
3214 =head1 AUTHOR
3215
3216 Fabian Keil <fk@fabiankeil.de>
3217
3218 =cut