utils/prepare-configfile.pl

   1 #!/usr/local/bin/perl
   2
   3 # This script is used by the config-file target in GNUMakefile.
   4 #
   5 # It removes garbage in the w3m output and separates comments
   6 # and active directives.
   7
   8 use strict;
   9 use warnings;
  10
  11 sub main() {
  12     my $hit_header = 0;
  13     my $hit_option = 0;
  14     my $header_len;
  15     my $unfold_mode = 0;
  16     my $unfolding_enabled = 0;
  17     my $windows_section_reached = 0;
  18
  19     while (<>) {
  20
  21         if (!$unfolding_enabled and m/=========/) {
  22             # We passed the table of contents
  23             # and can try to unfold unintentional
  24             # line breaks;
  25             $unfolding_enabled = 1;
  26         }
  27         if (m/specific to the Windows GUI/) {
  28             # The Windows section is formatted differently.
  29             $windows_section_reached = 1;
  30         }
  31
  32         s/^1\. \@\@TITLE\@\@/     /i;
  33
  34         if (m/^(\d*\.){1,3}\s/) {
  35             # Remove the first digit as it's the
  36             # config file section in the User Manual.
  37             s/^(\d\.)//;
  38
  39             # If it's a section header, uppercase it.
  40             $_ = uc() if (/^\d\.\s+/);
  41
  42             # Remember to underline it.
  43             $hit_header = 1;
  44             $header_len = length($_);
  45         }
  46
  47         if ($unfold_mode) {
  48             s/^\s+/ /;
  49             $unfold_mode = 0;
  50         } else {
  51             s/^/#  /;
  52         }
  53         if ($unfolding_enabled and m/(\s+#)\s*$/) {
  54             $unfold_mode = 1;
  55             chomp;
  56         }
  57
  58         # XXX: someone should figure out what this stuff
  59         # is supposed to do (and if it really does that).
  60         s/^#  #/####/ if /^#  #{12,}/;
  61         s/^.*$// if $hit_option;
  62         $hit_option = 0;
  63         s/^\n//;
  64         s/^#\s*-{20,}//;
  65         s/ *$//;
  66         $hit_option = 1 if s/^#\s+@@//;
  67
  68         if ($windows_section_reached) {
  69             # Do not drop empty lines in the Windows section
  70             s/^\s*$/#\n/;
  71         }
  72
  73         print unless (/^\s*$/);
  74
  75         if ($hit_header) {
  76             # The previous line was a section
  77             # header so we better underline it.
  78             die "Invalid header length" unless defined $header_len;
  79             print "#  " . "=" x $header_len . "\n";
  80             $hit_header = 0;
  81         };
  82     }
  83 }
  84 main();