tools/privoxy-regression-test.pl

   1 #!/usr/bin/perl
   2
   3 ############################################################################
   4 #
   5 # Privoxy-Regression-Test
   6 #
   7 # A regression test "framework" for Privoxy. For documentation see:
   8 # perldoc privoxy-regression-test.pl
   9 #
  10 # $Id: privoxy-regression-test.pl,v 1.114 2008/03/18 16:52:09 fk Exp $
  11 #
  12 # Wish list:
  13 #
  14 # - Update documentation
  15 # - Validate HTTP times.
  16 # - Understand default.action.master comment syntax
  17 #   and verify that we actually block and unblock what
  18 #   the comments claim we do.
  19 # - Implement a HTTP_VERSION directive or allow to
  20 #   specify whole request lines.
  21 # - Support filter regression tests.
  22 # - Add option to fork regression tests and run them in parallel,
  23 #   possibly optional forever.
  24 # - Document magic Expect Header values
  25 # - Internal fuzz support?
  26 #
  27 # Copyright (c) 2007-2008 Fabian Keil <fk@fabiankeil.de>
  28 #
  29 # Permission to use, copy, modify, and distribute this software for any
  30 # purpose with or without fee is hereby granted, provided that the above
  31 # copyright notice and this permission notice appear in all copies.
  32 #
  33 # THE SOFTWARE IS PROVIDED "AS IS" AND THE AUTHOR DISCLAIMS ALL WARRANTIES
  34 # WITH REGARD TO THIS SOFTWARE INCLUDING ALL IMPLIED WARRANTIES OF
  35 # MERCHANTABILITY AND FITNESS. IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR
  36 # ANY SPECIAL, DIRECT, INDIRECT, OR CONSEQUENTIAL DAMAGES OR ANY DAMAGES
  37 # WHATSOEVER RESULTING FROM LOSS OF USE, DATA OR PROFITS, WHETHER IN AN
  38 # ACTION OF CONTRACT, NEGLIGENCE OR OTHER TORTIOUS ACTION, ARISING OUT OF
  39 # OR IN CONNECTION WITH THE USE OR PERFORMANCE OF THIS SOFTWARE.
  40 #
  41 ############################################################################
  42
  43 use warnings;
  44 use strict;
  45 use Getopt::Long;
  46
  47 use constant {
  48                PRT_VERSION => 'Privoxy-Regression-Test 0.2',
  49
  50                CURL => 'curl',
  51
  52                # CLI option defaults
  53                CLI_RETRIES  => 1,
  54                CLI_LOOPS    => 1,
  55                CLI_MAX_TIME => 5,
  56                CLI_MIN_LEVEL => 0,
  57                CLI_MAX_LEVEL => 25,
  58
  59                PRIVOXY_CGI_URL => 'http://p.p/',
  60                FELLATIO_URL    => 'http://10.0.0.1:8080/',
  61                LEADING_LOG_DATE => 1,
  62                LEADING_LOG_TIME => 1,
  63
  64                DEBUG_LEVEL_FILE_LOADING    => 0,
  65                DEBUG_LEVEL_PAGE_FETCHING   => 0,
  66
  67                VERBOSE_TEST_DESCRIPTION    => 1,
  68
  69                DEBUG_LEVEL_VERBOSE_FAILURE => 1,
  70                # XXX: Only partly implemented and mostly useless.
  71                DEBUG_LEVEL_VERBOSE_SUCCESS => 0,
  72                DEBUG_LEVEL_STATUS          => 1,
  73
  74                # Internal use, don't modify
  75                # Available debug bits:
  76                LL_ERROR                   =>  1,
  77                LL_VERBOSE_FAILURE         =>  2,
  78                LL_PAGE_FETCHING           =>  4,
  79                LL_FILE_LOADING            =>  8,
  80                LL_VERBOSE_SUCCESS         => 16,
  81                LL_STATUS                  => 32,
  82                LL_SOFT_ERROR              => 64,
  83
  84                CLIENT_HEADER_TEST         =>  1,
  85                SERVER_HEADER_TEST         =>  2,
  86                DUMB_FETCH_TEST            =>  3,
  87                METHOD_TEST                =>  4,
  88                TRUSTED_CGI_REQUEST        =>  6,
  89                BLOCK_TEST                 =>  7,
  90 };
  91
  92 sub init_our_variables () {
  93
  94     our $leading_log_time = LEADING_LOG_TIME;
  95     our $leading_log_date = LEADING_LOG_DATE;
  96
  97     our $privoxy_cgi_url  = PRIVOXY_CGI_URL;
  98
  99     our $verbose_test_description = VERBOSE_TEST_DESCRIPTION;
 100
 101     our $log_level = get_default_log_level();
 102
 103 }
 104
 105 sub get_default_log_level () {
 106
 107     my $log_level = 0;
 108
 109     $log_level |= LL_FILE_LOADING    if DEBUG_LEVEL_FILE_LOADING;
 110     $log_level |= LL_PAGE_FETCHING   if DEBUG_LEVEL_PAGE_FETCHING;
 111     $log_level |= LL_VERBOSE_FAILURE if DEBUG_LEVEL_VERBOSE_FAILURE;
 112     $log_level |= LL_VERBOSE_SUCCESS if DEBUG_LEVEL_VERBOSE_SUCCESS;
 113     $log_level |= LL_STATUS          if DEBUG_LEVEL_STATUS;
 114
 115     # These are intended to be always on.
 116     $log_level |= LL_SOFT_ERROR;
 117     $log_level |= LL_ERROR;
 118
 119     return $log_level;
 120 }
 121
 122 ############################################################################
 123 #
 124 # File loading functions
 125 #
 126 ############################################################################
 127
 128 sub parse_tag ($) {
 129
 130     my $tag = shift;
 131
 132     # Remove anchors
 133     $tag =~ s@[\$\^]@@g;
 134     # Unescape brackets and dots
 135     $tag =~ s@\\(?=[{}().+])@@g;
 136
 137     # log_message("Parsed tag: " . $tag);
 138
 139     check_for_forbidden_characters($tag);
 140
 141     return $tag;
 142 }
 143
 144 sub check_for_forbidden_characters ($) {
 145
 146     my $tag = shift; # XXX: also used to check values though.
 147     my $allowed = '[-=\dA-Za-z{}:.\/();\s,+@"_%\?&]';
 148
 149     unless ($tag =~ m/^$allowed*$/) {
 150         my $forbidden = $tag;
 151         $forbidden =~ s@^$allowed*(.).*@$1@;
 152
 153         l(LL_ERROR, "'" . $tag . "' contains character '" . $forbidden. "' which is unacceptable.");
 154     }
 155 }
 156
 157 sub load_regressions_tests () {
 158
 159     our $privoxy_cgi_url;
 160     our @privoxy_config;
 161     my @actionfiles;
 162     my $curl_url = '';
 163     my $file_number = 0;
 164
 165     $curl_url .= $privoxy_cgi_url;
 166     $curl_url .= 'show-status';
 167
 168     l(LL_STATUS, "Asking Privoxy for the number of action files available ...");
 169
 170     foreach (@{get_cgi_page_or_else($curl_url)}) {
 171
 172         chomp;
 173         if (/<td>(.*?)<\/td><td class=\"buttons\"><a href=\"\/show-status\?file=actions&amp;index=(\d+)\">/) {
 174
 175             my $url = $privoxy_cgi_url . 'show-status?file=actions&index=' . $2;
 176             $actionfiles[$file_number++] = $url;
 177
 178         } elsif (m@config\.html#.*\">([^<]*)</a>\s+(.*)<br>@) {
 179
 180             my $directive = $1 . " " . $2;
 181             push (@privoxy_config, $directive);
 182         }
 183     }
 184
 185     l(LL_FILE_LOADING, "Recognized " . @actionfiles . " actions files");
 186
 187     load_action_files(\@actionfiles);
 188 }
 189
 190 sub token_starts_new_test ($) {
 191
 192     my $token = shift;
 193     my @new_test_directives =
 194         ('set header', 'fetch test', 'trusted cgi request', 'request header', 'method test', 'block test');
 195
 196     foreach my $new_test_directive (@new_test_directives) {
 197         return 1 if $new_test_directive eq $token;
 198     }
 199     return 0;
 200
 201 }
 202
 203 sub tokenize ($) {
 204
 205     my ($token, $value) = (undef, undef);
 206
 207     # Remove leading and trailing white space.
 208     s@^\s*@@;
 209     s@\s*$@@;
 210
 211     # Reverse HTML-encoding
 212     # XXX: Seriously imcomplete.
 213     s@&quot;@"@g;
 214
 215     # Tokenize
 216     if (/^\#\s*([^=]*?)\s*[=]\s*(.*?)\s*$/) {
 217
 218         $token = $1;
 219         $token =~ tr/[A-Z]/[a-z]/;
 220         $value = $2;
 221
 222     } elsif (/^TAG\s*:(.*)$/) {
 223
 224         $token = 'tag';
 225         $value = $1;
 226
 227     }
 228
 229     return ($token, $value);
 230 }
 231
 232 sub enlist_new_test ($$$$$$) {
 233
 234     my ($regression_tests, $token, $value, $si, $ri, $number) = @_;
 235
 236     if ($token eq 'set header') {
 237
 238         l(LL_FILE_LOADING, "Header to set: " . $value);
 239         ${$regression_tests}[$si][$ri]{'type'} = CLIENT_HEADER_TEST;
 240         # Implicit default
 241         $$regression_tests[$si][$ri]{'level'} = CLIENT_HEADER_TEST;
 242
 243     } elsif ($token eq 'request header') {
 244
 245         l(LL_FILE_LOADING, "Header to request: " . $value);
 246         $$regression_tests[$si][$ri]{'type'} = SERVER_HEADER_TEST;
 247         # Implicit default
 248         $$regression_tests[$si][$ri]{'expected-status-code'} = 200;
 249         $$regression_tests[$si][$ri]{'level'} = SERVER_HEADER_TEST;
 250
 251     } elsif ($token eq 'trusted cgi request') {
 252
 253         l(LL_FILE_LOADING, "CGI URL to test in a dumb way: " . $value);
 254         $$regression_tests[$si][$ri]{'type'} = TRUSTED_CGI_REQUEST;
 255         # Implicit default
 256         $$regression_tests[$si][$ri]{'expected-status-code'} = 200;
 257         $$regression_tests[$si][$ri]{'level'} = TRUSTED_CGI_REQUEST;
 258
 259     } elsif ($token eq 'fetch test') {
 260
 261         l(LL_FILE_LOADING, "URL to test in a dumb way: " . $value);
 262         $$regression_tests[$si][$ri]{'type'} = DUMB_FETCH_TEST;
 263         # Implicit default
 264         $$regression_tests[$si][$ri]{'expected-status-code'} = 200;
 265         $$regression_tests[$si][$ri]{'level'} = DUMB_FETCH_TEST;
 266
 267     } elsif ($token eq 'method test') {
 268
 269         l(LL_FILE_LOADING, "Method to test: " . $value);
 270         $$regression_tests[$si][$ri]{'type'} = METHOD_TEST;
 271         # Implicit default
 272         $$regression_tests[$si][$ri]{'expected-status-code'} = 200;
 273         $$regression_tests[$si][$ri]{'level'} = METHOD_TEST;
 274
 275     } elsif ($token eq 'block test') {
 276
 277         l(LL_FILE_LOADING, "URL to block-test: " . $value);
 278         $$regression_tests[$si][$ri]{'type'} = BLOCK_TEST;
 279         # Implicit default
 280         $$regression_tests[$si][$ri]{'expected-status-code'} = 403;
 281         $$regression_tests[$si][$ri]{'level'} = BLOCK_TEST;
 282
 283     } else {
 284
 285         die "Incomplete '" . $token . "' support detected.";
 286
 287     }
 288
 289     check_for_forbidden_characters($value);
 290
 291     $$regression_tests[$si][$ri]{'data'} = $value;
 292
 293     # For function that only get passed single tests
 294     $$regression_tests[$si][$ri]{'section-id'} = $si;
 295     $$regression_tests[$si][$ri]{'regression-test-id'} = $ri;
 296     $$regression_tests[$si][$ri]{'number'} = $number - 1;
 297     l(LL_FILE_LOADING,
 298       "Regression test " . $number . " (section:" . $si . "):");
 299 }
 300
 301 sub load_action_files ($) {
 302
 303     # initialized here
 304     our %actions;
 305     our @regression_tests;
 306
 307     my $actionfiles_ref = shift;
 308     my @actionfiles = @{$actionfiles_ref};
 309
 310     my $si = 0;  # Section index
 311     my $ri = -1; # Regression test index
 312     my $count = 0;
 313
 314     my $ignored = 0;
 315
 316     l(LL_STATUS, "Loading regression tests from action file(s) delivered by Privoxy.");
 317
 318     for my $file_number (0 .. @actionfiles - 1) {
 319
 320         my $curl_url = ' "' . $actionfiles[$file_number] . '"';
 321         my $actionfile = undef;
 322
 323         foreach (@{get_cgi_page_or_else($curl_url)}) {
 324
 325             my $no_checks = 0;
 326             chomp;
 327
 328             if (/<h2>Contents of Actions File (.*?)</) {
 329                 $actionfile = $1;
 330                 next;
 331             }
 332             next unless defined $actionfile;
 333
 334             last if (/<\/pre>/);
 335
 336             my ($token, $value) = tokenize($_);
 337
 338             next unless defined $token;
 339
 340             # Load regression tests
 341
 342             if (token_starts_new_test($token)) {
 343
 344                 # Beginning of new regression test.
 345                 $ri++;
 346                 $count++;
 347                 enlist_new_test(\@regression_tests, $token, $value, $si, $ri, $count);
 348             }
 349
 350             if ($token =~ /level\s+(\d+)/i) {
 351
 352                 my $level = $1;
 353                 register_dependency($level, $value);
 354             }
 355
 356             if ($si == -1 || $ri == -1) {
 357                 # No beginning of a test detected yet,
 358                 # so we don't care about any other test
 359                 # attributes.
 360                 next;
 361             }
 362
 363             if ($token eq 'expect header') {
 364
 365                 l(LL_FILE_LOADING, "Detected expectation: " . $value);
 366                 $regression_tests[$si][$ri]{'expect-header'} = $value;
 367
 368             } elsif ($token eq 'tag') {
 369
 370                 next if ($ri == -1);
 371
 372                 my $tag = parse_tag($value);
 373
 374                 # We already checked in parse_tag() after filtering
 375                 $no_checks = 1;
 376
 377                 l(LL_FILE_LOADING, "Detected TAG: " . $tag);
 378
 379                 # Save tag for all tests in this section
 380                 do {
 381                     $regression_tests[$si][$ri]{'tag'} = $tag;
 382                 } while ($ri-- > 0);
 383
 384                 $si++;
 385                 $ri = -1;
 386
 387             } elsif ($token eq 'ignore' && $value =~ /Yes/i) {
 388
 389                 l(LL_FILE_LOADING, "Ignoring section: " . test_content_as_string($regression_tests[$si][$ri]));
 390                 $regression_tests[$si][$ri]{'ignore'} = 1;
 391                 $ignored++;
 392
 393             } elsif ($token eq 'expect status code') {
 394
 395                 l(LL_FILE_LOADING, "Expecting status code: " . $value);
 396                 $regression_tests[$si][$ri]{'expected-status-code'} = $value;
 397
 398             } elsif ($token eq 'level') { # XXX: stupid name
 399
 400                 $value =~ s@(\d+).*@$1@;
 401                 l(LL_FILE_LOADING, "Level: " . $value);
 402                 $regression_tests[$si][$ri]{'level'} = $value;
 403
 404             } elsif ($token eq 'method') {
 405
 406                 l(LL_FILE_LOADING, "Method: " . $value);
 407                 $regression_tests[$si][$ri]{'method'} = $value;
 408
 409             } else {
 410
 411                 # We don't use it, so we don't need
 412                 $no_checks = 1;
 413             }
 414             # XXX: Neccessary?
 415             check_for_forbidden_characters($value) unless $no_checks;
 416             check_for_forbidden_characters($token);
 417         }
 418     }
 419
 420     l(LL_FILE_LOADING, "Done loading " . $count . " regression tests."
 421       . " Of which " . $ignored. " will be ignored)\n");
 422 }
 423
 424 ############################################################################
 425 #
 426 # Regression test executing functions
 427 #
 428 ############################################################################
 429
 430 sub execute_regression_tests () {
 431
 432     our @regression_tests;
 433     my $loops = get_cli_option('loops');
 434     my $all_tests    = 0;
 435     my $all_failures = 0;
 436     my $all_successes = 0;
 437
 438     unless (@regression_tests) {
 439
 440         l(LL_STATUS, "No regression tests found.");
 441         return;
 442     }
 443
 444     l(LL_STATUS, "Executing regression tests ...");
 445
 446     while ($loops-- > 0) {
 447
 448         my $successes = 0;
 449         my $tests = 0;
 450         my $failures;
 451         my $skipped = 0;
 452
 453         for my $s (0 .. @regression_tests - 1) {
 454
 455             my $r = 0;
 456
 457             while (defined $regression_tests[$s][$r]) {
 458
 459                 die "Section id mismatch" if ($s != $regression_tests[$s][$r]{'section-id'});
 460                 die "Regression test id mismatch" if ($r != $regression_tests[$s][$r]{'regression-test-id'});
 461
 462                 my $number = $regression_tests[$s][$r]{'number'};
 463
 464                 if ($regression_tests[$s][$r]{'ignore'}
 465                     or level_is_unacceptable($regression_tests[$s][$r]{'level'})
 466                     or test_number_is_unacceptable($number)) {
 467
 468                     $skipped++;
 469
 470                 } else {
 471
 472                     my $result = execute_regression_test($regression_tests[$s][$r]);
 473
 474                     log_result($regression_tests[$s][$r], $result, $tests);
 475
 476                     $successes += $result;
 477                     $tests++;
 478                 }
 479                 $r++;
 480             }
 481         }
 482         $failures = $tests - $successes;
 483
 484         log_message("Executed " . $tests . " regression tests. " .
 485             'Skipped ' . $skipped . '. ' .
 486             $successes . " successes, " . $failures . " failures.");
 487
 488         $all_tests    += $tests;
 489         $all_failures += $failures;
 490         $all_successes += $successes;
 491
 492     }
 493
 494     if (get_cli_option('loops') > 1) {
 495         log_message("Total: Executed " . $all_tests . " regression tests. " .
 496             $all_successes . " successes, " . $all_failures . " failures.");
 497     }
 498 }
 499
 500 sub level_is_unacceptable ($) {
 501     my $level = shift;
 502     return ((cli_option_is_set('level') and get_cli_option('level') != $level)
 503             or ($level < get_cli_option('min-level'))
 504             or ($level > get_cli_option('max-level'))
 505             or dependency_unsatisfied($level)
 506             );
 507 }
 508
 509 sub test_number_is_unacceptable ($) {
 510     my $test_number = shift;
 511     return (cli_option_is_set('test-number')
 512             and get_cli_option('test-number') != $test_number)
 513 }
 514
 515 sub dependency_unsatisfied ($) {
 516
 517     my $level = shift;
 518     our %dependencies;
 519     our @privoxy_config;
 520     my $dependency_problem = 0;
 521
 522     if (defined ($dependencies{$level}{'config line'})) {
 523
 524         my $dependency = $dependencies{$level}{'config line'};
 525         $dependency_problem = 1;
 526
 527         foreach (@privoxy_config) {
 528
 529              $dependency_problem = 0 if (/$dependency/);
 530         }
 531     }
 532
 533     return $dependency_problem;
 534 }
 535
 536 sub register_dependency ($$) {
 537
 538     my $level = shift;
 539     my $dependency = shift;
 540     our %dependencies;
 541
 542     if ($dependency =~ /config line\s+(.*)/) {
 543
 544        $dependencies{$level}{'config line'} = $1;
 545     }
 546 }
 547
 548 # XXX: somewhat misleading name
 549 sub execute_regression_test ($) {
 550
 551     my $test_ref = shift;
 552     my %test = %{$test_ref};
 553     my $result = 0;
 554
 555     if ($test{'type'} == CLIENT_HEADER_TEST) {
 556
 557         $result = execute_client_header_regression_test($test_ref);
 558
 559     } elsif ($test{'type'} == SERVER_HEADER_TEST) {
 560
 561         $result = execute_server_header_regression_test($test_ref);
 562
 563     } elsif ($test{'type'} == DUMB_FETCH_TEST
 564           or $test{'type'} == TRUSTED_CGI_REQUEST) {
 565
 566         $result = execute_dumb_fetch_test($test_ref);
 567
 568     } elsif ($test{'type'} == METHOD_TEST) {
 569
 570         $result = execute_method_test($test_ref);
 571
 572     } elsif ($test{'type'} == BLOCK_TEST) {
 573
 574         $result = execute_block_test($test_ref);
 575
 576     } else {
 577
 578         die "Unsupported test type detected: " . $test{'type'};
 579
 580     }
 581
 582     return $result;
 583 }
 584
 585 sub execute_method_test ($) {
 586
 587     my $test_ref = shift;
 588     my %test = %{$test_ref};
 589     my $buffer_ref;
 590     my $result = 0;
 591     my $status_code;
 592     my $method = $test{'data'};
 593
 594     my $curl_parameters = '';
 595     my $expected_status_code = $test{'expected-status-code'};
 596
 597     $curl_parameters .= '--request ' . $method . ' ';
 598     # Don't complain in case about the 'missing' body
 599     $curl_parameters .= '--head ' if ($method =~ /^HEAD$/i);
 600
 601     $curl_parameters .= PRIVOXY_CGI_URL;
 602
 603     $buffer_ref = get_page_with_curl($curl_parameters);
 604     $status_code = get_status_code($buffer_ref);
 605
 606     $result = check_status_code_result($status_code, $expected_status_code);
 607
 608     return $result;
 609 }
 610
 611 sub execute_dumb_fetch_test ($) {
 612
 613     my $test_ref = shift;
 614     my %test = %{$test_ref};
 615     my $buffer_ref;
 616     my $result = 0;
 617     my $status_code;
 618
 619     my $curl_parameters = '';
 620     my $expected_status_code = $test{'expected-status-code'};
 621
 622     if (defined $test{method}) {
 623         $curl_parameters .= '--request ' . $test{method} . ' ';
 624     }
 625     if ($test{type} == TRUSTED_CGI_REQUEST) {
 626         $curl_parameters .= '--referer ' . PRIVOXY_CGI_URL . ' ';
 627     }
 628
 629     $curl_parameters .= $test{'data'};
 630
 631     $buffer_ref = get_page_with_curl($curl_parameters);
 632     $status_code = get_status_code($buffer_ref);
 633
 634     $result = check_status_code_result($status_code, $expected_status_code);
 635
 636     return $result;
 637 }
 638
 639 sub execute_block_test ($) {
 640
 641     my $test = shift;
 642     my $url = $test->{'data'};
 643     my $final_results = get_final_results($url);
 644
 645     return defined $final_results->{'+block'};
 646 }
 647
 648 sub get_final_results ($) {
 649
 650     my $url = shift;
 651     my $curl_parameters = '';
 652     my %final_results = ();
 653     my $final_results_reached = 0;
 654
 655     $curl_parameters .= PRIVOXY_CGI_URL . 'show-url-info?url=' . $url;
 656
 657     foreach (@{get_cgi_page_or_else($curl_parameters)}) {
 658
 659         $final_results_reached = 1 if (m@<h2>Final results:</h2>@);
 660
 661         next unless ($final_results_reached);
 662         last if (m@</td>@);
 663
 664         if (m@<br>([-+])<a.*>([^>]*)</a>( \{.*\})@) {
 665             my $action = $1.$2;
 666             my $value = $3;
 667             $final_results{$action}{$value};
 668         }
 669     }
 670
 671     return \%final_results;
 672 }
 673
 674 sub check_status_code_result ($$) {
 675
 676     my $status_code = shift;
 677     my $expected_status_code = shift;
 678     my $result = 0;
 679
 680     if ($expected_status_code == $status_code) {
 681
 682         $result = 1;
 683         l(LL_VERBOSE_SUCCESS,
 684           "Yay. We expected status code " . $expected_status_code . ", and received: " . $status_code . '.');
 685
 686     } elsif (cli_option_is_set('fuzzer-feeding') and $status_code == 123) {
 687
 688         l(LL_VERBOSE_FAILURE,
 689           "Oh well. Status code lost while fuzzing. Can't check if it was " . $expected_status_code . '.');
 690
 691     } else {
 692
 693         l(LL_VERBOSE_FAILURE,
 694           "Ooops. We expected status code " . $expected_status_code . ", but received: " . $status_code . '.');
 695
 696     }
 697
 698     return $result;
 699 }
 700
 701 sub execute_client_header_regression_test ($) {
 702
 703     my $test_ref = shift;
 704     my $buffer_ref;
 705     my $header;
 706     my $result = 0;
 707
 708     $buffer_ref = get_show_request_with_curl($test_ref);
 709
 710     $header = get_header($buffer_ref, $test_ref);
 711     $result = check_header_result($test_ref, $header);
 712
 713     return $result;
 714 }
 715
 716 sub execute_server_header_regression_test ($) {
 717
 718     my $test_ref = shift;
 719     my $buffer_ref;
 720     my $header;
 721     my $result = 0;
 722
 723     $buffer_ref = get_head_with_curl($test_ref);
 724
 725     $header = get_server_header($buffer_ref, $test_ref);
 726     $result = check_header_result($test_ref, $header);
 727
 728     return $result;
 729 }
 730
 731
 732 sub interpret_result ($) {
 733     my $success = shift;
 734     return $success ? "Success" : "Failure";
 735 }
 736
 737 sub check_header_result ($$) {
 738
 739     my $test_ref = shift;
 740     my $header = shift;
 741
 742     my %test = %{$test_ref};
 743     my $expect_header = $test{'expect-header'};
 744     my $success = 0;
 745
 746     $header =~ s@   @ @g if defined($header);
 747
 748     if ($expect_header eq 'NO CHANGE') {
 749
 750         if (defined($header) and $header eq $test{'data'}) {
 751
 752             $success = 1;
 753
 754         } else {
 755
 756             $header //= "REMOVAL";
 757             l(LL_VERBOSE_FAILURE,
 758               "Ooops. Got: " . $header . " while expecting: " . $expect_header);
 759         }
 760
 761     } elsif ($expect_header eq 'REMOVAL') {
 762
 763         if (defined($header) and $header eq $test{'data'}) {
 764
 765             l(LL_VERBOSE_FAILURE,
 766               "Ooops. Expected removal but: " . $header . " is still there.");
 767
 768         } else {
 769
 770             # XXX: Use more reliable check here and make sure
 771             # the header has a different name.
 772             $success = 1;
 773
 774         }
 775
 776     } elsif ($expect_header eq 'SOME CHANGE') {
 777
 778         if (defined($header) and not $header eq $test{'data'}) {
 779
 780             $success = 1;
 781
 782         } else {
 783
 784             $header //= "REMOVAL";
 785             l(LL_VERBOSE_FAILURE,
 786               "Ooops. Got: " . $header . " while expecting: SOME CHANGE");
 787         }
 788
 789
 790     } else {
 791
 792         if (defined($header) and $header eq $expect_header) {
 793
 794             $success = 1;
 795
 796         } else {
 797
 798             $header //= "'No matching header'"; # XXX: No header detected to be precise
 799             l(LL_VERBOSE_FAILURE,
 800               "Ooops. Got: " . $header . " while expecting: " . $expect_header);
 801         }
 802     }
 803     return $success;
 804 }
 805
 806 sub get_header_name ($) {
 807
 808     my $header = shift;
 809
 810     $header =~ s@(.*?: ).*@$1@;
 811
 812     return $header;
 813 }
 814
 815 sub get_header ($$) {
 816
 817     our $filtered_request = '';
 818
 819     my $buffer_ref = shift;
 820     my $test_ref = shift;
 821
 822     my %test = %{$test_ref};
 823     my @buffer = @{$buffer_ref};
 824
 825     my $expect_header = $test{'expect-header'};
 826
 827     my $line;
 828     my $processed_request_reached = 0;
 829     my $read_header = 0;
 830     my $processed_request = '';
 831     my $header;
 832     my $header_to_get;
 833
 834     if ($expect_header eq 'REMOVAL'
 835      or $expect_header eq 'NO CHANGE'
 836      or  $expect_header eq 'SOME CHANGE') {
 837
 838         $expect_header = $test{'data'};
 839
 840     }
 841
 842     $header_to_get = get_header_name($expect_header);
 843
 844     foreach (@buffer) {
 845
 846         # Skip everything before the Processed request
 847         if (/Processed Request/) {
 848             $processed_request_reached = 1;
 849             next;
 850         }
 851         next unless $processed_request_reached;
 852
 853         # End loop after the Processed request
 854         last if (/<\/pre>/);
 855
 856         # Ditch tags and leading/trailing white space.
 857         s@^\s*<.*?>@@g;
 858         s@\s*$@@g;
 859
 860         $filtered_request .=  "\n" . $_;
 861
 862         if (/^$header_to_get/) {
 863             $read_header = 1;
 864             $header = $_;
 865             last;
 866         }
 867     }
 868
 869     return $header;
 870 }
 871
 872 sub get_server_header ($$) {
 873
 874     my $buffer_ref = shift;
 875     my $test_ref = shift;
 876
 877     my %test = %{$test_ref};
 878     my @buffer = @{$buffer_ref};
 879
 880     my $expect_header = $test{'expect-header'};
 881     my $header;
 882     my $header_to_get;
 883
 884     if ($expect_header eq 'REMOVAL'
 885      or $expect_header eq 'NO CHANGE'
 886      or $expect_header eq 'SOME CHANGE') {
 887
 888         $expect_header = $test{'data'};
 889
 890     }
 891
 892     $header_to_get = get_header_name($expect_header);
 893
 894     foreach (@buffer) {
 895
 896         # XXX: should probably verify that the request
 897         # was actually answered by Fellatio.
 898         if (/^$header_to_get/) {
 899             $header = $_;
 900             $header =~ s@\s*$@@g;
 901             last;
 902         }
 903     }
 904
 905     return $header;
 906 }
 907
 908 sub get_status_code ($) {
 909
 910     my $buffer_ref = shift;
 911     my @buffer = @{$buffer_ref};
 912
 913     foreach (@buffer) {
 914
 915         if (/^HTTP\/\d\.\d (\d{3})/) {
 916
 917             return $1;
 918
 919         } else {
 920
 921             return '123' if cli_option_is_set('fuzzer-feeding');
 922             chomp;
 923             l(LL_ERROR, 'Unexpected buffer line: "' . $_ . '"');
 924         }
 925     }
 926 }
 927
 928 sub get_test_keys () {
 929     return ('tag', 'data', 'expect-header', 'ignore');
 930 }
 931
 932 # XXX: incomplete
 933 sub test_content_as_string ($) {
 934
 935     my $test_ref = shift;
 936     my %test = %{$test_ref};
 937
 938     my $s = "\n\t";
 939
 940     foreach my $key (get_test_keys()) {
 941         $test{$key} = 'Not set' unless (defined $test{$key});
 942     }
 943
 944     $s .= 'Tag: ' . $test{'tag'};
 945     $s .= "\n\t";
 946     $s .= 'Set header: ' . $test{'data'}; # XXX: adjust for other test types
 947     $s .= "\n\t";
 948     $s .= 'Expected header: ' . $test{'expect-header'};
 949     $s .= "\n\t";
 950     $s .= 'Ignore: ' . $test{'ignore'};
 951
 952     return $s;
 953 }
 954
 955 ############################################################################
 956 #
 957 # HTTP fetch functions
 958 #
 959 ############################################################################
 960
 961 sub check_for_curl () {
 962     my $curl = CURL;
 963     l(LL_ERROR, "No curl found.") unless (`which $curl`);
 964 }
 965
 966 sub get_cgi_page_or_else ($) {
 967
 968     my $cgi_url = shift;
 969     my $content_ref = get_page_with_curl($cgi_url);
 970     my $status_code = get_status_code($content_ref);
 971
 972     if (200 != $status_code) {
 973
 974         my $log_message = "Failed to fetch Privoxy CGI Page. " .
 975                           "Received status code ". $status_code .
 976                           " while only 200 is acceptable.";
 977
 978         if (cli_option_is_set('fuzzer-feeding')) {
 979
 980             $log_message .= " Ignored due to fuzzer feeding.";
 981             l(LL_SOFT_ERROR, $log_message)
 982
 983         } else {
 984
 985             l(LL_ERROR, $log_message);
 986
 987         }
 988     }
 989
 990     return $content_ref;
 991 }
 992
 993 sub get_show_request_with_curl ($) {
 994
 995     our $privoxy_cgi_url;
 996     my $test_ref = shift;
 997     my %test = %{$test_ref};
 998
 999     my $curl_parameters = ' ';
1000
1001     # Enable the action to test
1002     $curl_parameters .= '-H \'X-Privoxy-Control: ' . $test{'tag'} . '\' ';
1003     # The header to filter
1004     $curl_parameters .= '-H \'' . $test{'data'} . '\' ';
1005
1006     $curl_parameters .= ' ';
1007     $curl_parameters .= $privoxy_cgi_url;
1008     $curl_parameters .= 'show-request';
1009
1010     return get_cgi_page_or_else($curl_parameters);
1011 }
1012
1013
1014 sub get_head_with_curl ($) {
1015
1016     our $fellatio_url = FELLATIO_URL;
1017     my $test_ref = shift;
1018     my %test = %{$test_ref};
1019
1020     my $curl_parameters = ' ';
1021
1022     # Enable the action to test
1023     $curl_parameters .= '-H \'X-Privoxy-Control: ' . $test{'tag'} . '\' ';
1024     # The header to filter
1025     $curl_parameters .= '-H \'X-Gimme-Head-With: ' . $test{'data'} . '\' ';
1026     $curl_parameters .= '--head ';
1027
1028     $curl_parameters .= ' ';
1029     $curl_parameters .= $fellatio_url;
1030
1031     return get_page_with_curl($curl_parameters);
1032 }
1033
1034
1035 sub get_page_with_curl ($) {
1036
1037     my $parameters = shift;
1038     my @buffer;
1039     my $curl_line = CURL;
1040     my $retries_left = get_cli_option('retries') + 1;
1041     my $failure_reason;
1042
1043     if (cli_option_is_set('privoxy-address')) {
1044         $curl_line .= ' --proxy ' . get_cli_option('privoxy-address');
1045     }
1046
1047     # We want to see the HTTP status code
1048     $curl_line .= " --include ";
1049     # Let Privoxy emit two log messages less.
1050     $curl_line .= ' -H \'Proxy-Connection:\' ' unless $parameters =~ /Proxy-Connection:/;
1051     $curl_line .= ' -H \'Connection: close\' ' unless $parameters =~ /Connection:/;
1052     # We don't care about fetch statistic.
1053     $curl_line .= " -s ";
1054     # We do care about the failure reason if any.
1055     $curl_line .= " -S ";
1056     # We want to advertise ourselves
1057     $curl_line .= " --user-agent '" . PRT_VERSION . "' ";
1058     # We aren't too patient
1059     $curl_line .= " --max-time '" . get_cli_option('max-time') . "' ";
1060
1061     $curl_line .= $parameters;
1062     # XXX: still necessary?
1063     $curl_line .= ' 2>&1';
1064
1065     l(LL_PAGE_FETCHING, "Executing: " . $curl_line);
1066
1067     do {
1068         @buffer = `$curl_line`;
1069
1070         if ($?) {
1071             $failure_reason = array_as_string(\@buffer);
1072             chomp $failure_reason;
1073             l(LL_SOFT_ERROR, "Fetch failure: '" . $failure_reason . $! ."'");
1074         }
1075     } while ($? && --$retries_left);
1076
1077     unless ($retries_left) {
1078         l(LL_ERROR,
1079           "Running curl failed " . get_cli_option('retries') .
1080           " times in a row. Last error: '" . $failure_reason . "'.");
1081     }
1082
1083     return \@buffer;
1084 }
1085
1086
1087 ############################################################################
1088 #
1089 # Log functions
1090 #
1091 ############################################################################
1092
1093 sub array_as_string ($) {
1094     my $array_ref = shift;
1095     my $string = '';
1096
1097     foreach (@{$array_ref}) {
1098         $string .= $_;
1099     }
1100
1101     return $string;
1102 }
1103
1104
1105 sub show_test ($) {
1106     my $test_ref = shift;
1107     log_message('Test is:' . test_content_as_string($test_ref));
1108 }
1109
1110 # Conditional log
1111 sub l ($$) {
1112     our $log_level;
1113     my $this_level = shift;
1114     my $message = shift;
1115
1116     return unless ($log_level & $this_level);
1117
1118     if (LL_ERROR & $this_level) {
1119         $message = 'Oh noes. ' . $message . ' Fatal error. Exiting.';
1120     }
1121
1122     log_message($message);
1123
1124     if (LL_ERROR & $this_level) {
1125         exit;
1126     }
1127 }
1128
1129 sub log_message ($) {
1130
1131     my $message = shift;
1132
1133     our $logfile;
1134     our $no_logging;
1135     our $leading_log_date;
1136     our $leading_log_time;
1137
1138     my $time_stamp = '';
1139     my ( $sec, $min, $hour, $mday, $mon, $year, $wday, $yday, $isdst ) = localtime time;
1140
1141     if ($leading_log_date || $leading_log_time) {
1142
1143         if ($leading_log_date) {
1144             $year += 1900;
1145             $mon  += 1;
1146             $time_stamp = sprintf("%i/%.2i/%.2i", $year, $mon, $mday);
1147         }
1148
1149         if ($leading_log_time) {
1150             $time_stamp .= ' ' if $leading_log_date;
1151             $time_stamp.= sprintf("%.2i:%.2i:%.2i", $hour, $min, $sec);
1152         }
1153
1154         $message = $time_stamp . ": " . $message;
1155     }
1156
1157
1158     printf(STDERR "%s\n", $message);
1159
1160 }
1161
1162 sub log_result ($$) {
1163
1164     our $verbose_test_description;
1165     our $filtered_request;
1166
1167     my $test_ref = shift;
1168     my $result = shift;
1169     my $number = shift;
1170
1171     my %test = %{$test_ref};
1172     my $message = '';
1173
1174     $message .= interpret_result($result);
1175     $message .= " for test ";
1176     $message .= $number;
1177     $message .= '/';
1178     $message .= $test{'number'};
1179     $message .= '/';
1180     $message .= $test{'section-id'};
1181     $message .= '/';
1182     $message .= $test{'regression-test-id'};
1183     $message .= '.';
1184
1185     if ($verbose_test_description) {
1186
1187         if ($test{'type'} == CLIENT_HEADER_TEST) {
1188
1189             $message .= ' Header ';
1190             $message .= quote($test{'data'});
1191             $message .= ' and tag ';
1192             $message .= quote($test{'tag'});
1193
1194         } elsif ($test{'type'} == SERVER_HEADER_TEST) {
1195
1196             $message .= ' Request Header ';
1197             $message .= quote($test{'data'});
1198             $message .= ' and tag ';
1199             $message .= quote($test{'tag'});
1200
1201         } elsif ($test{'type'} == DUMB_FETCH_TEST) {
1202
1203             $message .= ' URL ';
1204             $message .= quote($test{'data'});
1205             $message .= ' and expected status code ';
1206             $message .= quote($test{'expected-status-code'});
1207
1208         } elsif ($test{'type'} == TRUSTED_CGI_REQUEST) {
1209
1210             $message .= ' CGI URL ';
1211             $message .= quote($test{'data'});
1212             $message .= ' and expected status code ';
1213             $message .= quote($test{'expected-status-code'});
1214
1215         } elsif ($test{'type'} == METHOD_TEST) {
1216
1217             $message .= ' HTTP method ';
1218             $message .= quote($test{'data'});
1219             $message .= ' and expected status code ';
1220             $message .= quote($test{'expected-status-code'});
1221
1222         } elsif ($test{'type'} == BLOCK_TEST) {
1223
1224             $message .= ' Supposedly-blocked URL: ';
1225             $message .= quote($test{'data'});
1226
1227         } else {
1228
1229             die "Incomplete support for test type " . $test{'type'} .  " detected.";
1230
1231         }
1232     }
1233
1234     log_message($message) unless ($result && cli_option_is_set('silent'));
1235 }
1236
1237 sub quote ($) {
1238     my $s = shift;
1239     return '\'' . $s . '\'';
1240 }
1241
1242 sub print_version () {
1243     printf PRT_VERSION . "\n" . 'Copyright (C) 2007-2008 Fabian Keil <fk@fabiankeil.de>' . "\n";
1244 }
1245
1246 sub help () {
1247
1248     our %cli_options;
1249
1250     print_version();
1251
1252     print << "    EOF"
1253
1254 Options and their default values if they have any:
1255     [--debug $cli_options{'debug'}]
1256     [--fuzzer-feeding]
1257     [--help]
1258     [--level]
1259     [--loops $cli_options{'loops'}]
1260     [--max-level $cli_options{'max-level'}]
1261     [--max-time $cli_options{'max-time'}]
1262     [--min-level $cli_options{'min-level'}]
1263     [--privoxy-address]
1264     [--retries $cli_options{'retries'}]
1265     [--silent]
1266     [--version]
1267 see "perldoc $0" for more information
1268     EOF
1269     ;
1270     exit(0);
1271 }
1272
1273 sub init_cli_options () {
1274
1275     our %cli_options;
1276     our $log_level;
1277
1278     $cli_options{'min-level'} = CLI_MIN_LEVEL;
1279     $cli_options{'max-level'} = CLI_MAX_LEVEL;
1280     $cli_options{'debug'}  = $log_level;
1281     $cli_options{'loops'}  = CLI_LOOPS;
1282     $cli_options{'max-time'}  = CLI_MAX_TIME;
1283     $cli_options{'retries'}  = CLI_RETRIES;
1284 }
1285
1286 sub parse_cli_options () {
1287
1288     our %cli_options;
1289     our $log_level;
1290
1291     init_cli_options();
1292
1293     GetOptions (
1294                 'debug=s' => \$cli_options{'debug'},
1295                 'help'     => sub { help },
1296                 'silent' => \$cli_options{'silent'},
1297                 'min-level=s' => \$cli_options{'min-level'},
1298                 'max-level=s' => \$cli_options{'max-level'},
1299                 'privoxy-address=s' => \$cli_options{'privoxy-address'},
1300                 'level=s' => \$cli_options{'level'},
1301                 'loops=s' => \$cli_options{'loops'},
1302                 'test-number=s' => \$cli_options{'test-number'},
1303                 'fuzzer-feeding' => \$cli_options{'fuzzer-feeding'},
1304                 'retries=s' => \$cli_options{'retries'},
1305                 'max-time=s' => \$cli_options{'max-time'},
1306                 'version'  => sub { print_version && exit(0) }
1307     );
1308     $log_level |= $cli_options{'debug'};
1309 }
1310
1311 sub cli_option_is_set ($) {
1312
1313     our %cli_options;
1314     my $cli_option = shift;
1315
1316     return defined $cli_options{$cli_option};
1317 }
1318
1319 sub get_cli_option ($) {
1320
1321     our %cli_options;
1322     my $cli_option = shift;
1323
1324     die "Unknown CLI option: $cli_option" unless defined $cli_options{$cli_option};
1325
1326     return $cli_options{$cli_option};
1327 }
1328
1329 sub main () {
1330
1331     init_our_variables();
1332     parse_cli_options();
1333     check_for_curl();
1334     load_regressions_tests();
1335     execute_regression_tests();
1336 }
1337
1338 main();
1339
1340 =head1 NAME
1341
1342 B<privoxy-regression-test> - A regression test "framework" for Privoxy.
1343
1344 =head1 SYNOPSIS
1345
1346 B<privoxy-regression-test> [B<--debug bitmask>] [B<--fuzzer-feeding>] [B<--help>]
1347 [B<--level level>] [B<--loops count>] [B<--max-level max-level>]
1348 [B<--max-time max-time>] [B<--min-level min-level>] B<--privoxy-address proxy-address>
1349 [B<--retries retries>] [B<--silent>] [B<--version>]
1350
1351 =head1 DESCRIPTION
1352
1353 Privoxy-Regression-Test is supposed to one day become
1354 a regression test suite for Privoxy. It's not quite there
1355 yet, however, and can currently only test client header
1356 actions and check the returned status code for requests
1357 to arbitrary URLs.
1358
1359 Client header actions are tested by requesting
1360 B<http://config.privoxy.org/show-request> and checking whether
1361 or not Privoxy modified the original request as expected.
1362
1363 The original request contains both the header the action-to-be-tested
1364 acts upon and an additional tagger-triggering header that enables
1365 the action to test.
1366
1367 =head1 CONFIGURATION FILE SYNTAX
1368
1369 Privoxy-Regression-Test's configuration is embedded in
1370 Privoxy action files and loaded through Privoxy's web interface.
1371
1372 It makes testing a Privoxy version running on a remote system easier
1373 and should prevent you from updating your tests without updating Privoxy's
1374 configuration accordingly.
1375
1376 A client-header-action test section looks like this:
1377
1378     # Set Header    = Referer: http://www.example.org.zwiebelsuppe.exit/
1379     # Expect Header = Referer: http://www.example.org/
1380     {+client-header-filter{hide-tor-exit-notation} -hide-referer}
1381     TAG:^client-header-filter\{hide-tor-exit-notation\}$
1382
1383 The example above causes Privoxy-Regression-Test to set
1384 the header B<Referer: http://www.example.org.zwiebelsuppe.exit/>
1385 and to expect it to be modified to
1386 B<Referer: http://www.example.org/>.
1387
1388 When testing this section, Privoxy-Regression-Test will set the header
1389 B<X-Privoxy-Control: client-header-filter{hide-tor-exit-notation}>
1390 causing the B<privoxy-control> tagger to create the tag
1391 B<client-header-filter{hide-tor-exit-notation}> which will finally
1392 cause Privoxy to enable the action section.
1393
1394 Note that the actions itself are only used by Privoxy,
1395 Privoxy-Regression-Test ignores them and will be happy
1396 as long as the expectations are satisfied.
1397
1398 A fetch test looks like this:
1399
1400     # Fetch Test = http://p.p/user-manual
1401     # Expect Status Code = 302
1402
1403 It tells Privoxy-Regression-Test to request B<http://p.p/user-manual>
1404 and to expect a response with the HTTP status code B<302>. Obviously that's
1405 not a very thorough test and mainly useful to get some code coverage
1406 for Valgrind or to verify that the templates are installed correctly.
1407
1408 If you want to test CGI pages that require a trusted
1409 referer, you can use:
1410
1411     # Trusted CGI Request =  http://p.p/edit-actions
1412
1413 It works like ordinary fetch tests, but sets the referer
1414 header to a trusted value.
1415
1416 If no explicit status code expectation is set, B<200> is used.
1417
1418 Additionally all tests have test levels to let the user
1419 control which ones to execute (see I<OPTIONS> below).
1420 Test levels are either set with the B<Level> directive,
1421 or implicitly through the test type.
1422
1423 Fetch tests default to level 6, tests for trusted
1424 CGI requests to level 3 and client-header-action tests
1425 to level 1.
1426
1427 =head1 OPTIONS
1428
1429 B<--debug bitmask> Add the bitmask provided as integer
1430 to the debug settings.
1431
1432 B<--fuzzer-feeding> Ignore some errors that would otherwise
1433 cause Privoxy-Regression-Test to abort the test because
1434 they shouldn't happen in normal operation. This option is
1435 intended to be used if Privoxy-Regression-Test is only
1436 used to feed a fuzzer in which case there's a high chance
1437 that Privoxy gets an invalid request and returns an error
1438 message.
1439
1440 B<--help> Shows available command line options.
1441
1442 B<--level level> Only execute tests with the specified B<level>.
1443
1444 B<--loop count> Loop through the regression tests B<count> times.
1445 Useful to feed a fuzzer, or when doing stress tests with
1446 several Privoxy-Regression-Test instances running at the same
1447 time.
1448
1449 B<--max-level max-level> Only execute tests with a B<level>
1450 below or equal to the numerical B<max-level>.
1451
1452 B<--max-time max-time> Give Privoxy B<max-time> seconds
1453 to return data. Increasing the default may make sense when
1454 Privoxy is run through Valgrind, decreasing the default may
1455 make sense when Privoxy-Regression-Test is used to feed
1456 a fuzzer.
1457
1458 B<--min-level min-level> Only execute tests with a B<level>
1459 above or equal to the numerical B<min-level>.
1460
1461 B<--privoxy-address proxy-address> Privoxy's listening address.
1462 If it's not set, the value of the environment variable http_proxy
1463 will be used. B<proxy-address> has to be specified in http_proxy
1464 syntax.
1465
1466 B<--retries retries> Retry B<retries> times.
1467
1468 B<--silent> Don't log succesful test runs.
1469
1470 B<--version> Print version and exit.
1471
1472 The second dash is optional, options can be shortened,
1473 as long as there are no ambiguities.
1474
1475 =head1 PRIVOXY CONFIGURATION
1476
1477 Privoxy-Regression-Test is shipped with B<regression-tests.action>
1478 which aims to test all official client-header modifying actions
1479 and can be used to verify that the templates and the user manual
1480 files are installed correctly.
1481
1482 To use it, it has to be copied in Privoxy's configuration
1483 directory, and afterwards referenced in Privoxy's configuration
1484 file with the line:
1485
1486     actionsfile regression-tests.action
1487
1488 In general, its tests are supposed to work without changing
1489 any other action files, unless you already added lots of
1490 taggers yourself. If you are using taggers that cause problems,
1491 you might have to temporary disable them for Privoxy's CGI pages.
1492
1493 Some of the regression tests rely on Privoxy features that
1494 may be disabled in your configuration. Tests with a level below
1495 7 are supposed to work with all Privoxy configurations (provided
1496 you didn't build with FEATURE_GRACEFUL_TERMINATION).
1497
1498 Tests with level 9 require Privoxy to deliver the User Manual,
1499 tests with level 12 require the CGI editor to be enabled.
1500
1501 =head1 CAVEATS
1502
1503 Expect the configuration file syntax to change with future releases.
1504
1505 =head1 LIMITATIONS
1506
1507 As Privoxy's B<show-request> page only shows client headers,
1508 Privoxy-Regression-Test can't use it to test Privoxy actions
1509 that modify server headers.
1510
1511 As Privoxy-Regression-Test relies on Privoxy's tag feature to
1512 control the actions to test, it currently only works with
1513 Privoxy 3.0.7 or later.
1514
1515 At the moment Privoxy-Regression-Test fetches Privoxy's
1516 configuration page through I<curl>(1), therefore you have to
1517 have I<curl> installed, otherwise you won't be able to run
1518 Privoxy-Regression-Test in a meaningful way.
1519
1520 =head1 SEE ALSO
1521
1522 privoxy(1) curl(1)
1523
1524 =head1 AUTHOR
1525
1526 Fabian Keil <fk@fabiankeil.de>
1527
1528 =cut