tools/privoxy-log-parser.pl

   1 #!/usr/bin/perl
   2
   3 ################################################################################
   4 # privoxy-log-parser
   5 #
   6 # A parser for Privoxy log messages. For incomplete documentation run
   7 # perldoc privoxy-log-parser(.pl), for fancy screenshots see:
   8 #
   9 # http://www.fabiankeil.de/sourcecode/privoxy-log-parser/
  10 #
  11 # $Id: privoxy-log-parser.pl,v 1.75 2010/01/11 11:47:59 fabiankeil Exp $
  12 #
  13 # TODO:
  14 #       - LOG_LEVEL_CGI, LOG_LEVEL_ERROR, LOG_LEVEL_WRITE content highlighting
  15 #       - create fancy statistics
  16 #       - grep through Privoxy sources to find unsupported log messages
  17 #       - hunt down substitutions that match content from variables which
  18 #         can contain stuff like ()?'[]
  19 #       - replace $h{'foo'} with h('foo') where possible
  20 #       - hunt down XXX comments instead of just creating them
  21 #       - add example log lines for every regex and mark them up for
  22 #         regression testing
  23 #       - Handle incomplete input without Perl warning about undefined variables.
  24 #       - Use generic highlighting function that takes a regex and the
  25 #         hash key as input.
  26 #
  27 # Copyright (c) 2007-2009 Fabian Keil <fk@fabiankeil.de>
  28 #
  29 # Permission to use, copy, modify, and distribute this software for any
  30 # purpose with or without fee is hereby granted, provided that the above
  31 # copyright notice and this permission notice appear in all copies.
  32 #
  33 # THE SOFTWARE IS PROVIDED "AS IS" AND THE AUTHOR DISCLAIMS ALL WARRANTIES
  34 # WITH REGARD TO THIS SOFTWARE INCLUDING ALL IMPLIED WARRANTIES OF
  35 # MERCHANTABILITY AND FITNESS. IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR
  36 # ANY SPECIAL, DIRECT, INDIRECT, OR CONSEQUENTIAL DAMAGES OR ANY DAMAGES
  37 # WHATSOEVER RESULTING FROM LOSS OF USE, DATA OR PROFITS, WHETHER IN AN
  38 # ACTION OF CONTRACT, NEGLIGENCE OR OTHER TORTIOUS ACTION, ARISING OUT OF
  39 # OR IN CONNECTION WITH THE USE OR PERFORMANCE OF THIS SOFTWARE.
  40 ################################################################################
  41
  42 use strict;
  43 use warnings;
  44 use Getopt::Long;
  45
  46 use constant {
  47     PRIVOXY_LOG_PARSER_VERSION => '0.6',
  48     # Feel free to mess with these ...
  49     DEFAULT_BACKGROUND => 'black',  # Choose registered colour (like 'black')
  50     DEFAULT_TEXT_COLOUR => 'white', # Choose registered colour (like 'black')
  51     HEADER_DEFAULT_COLOUR => 'yellow',
  52     REGISTER_HEADERS_WITH_THE_SAME_COLOUR => 1,
  53
  54     CLI_OPTION_DEFAULT_TO_HTML_OUTPUT => 0,
  55     CLI_OPTION_TITLE => 'Privoxy-Log-Parser in da house',
  56     CLI_OPTION_NO_EMBEDDED_CSS => 0,
  57     CLI_OPTION_NO_MSECS => 0,
  58     CLI_OPTION_NO_SYNTAX_HIGHLIGHTING => 0,
  59     CLI_OPTION_SHOW_INEFFECTIVE_FILTERS => 0,
  60     CLI_OPTION_ACCEPT_UNKNOWN_MESSAGES => 0,
  61     CLI_OPTION_STATISTICS => 0,
  62
  63     SUPPRESS_SUCCEEDED_FILTER_ADDITIONS => 1,
  64     SHOW_SCAN_INTRO => 0,
  65     SHOW_FILTER_READIN_IN => 0,
  66     SUPPRESS_EMPTY_LINES => 1,
  67     SUPPRESS_SUCCESSFUL_CONNECTIONS => 1,
  68     SUPPRESS_ACCEPTED_CONNECTIONS => 1,
  69     SUPPRESS_GIF_NOT_CHANGED => 1,
  70     SUPPRESS_NEED_TO_DE_CHUNK_FIRST => 1,
  71
  72     DEBUG_HEADER_REGISTERING => 0,
  73     DEBUG_HEADER_HIGHLIGHTING => 0,
  74     DEBUG_TICKS => 0,
  75     DEBUG_PAINT_IT => 0,
  76     DEBUG_SUPPRESS_LOG_MESSAGES => 0,
  77
  78     PUNISH_MISSING_LOG_KNOWLEDGE_WITH_DEATH => 0,
  79     PUNISH_MISSING_HIGHLIGHT_KNOWLEDGE_WITH_DEATH => 1,
  80
  81     LOG_UNPARSED_LINES_TO_EXTRA_FILE => 0,
  82     ERROR_LOG_FILE => '/var/log/privoxy-log-parser',
  83
  84     # You better leave these alone unless you know what you're doing.
  85     COLOUR_RESET      => "\033[0;0m",
  86     ESCAPE => "\033[",
  87 };
  88
  89 # For performance reasons, these are global.
  90
  91 my $t;
  92 my %req; # request data from previous lines
  93 my %h;
  94 my %thread_colours;
  95 my @all_colours;
  96 my @time_colours;
  97 my $thread_colour_index = 0;
  98 my $header_colour_index = 0;
  99 my $time_colour_index = 0;
 100 my %header_colours;
 101 my $no_special_header_highlighting;
 102 my %reason_colours;
 103 my %h_colours;
 104 my $header_highlight_regex = '';
 105
 106 my $html_output_mode;
 107 my $no_msecs_mode; # XXX: should probably be removed
 108 my $line_end;
 109
 110 sub prepare_our_stuff () {
 111
 112     # Syntax Higlight hash
 113     @all_colours = (
 114         'red', 'green', 'brown', 'blue', 'purple', 'cyan',
 115         'light_gray', 'light_red', 'light_green', 'yellow',
 116         'light_blue', 'pink', 'light_cyan', 'white'
 117     );
 118
 119     %h = (
 120         # LOG_LEVEL
 121         Info            => 'blue',
 122         Header          => 'green',
 123         Filter          => 'purple', # XXX: Used?
 124         'Re-Filter'     => 'purple',
 125         Connect         => 'brown',
 126         Request         => 'light_cyan',
 127         CGI             => 'light_green',
 128         Redirect        => 'cyan',
 129         Error           => 'light_red',
 130         Crunch          => 'cyan',
 131         'Fatal error'   => 'light_red',
 132         'Gif-Deanimate' => 'blue',
 133         Force           => 'red',
 134         Writing         => 'light_green',
 135         # ----------------------
 136         URL                  => 'yellow',
 137         path                 => 'brown',
 138         request_             => 'brown', # host+path but no protocol
 139         'ip-address'         => 'yellow',
 140         Number               => 'yellow',
 141         Standard             => 'reset',
 142         Truncation           => 'light_red',
 143         Status               => 'brown',
 144         Timestamp            => 'brown',
 145         Crunching            => 'light_red',
 146         crunched             => 'light_red',
 147         'Request-Line'       => 'pink',
 148         method               => 'purple',
 149         destination          => 'yellow',
 150         'http-version'       => 'pink',
 151         'crunch-pattern'     => 'pink',
 152         not                  => 'brown',
 153         file                 => 'brown',
 154         signal               => 'yellow',
 155         version              => 'green',
 156         'program-name'       => 'cyan',
 157         port                 => 'red',
 158         host                 => 'red',
 159         warning              => 'light_red',
 160         debug                => 'light_red',
 161         filter               => 'green',
 162         tag                  => 'green',
 163         tagger               => 'green',
 164         'status-message'     => 'light_cyan',
 165         'status-code'        => 'yellow',
 166         'invalid-request'    => 'light_red',
 167         'hits'               => 'yellow',
 168         error                => 'light_red',
 169         'rewritten-URL'      => 'light_red',
 170         'pcrs-delimiter'     => 'light_red',
 171         'ignored'            => 'light_red',
 172         'action-bits-update' => 'light_red',
 173         'configuration-line' => 'red',
 174         'content-type'       => 'yellow',
 175     );
 176
 177     %h_colours = %h;
 178
 179     # Header colours need their own hash so the keys can be accessed properly
 180     %header_colours = (
 181         # Prefilled with headers that should not appear with default header colours
 182         Cookie => 'light_red',
 183         'Set-Cookie' => 'light_red',
 184         Warning => 'light_red',
 185         Default => HEADER_DEFAULT_COLOUR,
 186     );
 187
 188     # Crunch reasons need their own hash as well
 189     %reason_colours = (
 190         'Unsupported HTTP feature'               => 'light_red',
 191         Blocked                                  => 'light_red',
 192         Untrusted                                => 'light_red',
 193         Redirected                               => 'green',
 194         'CGI Call'                               => 'white',
 195         'DNS failure'                            => 'red',
 196         'Forwarding failed'                      => 'light_red',
 197         'Connection failure'                     => 'light_red',
 198         'Out of memory (may mask other reasons)' => 'light_red',
 199         'No reason recorded'                     => 'light_red',
 200     );
 201
 202     @time_colours = ('white', 'light_gray');
 203
 204     # Translate highlight strings into highlight code
 205     prepare_highlight_hash(\%header_colours);
 206     prepare_highlight_hash(\%reason_colours);
 207     prepare_highlight_hash(\%h);
 208     prepare_colour_array(\@all_colours);
 209     prepare_colour_array(\@time_colours);
 210     init_css_colours();
 211
 212     init_stats();
 213 }
 214
 215 sub paint_it ($) {
 216 ###############################################################
 217 # Takes a colour string and returns an ANSI escape sequence
 218 # (unless --no-syntax-highlighting is used).
 219 # XXX: The Rolling Stones reference has to go.
 220 ###############################################################
 221
 222     my $colour = shift @_;
 223
 224     return "" if cli_option_is_set('no-syntax-highlighting');
 225
 226     my %light = (
 227         black       => 0,
 228         red         => 0,
 229         green       => 0,
 230         brown       => 0,
 231         blue        => 0,
 232         purple      => 0,
 233         cyan        => 0,
 234         light_gray  => 0,
 235         gray        => 0,
 236         dark_gray   => 1,
 237         light_red   => 1,
 238         light_green => 1,
 239         yellow      => 1,
 240         light_blue  => 1,
 241         pink        => 1,
 242         light_cyan  => 1,
 243         white       => 1,
 244     );
 245
 246     my %text = (
 247         black       => 30,
 248         red         => 31,
 249         green       => 32,
 250         brown       => 33,
 251         blue        => 34,
 252         purple      => 35,
 253         cyan        => 36,
 254         gray        => 37,
 255         light_gray  => 37,
 256         dark_gray   => 30,
 257         light_red   => 31,
 258         light_green => 32,
 259         yellow      => 33,
 260         light_blue  => 34,
 261         pink        => 35,
 262         light_cyan  => 36,
 263         white       => 37,
 264     );
 265
 266     my $bg_code = get_background();
 267     my $colour_code;
 268     our $default = default_colours();
 269
 270     if (defined($text{$colour})) {
 271         $colour_code  = ESCAPE;
 272         $colour_code .= $text{$colour};
 273         $colour_code .= ";";
 274         $colour_code .= $light{$colour} ? "1" : "2";
 275         $colour_code .= ";";
 276         $colour_code .= $bg_code;
 277         $colour_code .= "m";
 278         debug_message $colour . " is \'" . $colour_code . $colour . $default . "\'" if DEBUG_PAINT_IT;
 279
 280     } elsif ($colour =~ /reset/) {
 281
 282         $colour_code = default_colours();
 283
 284     } else {
 285
 286         die "What's $colour supposed to mean?\n";
 287     }
 288
 289     return $colour_code;
 290 }
 291
 292 sub get_semantic_html_markup ($) {
 293 ###############################################################
 294 # Takes a string and returns a span element
 295 ###############################################################
 296
 297     my $type = shift @_;
 298     my $code;
 299
 300     if ($type =~ /Standard/) {
 301         $code = '</span>';
 302     } else {
 303         $type = lc($type);
 304         $code = '<span title="' . $type . '" class="' . $type . '">';
 305     }
 306
 307     return $code;
 308 }
 309
 310 sub cli_option_is_set ($) {
 311
 312     our %cli_options;
 313     my $cli_option = shift;
 314
 315     die "Unknown CLI option: $cli_option" unless defined $cli_options{$cli_option};
 316
 317     return $cli_options{$cli_option};
 318 }
 319
 320 sub get_html_title () {
 321
 322     our %cli_options;
 323     return $cli_options{'title'};
 324
 325 }
 326
 327 sub init_css_colours() {
 328
 329     our %css_colours = (
 330         black       => "000",
 331         red         => "F00",
 332         green       => "0F0",
 333         brown       => "C90",
 334         blue        => "0F0",
 335         purple      => "F06", # XXX: wrong
 336         cyan        => "F09", # XXX: wrong
 337         light_gray  => "999",
 338         gray        => "333",
 339         dark_gray   => "222",
 340         light_red   => "F33",
 341         light_green => "33F",
 342         yellow      => "FF0",
 343         light_blue  => "30F",
 344         pink        => "F0F",
 345         light_cyan  => "66F",
 346         white       => "FFF",
 347     );
 348 }
 349
 350 sub get_css_colour ($) {
 351
 352    our %css_colours;
 353    my $colour = shift;
 354
 355    die "What's $colour supposed to mean?\n" unless defined($css_colours{$colour});
 356
 357    return '#' . $css_colours{$colour};
 358 }
 359
 360 sub get_css_line ($) {
 361
 362     my $class = shift;
 363     my $css_line;
 364
 365     $css_line .= '.' . lc($class) . ' {'; # XXX: lc() shouldn't be necessary
 366     die "What's $class supposed to mean?\n" unless defined($h_colours{$class});
 367     $css_line .= 'color:' . get_css_colour($h_colours{$class}) . ';';
 368     $css_line .= 'background-color:' . get_css_colour(DEFAULT_BACKGROUND) . ';';
 369     $css_line .= '}' . "\n";
 370
 371     return $css_line;
 372 }
 373
 374 sub get_css_line_for_colour ($) {
 375
 376     my $colour = shift;
 377     my $css_line;
 378
 379     $css_line .= '.' . lc($colour) . ' {'; # XXX: lc() shouldn't be necessary
 380     $css_line .= 'color:' . get_css_colour($colour) . ';';
 381     $css_line .= 'background-color:' . get_css_colour(DEFAULT_BACKGROUND) . ';';
 382     $css_line .= '}' . "\n";
 383
 384     return $css_line;
 385 }
 386
 387 # XXX: Wrong solution
 388 sub get_missing_css_lines () {
 389
 390     my $css_line;
 391
 392     $css_line .= '.' . 'default' . ' {';
 393     $css_line .= 'color:' . HEADER_DEFAULT_COLOUR . ';';
 394     $css_line .= 'background-color:' . get_css_colour(DEFAULT_BACKGROUND) . ';';
 395     $css_line .= '}' . "\n";
 396
 397     return $css_line;
 398 }
 399
 400 sub get_css () {
 401
 402     our %css_colours; #XXX: Wrong solution
 403
 404     my $css = '';
 405
 406     $css .= '.privoxy-log {';
 407     $css .= 'color:' . get_css_colour(DEFAULT_TEXT_COLOUR) . ';';
 408     $css .= 'background-color:' . get_css_colour(DEFAULT_BACKGROUND) . ';';
 409     $css .= '}' . "\n";
 410
 411     foreach my $key (keys %h_colours) {
 412
 413         next if ($h_colours{$key} =~ m/reset/); #XXX: Wrong solution.
 414         $css .= get_css_line($key);
 415
 416     }
 417
 418     foreach my $colour (keys %css_colours) {
 419
 420         $css .= get_css_line_for_colour($colour);
 421
 422     }
 423
 424     $css .= get_missing_css_lines(); #XXX: Wrong solution
 425
 426     return $css;
 427 }
 428
 429 sub print_intro () {
 430
 431     my $intro = '';
 432
 433     if (cli_option_is_set('html-output')) {
 434
 435         my $title = get_html_title();
 436
 437         $intro .= '<html><head>';
 438         $intro .= '<title>' . $title . '</title>';
 439         $intro .= '<style>' . get_css() . '</style>' unless cli_option_is_set('no-embedded-css');
 440         $intro .= '</head><body>';
 441         $intro .= '<h1>' . $title . '</h1><p class="privoxy-log">';
 442
 443         print $intro;
 444     }
 445 }
 446
 447 sub print_outro () {
 448
 449     my $outro = '';
 450
 451     if (cli_option_is_set('html-output')) {
 452
 453         $outro = '</p></body></html>';
 454         print $outro;
 455
 456     }
 457 }
 458
 459 sub get_line_end () {
 460     return cli_option_is_set('html-output') ? "<br>\n" : "\n";
 461 }
 462
 463 sub get_colour_html_markup ($) {
 464 ###############################################################
 465 # Takes a colour string a span element. XXX: WHAT?
 466 # XXX: This function shouldn't be necessary, the
 467 # markup should always be semantically correct.
 468 ###############################################################
 469
 470     my $type = shift @_;
 471     my $code;
 472
 473     if ($type =~ /Standard/) {
 474         $code = '</span>';
 475     } else {
 476         $code = '<span class="' . lc($type) . '">';
 477     }
 478
 479     return $code;
 480 }
 481
 482 sub default_colours () {
 483     # XXX: Properly
 484     our $bg_code;
 485     return reset_colours();
 486 }
 487
 488 sub show_colours () {
 489     # XXX: Implement
 490 }
 491
 492 sub reset_colours () {
 493     return ESCAPE . "0m";
 494 }
 495
 496 sub set_background ($){
 497
 498     my $colour = shift;
 499     our $bg_code;
 500     my %backgrounds = (
 501               black       => "40",
 502               red         => "41",
 503               green       => "42",
 504               brown       => "43",
 505               blue        => "44",
 506               magenta     => "45",
 507               cyan        => "46",
 508               white       => "47",
 509               default     => "49",
 510     );
 511
 512     if (defined($backgrounds{$colour})) {
 513         $bg_code = $backgrounds{$colour};
 514     } else {
 515         die "Invalid background colour: " . $colour;
 516     }
 517 }
 518
 519 sub get_background (){
 520     return our $bg_code;
 521 }
 522
 523 sub prepare_highlight_hash ($) {
 524     my $ref = shift;
 525
 526     foreach my $key (keys %$ref) {
 527         $$ref{$key} = $html_output_mode ?
 528             get_semantic_html_markup($key) :
 529             paint_it($$ref{$key});
 530     }
 531 }
 532
 533 sub prepare_colour_array ($) {
 534     my $ref = shift;
 535
 536     foreach my $i (0 ... @$ref - 1) {
 537         $$ref[$i] = $html_output_mode ?
 538             get_colour_html_markup($$ref[$i]) :
 539             paint_it($$ref[$i]);
 540     }
 541 }
 542
 543 sub found_unknown_content ($) {
 544
 545     my $unknown = shift;
 546     my $message;
 547
 548     return if cli_option_is_set('accept-unknown-messages');
 549
 550     return if ($unknown =~ /\[too long, truncated\]$/);
 551
 552     $message = "found_unknown_content: Don't know how to highlight: ";
 553     # Break line so the log file can later be parsed as Privoxy log file again
 554     $message .= '"' . $unknown . '"' . " in:\n";
 555     $message .= $req{$t}{'log-message'};
 556     debug_message($message);
 557     log_parse_error($req{$t}{'log-message'});
 558
 559     die "Unworthy content parser" if PUNISH_MISSING_LOG_KNOWLEDGE_WITH_DEATH;
 560 }
 561
 562 sub log_parse_error ($) {
 563
 564     my $message = shift;
 565
 566     if (LOG_UNPARSED_LINES_TO_EXTRA_FILE) {
 567         open(ERRORLOG, ">>" . ERROR_LOG_FILE) || die "Writing " . ERROR_LOG_FILE . " failed";
 568         print ERRORLOG $message;
 569         close(ERRORLOG);
 570     }
 571 }
 572
 573 sub debug_message (@) {
 574     my @message = @_;
 575
 576     print $h{'debug'} . "@message" . $h{'Standard'} . "\n";
 577 }
 578
 579 ################################################################################
 580 # highlighter functions that aren't loglevel-specific
 581 ################################################################################
 582
 583 sub h ($) {
 584
 585     # Get highlight marker
 586     my $highlight = shift; # XXX: Stupid name;
 587     my $result = '';
 588     my $message;
 589
 590     if (defined($highlight)) {
 591
 592         $result = $h{$highlight};
 593
 594     } else {
 595
 596         $message = "h: Don't recognize highlighter $highlight.";
 597         debug_message($message);
 598         log_parser_error($message);
 599         die "Unworthy highlighter function" if PUNISH_MISSING_HIGHLIGHT_KNOWLEDGE_WITH_DEATH;
 600     }
 601
 602     return $result;
 603 }
 604
 605 sub highlight_known_headers ($) {
 606
 607     my $content = shift;
 608
 609     debug_message("Searching $content for things to highlight.") if DEBUG_HEADER_HIGHLIGHTING;
 610
 611     if ($content =~ m/(?<=\s)($header_highlight_regex):/) {
 612         my $header = $1;
 613         $content =~ s@(?<=[\s|'])($header)(?=:)@$header_colours{$header}$1$h{'Standard'}@ig;
 614         debug_message("Highlighted '$header' in '$content'") if DEBUG_HEADER_HIGHLIGHTING;
 615     }
 616
 617     return $content;
 618 }
 619
 620 sub highlight_matched_request_line ($$) {
 621
 622     my $result = shift; # XXX: Stupid name;
 623     my $regex = shift;
 624     if ($result =~ m@(.*)($regex)(.*)@) {
 625         $result = $1 . highlight_request_line($2) . $3
 626     }
 627     return $result;
 628 }
 629
 630 sub highlight_request_line ($) {
 631
 632     my $rl = shift;
 633     my ($method, $url, $http_version);
 634
 635     #GET http://images.sourceforge.net/sfx/icon_warning.gif HTTP/1.1
 636     if ($rl =~ m/Invalid request/) {
 637
 638         $rl = h('invalid-request') . $rl . h('Standard');
 639
 640     } elsif ($rl =~ m/^([-\w]+) (.*) (HTTP\/\d\.\d)/) {
 641
 642         # XXX: might not match in case of HTTP method fuzzing.
 643         # XXX: save these: ($method, $path, $http_version) = ($1, $2, $3);
 644         $rl =~ s@^(\w+)@$h{'method'}$1$h{'Standard'}@;
 645         if ($rl =~ /http:\/\//) {
 646             $rl = highlight_matched_url($rl, '[^\s]*(?=\sHTTP)');
 647         } else {
 648             $rl = highlight_matched_pattern($rl, 'request_', '[^\s]*(?=\sHTTP)');
 649         }
 650
 651         $rl =~ s@(HTTP\/\d\.\d)$@$h{'http-version'}$1$h{'Standard'}@;
 652
 653     } elsif ($rl =~ m/\.\.\. \[too long, truncated\]$/) {
 654
 655         $rl =~ s@^(\w+)@$h{'method'}$1$h{'Standard'}@;
 656         $rl = highlight_matched_url($rl, '[^\s]*(?=\.\.\.)');
 657
 658     } elsif ($rl =~ m/^ $/) {
 659
 660         $rl = h('error') . "No request line specified!" . h('Standard');
 661
 662     } else {
 663
 664         debug_message ("Can't parse request line: $rl");
 665
 666     }
 667
 668     return $rl;
 669 }
 670
 671 sub highlight_response_line ($) {
 672
 673     my $rl = shift;
 674     my ($http_version, $status_code, $status_message);
 675
 676     #HTTP/1.1 200 OK
 677     #ICY 200 OK
 678
 679     # TODO: Mark different status codes differently
 680
 681     if ($rl =~ m/((?:HTTP\/\d\.\d|ICY)) (\d+) (.*)/) {
 682         ($http_version, $status_code, $status_message) = ($1, $2, $3);
 683     } else {
 684         debug_message ("Can't parse response line: $rl") and die 'Fix this';
 685     }
 686
 687     # Rebuild highlighted
 688     $rl= "";
 689     $rl .= h('http-version') . $http_version . h('Standard');
 690     $rl .= " ";
 691     $rl .= h('status-code') . $status_code . h('Standard');
 692     $rl .= " ";
 693     $rl .= h('status-message') . $status_message . h('Standard');
 694
 695     return $rl;
 696 }
 697
 698 sub highlight_matched_url ($$) {
 699
 700     my $result = shift; # XXX: Stupid name;
 701     my $regex = shift;
 702
 703     #print "Got $result, regex ($regex)\n";
 704
 705     if ($result =~ m@(.*?)($regex)(.*)@) {
 706         $result = $1 . highlight_url($2) . $3;
 707         #print "Now the result is $result\n";
 708     }
 709
 710     return $result;
 711 }
 712
 713 sub highlight_matched_host ($$) {
 714
 715     my ($result, $regex) = @_; # XXX: result ist stupid name;
 716
 717     if ($result =~ m@(.*?)($regex)(.*)@) {
 718         $result = $1 . $h{host} . $2 . $h{Standard} . $3;
 719     }
 720
 721     return $result;
 722 }
 723
 724 sub highlight_matched_pattern ($$$) {
 725
 726     my $result = shift; # XXX: Stupid name;
 727     my $key = shift;
 728     my $regex = shift;
 729
 730     die "Unknown key $key" unless defined $h{$key};
 731
 732     if ($result =~ m@(.*?)($regex)(.*)@) {
 733         $result = $1 . h($key) . $2 . h('Standard') . $3;
 734     }
 735
 736     return $result;
 737 }
 738
 739 sub highlight_matched_path ($$) {
 740
 741     my $result = shift; # XXX: Stupid name;
 742     my $regex = shift;
 743
 744     if ($result =~ m@(.*?)($regex)(.*)@) {
 745         $result = $1 . h('path') . $2 . h('Standard') . $3;
 746     }
 747
 748     return $result;
 749 }
 750
 751 sub highlight_url ($) {
 752
 753     my $url = shift;
 754
 755     if ($html_output_mode) {
 756
 757         $url = '<a href="' . $url . '">' . $url . '</a>';
 758
 759     } else {
 760
 761         $url = h('URL') . $url . h('Standard');
 762
 763     }
 764
 765     return $url;
 766 }
 767
 768 sub update_header_highlight_regex ($) {
 769
 770     my $header = shift;
 771     my $headers = join ('|', keys %header_colours);
 772
 773     $header_highlight_regex = qr/$headers/;
 774     print "Registering '$header'\n" if DEBUG_HEADER_HIGHLIGHTING;
 775 }
 776
 777 ################################################################################
 778 # loglevel-specific highlighter functions
 779 ################################################################################
 780
 781 sub handle_loglevel_header ($) {
 782
 783     my $c = shift;
 784
 785     if ($c =~ /^scan:/) {
 786
 787         if ($c =~ m/^scan: ([^: ]+):/) {
 788
 789             # Register new headers
 790             # scan: Accept: image/png,image/*;q=0.8,*/*;q=0.5
 791             my $header = $1;
 792             if (!defined($header_colours{$header}) and $header =~ /^[\d\w-]*$/) {
 793                 debug_message "Registering previously unknown header $1" if DEBUG_HEADER_REGISTERING;
 794
 795                 if (REGISTER_HEADERS_WITH_THE_SAME_COLOUR) {
 796                     $header_colours{$header} =  $header_colours{'Default'};
 797                 } else {
 798                     $header_colours{$header} = $all_colours[$header_colour_index % @all_colours];
 799                     $header_colour_index++;
 800                 }
 801                 update_header_highlight_regex($header);
 802             }
 803
 804         } elsif ($c =~ m/^scan: ((\w+) (.+) (HTTP\/\d\.\d))/) {
 805
 806             # Client request line
 807             # Save for statistics (XXX: Not implemented yet)
 808             $req{$t}{'method'} = $2;
 809             $req{$t}{'destination'} = $3;
 810             $req{$t}{'http-version'} = $4;
 811
 812             $c = highlight_request_line($1);
 813
 814         } elsif ($c =~ m/^(scan: )((?:HTTP\/\d\.\d|ICY) (\d+) (.*))/) {
 815
 816             # Server response line
 817             $req{$t}{'response_line'} = $2;
 818             $req{$t}{'status_code'} = $3;
 819             $req{$t}{'status_message'} = $4;
 820             $c = $1 . highlight_response_line($req{$t}{'response_line'});
 821         }
 822
 823     } elsif ($c =~ m/^Crunching (?:server|client) header: .* \(contains: ([^\)]*)\)/) {
 824
 825         # Crunching server header: Set-Cookie: trac_form_token=d5308c34e16d15e9e301a456; (contains: Cookie:)
 826         $c =~ s@(?<=contains: )($1)@$h{'crunch-pattern'}$1$h{'Standard'}@;
 827         $c =~ s@(Crunching)@$h{$1}$1$h{'Standard'}@;
 828
 829     } elsif ($c =~ m/^New host is: ([^\s]*)\./) {
 830
 831         # New host is: trac.vidalia-project.net. Crunching Referer: http://www.vidalia-project.net/!
 832         $c = highlight_matched_host($c, '(?<=New host is: )[^\s]+(?=\.)');
 833         $c = highlight_matched_url($c, '(?<=Crunching Referer: )[^\s!]+');
 834
 835     } elsif ($c =~ m/^Text mode enabled by force. (Take cover)!/) {
 836
 837         # Text mode enabled by force. Take cover!
 838         $c =~ s@($1)@$h{'warning'}$1$h{'Standard'}@;
 839
 840     } elsif ($c =~ m/^(New HTTP Request-Line: )(.*)/) {
 841
 842         # New HTTP Request-Line: GET http://www.privoxy.org/ HTTP/1.1
 843         $c = $1 . highlight_request_line($2);
 844
 845     } elsif ($c =~ m/^Adjust(ed)? Content-Length to \d+/) {
 846
 847         # Adjusted Content-Length to 2132
 848         # Adjust Content-Length to 33533
 849         $c =~ s@(?<=Content-Length to )(\d+)@$h{'Number'}$1$h{'Standard'}@;
 850         $c = highlight_known_headers($c);
 851
 852     } elsif ($c =~ m/^Destination extracted from "Host:" header. New request URL:/) {
 853
 854         # Destination extracted from "Host:" header. New request URL: http://www.cccmz.de/~ridcully/blog/
 855         $c = highlight_matched_url($c, '(?<=New request URL: ).*');
 856
 857     } elsif ($c =~ m/^Couldn\'t parse:/) {
 858
 859         # XXX: These should probable be logged with LOG_LEVEL_ERROR
 860         # Couldn't parse: If-Modified-Since: Wed, 21 Mar 2007 16:34:50 GMT (crunching!)
 861         # Couldn't parse: at, 24 Mar 2007 13:46:21 GMT in If-Modified-Since: Sat, 24 Mar 2007 13:46:21 GMT (crunching!)
 862         $c =~ s@^(Couldn\'t parse)@$h{'error'}$1$h{'Standard'}@;
 863
 864     } elsif ($c =~ /^Tagger \'([^\']*)\' added tag \'([^\']*)\'/ or
 865              $c =~ m/^Adding tag \'([^\']*)\' created by header tagger \'([^\']*)\'/) {
 866
 867         # Adding tag 'GET request' created by header tagger 'method-man' (XXX: no longer used)
 868         # Tagger 'revalidation' added tag 'REVALIDATION-REQUEST'. No action bit update necessary.
 869         # Tagger 'revalidation' added tag 'REVALIDATION-REQUEST'. Action bits updated accordingly.
 870
 871         # XXX: Save tag and tagger
 872
 873         $c =~ s@(?<=^Tagger \')([^\']*)@$h{'tagger'}$1$h{'Standard'}@;
 874         $c =~ s@(?<=added tag \')([^\']*)@$h{'tag'}$1$h{'Standard'}@;
 875         $c =~ s@(?<=Action bits )(updated)@$h{'action-bits-update'}$1$h{'Standard'}@;
 876         $no_special_header_highlighting = 1;
 877
 878     } elsif ($c =~ /^Tagger \'([^\']*)\' didn['']t add tag \'([^\']*)\'/) {
 879
 880         # Tagger 'revalidation' didn't add tag 'REVALIDATION-REQUEST'. Tag already present
 881         # XXX: Save tag and tagger
 882
 883         $c =~ s@(?<=^Tagger \')([^\']*)@$h{'tag'}$1$h{'Standard'}@;
 884         $c =~ s@(?<=didn['']t add tag \')([^\']*)@$h{'tagger'}$1$h{'Standard'}@;
 885
 886     } elsif ($c =~ m/^(?:scan:|Randomiz|addh:|Adding:|Removing:|Referer:|Modified:|Accept-Language header|[Cc]ookie)/
 887           or $c =~ m/^(Text mode is already enabled|Denied request with NULL byte|Replaced:|add-unique:)/
 888           or $c =~ m/^(Crunched (incoming|outgoing) cookie|Suppressed offer|Accepted the client)/
 889           or $c =~ m/^(addh-unique|Referer forged to)/
 890           or $c =~ m/^Downgraded answer to HTTP\/1.0/
 891           or $c =~ m/^Parameter: \+hide-referrer\{[^\}]*\} is a bad idea, but I don\'t care./
 892           or $c =~ m/^Referer (?:overwritten|replaced) with: Referer: / #XXX: should this be highlighted?
 893           or $c =~ m/^Referer crunched!/
 894           or $c =~ m/^crunched x-forwarded-for!/
 895           or $c =~ m/^crunched From!/
 896           or $c =~ m/^ modified$/
 897           or $c =~ m/^Content filtering is enabled. Crunching:/
 898           or $c =~ m/^force-text-mode overruled the client/
 899           or $c =~ m/^Server time in the future\./
 900           or $c =~ m/^content-disposition header crunched and replaced with:/i
 901           or $c =~ m/^Reducing white space in /
 902           or $c =~ m/^Ignoring single quote in /
 903           or $c =~ m/^Converting tab to space in /
 904           or $c =~ m/A HTTP\/1\.1 response without/
 905           or $c =~ m/Disabled filter mode on behalf of the client/
 906           or $c =~ m/Keeping the (?:server|client) header /
 907           or $c =~ m/Content modified with no Content-Length header set/
 908           or $c =~ m/^Appended client IP address to/
 909           or $c =~ m/^Removing 'Connection: close' to imply keep-alive./
 910           or $c =~ m/^keep-alive support is disabled/
 911             )
 912     {
 913         # XXX: Some of these may need highlighting
 914
 915         # Modified: User-Agent: Mozilla/5.0 (X11; U; SunOS i86pc; pl-PL; rv:1.8.1.1) Gecko/20070214 Firefox/2.0.0.1
 916         # Accept-Language header crunched and replaced with: Accept-Language: pl-pl
 917         # cookie 'Set-Cookie: eZSessionCookie=07bfec287c197440d299f81580593c3d; \
 918         #  expires=Thursday, 12-Apr-07 15:16:18 GMT; path=/' send by \
 919         #  http://wirres.net/article/articleview/4265/1/6/ appears to be using time format 1 (XXX: gone with the wind)
 920         # Cookie rewritten to a temporary one: Set-Cookie: NSC_gffe-iuuq-mc-wtfswfs=8efb33a53660;path=/
 921         # Text mode is already enabled
 922         # Denied request with NULL byte(s) turned into line break(s)
 923         # Replaced: 'Connection: Yo, home to Bel Air' with 'Connection: close'
 924         # addh-unique: Host: people.freebsd.org
 925         # Suppressed offer to compress content
 926         # Crunched incoming cookie -- yum!
 927         # Accepted the client's request to fetch without filtering.
 928         # Crunched outgoing cookie: Cookie: PREF=ID=6cf0abd347b30262:TM=1173357617:LM=1173357617:S=jZypyyJ7LPiwFi1_
 929         # addh-unique: Host: subkeys.pgp.net:11371
 930         # Referer forged to: Referer: http://10.0.0.1/
 931         # Downgraded answer to HTTP/1.0
 932         # Parameter: +hide-referrer{pille-palle} is a bad idea, but I don't care.
 933         # Referer overwritten with: Referer: pille-palle
 934         # Referer replaced with: Referer: pille-palle
 935         # crunched x-forwarded-for!
 936         # crunched From!
 937         #  modified # XXX: pretty stupid log message
 938         # Content filtering is enabled. Crunching: 'Range: 1234-5678' to prevent range-mismatch problems
 939         # force-text-mode overruled the client's request to fetch without filtering!
 940         # Server time in the future.
 941         # content-disposition header crunched and replaced with: content-disposition: filename=baz
 942         # Content-Disposition header crunched and replaced with: content-disposition: filename=baz
 943         # Reducing white space in 'X-LWS-Test: "This  is  quoted" this is not "this  is  " but " this again   is  not'
 944         # Ignoring single quote in 'X-LWS-Test: "This  is  quoted" this is not "this  is  " but "  this again   is  not'
 945         # Converting tab to space in 'X-LWS-Test:   "This  is  quoted" this   is  not "this  is  "  but  "\
 946         #  this again   is  not'
 947         # A HTTP/1.1 response without Connection header implies keep-alive.
 948         # Disabled filter mode on behalf of the client.
 949         # Keeping the server header 'Connection: keep-alive' around.
 950         # Keeping the client header 'Connection: close' around. The connection will not be kept alive.
 951         # Keeping the client header 'Connection: keep-alive' around. The connection will be kept alive if possible.
 952         # Content modified with no Content-Length header set. Creating a fake one for adjustment later on.
 953         # Appended client IP address to X-Forwarded-For: 10.0.0.2, 10.0.0.1
 954         # Removing 'Connection: close' to imply keep-alive.
 955         # keep-alive support is disabled. Crunching: Keep-Alive: 300.
 956
 957     } elsif ($c =~ m/^scanning headers for:/) {
 958
 959         return '' unless SHOW_SCAN_INTRO;
 960
 961     } elsif ($c =~ m/^[Cc]runch(ing|ed)|crumble crunched:/) {
 962         # crunched User-Agent!
 963         # Crunching: Content-Encoding: gzip
 964
 965         $c =~ s@(Crunching|crunched)@$h{$1}$1$h{'Standard'}@;
 966
 967     } elsif ($c =~ m/^Offending request data with NULL bytes turned into \'°\' characters:/) {
 968
 969         # Offending request data with NULL bytes turned into '°' characters: °°n°°(°°°
 970
 971         $c = h('warning') . $c . h('Standard');
 972
 973     } elsif ($c =~ m/^(Transforming \")(.*?)(\" to \")(.*?)(\")/) {
 974
 975         # Transforming "Proxy-Authenticate: Basic realm="Correos Proxy Server"" to\
 976         #  "Proxy-Authenticate: Basic realm="Correos Proxy Server""
 977
 978        $c =~ s@(?<=^Transforming \")(.*)(?=\" to)@$h{'Header'}$1$h{'Standard'}@;
 979        $c =~ s@(?<=to \")(.*)(?=\")@$h{'Header'}$1$h{'Standard'}@;
 980
 981     } elsif ($c =~ m/^Removing empty header/) {
 982
 983         # Removing empty header
 984         # Ignore for now
 985
 986     } elsif ($c =~ m/^Content-Type: .* not replaced/) {
 987
 988         # Content-Type: application/octet-stream not replaced. It doesn't look like text.\
 989         #  Enable force-text-mode if you know what you're doing.
 990         # XXX: Could highlight more here.
 991         $c =~ s@(?<=^Content-Type: )(.*)(?= not replaced)@$h{'content-type'}$1$h{'Standard'}@;
 992
 993     } elsif ($c =~ m/^(Server|Client) keep-alive timeout is/) {
 994
 995        # Server keep-alive timeout is 5. Sticking with 10.
 996        # Client keep-alive timeout is 20. Sticking with 10.
 997
 998        $c =~ s@(?<=timeout is )(\d+)@$h{'Number'}$1$h{'Standard'}@;
 999        $c =~ s@(?<=Sticking with )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1000
1001     } elsif ($c =~ m/^Reducing keep-alive timeout/) {
1002
1003        # Reducing keep-alive timeout from 60 to 10.
1004
1005        $c =~ s@(?<= from )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1006        $c =~ s@(?<= to )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1007
1008     } else {
1009
1010         found_unknown_content($c);
1011     }
1012
1013     # Highlight headers
1014     unless ($c =~ m/^Transforming/) {
1015         $c = highlight_known_headers($c) unless $no_special_header_highlighting;
1016     }
1017
1018     return $c;
1019 }
1020
1021 sub handle_loglevel_re_filter ($) {
1022
1023     my $content = shift;
1024     my $c = $content;
1025     my $key;
1026
1027     if ($c =~ m/^(?:re_)?filtering ([^\s]+) \(size (\d+)\) with (?:filter )?\'?([^\s]+?)\'? produced (\d+) hits \(new size (\d+)\)/) {
1028
1029         # XXX: only the second version gets highlighted properly.
1030         # re_filtering www.lfk.de/favicon.ico (size 209) with filter untrackable-hulk produced 0 hits (new size 209).
1031         # filtering aci.blogg.de/ (size 37988) with 'blogg.de' produced 3 hits (new size 38057)
1032         $req{$t}{'content_source'} = $1;
1033         $req{$t}{'content_size'}   = $2;
1034         $req{$t}{'content_filter'} = $3;
1035         $req{$t}{'content_hits'}   = $4;
1036         $req{$t}{'new_content_size'} = $5;
1037         $req{$t}{'content_size_change'} = $req{$t}{'new_content_size'} - $req{$t}{'content_size'};
1038         #return '' if ($req{$t}{'content_hits'} == 0 && !cli_option_is_set('show-ineffective-filters'));
1039         if ($req{$t}{'content_hits'} == 0 and
1040             not (cli_option_is_set('show-ineffective-filters')
1041                  or ($req{$t}{'content_filter'} =~ m/^privoxy-filter-test$/))) {
1042                 return '';
1043         }
1044
1045         $c =~ s@(?<=\(size )(\d+)\)(?= with)@$h{'Number'}$1$h{'Standard'}@;
1046         $c =~ s@(?<=\(new size )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1047         $c =~ s@(?<=produced )(\d+)(?= hits)@$h{'Number'}$1$h{'Standard'}@;
1048
1049         $c =~ s@([^\s]+?)(\'? produced)@$h{'filter'}$1$h{'Standard'}$2@;
1050         $c = highlight_matched_host($c, '(?<=filtering )[^\s]+');
1051
1052         $c =~ s@\.$@ @;
1053         $c .= "(" . $h{'Number'};
1054         $c .= "+" if ($req{$t}{'content_size_change'} >= 0);
1055         $c .= $req{$t}{'content_size_change'} . $h{'Standard'} . ")";
1056         $content = $c;
1057
1058   } elsif ($c =~ /\.{3}$/
1059         and $c =~ m/^(?:re_)?filtering \'?(.*?)\'? \(size (\d*)\) with (?:filter )?\'?([^\s]*?)\'? ?\.{3}$/) {
1060
1061         # Used by Privoxy 3.0.5 and 3.0.6:
1062         # XXX: Fill in ...
1063         # Used by Privoxy 3.0.7:
1064         # filtering 'Connection: close' (size 17) with 'generic-content-ads' ...
1065
1066         $req{$t}{'filtered_header'} = $1;
1067         $req{$t}{'old_header_size'} = $2;
1068         $req{$t}{'header_filter_name'} = $3;
1069
1070         unless (cli_option_is_set('show-ineffective-filters') or
1071                 $req{$t}{'header_filter_name'} =~ m/^privoxy-filter-test$/) {
1072             return '';
1073         }
1074         $content =~ s@(?<=\(size )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1075         $content =~ s@($req{$t}{'header_filter_name'})@$h{'filter'}$1$h{'Standard'}@;
1076
1077     } elsif ($c =~ m/^ ?\.\.\. ?produced (\d*) hits \(new size (\d*)\)\./) {
1078
1079         # ...produced 0 hits (new size 23).
1080         #... produced 1 hits (new size 54).
1081
1082         $req{$t}{'header_filter_hits'} = $1;
1083         $req{$t}{'new_header_size'} = $2;
1084
1085         unless (cli_option_is_set('show-ineffective-filters') or
1086                 (defined($req{$t}{'header_filter_name'}) and
1087                  $req{$t}{'header_filter_name'} =~ m/^privoxy-filter-test$/)) {
1088
1089             if ($req{$t}{'header_filter_hits'} == 0 and
1090                 not (defined($req{$t}{'header_filter_name'}) and
1091                  $req{$t}{'header_filter_name'} =~ m/^privoxy-filter-test$/)) {
1092                 return '';
1093             }
1094             # Reformat including information from the intro
1095             $c = "'" . h('filter') . $req{$t}{'header_filter_name'} . h('Standard') . "'";
1096             $c .= " hit ";
1097             # XXX: Hide behind constant, it may be interesting if LOG_LEVEL_HEADER isn't enabled as well.
1098             # $c .= $req{$t}{'filtered_header'} . " ";
1099             $c .= h('Number') . $req{$t}{'header_filter_hits'}. h('Standard');
1100             $c .= ($req{$t}{'header_filter_hits'} == 1) ? " time, " : " times, ";
1101
1102             if ($req{$t}{'old_header_size'} !=  $req{$t}{'new_header_size'}) {
1103
1104                 $c .= "changing size from ";
1105                 $c .=  h('Number') . $req{$t}{'old_header_size'} . h('Standard');
1106                 $c .= " to ";
1107                 $c .= h('Number') . $req{$t}{'new_header_size'} . h('Standard');
1108                 $c .= ".";
1109
1110             } else {
1111
1112                 $c .= "keeping the size at " . $req{$t}{'old_header_size'};
1113
1114             }
1115
1116             # Highlight from last line (XXX: What?)
1117             # $c =~ s@(?<=produced )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1118             # $c =~ s@($req{$t}{'header_filter_name'})@$h{'filter'}$1$h{'Standard'}@;
1119
1120         } else {
1121
1122            # XXX: Untested
1123            $c =~ s@(?<=produced )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1124            $c =~ s@(?<=new size )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1125
1126         }
1127         $content = $c;
1128
1129     } elsif ($c =~ m/^(Tagger|Filter) ([^\s]*) has empty joblist. Nothing to do./) {
1130
1131         # Filter privoxy-filter-test has empty joblist. Nothing to do.
1132         # Tagger variable-test has empty joblist. Nothing to do.
1133
1134         $content =~ s@(?<=$1 )([^\s]*)@$h{'filter'}$1$h{'Standard'}@;
1135
1136     } elsif ($c =~ m/^De-chunking successful. Shrunk from (\d+) to (\d+)/) {
1137
1138         $req{$t}{'chunked-size'} = $1;
1139         $req{$t}{'dechunked-size'} = $2;
1140         $req{$t}{'dechunk-change'} = $req{$t}{'dechunked-size'} - $req{$t}{'chunked-size'};
1141
1142         $content .= " (" . h('Number') . $req{$t}{'dechunk-change'} . h('Standard') . ")";
1143
1144         $content =~ s@(?<=from )($req{$t}{'chunked-size'})@$h{'Number'}$1$h{'Standard'}@;
1145         $content =~ s@(?<=to )($req{$t}{'dechunked-size'})@$h{'Number'}$1$h{'Standard'}@;
1146
1147     } elsif ($c =~ m/^Decompression successful. Old size: (\d+), new size: (\d+)./) {
1148
1149         # Decompression successful. Old size: 670, new size: 1166.
1150
1151         $req{$t}{'size-compressed'} = $1;
1152         $req{$t}{'size-decompressed'} = $2;
1153         $req{$t}{'decompression-gain'} = $req{$t}{'size-decompressed'} - $req{$t}{'size-compressed'};
1154
1155         $content =~ s@(?<=Old size: )($req{$t}{'size-compressed'})@$h{'Number'}$1$h{'Standard'}@;
1156         $content =~ s@(?<=new size: )($req{$t}{'size-decompressed'})@$h{'Number'}$1$h{'Standard'}@;
1157
1158         # XXX: Create sub get_percentage()
1159         if ($req{$t}{'size-decompressed'}) {
1160             $req{$t}{'decompression-gain-percent'} =
1161                 $req{$t}{'decompression-gain'} / $req{$t}{'size-decompressed'} * 100;
1162
1163             $content .= " (saved: ";
1164             #$content .= h('Number') . $req{$t}{'decompression-gain'} . h('Standard');
1165             #$content .= "/";
1166             $content .= h('Number') . sprintf("%.2f%%", $req{$t}{'decompression-gain-percent'}) . h('Standard');
1167             $content .= ")";
1168         }
1169
1170     } elsif ($c =~ m/^(Need to de-chunk first)/) {
1171
1172         # Need to de-chunk first
1173         return '' if SUPPRESS_NEED_TO_DE_CHUNK_FIRST;
1174
1175     } elsif ($c =~ m/^(Adding (?:dynamic )?re_filter job)/) {
1176
1177         return ''  if (SUPPRESS_SUCCEEDED_FILTER_ADDITIONS && m/succeeded/);
1178
1179         # Adding re_filter job ...
1180         # Adding dynamic re_filter job s@^(?:\w*)\s+.*\s+HTTP/\d\.\d\s*@IP-ADDRESS: $origin@D\
1181         #  to filter client-ip-address succeeded.
1182
1183     } elsif ($c =~ m/^Reading in filter/) {
1184
1185         return '' unless SHOW_FILTER_READIN_IN;
1186
1187     } else {
1188
1189         found_unknown_content($content);
1190
1191     }
1192
1193     return $content;
1194 }
1195
1196 sub handle_loglevel_redirect ($) {
1197
1198     my $c = shift;
1199
1200     if ($c =~ m/^Decoding "([^""]*)"/) {
1201
1202          $req{$t}{'original-destination'} = $1;
1203          $c = highlight_matched_path($c, '(?<=Decoding ")[^"]*');
1204          $c =~ s@\"@@g;
1205
1206     } elsif ($c =~ m/^Checking/) {
1207
1208          # Checking /_ylt=A0geu.Z76BRGR9k/**http://search.yahoo.com/search?p=view+odb+presentation+on+freebsd\
1209          #  &ei=UTF-8&xargs=0&pstart=1&fr=moz2&b=11 for redirects.
1210
1211          # TODO: Change colour if really url-decoded
1212          $req{$t}{'decoded-original-destination'} = $1;
1213          $c = highlight_matched_path($c, '(?<=Checking ")[^"]*');
1214          $c =~ s@\"@@g;
1215
1216     } elsif ($c =~ m/^pcrs command "([^""]*)" changed /) {
1217
1218         # pcrs command "s@&from=rss@@" changed \
1219         #  "http://it.slashdot.org/article.pl?sid=07/03/02/1657247&from=rss"\
1220         #  to "http://it.slashdot.org/article.pl?sid=07/03/02/1657247" (1 hit).
1221         $c =~ s@(?<=pcrs command )"([^""]*)"@$h{'filter'}$1$h{'Standard'}@;
1222         $c = highlight_matched_url($c, '(?<=changed ")[^""]*');
1223         $c =~ s@(?<=changed )"([^""]*)"@$1@; # Remove quotes
1224         $c = highlight_matched_url($c, '(?<=to ")[^""]*');
1225         $c =~ s@(?<=to )"([^""]*)"@$1@; # Remove quotes
1226         $c =~ s@(\d+)(?= hits?)@$h{'hits'}$1$h{'Standard'}@;
1227
1228     } elsif ($c =~ m/^pcrs command "([^""]*)" didn\'t change/) {
1229
1230         # pcrs command "s@^http://([^.]+?)/?$@http://www.bing.com/search?q=$1@" didn't \
1231         #  change "http://www.example.org/".
1232         $c =~ s@(?<=pcrs command )"([^""]*)"@$h{'filter'}$1$h{'Standard'}@;
1233         $c = highlight_matched_url($c, '(?<=change ")[^""]*');
1234
1235     } elsif ($c =~ m/(^New URL is: )(.*)/) {
1236
1237         # New URL is: http://it.slashdot.org/article.pl?sid=07/03/04/1511210
1238         # XXX: Use URL highlighter
1239         # XXX: Save?
1240         $c = $1 . h('rewritten-URL') . $2 . h('Standard');
1241
1242     } elsif ($c =~ m/No pcrs command recognized, assuming that/) {
1243         # No pcrs command recognized, assuming that "http://config.privoxy.org/user-manual/favicon.png"\
1244         #  is already properly formatted.
1245         # XXX: assume the same?
1246         $c = highlight_matched_url($c, '(?<=assuming that \")[^"]*');
1247
1248     } else {
1249
1250         found_unknown_content($c);
1251
1252     }
1253
1254     return $c;
1255 }
1256
1257 sub handle_loglevel_gif_deanimate ($) {
1258
1259     my $content = shift;
1260
1261     if ($content =~ m/Success! GIF shrunk from (\d+) bytes to (\d+)\./) {
1262
1263         my $bytes_from = $1;
1264         my $bytes_to = $2;
1265         # Gif-Deanimate: Success! GIF shrunk from 205 bytes to 133.
1266         $content =~ s@$bytes_from@$h{'Number'}$bytes_from$h{'Standard'}@;
1267         # XXX: Do we need g in case of ($1 == $2)?
1268         $content =~ s@$bytes_to@$h{'Number'}$bytes_to$h{'Standard'}@;
1269
1270     } elsif ($content =~ m/GIF (not) changed/) {
1271
1272         # Gif-Deanimate: GIF not changed.
1273         return '' if SUPPRESS_GIF_NOT_CHANGED;
1274         $content =~ s@($1)@$h{'not'}$1$h{'Standard'}@;
1275
1276     } elsif ($content =~ m/^failed! \(gif parsing\)/) {
1277
1278         # failed! (gif parsing)
1279         # XXX: Replace this error message with something less stupid
1280         $content =~ s@(failed!)@$h{'error'}$1$h{'Standard'}@;
1281
1282     } elsif ($content =~ m/^Need to de-chunk first/) {
1283
1284         # Need to de-chunk first
1285         return '' if SUPPRESS_NEED_TO_DE_CHUNK_FIRST;
1286
1287     } elsif ($content =~ m/^(?:No GIF header found|failed while parsing)/) {
1288
1289         # No GIF header found (XXX: Did I ever commit this?)
1290         # failed while parsing 195 134747048 (XXX: never commited)
1291
1292         # Ignore these for now
1293
1294     } else {
1295
1296         found_unknown_content($content);
1297
1298     }
1299
1300     return $content;
1301 }
1302
1303 sub handle_loglevel_request ($) {
1304
1305     my $content = shift;
1306
1307     if ($content =~ m/crunch! /) {
1308
1309         # config.privoxy.org/send-stylesheet crunch! (CGI Call)
1310
1311         # Highlight crunch reasons
1312         foreach my $reason (keys %reason_colours) {
1313             $content =~ s@\(($reason)\)@$reason_colours{$reason}($1)$h{'Standard'}@g;
1314         }
1315         # Highlight request URL domain and ditch 'crunch!'
1316         $content = highlight_matched_pattern($content, 'request_', '[^ ]*(?= crunch!)');
1317         $content =~ s@ crunch!@@;
1318
1319     } elsif ($content =~ m/\[too long, truncated\]$/) {
1320
1321         # config.privoxy.org/edit-actions-submit?f=3&v=1176116716&s=7&Submit=Submit[...]&filter... [too long, truncated]
1322         $content = highlight_matched_pattern($content, 'request_', '^.*(?=\.\.\. \[too long, truncated\]$)');
1323
1324     } elsif ($content =~ m/(.*)/) { # XXX: Pretty stupid
1325
1326         # trac.vidalia-project.net/wiki/Volunteer?format=txt
1327         $content = h('request_') . $content . h('Standard');
1328
1329     } else {  # XXX: Nop
1330
1331         found_unknown_content($content);
1332
1333     }
1334
1335     return $content;
1336 }
1337
1338 sub handle_loglevel_crunch ($) {
1339
1340     my $content = shift;
1341
1342     # Highlight crunch reason
1343     foreach my $reason (keys %reason_colours) {
1344         $content =~ s@($reason)@$reason_colours{$reason}$1$h{'Standard'}@g;
1345     }
1346
1347     if ($content =~ m/\[too long, truncated\]$/) {
1348
1349         # Blocked: config.privoxy.org/edit-actions-submit?f=3&v=1176116716&s=7&Submit=Submit\
1350         #  [...]&filter... [too long, truncated]
1351         $content = highlight_matched_pattern($content, 'request_', '^.*(?=\.\.\. \[too long, truncated\]$)');
1352
1353     } else {
1354
1355         # Blocked: http://ads.example.org/
1356         $content = highlight_matched_pattern($content, 'request_', '(?<=: ).*');
1357     }
1358
1359     return $content;
1360 }
1361
1362 sub handle_loglevel_connect ($) {
1363
1364     my $c = shift;
1365
1366     if ($c =~ m/^via [^\s]+ to: [^\s]+/) {
1367
1368         # Connect: via 10.0.0.1:8123 to: www.example.org.noconnect
1369
1370         $c = highlight_matched_host($c, '(?<=via )[^\s]+');
1371         $c = highlight_matched_host($c, '(?<=to: )[^\s]+');
1372
1373     } elsif ($c =~ m/^connect to: .* failed: .*/) {
1374
1375         # connect to: www.example.org.noconnect failed: Operation not permitted
1376
1377         $c = highlight_matched_host($c, '(?<=connect to: )[^\s]+');
1378
1379         $c =~ s@(?<=failed: )(.*)@$h{'error'}$1$h{'Standard'}@;
1380
1381     } elsif ($c =~ m/^to ([^\s]*)( successful)?$/) {
1382
1383         # Connect: to www.nzherald.co.nz successful
1384         # Connect: to archiv.radiotux.de
1385
1386         return '' if SUPPRESS_SUCCESSFUL_CONNECTIONS;
1387         $c = highlight_matched_host($c, '(?<=to )[^\s]+');
1388
1389     } elsif ($c =~ m/^to ([^\s]*)$/) {
1390
1391         # Connect: to lists.sourceforge.net:443
1392
1393         $c = highlight_matched_host($c, '(?<=to )[^\s]+');
1394
1395     } elsif ($c =~ m/^accepted connection from .*/ or
1396              $c =~ m/^OK/) {
1397
1398         # accepted connection from 10.0.0.1
1399         # Privoxy 3.0.6 and earlier just say:
1400         # OK
1401         return '' if SUPPRESS_ACCEPTED_CONNECTIONS;
1402         $c = highlight_matched_host($c, '(?<=connection from ).*');
1403
1404     } elsif ($c =~ m/^write header to: .* failed:/) {
1405
1406         # write header to: 10.0.0.1 failed: Broken pipe
1407
1408         $c = highlight_matched_host($c, '(?<=write header to: )[^\s]*');
1409         $c =~ s@(?<=failed: )(.*)@$h{'Error'}$1$h{'Standard'}@;
1410
1411     } elsif ($c =~ m/^write header to client failed:/) {
1412
1413         # write header to client failed: Broken pipe
1414         # XXX: Stil in use?
1415         $c =~ s@(?<=failed: )(.*)@$h{'Error'}$1$h{'Standard'}@;
1416
1417     } elsif ($c =~ m/^socks4_connect:/) {
1418
1419         # socks4_connect: SOCKS request rejected or failed.
1420         $c =~ s@(?<=socks4_connect: )(.*)@$h{'Error'}$1$h{'Standard'}@;
1421
1422     } elsif ($c =~ m/^Listening for new connections/ or
1423              $c =~ m/^accept connection/) {
1424         # XXX: Highlight?
1425         # Privoxy versions above 3.0.6 say:
1426         # Listening for new connections ...
1427         # earlier versions say:
1428         # accept connection ...
1429         return '';
1430
1431     } elsif ($c =~ m/^accept failed:/) {
1432
1433         $c =~ s@(?<=accept failed: )(.*)@$h{'Error'}$1$h{'Standard'}@;
1434
1435     } elsif ($c =~ m/^Overriding forwarding settings/) {
1436
1437         # Overriding forwarding settings based on 'forward 10.0.0.1:8123'
1438         $c =~ s@(?<=based on \')(.*)(?=\')@$h{'configuration-line'}$1$h{'Standard'}@;
1439
1440     } elsif ($c =~ m/^Denying suspicious CONNECT request from/) {
1441
1442         # Denying suspicious CONNECT request from 10.0.0.1
1443         $c = highlight_matched_host($c, '(?<=from )[^\s]+'); # XXX: not an URL
1444
1445     } elsif ($c =~ m/^socks5_connect:/) {
1446
1447         $c =~ s@(?<=socks5_connect: )(.*)@$h{'error'}$1$h{'Standard'}@;
1448
1449     } elsif ($c =~ m/^Created new connection to/) {
1450
1451         # Created new connection to www.privoxy.org:80 on socket 11.
1452         $c = highlight_matched_host($c, '(?<=connection to )[^\s]+');
1453         $c =~ s@(?<=on socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1454
1455     } elsif ($c =~ m/^Found reusable socket/) {
1456
1457         # Found reusable socket 9 for www.privoxy.org:80 in slot 0.
1458         # 3.0.15 and later:
1459         # Found reusable socket 8 for www.privoxy.org:80 in slot 2.\
1460         #  Timestamp made 0 seconds ago. Timeout: 1. Latency: 0.
1461         $c =~ s@(?<=Found reusable socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1462         $c = highlight_matched_host($c, '(?<=for )[^\s]+');
1463         $c =~ s@(?<=in slot )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1464         $c =~ s@(?<=made )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1465         $c =~ s@(?<=Timeout: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1466         $c =~ s@(?<=Latency: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1467
1468     } elsif ($c =~ m/^Marking open socket/) {
1469
1470         # Marking open socket 9 for www.privoxy.org:80 in slot 0 as unused.
1471         $c =~ s@(?<=Marking open socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1472         $c = highlight_matched_host($c, '(?<=for )[^\s]+');
1473         $c =~ s@(?<=in slot )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1474
1475     } elsif ($c =~ m/^No reusable/) {
1476
1477         # No reusable socket for addons.mozilla.org:443 found. Opening a new one.
1478         $c = highlight_matched_host($c, '(?<=for )[^\s]+');
1479
1480     } elsif ($c =~ m/^(Remembering|Forgetting) socket/) {
1481
1482         # Remembering socket 13 for www.privoxy.org:80 in slot 0.
1483         # Forgetting socket 38 for www.privoxy.org:80 in slot 5.
1484
1485         $c =~ s@(?<=socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1486         $c = highlight_matched_host($c, '(?<=for )[^\s]+');
1487         $c =~ s@(?<=in slot )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1488
1489     } elsif ($c =~ m/^Socket/) {
1490
1491         # Socket 16 already forgotten or never remembered.
1492         $c =~ s@(?<=Socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1493
1494     } elsif ($c =~ m/^The connection to/) {
1495
1496         # The connection to www.privoxy.org:80 in slot 6 timed out. Closing socket 19. Timeout is: 61.
1497         # 3.0.15 and later:
1498         # The connection to 1.bp.blogspot.com:80 in slot 0 timed out. Closing socket 5.\
1499         #  Timeout is: 1. Assumed latency: 4.
1500         # The connection to 10.0.0.1:80 in slot 0 is no longer usable. Closing socket 4.
1501         $c = highlight_matched_host($c, '(?<=connection to )[^\s]+');
1502         $c =~ s@(?<=in slot )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1503         $c =~ s@(?<=Closing socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1504         $c =~ s@(?<=Timeout is: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1505         $c =~ s@(?<=Assumed latency: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1506
1507     } elsif ($c =~ m/^Stopped waiting for the request line./) {
1508
1509         # Stopped waiting for the request line. Timeout: 121.
1510         $c =~ s@(?<=Timeout: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1511
1512     } elsif ($c =~ m/^Waiting for \d/) {
1513
1514         # Waiting for 1 connections to timeout.
1515         $c =~ s@(?<=^Waiting for )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1516
1517     } elsif ($c =~ m/^Initialized/) {
1518
1519         # Initialized 20 socket slots.
1520         $c =~ s@(?<=Initialized )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1521
1522     } elsif ($c =~ m/^Done reading from server/) {
1523
1524         # Done reading from server. Expected content length: 24892. \
1525         #  Actual content length: 24892. Most recently received: 4412.
1526         # 3.0.15 and later:
1527         # Done reading from server. Expected content length: 24892. \
1528         #  Actual content length: 24892. Bytes most recently read: 4412.
1529         # Done reading from server. Content length: 6018 as expected. \
1530         #  Bytes most recently read: 294.
1531         $c =~ s@(?<=ontent length: )(\d+)@$h{'Number'}$1$h{'Standard'}@g;
1532         $c =~ s@(?<=received: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1533         $c =~ s@(?<=read: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1534
1535     } elsif ($c =~ m/^Continuing buffering headers/) {
1536
1537         # Continuing buffering headers. byte_count: 19. header_offset: 517. len: 536.
1538         $c =~ s@(?<=byte_count: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1539         $c =~ s@(?<=header_offset: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1540         $c =~ s@(?<=len: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1541         # 3.0.15 and later:
1542         # Continuing buffering headers. Bytes most recently read: %d.
1543         $c =~ s@(?<=read: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1544
1545     } elsif ($c =~ m/^Received \d+ bytes while/) {
1546
1547         # Received 206 bytes while expecting 12103.
1548         $c =~ s@(?<=Received )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1549         $c =~ s@(?<=expecting )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1550
1551     } elsif ($c =~ m/^Connection from/) {
1552
1553         # Connection from 81.163.28.218 dropped due to ACL
1554         $c =~ s@(?<=^Connection from )((?:\d+\.?){4})@$h{'Number'}$1$h{'Standard'}@;
1555
1556     } elsif ($c =~ m/^(?:Reusing|Closing) server socket \d./ or
1557              $c =~ m/^No additional client request/) {
1558
1559         # Reusing server socket 4. Opened for 10.0.0.1.
1560         # Closing server socket 2. Opened for 10.0.0.1.
1561         # No additional client request received in time. \
1562         #  Closing server socket 4, initially opened for 10.0.0.1.
1563         # No additional client request received in time on socket 29.
1564
1565         $c =~ s@(?<= socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1566         $c = highlight_matched_host($c, '(?<=for )[^\s]+(?=\.$)');
1567
1568     } elsif ($c =~ m/^Connected to /) {
1569
1570         # Connected to tor-jail[10.0.0.2]:9050.
1571
1572         $c = highlight_matched_host($c, '(?<=\[)[^\]]+');
1573         $c = highlight_matched_host($c, '(?<=Connected to )[^\[\s]+');
1574         $c =~ s@(?<=\]:)(\d+)@$h{'Number'}$1$h{'Standard'}@;
1575
1576     } elsif ($c =~ m/^Could not connect to /) {
1577
1578         # Could not connect to [10.0.0.1]:80.
1579
1580         $c = highlight_matched_host($c, '(?<=\[)[^\]]+');
1581         $c =~ s@(?<=\]:)(\d+)@$h{'Number'}$1$h{'Standard'}@;
1582
1583     } elsif ($c =~ m/^Waiting for the next client request/ or
1584              $c =~ m/^The connection on server socket/ or
1585              $c =~ m/^Client request arrived in time or the client closed the connection/) {
1586
1587         # Waiting for the next client request on socket 3. Keeping the server \
1588         #  socket 12 to a.fsdn.com open.
1589         # The connection on server socket 6 to upload.wikimedia.org isn't reusable. Closing.
1590         # Client request arrived in time or the client closed the connection on socket 12.
1591
1592         $c =~ s@(?<=on socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1593         $c =~ s@(?<=server socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1594         $c = highlight_matched_host($c, '(?<=to )[^\s]+');
1595
1596     } elsif ($c =~ m/^Marking the server socket/) {
1597
1598         # Marking the server socket 7 tainted.
1599
1600         $c =~ s@(?<=server socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1601
1602     } elsif ($c =~ m/^Reduced expected bytes to /) {
1603
1604         # Reduced expected bytes to 0 to account for the 1542 ones we already got.
1605         $c =~ s@(?<=bytes to )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1606         $c =~ s@(?<=for the )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1607
1608     } elsif ($c =~ m/^The client closed socket /) {
1609
1610         # The client closed socket 2 while the server socket 4 is still open.
1611         $c =~ s@(?<=closed socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1612         $c =~ s@(?<=server socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1613
1614     } elsif ($c =~ m/^Expected client content length set /) {
1615
1616         # Expected client content length set to 667325411 after reading 4999 bytes.
1617         $c =~ s@(?<=set to )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1618         $c =~ s@(?<=reading )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1619
1620     } elsif ($c =~ m/^Waiting for up to /) {
1621
1622         # Waiting for up to 4999 bytes from the client.
1623         $c =~ s@(?<=up to )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1624
1625     } elsif ($c =~ m/^Looks like we rea/ or
1626              $c =~ m/^Unsetting keep-alive flag/ or
1627              $c =~ m/^No connections to wait/ or
1628              $c =~ m/^Complete client request received/ or
1629              $c =~ m/^Possible pipeline attempt detected./ or
1630              $c =~ m/^POST request detected. The connection will not be kept alive./ or
1631              $c =~ m/^The server still wants to talk, but the client hung up on us./ or
1632              $c =~ m/^The server didn't specify how long the connection will stay open/ or
1633              $c =~ m/^There might be a request body. The connection will not be kept alive/ or
1634              $c =~ m/^Stopping to watch the client socket. There's already another request waiting./ or
1635              $c =~ m/^Done reading from the client\.$/) {
1636
1637         # Looks like we reached the end of the last chunk. We better stop reading.
1638         # Looks like we read the end of the last chunk together with the server \
1639         #  headers. We better stop reading.
1640         # Unsetting keep-alive flag.
1641         # No connections to wait for left.
1642         # Client request arrived in time or the client closed the connection.
1643         # Complete client request received
1644         # Possible pipeline attempt detected. The connection will not be \
1645         #  kept alive and we will only serve the first request.
1646         # POST request detected. The connection will not be kept alive.
1647         # The server still wants to talk, but the client hung up on us.
1648         # The server didn't specify how long the connection will stay open. Assume it's only a second.
1649         # There might be a request body. The connection will not be kept alive.
1650         # Stopping to watch the client socket. There's already another request waiting.
1651         # Done reading from the client\.
1652
1653     } else {
1654
1655         found_unknown_content($c);
1656
1657     }
1658
1659     return $c;
1660 }
1661
1662
1663 sub handle_loglevel_info ($) {
1664
1665     my $c = shift;
1666
1667     if ($c =~ m/^Rewrite detected:/) {
1668
1669         # Rewrite detected: GET http://10.0.0.2:88/blah.txt HTTP/1.1
1670         $c = highlight_matched_request_line($c, '(?<=^Rewrite detected: ).*');
1671
1672     } elsif ($c =~ m/^Decompress(ing deflated|ion didn)/ or
1673              $c =~ m/^Compressed content detected/ or
1674              $c =~ m/^Tagger/
1675             ) {
1676         # Decompressing deflated iob: 117
1677         # Decompression didn't result in any content.
1678         # Compressed content detected, content filtering disabled. Consider recompiling Privoxy\
1679         #  with zlib support or enable the prevent-compression action.
1680         # Tagger 'complete-url' created empty tag. Ignored.
1681
1682         # Ignored for now
1683
1684     } elsif ($c =~ m/^(Re)?loading configuration file /) {
1685
1686         # loading configuration file '/usr/local/etc/privoxy/config':
1687         # Reloading configuration file '/usr/local/etc/privoxy/config'
1688         $c =~ s@(?<=loading configuration file \')([^\']*)@$h{'file'}$1$h{'Standard'}@;
1689
1690     } elsif ($c =~ m/^exiting by signal/) {
1691
1692         # exiting by signal 15 .. bye
1693         $c =~ s@(?<=exiting by signal )(\d+)@$h{'signal'}$1$h{'Standard'}@;
1694
1695     } elsif ($c =~ m/^Privoxy version/) {
1696
1697         # Privoxy version 3.0.7
1698         $c =~ s@(?<=^Privoxy version )(\d+\.\d+\.\d+)$@$h{'version'}$1$h{'Standard'}@;
1699
1700     } elsif ($c =~ m/^Program name: /) {
1701
1702         # Program name: /usr/local/sbin/privoxy
1703         $c =~ s@(?<=Program name: )(.*)@$h{'program-name'}$1$h{'Standard'}@;
1704
1705     } elsif ($c =~ m/^Listening on port /) {
1706
1707         # Listening on port 8118 on IP address 10.0.0.1
1708         $c =~ s@(?<=Listening on port )(\d+)@$h{'port'}$1$h{'Standard'}@;
1709         $c =~ s@(?<=on IP address )(.*)@$h{'ip-address'}$1$h{'Standard'}@;
1710
1711     } elsif ($c =~ m/^\(Re-\)Open(?:ing)? logfile/) {
1712
1713         # (Re-)Open logfile /var/log/privoxy/privoxy.log
1714         $c =~ s@(?<=Open logfile )(.*)@$h{'file'}$1$h{'Standard'}@;
1715
1716     } elsif ($c =~ m/^(Request from|Malformed server response detected)/) {
1717
1718         # Request from 10.0.0.1 denied. limit-connect{,} doesn't allow CONNECT requests to port 443.
1719         # Request from 10.0.0.1 marked for blocking. limit-connect{,} doesn't allow CONNECT requests to port 443.
1720         # Malformed server response detected. Downgrading to HTTP/1.0 impossible.
1721
1722         $c =~ s@(?<=Request from )([^\s]*)@$h{'ip-address'}$1$h{'Standard'}@;
1723         $c =~ s@(denied|blocking)@$h{'warning'}$1$h{'Standard'}@;
1724         $c =~ s@(CONNECT)@$h{'method'}$1$h{'Standard'}@;
1725         $c =~ s@(?<=to port )(\d+)@$h{'port'}$1$h{'Standard'}@;
1726
1727     } elsif ($c =~ m/^Status code/) {
1728
1729         # Status code 304 implies no body.
1730         $c =~ s@(?<=Status code )(\d+)@$h{'status-code'}$1$h{'Standard'}@;
1731
1732     } elsif ($c =~ m/^Method/) {
1733
1734         # Method HEAD implies no body.
1735         $c =~ s@(?<=Method )([^\s]+)@$h{'method'}$1$h{'Standard'}@;
1736
1737     } elsif ($c =~ m/^Buffer limit reached while extending /) {
1738
1739         # Buffer limit reached while extending the buffer (iob). Needed: 4197470. Limit: 4194304
1740         $c =~ s@(?<=Needed: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1741         $c =~ s@(?<=Limit: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1742
1743     } elsif ($c =~ m/^No logfile configured/ or
1744              $c =~ m/^Malformerd HTTP headers detected and MS IIS5 hack enabled/ or
1745              $c =~ m/^Invalid \"chunked\" transfer/ or
1746              $c =~ m/^Support for/ or
1747              $c =~ m/^Flushing header and buffers/
1748              ) {
1749
1750         # No logfile configured. Please enable it before reporting any problems.
1751         # Malformerd HTTP headers detected and MS IIS5 hack enabled. Expect an invalid \
1752         #  response or even no response at all.
1753         # No logfile configured. Logging disabled.
1754         # Invalid "chunked" transfer encoding detected and ignored.
1755         # Support for 'Connection: keep-alive' is experimental, incomplete and\
1756         #  known not to work properly in some situations.
1757         # Flushing header and buffers. Stepping back from filtering.
1758
1759     } else {
1760
1761         found_unknown_content($c);
1762
1763     }
1764
1765     return $c;
1766 }
1767
1768 sub handle_loglevel_cgi ($) {
1769
1770     my $c = shift;
1771
1772     if ($c =~ m/^Granting access to/) {
1773
1774         #Granting access to http://config.privoxy.org/send-stylesheet, referrer http://p.p/ is trustworthy.
1775
1776     } elsif ($c =~ m/^Substituting: s(.)/) {
1777
1778         # Substituting: s/@else-not-FEATURE_ZLIB@.*@endif-FEATURE_ZLIB@//sigTU
1779         # XXX: prone to span several lines
1780
1781         my $delimiter = $1;
1782         #$c =~ s@(?<=failed: )(.*)@$h{'error'}$1$h{'Standard'}@;
1783         $c =~ s@(?!<=\\)($delimiter)@$h{'pcrs-delimiter'}$1$h{'Standard'}@g; # XXX: Too aggressive
1784         #$c =~ s@(?!<=\\)($1)@$h{'pcrs-delimiter'}$1$h{'Standard'}@g;
1785     }
1786
1787     return $c;
1788 }
1789
1790 sub handle_loglevel_force ($) {
1791
1792     my $c = shift;
1793
1794     if ($c =~ m/^Ignored force prefix in request:/) {
1795
1796         # Ignored force prefix in request: "GET http://10.0.0.1/PRIVOXY-FORCE/block HTTP/1.1"
1797         $c =~ s@^(Ignored)@$h{'ignored'}$1$h{'Standard'}@;
1798         $c = highlight_matched_request_line($c, '(?<=request: ")[^"]*');
1799
1800     } elsif ($c =~ m/^Enforcing request:/) {
1801
1802         # Enforcing request: "GET http://10.0.0.1/block HTTP/1.1".
1803         $c = highlight_matched_request_line($c, '(?<=request: ")[^"]*');
1804
1805     } else {
1806
1807         found_unknown_content($c);
1808
1809     }
1810
1811     return $c;
1812 }
1813
1814 sub handle_loglevel_error ($) {
1815
1816     my $c = shift;
1817
1818     if ($c =~ m/^Empty server or forwarder response received on socket \d+./) {
1819
1820         # Empty server or forwarder response received on socket 4.
1821         # Empty server or forwarder response received on socket 3. \
1822         #  Closing client socket 15 without sending data.
1823         $c =~ s@(?<=on socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1824         $c =~ s@(?<=client socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1825     }
1826     # XXX: There are probably more messages that deserve highlighting.
1827
1828     return $c;
1829 }
1830
1831
1832 sub handle_loglevel_ignore ($) {
1833     return shift;
1834 }
1835
1836 sub gather_loglevel_request_stats ($$) {
1837     my $c = shift;
1838     my $thread = shift;
1839     our %stats;
1840
1841     $stats{requests}++;
1842 }
1843
1844 sub gather_loglevel_crunch_stats ($$) {
1845     my $c = shift;
1846     my $thread = shift;
1847     our %stats;
1848
1849     $stats{requests}++;
1850     $stats{crunches}++;
1851 }
1852
1853
1854 sub gather_loglevel_error_stats ($$) {
1855
1856     my $c = shift;
1857     my $thread = shift;
1858     our %stats;
1859     our %thread_data;
1860
1861     if ($c =~ m/^Empty server or forwarder response received on socket \d+./) {
1862
1863         # Empty server or forwarder response received on socket 4.
1864         $stats{'empty-responses'}++;
1865         if ($thread_data{$thread}{'new_connection'}) {
1866             $stats{'empty-responses-on-new-connections'}++;
1867         } else {
1868             $stats{'empty-responses-on-reused-connections'}++;
1869         }
1870     }
1871 }
1872
1873 sub gather_loglevel_connect_stats ($$) {
1874
1875     my ($c, $thread) = @_;
1876     our %thread_data;
1877     our %stats;
1878
1879     if ($c =~ m/^via ([^\s]+) to: [^\s]+/) {
1880
1881         # Connect: via 10.0.0.1:8123 to: www.example.org.noconnect
1882         $thread_data{$thread}{'forwarder'} = $1; # XXX: is this missue?
1883
1884     } elsif ($c =~ m/^to ([^\s]*)$/) {
1885
1886         # Connect: to lists.sourceforge.net:443
1887
1888         $thread_data{$thread}{'forwarder'} = 'direct connection';
1889
1890     } elsif ($c =~ m/^Created new connection to/) {
1891
1892         # Created new connection to www.privoxy.org:80 on socket 11.
1893
1894         $thread_data{$thread}{'new_connection'} = 1;
1895
1896     } elsif ($c =~ m/^Reusing server socket \d./ or
1897              $c =~ m/^Found reusable socket/) {
1898
1899         # Reusing server socket 4. Opened for 10.0.0.1.
1900         # Found reusable socket 9 for www.privoxy.org:80 in slot 0.
1901
1902         $thread_data{$thread}{'new_connection'} = 0;
1903         $stats{'reused-connections'}++;
1904     }
1905 }
1906
1907 sub gather_loglevel_header_stats ($$) {
1908
1909     my ($c, $thread) = @_;
1910     our %stats;
1911
1912     if ($c =~ m/^A HTTP\/1\.1 response without/ or
1913         $c =~ m/^Keeping the server header 'Connection: keep-alive' around./)
1914     {
1915         # A HTTP/1.1 response without Connection header implies keep-alive.
1916         # Keeping the server header 'Connection: keep-alive' around.
1917         $stats{'server-keep-alive'}++;
1918     }
1919 }
1920
1921 sub init_stats () {
1922     our %stats = (
1923         requests => 0,
1924         crunches => 0,
1925         'server-keep-alive' => 0,
1926         'reused-connections' => 0,
1927         'empty-responses' => 0,
1928         'empty-responses-on-new-connections' => 0,
1929         'empty-responses-on-reused-connections' => 0,
1930         );
1931 }
1932
1933 sub get_percentage ($$) {
1934     my $big = shift;
1935     my $small = shift;
1936     return "NaN" if ($big eq 0);
1937     return sprintf("%.2f%%", $small / $big * 100);
1938 }
1939
1940 sub print_stats () {
1941
1942     our %stats;
1943     my $new_connections = $stats{requests} - $stats{crunches} - $stats{'reused-connections'};
1944     my $outgoing_requests = $stats{requests} - $stats{crunches};
1945
1946     if ($stats{requests} eq 0) {
1947         print "No requests yet.\n";
1948         return;
1949     }
1950
1951     print "Client requests total: " . $stats{requests} . "\n";
1952     print "Crunches: " . $stats{crunches} . " (" .
1953         get_percentage($stats{requests}, $stats{crunches}) . ")\n";
1954     print "Outgoing requests: " . $outgoing_requests . " (" .
1955         get_percentage($stats{requests}, $outgoing_requests) . ")\n";
1956     print "Server keep-alive offers: " . $stats{'server-keep-alive'} . " (" .
1957         get_percentage($stats{requests}, $stats{'server-keep-alive'}) . ")\n";
1958     print "New outgoing connections: " . $new_connections . " (" .
1959         get_percentage($stats{requests}, $new_connections) . ")\n";
1960     print "Reused connections: " . $stats{'reused-connections'} . " (" .
1961         get_percentage($stats{requests}, $stats{'reused-connections'}) . ")\n";
1962     print "Empty responses: " . $stats{'empty-responses'} . " (" .
1963         get_percentage($stats{requests}, $stats{'empty-responses'}) . ")\n";
1964     print "Empty responses on new connections: "
1965          . $stats{'empty-responses-on-new-connections'} . " (" .
1966         get_percentage($stats{requests}, $stats{'empty-responses-on-new-connections'})
1967         . ")\n";
1968     print "Empty responses on reused connections: " .
1969         $stats{'empty-responses-on-reused-connections'} . " (" .
1970         get_percentage($stats{requests}, $stats{'empty-responses-on-reused-connections'}) .
1971         ")\n";
1972 }
1973
1974
1975 ################################################################################
1976 # Functions that actually print stuff
1977 ################################################################################
1978
1979 sub print_clf_message () {
1980
1981     our ($ip, $timestamp, $request_line, $status_code, $size);
1982     my $output = '';
1983
1984     return if DEBUG_SUPPRESS_LOG_MESSAGES;
1985
1986     # Rebuild highlighted
1987     $output .= $h{'Number'} . $ip . $h{'Standard'};
1988     $output .= " - - ";
1989     $output .= "[" . $h{'Timestamp'} . $timestamp . $h{'Standard'} . "]";
1990     $output .= " ";
1991     $output .= "\"" . highlight_request_line("$request_line") . "\"";
1992     $output .= " ";
1993     $output .= $h{'Status'} . $status_code . $h{'Standard'};
1994     $output .= " ";
1995     $output .= $h{'Number'} . $size . $h{'Standard'};
1996     $output .= $line_end;
1997
1998     print $output;
1999 }
2000
2001 sub print_non_clf_message ($) {
2002
2003     my $content = shift;
2004     my $msec_string = "." . $req{$t}{'msecs'} unless $no_msecs_mode;
2005     my $line_start = $html_output_mode ? '' : $h{"Standard"};
2006
2007     return if DEBUG_SUPPRESS_LOG_MESSAGES;
2008
2009     print $line_start
2010         . $time_colours[$time_colour_index % 2]
2011         . $req{$t}{'time-stamp'}
2012         . $msec_string
2013         . $h{Standard} . " "
2014         . $thread_colours{$t}
2015         . $t
2016         . $h{Standard}
2017         . " "
2018         . $h{$req{$t}{'log-level'}}
2019         . $req{$t}{'log-level'}
2020         . $h{Standard}
2021         . ": "
2022         . $content
2023         . $line_end;
2024 }
2025
2026 sub parse_loop () {
2027
2028     my ($day, $time_stamp, $thread, $log_level, $content, $c, $msecs);
2029     my $last_msecs  = 0;
2030     my $last_thread = 0;
2031     my $last_timestamp = 0;
2032     my $filters_that_did_nothing;
2033     my $key;
2034     my $time_colour;
2035     $time_colour = paint_it('white');
2036
2037     my %log_level_handlers = (
2038         'Re-Filter'         => \&handle_loglevel_re_filter,
2039         'Header'            => \&handle_loglevel_header,
2040         'Connect'           => \&handle_loglevel_connect,
2041         'Redirect'          => \&handle_loglevel_redirect,
2042         'Request'           => \&handle_loglevel_request,
2043         'Crunch'            => \&handle_loglevel_crunch,
2044         'Gif-Deanimate'     => \&handle_loglevel_gif_deanimate,
2045         'Info'              => \&handle_loglevel_info,
2046         'CGI'               => \&handle_loglevel_cgi,
2047         'Force'             => \&handle_loglevel_force,
2048         'Error'             => \&handle_loglevel_error,
2049         'Fatal error'       => \&handle_loglevel_ignore,
2050         'Writing'           => \&handle_loglevel_ignore,
2051         'Unknown log level' => \&handle_loglevel_ignore,
2052     );
2053
2054     while (<>) {
2055
2056         if (m/^(\w{3} \d{2}) (\d\d:\d\d:\d\d)\.?(\d+)? (?:Privoxy\()?([^\)\s]*)[\)]? ([\w -]*): (.*?)\r?$/) {
2057             $thread = $t = $4;
2058             $req{$t}{'day'} = $day = $1;
2059             $req{$t}{'time-stamp'} = $time_stamp = $2;
2060             $req{$t}{'msecs'} = $msecs = $3 ? $3 : 0; # Only the cool kids have micro second resolution;
2061             $req{$t}{'log-level'} = $log_level = $5;
2062             $req{$t}{'content'} = $content = $c = $6;
2063             $req{$t}{'log-message'} = $_;
2064             $no_special_header_highlighting = 0;
2065
2066             if (defined($log_level_handlers{$log_level})) {
2067
2068                 $content = $log_level_handlers{$log_level}($content);
2069
2070             } else {
2071
2072                 die "No handler found for log level \"$log_level\"\n";
2073             }
2074
2075             # Highlight Truncations
2076             if (length($_) > 4000) {
2077                 $content =~ s@(too long, truncated)]$@$h{'Truncation'}$1$h{'Standard'}]@g;
2078             }
2079
2080             next unless $content;
2081
2082             # Register threads to keep the colour constant
2083             if (!defined($thread_colours{$thread})) {
2084                 $thread_colours{$thread} = $all_colours[$thread_colour_index % @all_colours];
2085                 $thread_colour_index++;
2086             }
2087
2088             # Switch timestamp colour if timestamps differ
2089             if (($msecs ne $last_msecs) || ($time_stamp ne $last_timestamp)) {
2090                debug_message("Tick tack!") if DEBUG_TICKS;
2091                $time_colour = $time_colours[$time_colour_index % 2];
2092                $time_colour_index++;
2093                $last_msecs = $msecs;
2094                $last_timestamp = $time_stamp;
2095             }
2096
2097             $last_thread = $thread;
2098
2099             print_non_clf_message($content);
2100
2101         } elsif (m/^((?:\d+\.\d+\.\d+\.\d+|[:\d]+)) - - \[(.*)\] "(.*)" (\d+) (\d+)/) {
2102
2103             # LOG_LEVEL_CLF lines look like this
2104             # 61.152.239.32 - - [04/Mar/2007:18:28:23 +0100] "GET \
2105             #  http://ad.yieldmanager.com/imp?z=1&Z=120x600&s=109339&u=http%3A%2F%2Fwww.365loan.co.uk%2F&r=1\
2106             #  HTTP/1.1" 403 1730
2107             our ($ip, $timestamp, $request_line, $status_code, $size) = ($1, $2, $3, $4, $5);
2108
2109             print_clf_message();
2110
2111         } else {
2112
2113             # Some Privoxy log messages span more than one line,
2114             # usually to dump lots of content that doesn't need any syntax highlighting.
2115             # XXX: add mechanism to forward these lines to the right handler anyway.
2116             chomp();
2117             unless (DEBUG_SUPPRESS_LOG_MESSAGES or (SUPPRESS_EMPTY_LINES and m/^\s+$/)) {
2118                 print and print get_line_end(); # unless (SUPPRESS_EMPTY_LINES and m/^\s+$/);
2119             }
2120         }
2121     }
2122 }
2123
2124 sub stats_loop () {
2125
2126     my ($day, $time_stamp, $msecs, $thread, $log_level, $content);
2127     my %log_level_handlers = (
2128          'Re-Filter'         => \&handle_loglevel_ignore,
2129          'Header'            => \&gather_loglevel_header_stats,
2130          'Connect'           => \&gather_loglevel_connect_stats,
2131          'Redirect'          => \&handle_loglevel_ignore,
2132          'Request'           => \&gather_loglevel_request_stats,
2133          'Crunch'            => \&gather_loglevel_crunch_stats,
2134          'Gif-Deanimate'     => \&handle_loglevel_ignore,
2135          'Info'              => \&handle_loglevel_ignore,
2136          'CGI'               => \&handle_loglevel_ignore,
2137          'Force'             => \&handle_loglevel_ignore,
2138          'Error'             => \&gather_loglevel_error_stats,
2139          'Fatal error'       => \&handle_loglevel_ignore,
2140          'Writing'           => \&handle_loglevel_ignore,
2141          'Unknown log level' => \&handle_loglevel_ignore
2142     );
2143
2144     while (<>) {
2145         if (m/^(\w{3} \d{2}) (\d\d:\d\d:\d\d)\.?(\d+)? (?:Privoxy\()?([^\)\s]*)[\)]? ([\w -]*): (.*?)\r?$/) {
2146             $day = $1;
2147             $time_stamp = $2;
2148             $msecs = $3 ? $3 : 0;
2149             $thread = $4;
2150             $log_level = $5;
2151             $content = $6;
2152
2153             if (defined($log_level_handlers{$log_level})) {
2154
2155                 $content = $log_level_handlers{$log_level}($content, $thread);
2156
2157             } else {
2158
2159                 die "No handler found for log level \"$log_level\"\n";
2160
2161             }
2162         }
2163     }
2164
2165     print_stats();
2166
2167 }
2168
2169 sub VersionMessage {
2170     my $version_message;
2171
2172     $version_message .= 'Privoxy-Log-Parser ' . PRIVOXY_LOG_PARSER_VERSION  . "\n";
2173     $version_message .= 'Copyright (C) 2007-2009 Fabian Keil <fk@fabiankeil.de>' . "\n";
2174     $version_message .= 'http://www.fabiankeil.de/sourcecode/privoxy-log-parser/' . "\n";
2175
2176     print $version_message;
2177 }
2178
2179 sub get_cli_options () {
2180
2181     our %cli_options = (
2182         'html-output'              => CLI_OPTION_DEFAULT_TO_HTML_OUTPUT,
2183         'title'                    => CLI_OPTION_TITLE,
2184         'no-syntax-highlighting'   => CLI_OPTION_NO_SYNTAX_HIGHLIGHTING,
2185         'no-embedded-css'          => CLI_OPTION_NO_EMBEDDED_CSS,
2186         'no-msecs'                 => CLI_OPTION_NO_MSECS,
2187         'show-ineffective-filters' => CLI_OPTION_SHOW_INEFFECTIVE_FILTERS,
2188         'accept-unknown-messages'  => CLI_OPTION_ACCEPT_UNKNOWN_MESSAGES,
2189         'statistics'               => CLI_OPTION_STATISTICS,
2190     );
2191
2192     GetOptions (
2193         'html-output'              => \$cli_options{'html-output'},
2194         'title'                    => \$cli_options{'title'},
2195         'no-syntax-highlighting'   => \$cli_options{'no-syntax-highlighting'},
2196         'no-embedded-css'          => \$cli_options{'no-embedded-css'},
2197         'no-msecs'                 => \$cli_options{'no-msecs'},
2198         'show-ineffective-filters' => \$cli_options{'show-ineffective-filters'},
2199         'accept-unknown-messages'  => \$cli_options{'accept-unknown-messages'},
2200         'statistics'               => \$cli_options{'statistics'},
2201         'version'                  => sub { VersionMessage && exit(0) },
2202         'help'                     => \&help,
2203    ) or exit(1);
2204
2205    $html_output_mode = cli_option_is_set('html-output');
2206    $no_msecs_mode = cli_option_is_set('no-msecs');
2207    $line_end = get_line_end();
2208 }
2209
2210 sub help () {
2211
2212     our %cli_options;
2213
2214     VersionMessage();
2215
2216     print << "    EOF"
2217
2218 Options and their default values if they have any:
2219     [--accept-unknown-messages]
2220     [--html-output]
2221     [--no-embedded-css]
2222     [--no-msecs]
2223     [--no-syntax-highlighting]
2224     [--show-ineffective-filters]
2225     [--statistics]
2226     [--title $cli_options{'title'}]
2227     [--version]
2228 see "perldoc $0" for more information
2229     EOF
2230     ;
2231     exit(0);
2232 }
2233
2234 ################################################################################
2235 # main
2236 ################################################################################
2237 sub main () {
2238
2239     get_cli_options();
2240     set_background(DEFAULT_BACKGROUND);
2241     prepare_our_stuff();
2242
2243     print_intro();
2244
2245     if (cli_option_is_set('statistics')) {
2246         stats_loop();
2247     } else {
2248         parse_loop();
2249     }
2250
2251     print_outro();
2252 }
2253
2254 main();
2255
2256 =head1 NAME
2257
2258 B<privoxy-log-parser> - A parser and syntax-highlighter for Privoxy log messages
2259
2260 =head1 SYNOPSIS
2261
2262 B<privoxy-log-parser> [B<--accept-unknown-messages>] [B<--html-output>]
2263 [B<--no-msecs>] [B<--no-syntax-higlighting>] [B<--show-ineffective-filters>]
2264 [B<--version>]
2265
2266 =head1 DESCRIPTION
2267
2268 B<privoxy-log-parser> reads Privoxy log messages and
2269
2270 - syntax-highlights recognized lines,
2271
2272 - reformats some of them for easier comprehension,
2273
2274 - filters out less useful messages, and
2275
2276 - (in some cases) calculates additional information,
2277   like the compression ratio or how a filter affected
2278   the content size.
2279
2280 With B<privoxy-log-parser> you should be able to increase Privoxy's log level
2281 without getting confused by the resulting amount of output. For example for
2282 "debug 64" B<privoxy-log-parser> will (by default) only show messages that
2283 affect the content. If a filter doesn't cause any hits, B<privoxy-log-parser>
2284 will hide the "filter foo caused 0 hits" message.
2285
2286 =head1 OPTIONS
2287
2288 [B<--accept-unknown-messages>] Don't print warnings in case of unknown messages,
2289 just don't highlight them.
2290
2291 [B<--html-output>] Use HTML and CSS for the syntax highlighting. If this option is
2292 omitted, ANSI escape sequences are used unless B<--no-syntax-highlighting> is active.
2293 This option is only intended to make embedding log excerpts in web pages easier.
2294 It does not escape any input!
2295
2296 [B<--no-msecs>] Don't expect milisecond resolution
2297
2298 [B<--no-syntax-highlighting>] Disable syntax-highlighting. Useful when
2299 the filtered output is piped into less in which case the ANSI control
2300 codes don't work, or if the terminal itself doesn't support the control
2301 codes.
2302
2303 [B<--show-ineffective-filters>] Don't suppress log lines for filters
2304 that didn't modify the content.
2305
2306 [B<--statistics>] Gather various statistics instead of syntax highlighting
2307 log messages. This is an experimental feature, if the results look wrong
2308 they very well might be. Also note that the results a pretty much guaranteed
2309 to be incorrect if Privoxy and Privoxy-Log-Parser aren't in sync.
2310
2311 [B<--version>] Print version and exit.
2312
2313 =head1 EXAMPLES
2314
2315 To monitor a log file:
2316
2317 tail -F /usr/jails/privoxy-jail/var/log/privoxy/privoxy.log | B<privoxy-log-parser>
2318
2319 Replace '-F' with '-f' if your tail implementation lacks '-F' support
2320 or if the log won't get rotated anyway. The log file location depends
2321 on your system (Doh!).
2322
2323 To monitor Privoxy without having it write to a log file:
2324
2325 privoxy --no-daemon /usr/jails/privoxy-jail/usr/local/etc/privoxy/config 2>&1 | B<privoxy-log-parser>
2326
2327 Again, the config file location depends on your system. Output redirection
2328 depends on your shell, the above works with bourne shells.
2329
2330 To read a processed Privoxy log file from top to bottom, letting the content
2331 scroll by slightly faster than you can read:
2332
2333 B<privoxy-log-parser> < /usr/jails/privoxy-jail/var/log/privoxy/privoxy.log
2334
2335 This is probably only useful to fill screens in the background of haxor movies.
2336
2337 =head1 CAVEATS
2338
2339 Syntax highlighting with ANSI escape sequences will look strange
2340 if your background color isn't black.
2341
2342 Some messages aren't recognized yet and will not be fully highlighted.
2343
2344 B<privoxy-log-parser> is developed with Privoxy 3.0.7 or later in mind,
2345 using earlier Privoxy versions will probably result in an increased amount
2346 of unrecognized log lines.
2347
2348 Privoxy's log files tend to be rather large. If you use HTML
2349 highlighting some browsers can't handle them, get confused and
2350 will eventually crash because of segmentation faults or unexpected
2351 exceptions. This is a problem in the browser and not B<privoxy-log-parser>'s
2352 fault.
2353
2354 =head1 BUGS
2355
2356 Many settings can't be controlled through command line options yet.
2357
2358 =head1 SEE ALSO
2359
2360 privoxy(1)
2361
2362 =head1 AUTHOR
2363
2364 Fabian Keil <fk@fabiankeil.de>
2365
2366 =cut