tools/uagen.pl

   1 #!/usr/bin/perl
   2
   3 ##############################################################################################
   4 # uagen (https://www.fabiankeil.de/sourcecode/uagen/)
   5 #
   6 # Generates a pseudo-random Firefox user agent and writes it into a Privoxy action file
   7 # and optionally into a Mozilla prefs file. For documentation see 'perldoc uagen(.pl)'.
   8 #
   9 # Examples (created with v1.0):
  10 #
  11 # Mozilla/5.0 (X11; U; NetBSD i386; en-US; rv:1.8.0.2) Gecko/20060421 Firefox/1.5.0.2
  12 # Mozilla/5.0 (Macintosh; U; Intel Mac OS X; en-CA; rv:1.8.0.2) Gecko/20060425 Firefox/1.5.0.2
  13 # Mozilla/5.0 (X11; U; SunOS i86pc; no-NO; rv:1.8.0.2) Gecko/20060420 Firefox/1.5.0.2
  14 # Mozilla/5.0 (X11; U; Linux x86_64; de-AT; rv:1.8.0.2) Gecko/20060422 Firefox/1.5.0.2
  15 # Mozilla/5.0 (X11; U; NetBSD i386; en-US; rv:1.8.0.2) Gecko/20060415 Firefox/1.5.0.2
  16 # Mozilla/5.0 (X11; U; OpenBSD sparc64; pl-PL; rv:1.8.0.2) Gecko/20060429 Firefox/1.5.0.2
  17 # Mozilla/5.0 (X11; U; Linux i686; en-CA; rv:1.8.0.2) Gecko/20060413 Firefox/1.5.0.2
  18 #
  19 # Copyright (c) 2006-2011 Fabian Keil <fk@fabiankeil.de>
  20 #
  21 # Permission to use, copy, modify, and distribute this software for any
  22 # purpose with or without fee is hereby granted, provided that the above
  23 # copyright notice and this permission notice appear in all copies.
  24 #
  25 # THE SOFTWARE IS PROVIDED "AS IS" AND THE AUTHOR DISCLAIMS ALL WARRANTIES
  26 # WITH REGARD TO THIS SOFTWARE INCLUDING ALL IMPLIED WARRANTIES OF
  27 # MERCHANTABILITY AND FITNESS. IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR
  28 # ANY SPECIAL, DIRECT, INDIRECT, OR CONSEQUENTIAL DAMAGES OR ANY DAMAGES
  29 # WHATSOEVER RESULTING FROM LOSS OF USE, DATA OR PROFITS, WHETHER IN AN
  30 # ACTION OF CONTRACT, NEGLIGENCE OR OTHER TORTIOUS ACTION, ARISING OUT OF
  31 # OR IN CONNECTION WITH THE USE OR PERFORMANCE OF THIS SOFTWARE.
  32 ##############################################################################################
  33
  34 use strict;
  35 use warnings;
  36 use Time::Local;
  37 use Getopt::Long;
  38
  39 use constant {
  40
  41    UAGEN_VERSION       => 'uagen 1.2.2',
  42
  43    UAGEN_LOGFILE       => '/var/log/uagen.log',
  44    ACTION_FILE         => '/etc/privoxy/user-agent.action',
  45    MOZILLA_PREFS_FILE  => '',
  46    SILENT              =>  0,
  47    NO_LOGGING          =>  0,
  48    NO_ACTION_FILE      =>  0,
  49    LOOP                =>  0,
  50    SLEEPING_TIME       =>  5,
  51
  52    # As of Firefox 4, the "Gecko token" has been frozen
  53    # https://hacks.mozilla.org/2010/09/final-user-agent-string-for-firefox-4/
  54    RANDOMIZE_RELEASE_DATE => 0,
  55
  56    # These variables belong together. If you only change one of them, the generated
  57    # User-Agent might be invalid. If you're not sure which values make sense,
  58    # are too lazy to check, but want to change them anyway, take the values you
  59    # see in the "Help/About Mozilla Firefox" menu.
  60
  61    BROWSER_VERSION                   => "78.0",
  62    BROWSER_REVISION                  => '78.0',
  63    BROWSER_RELEASE_DATE              => '20100101',
  64 };
  65
  66 use constant LANGUAGES => qw(
  67    en-AU en-GB en-CA en-NZ en-US en-ZW es-ES de-DE de-AT de-CH fr-FR sk-SK nl-NL no-NO pl-PL
  68 );
  69
  70 #######################################################################################
  71
  72 sub generate_creation_time($) {
  73     my $release_date = shift;
  74
  75     my ($rel_year, $rel_mon, $rel_day);
  76     my ($c_day, $c_mon, $c_year);
  77     my $now = time;
  78     my (undef, undef, undef, $mday, $mon, $year, undef, undef, undef) = localtime($now);
  79     $mon  += 1;
  80     $year += 1900;
  81
  82     unless ($release_date =~ m/\d{6}/) {
  83         log_error("Invalid release date format: $release_date. Using "
  84                   . BROWSER_RELEASE_DATE . " instead.");
  85         $release_date = BROWSER_RELEASE_DATE;
  86     }
  87     $rel_year = substr($release_date, 0, 4);
  88     $rel_mon  = substr($release_date, 4, 2);
  89     $rel_day  = substr($release_date, 6, 2);
  90
  91     #1, 2, 3, Check.
  92     die "release year in the future" if ($year < $rel_year);
  93     die "release month in the future"
  94       if (($year == $rel_year) and ($mon < $rel_mon));
  95     die "release day in the future"
  96       if (($year == $rel_year) and ($mon == $rel_mon) and ($mday < $rel_day));
  97
  98     my @c_time = (0, 0, 0, $rel_day, $rel_mon - 1, $rel_year - 1900, 0, 0, 0);
  99     my $c_seconds = timelocal(@c_time);
 100
 101     $c_seconds = $now - (int rand ($now - $c_seconds));
 102     @c_time = localtime($c_seconds);
 103     (undef, undef, undef, $c_day, $c_mon, $c_year, undef, undef, undef) = @c_time;
 104     $c_mon  += 1;
 105     $c_year += 1900;
 106
 107     #3, 2, 1, Test.
 108     die "Compilation year in the future" if ($year < $c_year);
 109     die "Compilation month in the future"
 110       if (($year == $c_year) and ($mon < $c_mon));
 111     die "Compilation day in the future"
 112       if (($year == $c_year) and ($mon == $c_mon) and ($mday < $c_day));
 113
 114     return sprintf("%.2i%.2i%.2i", $c_year, $c_mon, $c_day);
 115 }
 116
 117 sub generate_language_settings() {
 118
 119     our @languages;
 120
 121     my $language_i      = int rand (@languages);
 122     my $accept_language = $languages[$language_i];
 123     $accept_language =~ tr/[A-Z]/[a-z]/;
 124
 125     return ($languages[$language_i], $accept_language);
 126 }
 127
 128 sub generate_platform_and_os() {
 129
 130     my %os_data = (
 131         ElectroBSD => {
 132             karma             => 1,
 133             platform          => 'X11',
 134             architectures     => [ 'i386', 'amd64' ],
 135             order_is_inversed => 0,
 136         },
 137         FreeBSD => {
 138             karma             => 1,
 139             platform          => 'X11',
 140             architectures     => [ 'i386', 'amd64', 'sparc64' ],
 141             order_is_inversed => 0,
 142         },
 143         OpenBSD => {
 144             karma             => 1,
 145             platform          => 'X11',
 146             architectures     => [ 'i386', 'amd64', 'sparc64', 'alpha' ],
 147             order_is_inversed => 0,
 148         },
 149         NetBSD => {
 150             karma             => 1,
 151             platform          => 'X11',
 152             architectures     => [ 'i386', 'amd64', 'sparc64', 'alpha' ],
 153             order_is_inversed => 0,
 154         },
 155         Linux => {
 156             karma             => 1,
 157             platform          => 'X11',
 158             architectures     => [ 'i586', 'i686', 'x86_64' ],
 159             order_is_inversed => 0,
 160         },
 161         SunOS => {
 162             karma             => 1,
 163             platform          => 'X11',
 164             architectures     => [ 'i86pc', 'sun4u' ],
 165             order_is_inversed => 0,
 166         },
 167         'Mac OS X' => {
 168             karma             => 1,
 169             platform          => 'Macintosh',
 170             architectures     => [ 'PPC', 'Intel' ],
 171             order_is_inversed => 1,
 172         },
 173         Windows => {
 174             karma             => 0,
 175             platform          => 'Windows',
 176             architectures     => [ 'NT 5.1' ],
 177             order_is_inversed => 0,
 178         }
 179     );
 180
 181     my @os_names;
 182
 183     foreach my $os_name ( keys %os_data ) {
 184         push @os_names, ($os_name) x $os_data{$os_name}{'karma'}
 185           if $os_data{$os_name}{'karma'};
 186     }
 187
 188     my $os_i   = int rand(@os_names);
 189     my $os     = $os_names[$os_i];
 190     my $arch_i = int rand( @{ $os_data{$os}{'architectures'} } );
 191     my $arch   = $os_data{$os}{'architectures'}[$arch_i];
 192
 193     my $platform = $os_data{$os}{'platform'};
 194
 195     my $os_or_cpu;
 196     $os_or_cpu = sprintf "%s %s",
 197       $os_data{$os}{'order_is_inversed'} ? ( $arch, $os ) : ( $os, $arch );
 198
 199     return $platform, $os_or_cpu;
 200 }
 201
 202 sub generate_firefox_user_agent() {
 203
 204     our $languages;
 205     our $browser_version;
 206     our $browser_revision;
 207     our $browser_release_date;
 208     our $randomize_release_date;
 209
 210     my $mozillaversion  = '5.0';
 211
 212     my $creation_time = $randomize_release_date ?
 213         generate_creation_time($browser_release_date) : $browser_release_date;
 214     my ( $locale,   $accept_language ) = generate_language_settings();
 215     my ( $platform, $os_or_cpu )       = generate_platform_and_os;
 216
 217     my $firefox_user_agent =
 218       sprintf "Mozilla/%s (%s; %s; rv:%s) Gecko/%s Firefox/%s",
 219       $mozillaversion, $platform, $os_or_cpu, $browser_revision,
 220       $creation_time, $browser_version;
 221
 222     return $accept_language, $firefox_user_agent;
 223 }
 224
 225 sub log_to_file($) {
 226
 227     my $message = shift;
 228
 229     our $logfile;
 230     our $no_logging;
 231
 232     my ( $sec, $min, $hour, $mday, $mon, $year, $wday, $yday, $isdst ) =
 233       localtime time;
 234     $year += 1900;
 235     $mon  += 1;
 236     my $logtime = sprintf "%i/%.2i/%.2i %.2i:%.2i", $year, $mon, $mday, $hour,
 237       $min;
 238
 239     return if $no_logging;
 240
 241     open(my $log_fd, ">>", $logfile) || die "Writing " . $logfile . " failed";
 242     printf $log_fd UAGEN_VERSION . " ($logtime) $message\n";
 243     close($log_fd);
 244 }
 245
 246 sub log_error($) {
 247
 248     my $message = shift;
 249
 250     $message = "Error: $message";
 251     log_to_file($message);
 252     print "$message\n";
 253
 254     exit(1);
 255 }
 256
 257 sub write_action_file() {
 258
 259     our $action_file;
 260     our $user_agent;
 261     our $accept_language;
 262     our $no_hide_accept_language;
 263     our $action_injection;
 264
 265     my $action_file_content = '';
 266
 267     if ($action_injection){
 268         open(my $actionfile_fd, "<", $action_file)
 269             or log_error "Reading action file $action_file failed!";
 270         while (<$actionfile_fd>) {
 271             s@(hide-accept-language\{).*?(\})@$1$accept_language$2@;
 272             s@(hide-user-agent\{).*?(\})@$1$user_agent$2@;
 273             $action_file_content .= $_;
 274         }
 275         close($actionfile_fd);
 276     } else {
 277         $action_file_content = "{";
 278         $action_file_content .= sprintf "+hide-accept-language{%s} \\\n",
 279             $accept_language unless $no_hide_accept_language;
 280         $action_file_content .= sprintf " +hide-user-agent{%s} \\\n}\n/\n",
 281             $user_agent;
 282     }
 283     open(my $actionfile_fd, ">", $action_file)
 284       or log_error "Writing action file $action_file failed!";
 285     print $actionfile_fd $action_file_content;
 286     close($actionfile_fd);
 287
 288     return 0;
 289 }
 290
 291 sub write_prefs_file() {
 292
 293     our $mozilla_prefs_file;
 294     our $user_agent;
 295     our $accept_language;
 296     our $clean_prefs;
 297
 298     my $prefs_file_content = '';
 299     my $prefsfile_fd;
 300
 301     if (open($prefsfile_fd, "<", $mozilla_prefs_file)) {
 302
 303         while (<$prefsfile_fd>) {
 304             s@user_pref\(\"general.useragent.override\",.*\);\n?@@;
 305             s@user_pref\(\"intl.accept_languages\",.*\);\n?@@;
 306             $prefs_file_content .= $_;
 307         }
 308         close($prefsfile_fd);
 309     } else {
 310         log_error "Reading prefs file $mozilla_prefs_file failed. Creating a new file!";
 311     }
 312
 313     $prefs_file_content .=
 314         sprintf("user_pref(\"general.useragent.override\", \"%s\");\n", $user_agent) .
 315         sprintf("user_pref(\"intl.accept_languages\", \"%s\");\n", $accept_language)
 316         unless $clean_prefs;
 317
 318     open($prefsfile_fd, ">", $mozilla_prefs_file)
 319       or log_error "Writing prefs file $mozilla_prefs_file failed!";
 320     print $prefsfile_fd $prefs_file_content;
 321     close($prefsfile_fd);
 322
 323 }
 324
 325 sub VersionMessage() {
 326     printf UAGEN_VERSION . "\n" . 'Copyright (C) 2006-2011 Fabian Keil <fk@fabiankeil.de> ' .
 327         "\nhttps://www.fabiankeil.de/sourcecode/uagen/\n";
 328 }
 329
 330 sub help() {
 331
 332     our $logfile;
 333     our $action_file;
 334     our $browser_version;
 335     our $browser_revision;
 336     our $browser_release_date;
 337     our $sleeping_time;
 338     our $loop;
 339     our $mozilla_prefs_file;
 340
 341     my $comma_separated_languages;
 342
 343     $loop = $loop ? ' ' . $loop : '';
 344     $mozilla_prefs_file = $mozilla_prefs_file ? ' ' . $mozilla_prefs_file : '';
 345     foreach (LANGUAGES){
 346         $comma_separated_languages .= $_ . ",";
 347     }
 348     chop $comma_separated_languages;
 349
 350     VersionMessage;
 351
 352     print << "    EOF"
 353
 354 Options and their default values if there are any:
 355     [--action-file $action_file]
 356     [--action-injection]
 357     [--browser-release-date $browser_release_date]
 358     [--browser-revision $browser_revision]
 359     [--browser-version $browser_version]
 360     [--clean-prefs-file]
 361     [--help]
 362     [--language-overwrite $comma_separated_languages]
 363     [--logfile $logfile]
 364     [--loop$loop]
 365     [--no-action-file]
 366     [--no-hide-accept-language]
 367     [--no-logfile]
 368     [--prefs-file$mozilla_prefs_file]
 369     [--randomize-release-date]
 370     [--quiet]
 371     [--silent]
 372     [--sleeping-time $sleeping_time]
 373     [--version]
 374 see "perldoc $0" for more information
 375     EOF
 376     ;
 377     exit(0);
 378 }
 379
 380 sub main() {
 381
 382     my $error_message;
 383     my  $no_action_file          = NO_ACTION_FILE;
 384
 385     our $silent                  = SILENT;
 386     our $no_logging              = NO_LOGGING;
 387     our $logfile                 = UAGEN_LOGFILE;
 388     our $action_file             = ACTION_FILE;
 389     our $randomize_release_date  = RANDOMIZE_RELEASE_DATE;
 390     our $browser_version         = BROWSER_VERSION;
 391     our $browser_revision        = BROWSER_REVISION;
 392     our $browser_release_date    = BROWSER_RELEASE_DATE;
 393     our $sleeping_time           = SLEEPING_TIME;
 394     our $loop                    = LOOP;
 395     our $no_hide_accept_language = 0;
 396     our $action_injection        = 0;
 397
 398     our @languages;
 399     our ( $accept_language, $user_agent );
 400     our $mozilla_prefs_file = MOZILLA_PREFS_FILE;
 401     our $clean_prefs = 0;
 402
 403     GetOptions('logfile=s' => \$logfile,
 404                'action-file=s' => \$action_file,
 405                'language-overwrite=s@' => \@languages,
 406                'silent|quiet' => \$silent,
 407                'no-hide-accept-language' => \$no_hide_accept_language,
 408                'no-logfile' => \$no_logging,
 409                'no-action-file' => \$no_action_file,
 410                'randomize-release-date' => \$randomize_release_date,
 411                'browser-version=s' => \$browser_version,
 412                'browser-revision=s' => \$browser_revision,
 413                'browser-release-date=s' => \$browser_release_date,
 414                'action-injection' => \$action_injection,
 415                'loop' => \$loop,
 416                'sleeping-time' => \$sleeping_time,
 417                'prefs-file=s' => \$mozilla_prefs_file,
 418                'clean-prefs-file' => \$clean_prefs,
 419                'help' => \&help,
 420                'version' => sub {VersionMessage() && exit(0)}
 421     ) or exit(0);
 422
 423     if (@languages) {
 424         @languages = split(/,/,join(',',@languages));
 425     } else {
 426         @languages = LANGUAGES;
 427     }
 428
 429     srand( time ^ ( $$ + ( $$ << 15 ) ) );
 430
 431     do {
 432         $error_message='';
 433         ( $accept_language, $user_agent ) = generate_firefox_user_agent();
 434
 435         print "$user_agent\n" unless $silent;
 436
 437         write_action_file() unless $no_action_file;
 438         write_prefs_file() if $mozilla_prefs_file;
 439
 440         log_to_file "Generated User-Agent: $user_agent";
 441
 442     } while ($loop && sleep($sleeping_time * 60));
 443 }
 444
 445 main();
 446
 447 =head1 NAME
 448
 449 B<uagen> - A Firefox User-Agent generator for Privoxy and Mozilla browsers
 450
 451 =head1 SYNOPSIS
 452
 453 B<uagen> [B<--action-file> I<action_file>] [B<--action-injection>]
 454 [B<--browser-release-date> I<browser_release_date>]
 455 [B<--browser-revision> I<browser_revision>]
 456 [B<--browser-version> I<browser_version>]
 457 [B<--clean-prefs-file>]
 458 [B<--help>] [B<--language-overwrite> I<language(s)>]
 459 [B<--logfile> I<logfile>] [B<--loop>] [B<--no-action-file>] [B<--no-logfile>]
 460 [B<--prefs-file> I<prefs_file>] [B<--randomize-release-date>]
 461 [B<--quiet>] [B<--sleeping-time> I<minutes>] [B<--silent>] [B<--version>]
 462
 463 =head1 DESCRIPTION
 464
 465 B<uagen> generates a fake Firefox User-Agent and writes it into a Privoxy action file
 466 as parameter for Privoxy's B<hide-user-agent> action. Operating system, architecture,
 467 platform, language and, optionally, the build date are randomized.
 468
 469 The generated language is also used as parameter for the
 470 B<hide-accept-language> action which is understood by Privoxy since
 471 version 3.0.5 beta.
 472
 473 Additionally the User-Agent can be written into prefs.js files which are
 474 used by many Mozilla browsers.
 475
 476 =head1 OPTIONS
 477
 478 B<--action-file> I<action_file> Privoxy action file to write the
 479 generated actions into. Default is /etc/privoxy/user-agent.action.
 480
 481 B<--action-injection> Don't generate a new action file from scratch,
 482 but read an old one and just replace the action values. Useful
 483 to keep custom URL patterns. For this to work, the action file
 484 has to be already present. B<uagen> neither checks the syntax
 485 nor cares if all actions are present. Garbage in, garbage out.
 486
 487 B<--browser-release-date> I<browser_release_date> Date to use.
 488 The format is YYYYMMDD. Some sanity checks are done, but you
 489 shouldn't rely on them.
 490
 491 B<--browser-revision> I<browser_revision> Use a custom revision.
 492 B<uagen> will use it without any sanity checks.
 493
 494 B<--browser-version> I<browser_version> Use a custom browser version.
 495 B<uagen> will use it without any sanity checks.
 496
 497 B<--clean-prefs-file> The I<prefs_file> is read and the variables
 498 B<general.useragent.override> and B<intl.accept_languages> are removed.
 499 Only effective if I<prefs_file> is set, and only useful if you want
 500 to use the browser's defaults again.
 501
 502 B<--help> List command line options and exit.
 503
 504 B<--language-overwrite> I<language(s)> Comma separated list of language codes
 505 to overwrite the default values. B<uagen> chooses one of them for the generated
 506 User-Agent, by default the chosen language in lower cases is also used as
 507 B<hide-accept-language> parameter.
 508
 509 B<--logfile> I<logfile> Logfile to save error messages and the generated
 510 User-Agents. Default is /var/log/uagen.log.
 511
 512 B<--loop> Don't exit after the generation of the action file. Sleep for
 513 a while and generate a new one instead. Useful if you don't have cron(8).
 514
 515 B<--no-logfile> Don't log anything.
 516
 517 B<--no-action-file> Don't write the action file.
 518
 519 B<--no-hide-accept-language> Stay compatible with Privoxy 3.0.3
 520 and don't generate the B<hide-accept-language> action line. You should
 521 really update your Privoxy version instead.
 522
 523 B<--prefs-file> I<prefs_file> Use the generated User-Agent to set the
 524 B<general.useragent.override> variable in the Mozilla preference file
 525 I<prefs_file>, The B<intl.accept_languages> variable will be set as well.
 526
 527 Firefox's preference file is usually located in
 528 ~/.mozilla/firefox/*.default/prefs.js. Note that Firefox doesn't reread
 529 the file once it is running.
 530
 531 B<--randomize-release-date> Randomly pick a date between the configured
 532 release date and the actual date. Note that Firefox versions after 4.0
 533 no longer provide the build date in the User-Agent header, so if you
 534 randomize the date anyway, it will be obvious that the generated User-Agent
 535 is fake.
 536
 537 B<--quiet> Don't print the generated User-Agent to the console.
 538
 539 B<--sleeping-time> I<minutes> Time to sleep. Only effective if used with B<--loop>.
 540
 541 B<--silent> Don't print the generated User-Agent to the console.
 542
 543 B<--version> Print version and exit.
 544
 545 The second dash is optional, options can be shortened, as long as there are
 546 no ambiguities.
 547
 548 =head1 PRIVOXY CONFIGURATION
 549
 550 In Privoxy's configuration file the line:
 551
 552     actionsfile user-agent.action
 553
 554 should be added after:
 555
 556     actionfile default.action
 557
 558 and before:
 559
 560     actionfile user.action
 561
 562 This way the user can still use custom User-Agents
 563 in I<user.action>. I<user-agent> has to be the name
 564 of the generated action file.
 565
 566 If you are using Privoxy 3.0.6 or earlier, don't add the ".action" extension.
 567
 568 =head1 EXAMPLES
 569
 570 Without any options, B<uagen> creates an action file like:
 571
 572  {+hide-accept-language{en-ca} \
 573   +hide-user-agent{Mozilla/5.0 (X11; U; OpenBSD i386; en-CA; rv:1.8.0.4) Gecko/20060628 Firefox/1.5.0.4} \
 574  }
 575  /
 576
 577 with the --no-accept-language option the generated file
 578 could look like this one:
 579
 580  {+hide-user-agent{Mozilla/5.0 (X11; U; FreeBSD i386; de-DE; rv:1.8.0.4) Gecko/20060720 Firefox/1.5.0.4} \
 581  }
 582  /
 583
 584 =head1 CAVEATS
 585
 586 If the browser opens an encrypted connection, Privoxy can't inspect
 587 the content and the browser's headers reach the server unmodified.
 588 It is the user's job to use Privoxy's limit-connect action to make sure
 589 there are no encrypted connections to untrusted sites.
 590
 591 Mozilla users can alter the browser's User-Agent with the
 592 B<--prefs-file> option. But note that the preference file is only read
 593 on startup. If the browser is already running, B<uagen's> changes will be ignored.
 594
 595 Hiding the User-Agent is pointless if the browser accepts all
 596 cookies or even is configured for remote maintenance through Flash,
 597 JavaScript, Java or similar security problems.
 598
 599 =head1 BUGS
 600
 601 Some parameters can't be specified at the command line.
 602
 603 =head1 SEE ALSO
 604
 605 privoxy(1)
 606
 607 =head1 AUTHOR
 608
 609 Fabian Keil <fk@fabiankeil.de>
 610
 611 https://www.fabiankeil.de/sourcecode/uagen/
 612
 613 https://www.fabiankeil.de/blog-surrogat/2006/01/26/firefox-user-agent-generator.html (German)
 614
 615 =cut
 616