tools/privoxy-log-parser.pl

   1 #!/usr/bin/perl
   2
   3 ################################################################################
   4 # privoxy-log-parser
   5 #
   6 # A parser for Privoxy log messages. For incomplete documentation run
   7 # perldoc privoxy-log-parser(.pl), for fancy screenshots see:
   8 #
   9 # http://www.fabiankeil.de/sourcecode/privoxy-log-parser/
  10 #
  11 # $Id: privoxy-log-parser.pl,v 1.216 2009/12/30 15:15:08 fk Exp $
  12 #
  13 # TODO:
  14 #       - LOG_LEVEL_CGI, LOG_LEVEL_ERROR, LOG_LEVEL_WRITE content highlighting
  15 #       - create fancy statistics
  16 #       - grep through Privoxy sources to find unsupported log messages
  17 #       - hunt down substitutions that match content from variables which
  18 #         can contain stuff like ()?'[]
  19 #       - replace $h{'foo'} with h('foo') where possible
  20 #       - hunt down XXX comments instead of just creating them
  21 #       - add example log lines for every regex and mark them up for
  22 #         regression testing
  23 #       - Handle incomplete input without Perl warning about undefined variables.
  24 #       - Use generic highlighting function that takes a regex and the
  25 #         hash key as input.
  26 #
  27 # Copyright (c) 2007-2009 Fabian Keil <fk@fabiankeil.de>
  28 #
  29 # Permission to use, copy, modify, and distribute this software for any
  30 # purpose with or without fee is hereby granted, provided that the above
  31 # copyright notice and this permission notice appear in all copies.
  32 #
  33 # THE SOFTWARE IS PROVIDED "AS IS" AND THE AUTHOR DISCLAIMS ALL WARRANTIES
  34 # WITH REGARD TO THIS SOFTWARE INCLUDING ALL IMPLIED WARRANTIES OF
  35 # MERCHANTABILITY AND FITNESS. IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR
  36 # ANY SPECIAL, DIRECT, INDIRECT, OR CONSEQUENTIAL DAMAGES OR ANY DAMAGES
  37 # WHATSOEVER RESULTING FROM LOSS OF USE, DATA OR PROFITS, WHETHER IN AN
  38 # ACTION OF CONTRACT, NEGLIGENCE OR OTHER TORTIOUS ACTION, ARISING OUT OF
  39 # OR IN CONNECTION WITH THE USE OR PERFORMANCE OF THIS SOFTWARE.
  40 ################################################################################
  41
  42 use strict;
  43 use warnings;
  44 use Getopt::Long;
  45
  46 use constant {
  47     PRIVOXY_LOG_PARSER_VERSION => '0.5',
  48     # Feel free to mess with these ...
  49     DEFAULT_BACKGROUND => 'black',  # Choose registered colour (like 'black')
  50     DEFAULT_TEXT_COLOUR => 'white', # Choose registered colour (like 'black')
  51     HEADER_DEFAULT_COLOUR => 'yellow',
  52     REGISTER_HEADERS_WITH_THE_SAME_COLOUR => 1,
  53
  54     CLI_OPTION_DEFAULT_TO_HTML_OUTPUT => 0,
  55     CLI_OPTION_TITLE => 'Privoxy-Log-Parser in da house',
  56     CLI_OPTION_NO_EMBEDDED_CSS => 0,
  57     CLI_OPTION_NO_MSECS => 0,
  58     CLI_OPTION_NO_SYNTAX_HIGHLIGHTING => 0,
  59     CLI_OPTION_ERROR_LOG_FILE => '/var/log/privoxy-log.log',
  60     CLI_OPTION_SHOW_INEFFECTIVE_FILTERS => 0,
  61     CLI_OPTION_ACCEPT_UNKNOWN_MESSAGES => 0,
  62     CLI_OPTION_STATISTICS => 0,
  63
  64     SUPPRESS_SUCCEEDED_FILTER_ADDITIONS => 1,
  65     SHOW_SCAN_INTRO => 0,
  66     SHOW_FILTER_READIN_IN => 0,
  67     SUPPRESS_EMPTY_LINES => 1,
  68     SUPPRESS_SUCCESSFUL_CONNECTIONS => 1,
  69     SUPPRESS_ACCEPTED_CONNECTIONS => 1,
  70     SUPPRESS_GIF_NOT_CHANGED => 1,
  71     SUPPRESS_NEED_TO_DE_CHUNK_FIRST => 1,
  72
  73     DEBUG_HEADER_REGISTERING => 0,
  74     DEBUG_HEADER_HIGHLIGHTING => 0,
  75     DEBUG_TICKS => 0,
  76     DEBUG_PAINT_IT => 0,
  77     DEBUG_SUPPRESS_LOG_MESSAGES => 0,
  78
  79     PUNISH_MISSING_LOG_KNOWLEDGE_WITH_DEATH => 0,
  80     PUNISH_MISSING_HIGHLIGHT_KNOWLEDGE_WITH_DEATH => 1,
  81
  82     LOG_UNPARSED_LINES_TO_EXTRA_FILE => 0,
  83
  84     # You better leave these alone unless you know what you're doing.
  85     COLOUR_RESET      => "\033[0;0m",
  86     ESCAPE => "\033[",
  87 };
  88
  89 # For performance reasons, these are global.
  90
  91 my $t;
  92 my %req; # request data from previous lines
  93 my %h;
  94 my %thread_colours;
  95 my @all_colours;
  96 my @time_colours;
  97 my $thread_colour_index = 0;
  98 my $header_colour_index = 0;
  99 my $time_colour_index = 0;
 100 my %header_colours;
 101 my $no_special_header_highlighting;
 102 my %reason_colours;
 103 my %h_colours;
 104 my $header_highlight_regex = '';
 105
 106 my $html_output_mode;
 107 my $no_msecs_mode; # XXX: should probably be removed
 108 my $line_end;
 109
 110 sub prepare_our_stuff () {
 111
 112     # Syntax Higlight hash
 113     @all_colours = (
 114         'red', 'green', 'brown', 'blue', 'purple', 'cyan',
 115         'light_gray', 'light_red', 'light_green', 'yellow',
 116         'light_blue', 'pink', 'light_cyan', 'white'
 117     );
 118
 119     %h = (
 120         # LOG_LEVEL
 121         Info            => 'blue',
 122         Header          => 'green',
 123         Filter          => 'purple', # XXX: Used?
 124         'Re-Filter'     => 'purple',
 125         Connect         => 'brown',
 126         Request         => 'light_cyan',
 127         CGI             => 'light_green',
 128         Redirect        => 'cyan',
 129         Error           => 'light_red',
 130         Crunch          => 'cyan',
 131         'Fatal error'   => 'light_red',
 132         'Gif-Deanimate' => 'blue',
 133         Force           => 'red',
 134         Writing         => 'light_green',
 135         # ----------------------
 136         URL                  => 'yellow',
 137         path                 => 'brown',
 138         request_             => 'brown', # host+path but no protocol
 139         'ip-address'         => 'yellow',
 140         Number               => 'yellow',
 141         Standard             => 'reset',
 142         Truncation           => 'light_red',
 143         Status               => 'brown',
 144         Timestamp            => 'brown',
 145         Crunching            => 'light_red',
 146         crunched             => 'light_red',
 147         'Request-Line'       => 'pink',
 148         method               => 'purple',
 149         destination          => 'yellow',
 150         'http-version'       => 'pink',
 151         'crunch-pattern'     => 'pink',
 152         not                  => 'brown',
 153         file                 => 'brown',
 154         signal               => 'yellow',
 155         version              => 'green',
 156         'program-name'       => 'cyan',
 157         port                 => 'red',
 158         host                 => 'red',
 159         warning              => 'light_red',
 160         debug                => 'light_red',
 161         filter               => 'green',
 162         tag                  => 'green',
 163         tagger               => 'green',
 164         'status-message'     => 'light_cyan',
 165         'status-code'        => 'yellow',
 166         'invalid-request'    => 'light_red',
 167         'hits'               => 'yellow',
 168         error                => 'light_red',
 169         'rewritten-URL'      => 'light_red',
 170         'pcrs-delimiter'     => 'light_red',
 171         'ignored'            => 'light_red',
 172         'action-bits-update' => 'light_red',
 173         'configuration-line' => 'red',
 174         'content-type'       => 'yellow',
 175     );
 176
 177     %h_colours = %h;
 178
 179     # Header colours need their own hash so the keys can be accessed properly
 180     %header_colours = (
 181         # Prefilled with headers that should not appear with default header colours
 182         Cookie => 'light_red',
 183         'Set-Cookie' => 'light_red',
 184         Warning => 'light_red',
 185         Default => HEADER_DEFAULT_COLOUR,
 186     );
 187
 188     # Crunch reasons need their own hash as well
 189     %reason_colours = (
 190         'Unsupported HTTP feature'               => 'light_red',
 191         Blocked                                  => 'light_red',
 192         Untrusted                                => 'light_red',
 193         Redirected                               => 'green',
 194         'CGI Call'                               => 'white',
 195         'DNS failure'                            => 'red',
 196         'Forwarding failed'                      => 'light_red',
 197         'Connection failure'                     => 'light_red',
 198         'Out of memory (may mask other reasons)' => 'light_red',
 199         'No reason recorded'                     => 'light_red',
 200     );
 201
 202     @time_colours = ('white', 'light_gray');
 203
 204     # Translate highlight strings into highlight code
 205     prepare_highlight_hash(\%header_colours);
 206     prepare_highlight_hash(\%reason_colours);
 207     prepare_highlight_hash(\%h);
 208     prepare_colour_array(\@all_colours);
 209     prepare_colour_array(\@time_colours);
 210     init_css_colours();
 211
 212     init_stats();
 213 }
 214
 215 sub paint_it ($) {
 216 ###############################################################
 217 # Takes a colour string and returns an ANSI escape sequence
 218 # (unless --no-syntax-highlighting is used).
 219 # XXX: The Rolling Stones reference has to go.
 220 ###############################################################
 221
 222     my $colour = shift @_;
 223
 224     return "" if cli_option_is_set('no-syntax-highlighting');
 225
 226     my %light = (
 227         black       => 0,
 228         red         => 0,
 229         green       => 0,
 230         brown       => 0,
 231         blue        => 0,
 232         purple      => 0,
 233         cyan        => 0,
 234         light_gray  => 0,
 235         gray        => 0,
 236         dark_gray   => 1,
 237         light_red   => 1,
 238         light_green => 1,
 239         yellow      => 1,
 240         light_blue  => 1,
 241         pink        => 1,
 242         light_cyan  => 1,
 243         white       => 1,
 244     );
 245
 246     my %text = (
 247         black       => 30,
 248         red         => 31,
 249         green       => 32,
 250         brown       => 33,
 251         blue        => 34,
 252         purple      => 35,
 253         cyan        => 36,
 254         gray        => 37,
 255         light_gray  => 37,
 256         dark_gray   => 30,
 257         light_red   => 31,
 258         light_green => 32,
 259         yellow      => 33,
 260         light_blue  => 34,
 261         pink        => 35,
 262         light_cyan  => 36,
 263         white       => 37,
 264     );
 265
 266     my $bg_code = get_background();
 267     my $colour_code;
 268     our $default = default_colours();
 269
 270     if (defined($text{$colour})) {
 271         $colour_code  = ESCAPE;
 272         $colour_code .= $text{$colour};
 273         $colour_code .= ";";
 274         $colour_code .= $light{$colour} ? "1" : "2";
 275         $colour_code .= ";";
 276         $colour_code .= $bg_code;
 277         $colour_code .= "m";
 278         debug_message $colour . " is \'" . $colour_code . $colour . $default . "\'" if DEBUG_PAINT_IT;
 279
 280     } elsif ($colour =~ /reset/) {
 281
 282         $colour_code = default_colours();
 283
 284     } else {
 285
 286         die "What's $colour supposed to mean?\n";
 287     }
 288
 289     return $colour_code;
 290 }
 291
 292 sub get_semantic_html_markup ($) {
 293 ###############################################################
 294 # Takes a string and returns a span element
 295 ###############################################################
 296
 297     my $type = shift @_;
 298     my $code;
 299
 300     if ($type =~ /Standard/) {
 301         $code = '</span>';
 302     } else {
 303         $type = lc($type);
 304         $code = '<span title="' . $type . '" class="' . $type . '">';
 305     }
 306
 307     return $code;
 308 }
 309
 310 sub cli_option_is_set ($) {
 311
 312     our %cli_options;
 313     my $cli_option = shift;
 314
 315     die "Unknown CLI option: $cli_option" unless defined $cli_options{$cli_option};
 316
 317     return $cli_options{$cli_option};
 318 }
 319
 320 sub get_html_title () {
 321
 322     our %cli_options;
 323     return $cli_options{'title'};
 324
 325 }
 326
 327 sub init_css_colours() {
 328
 329     our %css_colours = (
 330         black       => "000",
 331         red         => "F00",
 332         green       => "0F0",
 333         brown       => "C90",
 334         blue        => "0F0",
 335         purple      => "F06", # XXX: wrong
 336         cyan        => "F09", # XXX: wrong
 337         light_gray  => "999",
 338         gray        => "333",
 339         dark_gray   => "222",
 340         light_red   => "F33",
 341         light_green => "33F",
 342         yellow      => "FF0",
 343         light_blue  => "30F",
 344         pink        => "F0F",
 345         light_cyan  => "66F",
 346         white       => "FFF",
 347     );
 348 }
 349
 350 sub get_css_colour ($) {
 351
 352    our %css_colours;
 353    my $colour = shift;
 354
 355    die "What's $colour supposed to mean?\n" unless defined($css_colours{$colour});
 356
 357    return '#' . $css_colours{$colour};
 358 }
 359
 360 sub get_css_line ($) {
 361
 362     my $class = shift;
 363     my $css_line;
 364
 365     $css_line .= '.' . lc($class) . ' {'; # XXX: lc() shouldn't be necessary
 366     die "What's $class supposed to mean?\n" unless defined($h_colours{$class});
 367     $css_line .= 'color:' . get_css_colour($h_colours{$class}) . ';';
 368     $css_line .= 'background-color:' . get_css_colour(DEFAULT_BACKGROUND) . ';';
 369     $css_line .= '}' . "\n";
 370
 371     return $css_line;
 372 }
 373
 374 sub get_css_line_for_colour ($) {
 375
 376     my $colour = shift;
 377     my $css_line;
 378
 379     $css_line .= '.' . lc($colour) . ' {'; # XXX: lc() shouldn't be necessary
 380     $css_line .= 'color:' . get_css_colour($colour) . ';';
 381     $css_line .= 'background-color:' . get_css_colour(DEFAULT_BACKGROUND) . ';';
 382     $css_line .= '}' . "\n";
 383
 384     return $css_line;
 385 }
 386
 387 # XXX: Wrong solution
 388 sub get_missing_css_lines () {
 389
 390     my $css_line;
 391
 392     $css_line .= '.' . 'default' . ' {';
 393     $css_line .= 'color:' . HEADER_DEFAULT_COLOUR . ';';
 394     $css_line .= 'background-color:' . get_css_colour(DEFAULT_BACKGROUND) . ';';
 395     $css_line .= '}' . "\n";
 396
 397     return $css_line;
 398 }
 399
 400 sub get_css () {
 401
 402     our %css_colours; #XXX: Wrong solution
 403
 404     my $css = '';
 405
 406     $css .= '.privoxy-log {';
 407     $css .= 'color:' . get_css_colour(DEFAULT_TEXT_COLOUR) . ';';
 408     $css .= 'background-color:' . get_css_colour(DEFAULT_BACKGROUND) . ';';
 409     $css .= '}' . "\n";
 410
 411     foreach my $key (keys %h_colours) {
 412
 413         next if ($h_colours{$key} =~ m/reset/); #XXX: Wrong solution.
 414         $css .= get_css_line($key);
 415
 416     }
 417
 418     foreach my $colour (keys %css_colours) {
 419
 420         $css .= get_css_line_for_colour($colour);
 421
 422     }
 423
 424     $css .= get_missing_css_lines(); #XXX: Wrong solution
 425
 426     return $css;
 427 }
 428
 429 sub print_intro () {
 430
 431     my $intro = '';
 432
 433     if (cli_option_is_set('html-output')) {
 434
 435         my $title = get_html_title();
 436
 437         $intro .= '<html><head>';
 438         $intro .= '<title>' . $title . '</title>';
 439         $intro .= '<style>' . get_css() . '</style>' unless cli_option_is_set('no-embedded-css');
 440         $intro .= '</head><body>';
 441         $intro .= '<h1>' . $title . '</h1><p class="privoxy-log">';
 442
 443         print $intro;
 444     }
 445 }
 446
 447 sub print_outro () {
 448
 449     my $outro = '';
 450
 451     if (cli_option_is_set('html-output')) {
 452
 453         $outro = '</p></body></html>';
 454         print $outro;
 455
 456     }
 457 }
 458
 459 sub get_line_end () {
 460     return cli_option_is_set('html-output') ? "<br>\n" : "\n";
 461 }
 462
 463 sub get_colour_html_markup ($) {
 464 ###############################################################
 465 # Takes a colour string a span element. XXX: WHAT?
 466 # XXX: This function shouldn't be necessary, the
 467 # markup should always be semantically correct.
 468 ###############################################################
 469
 470     my $type = shift @_;
 471     my $code;
 472
 473     if ($type =~ /Standard/) {
 474         $code = '</span>';
 475     } else {
 476         $code = '<span class="' . lc($type) . '">';
 477     }
 478
 479     return $code;
 480 }
 481
 482 sub default_colours () {
 483     # XXX: Properly
 484     our $bg_code;
 485     return reset_colours();
 486 }
 487
 488 sub show_colours () {
 489     # XXX: Implement
 490 }
 491
 492 sub reset_colours () {
 493     return ESCAPE . "0m";
 494 }
 495
 496 sub set_background ($){
 497
 498     my $colour = shift;
 499     our $bg_code;
 500     my %backgrounds = (
 501               black       => "40",
 502               red         => "41",
 503               green       => "42",
 504               brown       => "43",
 505               blue        => "44",
 506               magenta     => "45",
 507               cyan        => "46",
 508               white       => "47",
 509               default     => "49",
 510     );
 511
 512     if (defined($backgrounds{$colour})) {
 513         $bg_code = $backgrounds{$colour};
 514     } else {
 515         die "Invalid background colour: " . $colour;
 516     }
 517 }
 518
 519 sub get_background (){
 520     return our $bg_code;
 521 }
 522
 523 sub prepare_highlight_hash ($) {
 524     my $ref = shift;
 525
 526     foreach my $key (keys %$ref) {
 527         $$ref{$key} = $html_output_mode ?
 528             get_semantic_html_markup($key) :
 529             paint_it($$ref{$key});
 530     }
 531 }
 532
 533 sub prepare_colour_array ($) {
 534     my $ref = shift;
 535
 536     foreach my $i (0 ... @$ref - 1) {
 537         $$ref[$i] = $html_output_mode ?
 538             get_colour_html_markup($$ref[$i]) :
 539             paint_it($$ref[$i]);
 540     }
 541 }
 542
 543 sub found_unknown_content ($) {
 544
 545     my $unknown = shift;
 546     my $message;
 547
 548     return if cli_option_is_set('accept-unknown-messages');
 549
 550     return if ($unknown =~ /\[too long, truncated\]$/);
 551
 552     $message = "found_unknown_content: Don't know how to highlight: ";
 553     # Break line so the log file can later be parsed as Privoxy log file again
 554     $message .= '"' . $unknown . '"' . " in:\n";
 555     $message .= $req{$t}{'log-message'};
 556     debug_message($message);
 557     log_parse_error($req{$t}{'log-message'});
 558
 559     die "Unworthy content parser" if PUNISH_MISSING_LOG_KNOWLEDGE_WITH_DEATH;
 560 }
 561
 562 sub log_parse_error ($) {
 563
 564     my $message = shift;
 565
 566     if (LOG_UNPARSED_LINES_TO_EXTRA_FILE) {
 567         open(ERRORLOG, ">>" . ERROR_LOG_FILE) || die "Writing " . ERROR_LOG_FILE . " failed";
 568         print ERRORLOG $message;
 569         close(ERRORLOG);
 570     }
 571 }
 572
 573 sub debug_message (@) {
 574     my @message = @_;
 575
 576     print $h{'debug'} . "@message" . $h{'Standard'} . "\n";
 577 }
 578
 579 ################################################################################
 580 # highlighter functions that aren't loglevel-specific
 581 ################################################################################
 582
 583 sub h ($) {
 584
 585     # Get highlight marker
 586     my $highlight = shift; # XXX: Stupid name;
 587     my $result = '';
 588     my $message;
 589
 590     if (defined($highlight)) {
 591
 592         $result = $h{$highlight};
 593
 594     } else {
 595
 596         $message = "h: Don't recognize highlighter $highlight.";
 597         debug_message($message);
 598         log_parser_error($message);
 599         die "Unworthy highlighter function" if PUNISH_MISSING_HIGHLIGHT_KNOWLEDGE_WITH_DEATH;
 600     }
 601
 602     return $result;
 603 }
 604
 605 sub highlight_known_headers ($) {
 606
 607     my $content = shift;
 608
 609     debug_message("Searching $content for things to highlight.") if DEBUG_HEADER_HIGHLIGHTING;
 610
 611     if ($content =~ m/(?<=\s)($header_highlight_regex):/) {
 612         my $header = $1;
 613         $content =~ s@(?<=[\s|'])($header)(?=:)@$header_colours{$header}$1$h{'Standard'}@ig;
 614         debug_message("Highlighted '$header' in '$content'") if DEBUG_HEADER_HIGHLIGHTING;
 615     }
 616
 617     return $content;
 618 }
 619
 620 sub highlight_matched_request_line ($$) {
 621
 622     my $result = shift; # XXX: Stupid name;
 623     my $regex = shift;
 624     if ($result =~ m@(.*)($regex)(.*)@) {
 625         $result = $1 . highlight_request_line($2) . $3
 626     }
 627     return $result;
 628 }
 629
 630 sub highlight_request_line ($) {
 631
 632     my $rl = shift;
 633     my ($method, $url, $http_version);
 634
 635     #GET http://images.sourceforge.net/sfx/icon_warning.gif HTTP/1.1
 636     if ($rl =~ m/Invalid request/) {
 637
 638         $rl = h('invalid-request') . $rl . h('Standard');
 639
 640     } elsif ($rl =~ m/^([-\w]+) (.*) (HTTP\/\d\.\d)/) {
 641
 642         # XXX: might not match in case of HTTP method fuzzing.
 643         # XXX: save these: ($method, $path, $http_version) = ($1, $2, $3);
 644         $rl =~ s@^(\w+)@$h{'method'}$1$h{'Standard'}@;
 645         if ($rl =~ /http:\/\//) {
 646             $rl = highlight_matched_url($rl, '[^\s]*(?=\sHTTP)');
 647         } else {
 648             $rl = highlight_matched_pattern($rl, 'request_', '[^\s]*(?=\sHTTP)');
 649         }
 650
 651         $rl =~ s@(HTTP\/\d\.\d)$@$h{'http-version'}$1$h{'Standard'}@;
 652
 653     } elsif ($rl =~ m/\.\.\. \[too long, truncated\]$/) {
 654
 655         $rl =~ s@^(\w+)@$h{'method'}$1$h{'Standard'}@;
 656         $rl = highlight_matched_url($rl, '[^\s]*(?=\.\.\.)');
 657
 658     } elsif ($rl =~ m/^ $/) {
 659
 660         $rl = h('error') . "No request line specified!" . h('Standard');
 661
 662     } else {
 663
 664         debug_message ("Can't parse request line: $rl");
 665
 666     }
 667
 668     return $rl;
 669 }
 670
 671 sub highlight_response_line ($) {
 672
 673     my $rl = shift;
 674     my ($http_version, $status_code, $status_message);
 675
 676     #HTTP/1.1 200 OK
 677     #ICY 200 OK
 678
 679     # TODO: Mark different status codes differently
 680
 681     if ($rl =~ m/((?:HTTP\/\d\.\d|ICY)) (\d+) (.*)/) {
 682         ($http_version, $status_code, $status_message) = ($1, $2, $3);
 683     } else {
 684         debug_message ("Can't parse response line: $rl") and die 'Fix this';
 685     }
 686
 687     # Rebuild highlighted
 688     $rl= "";
 689     $rl .= h('http-version') . $http_version . h('Standard');
 690     $rl .= " ";
 691     $rl .= h('status-code') . $status_code . h('Standard');
 692     $rl .= " ";
 693     $rl .= h('status-message') . $status_message . h('Standard');
 694
 695     return $rl;
 696 }
 697
 698 sub highlight_matched_url ($$) {
 699
 700     my $result = shift; # XXX: Stupid name;
 701     my $regex = shift;
 702
 703     #print "Got $result, regex ($regex)\n";
 704
 705     if ($result =~ m@(.*?)($regex)(.*)@) {
 706         $result = $1 . highlight_url($2) . $3;
 707         #print "Now the result is $result\n";
 708     }
 709
 710     return $result;
 711 }
 712
 713 sub highlight_matched_host ($$) {
 714
 715     my ($result, $regex) = @_; # XXX: result ist stupid name;
 716
 717     if ($result =~ m@(.*?)($regex)(.*)@) {
 718         $result = $1 . $h{host} . $2 . $h{Standard} . $3;
 719     }
 720
 721     return $result;
 722 }
 723
 724 sub highlight_matched_pattern ($$$) {
 725
 726     my $result = shift; # XXX: Stupid name;
 727     my $key = shift;
 728     my $regex = shift;
 729
 730     die "Unknown key $key" unless defined $h{$key};
 731
 732     if ($result =~ m@(.*?)($regex)(.*)@) {
 733         $result = $1 . h($key) . $2 . h('Standard') . $3;
 734     }
 735
 736     return $result;
 737 }
 738
 739 sub highlight_matched_path ($$) {
 740
 741     my $result = shift; # XXX: Stupid name;
 742     my $regex = shift;
 743
 744     if ($result =~ m@(.*?)($regex)(.*)@) {
 745         $result = $1 . h('path') . $2 . h('Standard') . $3;
 746     }
 747
 748     return $result;
 749 }
 750
 751 sub highlight_url ($) {
 752
 753     my $url = shift;
 754
 755     if ($html_output_mode) {
 756
 757         $url = '<a href="' . $url . '">' . $url . '</a>';
 758
 759     } else {
 760
 761         $url = h('URL') . $url . h('Standard');
 762
 763     }
 764
 765     return $url;
 766 }
 767
 768 sub update_header_highlight_regex ($) {
 769
 770     my $header = shift;
 771     my $headers = join ('|', keys %header_colours);
 772
 773     $header_highlight_regex = qr/$headers/;
 774     print "Registering '$header'\n" if DEBUG_HEADER_HIGHLIGHTING;
 775 }
 776
 777 ################################################################################
 778 # loglevel-specific highlighter functions
 779 ################################################################################
 780
 781 sub handle_loglevel_header ($) {
 782
 783     my $content = shift;
 784     my $c = $content;
 785
 786     if ($c =~ /^scan:/) {
 787
 788         if ($c =~ m/^scan: ((\w+) (.+) (HTTP\/\d\.\d))/) {
 789
 790             # Client request line
 791             # Save for statistics (XXX: Not implemented yet)
 792             $req{$t}{'method'} = $2;
 793             $req{$t}{'destination'} = $3;
 794             $req{$t}{'http-version'} = $4;
 795
 796             $content = highlight_request_line($1);
 797
 798         } elsif ($c =~ m/^(scan: )((?:HTTP\/\d\.\d|ICY) (\d+) (.*))/) {
 799
 800             # Server response line
 801             $req{$t}{'response_line'} = $2;
 802             $req{$t}{'status_code'} = $3;
 803             $req{$t}{'status_message'} = $4;
 804             $content = $1 . highlight_response_line($req{$t}{'response_line'});
 805
 806         } elsif ($c =~ m/^scan: ((?>[^:]+)):/) {
 807
 808             # Register new headers
 809             # scan: Accept: image/png,image/*;q=0.8,*/*;q=0.5
 810             my $header = $1;
 811             if (!defined($header_colours{$header}) and $header =~ /^[\d\w-]*$/) {
 812                 debug_message "Registering previously unknown header $1" if DEBUG_HEADER_REGISTERING;
 813
 814                 if (REGISTER_HEADERS_WITH_THE_SAME_COLOUR) {
 815                     $header_colours{$header} =  $header_colours{'Default'};
 816                 } else {
 817                     $header_colours{$header} = $all_colours[$header_colour_index % @all_colours];
 818                     $header_colour_index++;
 819                 }
 820                 update_header_highlight_regex($header);
 821             }
 822
 823         }
 824
 825     } elsif ($c =~ m/^Crunching (?:server|client) header: .* \(contains: ([^\)]*)\)/) {
 826
 827         # Crunching server header: Set-Cookie: trac_form_token=d5308c34e16d15e9e301a456; (contains: Cookie:)
 828         $content =~ s@(?<=contains: )($1)@$h{'crunch-pattern'}$1$h{'Standard'}@;
 829         $content =~ s@(Crunching)@$h{$1}$1$h{'Standard'}@;
 830
 831     } elsif ($c =~ m/^New host is: ([^\s]*)\./) {
 832
 833         # New host is: trac.vidalia-project.net. Crunching Referer: http://www.vidalia-project.net/
 834         $c = highlight_matched_host($c, '(?<=New host is: )[^\s]+');
 835         $content = highlight_matched_url($c, '(?<=Crunching Referer: )[^\s]+');
 836
 837     } elsif ($c =~ m/^Text mode enabled by force. (Take cover)!/) {
 838
 839         # Text mode enabled by force. Take cover!
 840         $content =~ s@($1)@$h{'warning'}$1$h{'Standard'}@;
 841
 842     } elsif ($c =~ m/^(New HTTP Request-Line: )(.*)/) {
 843
 844         # New HTTP Request-Line: GET http://www.privoxy.org/ HTTP/1.1
 845         $content = $1 . highlight_request_line($2);
 846
 847     } elsif ($c =~ m/^Adjust(ed)? Content-Length to \d+/) {
 848
 849         # Adjusted Content-Length to 2132
 850         # Adjust Content-Length to 33533
 851         $content =~ s@(?<=Content-Length to )(\d+)@$h{'Number'}$1$h{'Standard'}@;
 852         $content = highlight_known_headers($content);
 853
 854     } elsif ($c =~ m/^Destination extracted from "Host:" header. New request URL:/) {
 855
 856         # Destination extracted from "Host:" header. New request URL: http://www.cccmz.de/~ridcully/blog/
 857         $content = highlight_matched_url($content, '(?<=New request URL: ).*');
 858
 859     } elsif ($c =~ m/^Couldn\'t parse:/) {
 860
 861         # XXX: These should probable be logged with LOG_LEVEL_ERROR
 862         # Couldn't parse: If-Modified-Since: Wed, 21 Mar 2007 16:34:50 GMT (crunching!)
 863         # Couldn't parse: at, 24 Mar 2007 13:46:21 GMT in If-Modified-Since: Sat, 24 Mar 2007 13:46:21 GMT (crunching!)
 864         $content =~ s@^(Couldn\'t parse)@$h{'error'}$1$h{'Standard'}@;
 865
 866     } elsif ($c =~ /^Tagger \'([^\']*)\' added tag \'([^\']*)\'/ or
 867              $c =~ m/^Adding tag \'([^\']*)\' created by header tagger \'([^\']*)\'/) {
 868
 869         # Adding tag 'GET request' created by header tagger 'method-man' (XXX: no longer used)
 870         # Tagger 'revalidation' added tag 'REVALIDATION-REQUEST'. No action bit update necessary.
 871         # Tagger 'revalidation' added tag 'REVALIDATION-REQUEST'. Action bits updated accordingly.
 872
 873         # XXX: Save tag and tagger
 874
 875         $content =~ s@(?<=^Tagger \')([^\']*)@$h{'tagger'}$1$h{'Standard'}@;
 876         $content =~ s@(?<=added tag \')([^\']*)@$h{'tag'}$1$h{'Standard'}@;
 877         $content =~ s@(?<=Action bits )(updated)@$h{'action-bits-update'}$1$h{'Standard'}@;
 878         $no_special_header_highlighting = 1;
 879
 880     } elsif ($c =~ /^Tagger \'([^\']*)\' didn['']t add tag \'([^\']*)\'/) {
 881
 882         # Tagger 'revalidation' didn't add tag 'REVALIDATION-REQUEST'. Tag already present
 883         # XXX: Save tag and tagger
 884
 885         $content =~ s@(?<=^Tagger \')([^\']*)@$h{'tag'}$1$h{'Standard'}@;
 886         $content =~ s@(?<=didn['']t add tag \')([^\']*)@$h{'tagger'}$1$h{'Standard'}@;
 887
 888     } elsif ($c =~ m/^(?:scan:|Randomiz|addh:|Adding:|Removing:|Referer:|Modified:|Accept-Language header|[Cc]ookie)/
 889           or $c =~ m/^(Text mode is already enabled|Denied request with NULL byte|Replaced:|add-unique:)/
 890           or $c =~ m/^(Crunched (incoming|outgoing) cookie|Suppressed offer|Accepted the client)/
 891           or $c =~ m/^(addh-unique|Referer forged to)/
 892           or $c =~ m/^Downgraded answer to HTTP\/1.0/
 893           or $c =~ m/^Parameter: \+hide-referrer\{[^\}]*\} is a bad idea, but I don\'t care./
 894           or $c =~ m/^Referer (?:overwritten|replaced) with: Referer: / #XXX: should this be highlighted?
 895           or $c =~ m/^Referer crunched!/
 896           or $c =~ m/^crunched x-forwarded-for!/
 897           or $c =~ m/^crunched From!/
 898           or $c =~ m/^ modified$/
 899           or $c =~ m/^Content filtering is enabled. Crunching:/
 900           or $c =~ m/^force-text-mode overruled the client/
 901           or $c =~ m/^Server time in the future\./
 902           or $c =~ m/^content-disposition header crunched and replaced with:/i
 903           or $c =~ m/^Reducing white space in /
 904           or $c =~ m/^Ignoring single quote in /
 905           or $c =~ m/^Converting tab to space in /
 906           or $c =~ m/A HTTP\/1\.1 response without/
 907           or $c =~ m/Disabled filter mode on behalf of the client/
 908           or $c =~ m/Keeping the (?:server|client) header /
 909           or $c =~ m/Content modified with no Content-Length header set/
 910           or $c =~ m/^Appended client IP address to/
 911           or $c =~ m/^Removing 'Connection: close' to imply keep-alive./
 912           or $c =~ m/^keep-alive support is disabled/
 913             )
 914     {
 915         # XXX: Some of these may need highlighting
 916
 917         # Modified: User-Agent: Mozilla/5.0 (X11; U; SunOS i86pc; pl-PL; rv:1.8.1.1) Gecko/20070214 Firefox/2.0.0.1
 918         # Accept-Language header crunched and replaced with: Accept-Language: pl-pl
 919         # cookie 'Set-Cookie: eZSessionCookie=07bfec287c197440d299f81580593c3d; \
 920         #  expires=Thursday, 12-Apr-07 15:16:18 GMT; path=/' send by \
 921         #  http://wirres.net/article/articleview/4265/1/6/ appears to be using time format 1 (XXX: gone with the wind)
 922         # Cookie rewritten to a temporary one: Set-Cookie: NSC_gffe-iuuq-mc-wtfswfs=8efb33a53660;path=/
 923         # Text mode is already enabled
 924         # Denied request with NULL byte(s) turned into line break(s)
 925         # Replaced: 'Connection: Yo, home to Bel Air' with 'Connection: close'
 926         # addh-unique: Host: people.freebsd.org
 927         # Suppressed offer to compress content
 928         # Crunched incoming cookie -- yum!
 929         # Accepted the client's request to fetch without filtering.
 930         # Crunched outgoing cookie: Cookie: PREF=ID=6cf0abd347b30262:TM=1173357617:LM=1173357617:S=jZypyyJ7LPiwFi1_
 931         # addh-unique: Host: subkeys.pgp.net:11371
 932         # Referer forged to: Referer: http://10.0.0.1/
 933         # Downgraded answer to HTTP/1.0
 934         # Parameter: +hide-referrer{pille-palle} is a bad idea, but I don't care.
 935         # Referer overwritten with: Referer: pille-palle
 936         # Referer replaced with: Referer: pille-palle
 937         # crunched x-forwarded-for!
 938         # crunched From!
 939         #  modified # XXX: pretty stupid log message
 940         # Content filtering is enabled. Crunching: 'Range: 1234-5678' to prevent range-mismatch problems
 941         # force-text-mode overruled the client's request to fetch without filtering!
 942         # Server time in the future.
 943         # content-disposition header crunched and replaced with: content-disposition: filename=baz
 944         # Content-Disposition header crunched and replaced with: content-disposition: filename=baz
 945         # Reducing white space in 'X-LWS-Test: "This  is  quoted" this is not "this  is  " but " this again   is  not'
 946         # Ignoring single quote in 'X-LWS-Test: "This  is  quoted" this is not "this  is  " but "  this again   is  not'
 947         # Converting tab to space in 'X-LWS-Test:   "This  is  quoted" this   is  not "this  is  "  but  "\
 948         #  this again   is  not'
 949         # A HTTP/1.1 response without Connection header implies keep-alive.
 950         # Disabled filter mode on behalf of the client.
 951         # Keeping the server header 'Connection: keep-alive' around.
 952         # Keeping the client header 'Connection: close' around. The connection will not be kept alive.
 953         # Keeping the client header 'Connection: keep-alive' around. The connection will be kept alive if possible.
 954         # Content modified with no Content-Length header set. Creating a fake one for adjustment later on.
 955         # Appended client IP address to X-Forwarded-For: 10.0.0.2, 10.0.0.1
 956         # Removing 'Connection: close' to imply keep-alive.
 957         # keep-alive support is disabled. Crunching: Keep-Alive: 300.
 958
 959     } elsif ($c =~ m/^scanning headers for:/) {
 960
 961         return '' unless SHOW_SCAN_INTRO;
 962
 963     } elsif ($c =~ m/^[Cc]runch(ing|ed)|crumble crunched:/) {
 964         # crunched User-Agent!
 965         # Crunching: Content-Encoding: gzip
 966
 967         $content =~ s@(Crunching|crunched)@$h{$1}$1$h{'Standard'}@;
 968
 969     } elsif ($c =~ m/^Offending request data with NULL bytes turned into \'°\' characters:/) {
 970
 971         # Offending request data with NULL bytes turned into '°' characters: °°n°°(°°°
 972
 973         $content = h('warning') . $content . h('Standard');
 974
 975     } elsif ($c =~ m/^(Transforming \")(.*?)(\" to \")(.*?)(\")/) {
 976
 977         # Transforming "Proxy-Authenticate: Basic realm="Correos Proxy Server"" to\
 978         #  "Proxy-Authenticate: Basic realm="Correos Proxy Server""
 979
 980        $content =~ s@(?<=^Transforming \")(.*)(?=\" to)@$h{'Header'}$1$h{'Standard'}@;
 981        $content =~ s@(?<=to \")(.*)(?=\")@$h{'Header'}$1$h{'Standard'}@;
 982
 983     } elsif ($c =~ m/^Removing empty header/) {
 984
 985         # Removing empty header
 986         # Ignore for now
 987
 988     } elsif ($c =~ m/^Content-Type: .* not replaced/) {
 989
 990         # Content-Type: application/octet-stream not replaced. It doesn't look like text.\
 991         #  Enable force-text-mode if you know what you're doing.
 992         # XXX: Could highlight more here.
 993         $content =~ s@(?<=^Content-Type: )(.*)(?= not replaced)@$h{'content-type'}$1$h{'Standard'}@;
 994
 995     } elsif ($c =~ m/^(Server|Client) keep-alive timeout is/) {
 996
 997        # Server keep-alive timeout is 5. Sticking with 10.
 998        # Client keep-alive timeout is 20. Sticking with 10.
 999
1000        $content =~ s@(?<=timeout is )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1001        $content =~ s@(?<=Sticking with )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1002
1003     } elsif ($c =~ m/^Reducing keep-alive timeout/) {
1004
1005        # Reducing keep-alive timeout from 60 to 10.
1006
1007        $content =~ s@(?<= from )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1008        $content =~ s@(?<= to )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1009
1010     } else {
1011
1012         found_unknown_content($content);
1013     }
1014
1015     # Highlight headers
1016     unless ($c =~ m/^Transforming/) {
1017         $content = highlight_known_headers($content) unless $no_special_header_highlighting;
1018     }
1019
1020     return $content;
1021 }
1022
1023 sub handle_loglevel_re_filter ($) {
1024
1025     my $content = shift;
1026     my $c = $content;
1027     my $key;
1028
1029     if ($c =~ m/^(?:re_)?filtering ([^\s]+) \(size (\d+)\) with (?:filter )?\'?([^\s]+?)\'? produced (\d+) hits \(new size (\d+)\)/) {
1030
1031         # XXX: only the second version gets highlighted properly.
1032         # re_filtering www.lfk.de/favicon.ico (size 209) with filter untrackable-hulk produced 0 hits (new size 209).
1033         # filtering aci.blogg.de/ (size 37988) with 'blogg.de' produced 3 hits (new size 38057)
1034         $req{$t}{'content_source'} = $1;
1035         $req{$t}{'content_size'}   = $2;
1036         $req{$t}{'content_filter'} = $3;
1037         $req{$t}{'content_hits'}   = $4;
1038         $req{$t}{'new_content_size'} = $5;
1039         $req{$t}{'content_size_change'} = $req{$t}{'new_content_size'} - $req{$t}{'content_size'};
1040         #return '' if ($req{$t}{'content_hits'} == 0 && !cli_option_is_set('show-ineffective-filters'));
1041         if ($req{$t}{'content_hits'} == 0 and
1042             not (cli_option_is_set('show-ineffective-filters')
1043                  or ($req{$t}{'content_filter'} =~ m/^privoxy-filter-test$/))) {
1044                 return '';
1045         }
1046
1047         $c =~ s@(?<=\(size )(\d+)\)(?= with)@$h{'Number'}$1$h{'Standard'}@;
1048         $c =~ s@(?<=\(new size )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1049         $c =~ s@(?<=produced )(\d+)(?= hits)@$h{'Number'}$1$h{'Standard'}@;
1050
1051         $c =~ s@([^\s]+?)(\'? produced)@$h{'filter'}$1$h{'Standard'}$2@;
1052         $c = highlight_matched_host($c, '(?<=filtering )[^\s]+');
1053
1054         $c =~ s@\.$@ @;
1055         $c .= "(" . $h{'Number'};
1056         $c .= "+" if ($req{$t}{'content_size_change'} >= 0);
1057         $c .= $req{$t}{'content_size_change'} . $h{'Standard'} . ")";
1058         $content = $c;
1059
1060   } elsif ($c =~ /\.{3}$/
1061         and $c =~ m/^(?:re_)?filtering \'?(.*?)\'? \(size (\d*)\) with (?:filter )?\'?([^\s]*?)\'? ?\.{3}$/) {
1062
1063         # Used by Privoxy 3.0.5 and 3.0.6:
1064         # XXX: Fill in ...
1065         # Used by Privoxy 3.0.7:
1066         # filtering 'Connection: close' (size 17) with 'generic-content-ads' ...
1067
1068         $req{$t}{'filtered_header'} = $1;
1069         $req{$t}{'old_header_size'} = $2;
1070         $req{$t}{'header_filter_name'} = $3;
1071
1072         unless (cli_option_is_set('show-ineffective-filters') or
1073                 $req{$t}{'header_filter_name'} =~ m/^privoxy-filter-test$/) {
1074             return '';
1075         }
1076         $content =~ s@(?<=\(size )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1077         $content =~ s@($req{$t}{'header_filter_name'})@$h{'filter'}$1$h{'Standard'}@;
1078
1079     } elsif ($c =~ m/^ ?\.\.\. ?produced (\d*) hits \(new size (\d*)\)\./) {
1080
1081         # ...produced 0 hits (new size 23).
1082         #... produced 1 hits (new size 54).
1083
1084         $req{$t}{'header_filter_hits'} = $1;
1085         $req{$t}{'new_header_size'} = $2;
1086
1087         unless (cli_option_is_set('show-ineffective-filters') or
1088                 (defined($req{$t}{'header_filter_name'}) and
1089                  $req{$t}{'header_filter_name'} =~ m/^privoxy-filter-test$/)) {
1090
1091             if ($req{$t}{'header_filter_hits'} == 0 and
1092                 not (defined($req{$t}{'header_filter_name'}) and
1093                  $req{$t}{'header_filter_name'} =~ m/^privoxy-filter-test$/)) {
1094                 return '';
1095             }
1096             # Reformat including information from the intro
1097             $c = "'" . h('filter') . $req{$t}{'header_filter_name'} . h('Standard') . "'";
1098             $c .= " hit ";
1099             # XXX: Hide behind constant, it may be interesting if LOG_LEVEL_HEADER isn't enabled as well.
1100             # $c .= $req{$t}{'filtered_header'} . " ";
1101             $c .= h('Number') . $req{$t}{'header_filter_hits'}. h('Standard');
1102             $c .= ($req{$t}{'header_filter_hits'} == 1) ? " time, " : " times, ";
1103
1104             if ($req{$t}{'old_header_size'} !=  $req{$t}{'new_header_size'}) {
1105
1106                 $c .= "changing size from ";
1107                 $c .=  h('Number') . $req{$t}{'old_header_size'} . h('Standard');
1108                 $c .= " to ";
1109                 $c .= h('Number') . $req{$t}{'new_header_size'} . h('Standard');
1110                 $c .= ".";
1111
1112             } else {
1113
1114                 $c .= "keeping the size at " . $req{$t}{'old_header_size'};
1115
1116             }
1117
1118             # Highlight from last line (XXX: What?)
1119             # $c =~ s@(?<=produced )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1120             # $c =~ s@($req{$t}{'header_filter_name'})@$h{'filter'}$1$h{'Standard'}@;
1121
1122         } else {
1123
1124            # XXX: Untested
1125            $c =~ s@(?<=produced )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1126            $c =~ s@(?<=new size )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1127
1128         }
1129         $content = $c;
1130
1131     } elsif ($c =~ m/^(Tagger|Filter) ([^\s]*) has empty joblist. Nothing to do./) {
1132
1133         # Filter privoxy-filter-test has empty joblist. Nothing to do.
1134         # Tagger variable-test has empty joblist. Nothing to do.
1135
1136         $content =~ s@(?<=$1 )([^\s]*)@$h{'filter'}$1$h{'Standard'}@;
1137
1138     } elsif ($c =~ m/^De-chunking successful. Shrunk from (\d+) to (\d+)/) {
1139
1140         $req{$t}{'chunked-size'} = $1;
1141         $req{$t}{'dechunked-size'} = $2;
1142         $req{$t}{'dechunk-change'} = $req{$t}{'dechunked-size'} - $req{$t}{'chunked-size'};
1143
1144         $content .= " (" . h('Number') . $req{$t}{'dechunk-change'} . h('Standard') . ")";
1145
1146         $content =~ s@(?<=from )($req{$t}{'chunked-size'})@$h{'Number'}$1$h{'Standard'}@;
1147         $content =~ s@(?<=to )($req{$t}{'dechunked-size'})@$h{'Number'}$1$h{'Standard'}@;
1148
1149     } elsif ($c =~ m/^Decompression successful. Old size: (\d+), new size: (\d+)./) {
1150
1151         # Decompression successful. Old size: 670, new size: 1166.
1152
1153         $req{$t}{'size-compressed'} = $1;
1154         $req{$t}{'size-decompressed'} = $2;
1155         $req{$t}{'decompression-gain'} = $req{$t}{'size-decompressed'} - $req{$t}{'size-compressed'};
1156
1157         $content =~ s@(?<=Old size: )($req{$t}{'size-compressed'})@$h{'Number'}$1$h{'Standard'}@;
1158         $content =~ s@(?<=new size: )($req{$t}{'size-decompressed'})@$h{'Number'}$1$h{'Standard'}@;
1159
1160         # XXX: Create sub get_percentage()
1161         if ($req{$t}{'size-decompressed'}) {
1162             $req{$t}{'decompression-gain-percent'} =
1163                 $req{$t}{'decompression-gain'} / $req{$t}{'size-decompressed'} * 100;
1164
1165             $content .= " (saved: ";
1166             #$content .= h('Number') . $req{$t}{'decompression-gain'} . h('Standard');
1167             #$content .= "/";
1168             $content .= h('Number') . sprintf("%.2f%%", $req{$t}{'decompression-gain-percent'}) . h('Standard');
1169             $content .= ")";
1170         }
1171
1172     } elsif ($c =~ m/^(Need to de-chunk first)/) {
1173
1174         # Need to de-chunk first
1175         return '' if SUPPRESS_NEED_TO_DE_CHUNK_FIRST;
1176
1177     } elsif ($c =~ m/^(Adding (?:dynamic )?re_filter job)/) {
1178
1179         return ''  if (SUPPRESS_SUCCEEDED_FILTER_ADDITIONS && m/succeeded/);
1180
1181         # Adding re_filter job ...
1182         # Adding dynamic re_filter job s@^(?:\w*)\s+.*\s+HTTP/\d\.\d\s*@IP-ADDRESS: $origin@D\
1183         #  to filter client-ip-address succeeded.
1184
1185     } elsif ($c =~ m/^Reading in filter/) {
1186
1187         return '' unless SHOW_FILTER_READIN_IN;
1188
1189     } else {
1190
1191         found_unknown_content($content);
1192
1193     }
1194
1195     return $content;
1196 }
1197
1198 sub handle_loglevel_redirect ($) {
1199
1200     my $c = shift;
1201
1202     if ($c =~ m/^Decoding "([^""]*)"/) {
1203
1204          $req{$t}{'original-destination'} = $1;
1205          $c = highlight_matched_path($c, '(?<=Decoding ")[^"]*');
1206          $c =~ s@\"@@g;
1207
1208     } elsif ($c =~ m/^Checking/) {
1209
1210          # Checking /_ylt=A0geu.Z76BRGR9k/**http://search.yahoo.com/search?p=view+odb+presentation+on+freebsd\
1211          #  &ei=UTF-8&xargs=0&pstart=1&fr=moz2&b=11 for redirects.
1212
1213          # TODO: Change colour if really url-decoded
1214          $req{$t}{'decoded-original-destination'} = $1;
1215          $c = highlight_matched_path($c, '(?<=Checking ")[^"]*');
1216          $c =~ s@\"@@g;
1217
1218     } elsif ($c =~ m/^pcrs command "([^""]*)" changed /) {
1219
1220         # pcrs command "s@&from=rss@@" changed \
1221         #  "http://it.slashdot.org/article.pl?sid=07/03/02/1657247&from=rss"\
1222         #  to "http://it.slashdot.org/article.pl?sid=07/03/02/1657247" (1 hit).
1223         $c =~ s@(?<=pcrs command )"([^""]*)"@$h{'filter'}$1$h{'Standard'}@;
1224         $c = highlight_matched_url($c, '(?<=changed ")[^""]*');
1225         $c =~ s@(?<=changed )"([^""]*)"@$1@; # Remove quotes
1226         $c = highlight_matched_url($c, '(?<=to ")[^""]*');
1227         $c =~ s@(?<=to )"([^""]*)"@$1@; # Remove quotes
1228         $c =~ s@(\d+)(?= hits?)@$h{'hits'}$1$h{'Standard'}@;
1229
1230     } elsif ($c =~ m/^pcrs command "([^""]*)" didn\'t change/) {
1231
1232         # pcrs command "s@^http://([^.]+?)/?$@http://www.bing.com/search?q=$1@" didn't \
1233         #  change "http://www.example.org/".
1234         $c =~ s@(?<=pcrs command )"([^""]*)"@$h{'filter'}$1$h{'Standard'}@;
1235         $c = highlight_matched_url($c, '(?<=change ")[^""]*');
1236
1237     } elsif ($c =~ m/(^New URL is: )(.*)/) {
1238
1239         # New URL is: http://it.slashdot.org/article.pl?sid=07/03/04/1511210
1240         # XXX: Use URL highlighter
1241         # XXX: Save?
1242         $c = $1 . h('rewritten-URL') . $2 . h('Standard');
1243
1244     } elsif ($c =~ m/No pcrs command recognized, assuming that/) {
1245         # No pcrs command recognized, assuming that "http://config.privoxy.org/user-manual/favicon.png"\
1246         #  is already properly formatted.
1247         # XXX: assume the same?
1248         $c = highlight_matched_url($c, '(?<=assuming that \")[^"]*');
1249
1250     } else {
1251
1252         found_unknown_content($c);
1253
1254     }
1255
1256     return $c;
1257 }
1258
1259 sub handle_loglevel_gif_deanimate ($) {
1260
1261     my $content = shift;
1262
1263     if ($content =~ m/Success! GIF shrunk from (\d+) bytes to (\d+)\./) {
1264
1265         my $bytes_from = $1;
1266         my $bytes_to = $2;
1267         # Gif-Deanimate: Success! GIF shrunk from 205 bytes to 133.
1268         $content =~ s@$bytes_from@$h{'Number'}$bytes_from$h{'Standard'}@;
1269         # XXX: Do we need g in case of ($1 == $2)?
1270         $content =~ s@$bytes_to@$h{'Number'}$bytes_to$h{'Standard'}@;
1271
1272     } elsif ($content =~ m/GIF (not) changed/) {
1273
1274         # Gif-Deanimate: GIF not changed.
1275         return '' if SUPPRESS_GIF_NOT_CHANGED;
1276         $content =~ s@($1)@$h{'not'}$1$h{'Standard'}@;
1277
1278     } elsif ($content =~ m/^failed! \(gif parsing\)/) {
1279
1280         # failed! (gif parsing)
1281         # XXX: Replace this error message with something less stupid
1282         $content =~ s@(failed!)@$h{'error'}$1$h{'Standard'}@;
1283
1284     } elsif ($content =~ m/^Need to de-chunk first/) {
1285
1286         # Need to de-chunk first
1287         return '' if SUPPRESS_NEED_TO_DE_CHUNK_FIRST;
1288
1289     } elsif ($content =~ m/^(?:No GIF header found|failed while parsing)/) {
1290
1291         # No GIF header found (XXX: Did I ever commit this?)
1292         # failed while parsing 195 134747048 (XXX: never commited)
1293
1294         # Ignore these for now
1295
1296     } else {
1297
1298         found_unknown_content($content);
1299
1300     }
1301
1302     return $content;
1303 }
1304
1305 sub handle_loglevel_request ($) {
1306
1307     my $content = shift;
1308
1309     if ($content =~ m/crunch! /) {
1310
1311         # config.privoxy.org/send-stylesheet crunch! (CGI Call)
1312
1313         # Highlight crunch reasons
1314         foreach my $reason (keys %reason_colours) {
1315             $content =~ s@\(($reason)\)@$reason_colours{$reason}($1)$h{'Standard'}@g;
1316         }
1317         # Highlight request URL domain and ditch 'crunch!'
1318         $content = highlight_matched_pattern($content, 'request_', '[^ ]*(?= crunch!)');
1319         $content =~ s@ crunch!@@;
1320
1321     } elsif ($content =~ m/\[too long, truncated\]$/) {
1322
1323         # config.privoxy.org/edit-actions-submit?f=3&v=1176116716&s=7&Submit=Submit[...]&filter... [too long, truncated]
1324         $content = highlight_matched_pattern($content, 'request_', '^.*(?=\.\.\. \[too long, truncated\]$)');
1325
1326     } elsif ($content =~ m/(.*)/) { # XXX: Pretty stupid
1327
1328         # trac.vidalia-project.net/wiki/Volunteer?format=txt
1329         $content = h('request_') . $content . h('Standard');
1330
1331     } else {  # XXX: Nop
1332
1333         found_unknown_content($content);
1334
1335     }
1336
1337     return $content;
1338 }
1339
1340 sub handle_loglevel_crunch ($) {
1341
1342     my $content = shift;
1343
1344     # Highlight crunch reason
1345     foreach my $reason (keys %reason_colours) {
1346         $content =~ s@($reason)@$reason_colours{$reason}$1$h{'Standard'}@g;
1347     }
1348
1349     if ($content =~ m/\[too long, truncated\]$/) {
1350
1351         # Blocked: config.privoxy.org/edit-actions-submit?f=3&v=1176116716&s=7&Submit=Submit\
1352         #  [...]&filter... [too long, truncated]
1353         $content = highlight_matched_pattern($content, 'request_', '^.*(?=\.\.\. \[too long, truncated\]$)');
1354
1355     } else {
1356
1357         # Blocked: http://ads.example.org/
1358         $content = highlight_matched_pattern($content, 'request_', '(?<=: ).*');
1359     }
1360
1361     return $content;
1362 }
1363
1364 sub handle_loglevel_connect ($) {
1365
1366     my $c = shift;
1367
1368     if ($c =~ m/^via [^\s]+ to: [^\s]+/) {
1369
1370         # Connect: via 10.0.0.1:8123 to: www.example.org.noconnect
1371
1372         $c = highlight_matched_host($c, '(?<=via )[^\s]+');
1373         $c = highlight_matched_host($c, '(?<=to: )[^\s]+');
1374
1375     } elsif ($c =~ m/^connect to: .* failed: .*/) {
1376
1377         # connect to: www.example.org.noconnect failed: Operation not permitted
1378
1379         $c = highlight_matched_host($c, '(?<=connect to: )[^\s]+');
1380
1381         $c =~ s@(?<=failed: )(.*)@$h{'error'}$1$h{'Standard'}@;
1382
1383     } elsif ($c =~ m/^to ([^\s]*)( successful)?$/) {
1384
1385         # Connect: to www.nzherald.co.nz successful
1386         # Connect: to archiv.radiotux.de
1387
1388         return '' if SUPPRESS_SUCCESSFUL_CONNECTIONS;
1389         $c = highlight_matched_host($c, '(?<=to )[^\s]+');
1390
1391     } elsif ($c =~ m/^to ([^\s]*)$/) {
1392
1393         # Connect: to lists.sourceforge.net:443
1394
1395         $c = highlight_matched_host($c, '(?<=to )[^\s]+');
1396
1397     } elsif ($c =~ m/^accepted connection from .*/ or
1398              $c =~ m/^OK/) {
1399
1400         # accepted connection from 10.0.0.1
1401         # Privoxy 3.0.6 and earlier just say:
1402         # OK
1403         return '' if SUPPRESS_ACCEPTED_CONNECTIONS;
1404         $c = highlight_matched_host($c, '(?<=connection from ).*');
1405
1406     } elsif ($c =~ m/^write header to: .* failed:/) {
1407
1408         # write header to: 10.0.0.1 failed: Broken pipe
1409
1410         $c = highlight_matched_host($c, '(?<=write header to: )[^\s]*');
1411         $c =~ s@(?<=failed: )(.*)@$h{'Error'}$1$h{'Standard'}@;
1412
1413     } elsif ($c =~ m/^write header to client failed:/) {
1414
1415         # write header to client failed: Broken pipe
1416         # XXX: Stil in use?
1417         $c =~ s@(?<=failed: )(.*)@$h{'Error'}$1$h{'Standard'}@;
1418
1419     } elsif ($c =~ m/^socks4_connect:/) {
1420
1421         # socks4_connect: SOCKS request rejected or failed.
1422         $c =~ s@(?<=socks4_connect: )(.*)@$h{'Error'}$1$h{'Standard'}@;
1423
1424     } elsif ($c =~ m/^Listening for new connections/ or
1425              $c =~ m/^accept connection/) {
1426         # XXX: Highlight?
1427         # Privoxy versions above 3.0.6 say:
1428         # Listening for new connections ...
1429         # earlier versions say:
1430         # accept connection ...
1431         return '';
1432
1433     } elsif ($c =~ m/^accept failed:/) {
1434
1435         $c =~ s@(?<=accept failed: )(.*)@$h{'Error'}$1$h{'Standard'}@;
1436
1437     } elsif ($c =~ m/^Overriding forwarding settings/) {
1438
1439         # Overriding forwarding settings based on 'forward 10.0.0.1:8123'
1440         $c =~ s@(?<=based on \')(.*)(?=\')@$h{'configuration-line'}$1$h{'Standard'}@;
1441
1442     } elsif ($c =~ m/^Denying suspicious CONNECT request from/) {
1443
1444         # Denying suspicious CONNECT request from 10.0.0.1
1445         $c = highlight_matched_host($c, '(?<=from )[^\s]+'); # XXX: not an URL
1446
1447     } elsif ($c =~ m/^socks5_connect:/) {
1448
1449         $c =~ s@(?<=socks5_connect: )(.*)@$h{'error'}$1$h{'Standard'}@;
1450
1451     } elsif ($c =~ m/^Created new connection to/) {
1452
1453         # Created new connection to www.privoxy.org:80 on socket 11.
1454         $c = highlight_matched_host($c, '(?<=connection to )[^\s]+');
1455         $c =~ s@(?<=on socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1456
1457     } elsif ($c =~ m/^Found reusable socket/) {
1458
1459         # Found reusable socket 9 for www.privoxy.org:80 in slot 0.
1460         # 3.0.15 and later:
1461         # Found reusable socket 8 for www.privoxy.org:80 in slot 2.\
1462         #  Timestamp made 0 seconds ago. Timeout: 1. Latency: 0.
1463         $c =~ s@(?<=Found reusable socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1464         $c = highlight_matched_host($c, '(?<=for )[^\s]+');
1465         $c =~ s@(?<=in slot )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1466         $c =~ s@(?<=made )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1467         $c =~ s@(?<=Timeout: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1468         $c =~ s@(?<=Latency: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1469
1470     } elsif ($c =~ m/^Marking open socket/) {
1471
1472         # Marking open socket 9 for www.privoxy.org:80 in slot 0 as unused.
1473         $c =~ s@(?<=Marking open socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1474         $c = highlight_matched_host($c, '(?<=for )[^\s]+');
1475         $c =~ s@(?<=in slot )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1476
1477     } elsif ($c =~ m/^No reusable/) {
1478
1479         # No reusable socket for addons.mozilla.org:443 found. Opening a new one.
1480         $c = highlight_matched_host($c, '(?<=for )[^\s]+');
1481
1482     } elsif ($c =~ m/^(Remembering|Forgetting) socket/) {
1483
1484         # Remembering socket 13 for www.privoxy.org:80 in slot 0.
1485         # Forgetting socket 38 for www.privoxy.org:80 in slot 5.
1486
1487         $c =~ s@(?<=socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1488         $c = highlight_matched_host($c, '(?<=for )[^\s]+');
1489         $c =~ s@(?<=in slot )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1490
1491     } elsif ($c =~ m/^Socket/) {
1492
1493         # Socket 16 already forgotten or never remembered.
1494         $c =~ s@(?<=Socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1495
1496     } elsif ($c =~ m/^The connection to/) {
1497
1498         # The connection to www.privoxy.org:80 in slot 6 timed out. Closing socket 19. Timeout is: 61.
1499         # 3.0.15 and later:
1500         # The connection to 1.bp.blogspot.com:80 in slot 0 timed out. Closing socket 5.\
1501         #  Timeout is: 1. Assumed latency: 4.
1502         # The connection to 10.0.0.1:80 in slot 0 is no longer usable. Closing socket 4.
1503         $c = highlight_matched_host($c, '(?<=connection to )[^\s]+');
1504         $c =~ s@(?<=in slot )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1505         $c =~ s@(?<=Closing socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1506         $c =~ s@(?<=Timeout is: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1507         $c =~ s@(?<=Assumed latency: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1508
1509     } elsif ($c =~ m/^Stopped waiting for the request line./) {
1510
1511         # Stopped waiting for the request line. Timeout: 121.
1512         $c =~ s@(?<=Timeout: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1513
1514     } elsif ($c =~ m/^Waiting for \d/) {
1515
1516         # Waiting for 1 connections to timeout.
1517         $c =~ s@(?<=^Waiting for )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1518
1519     } elsif ($c =~ m/^Initialized/) {
1520
1521         # Initialized 20 socket slots.
1522         $c =~ s@(?<=Initialized )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1523
1524     } elsif ($c =~ m/^Done reading from server/) {
1525
1526         # Done reading from server. Expected content length: 24892. \
1527         #  Actual content length: 24892. Most recently received: 4412.
1528         # 3.0.15 and later:
1529         # Done reading from server. Expected content length: 24892. \
1530         #  Actual content length: 24892. Bytes most recently read: 4412.
1531         # Done reading from server. Content length: 6018 as expected. \
1532         #  Bytes most recently read: 294.
1533         $c =~ s@(?<=ontent length: )(\d+)@$h{'Number'}$1$h{'Standard'}@g;
1534         $c =~ s@(?<=received: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1535         $c =~ s@(?<=read: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1536
1537     } elsif ($c =~ m/^Continuing buffering headers/) {
1538
1539         # Continuing buffering headers. byte_count: 19. header_offset: 517. len: 536.
1540         $c =~ s@(?<=byte_count: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1541         $c =~ s@(?<=header_offset: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1542         $c =~ s@(?<=len: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1543         # 3.0.15 and later:
1544         # Continuing buffering headers. Bytes most recently read: %d.
1545         $c =~ s@(?<=read: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1546
1547     } elsif ($c =~ m/^Received \d+ bytes while/) {
1548
1549         # Received 206 bytes while expecting 12103.
1550         $c =~ s@(?<=Received )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1551         $c =~ s@(?<=expecting )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1552
1553     } elsif ($c =~ m/^Connection from/) {
1554
1555         # Connection from 81.163.28.218 dropped due to ACL
1556         $c =~ s@(?<=^Connection from )((?:\d+\.?){4})@$h{'Number'}$1$h{'Standard'}@;
1557
1558     } elsif ($c =~ m/^(?:Reusing|Closing) server socket \d./ or
1559              $c =~ m/^No additional client request/) {
1560
1561         # Reusing server socket 4. Opened for 10.0.0.1.
1562         # Closing server socket 2. Opened for 10.0.0.1.
1563         # No additional client request received in time. \
1564         #  Closing server socket 4, initially opened for 10.0.0.1.
1565         # No additional client request received in time on socket 29.
1566
1567         $c =~ s@(?<= socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1568         $c = highlight_matched_host($c, '(?<=for )[^\s]+(?=\.$)');
1569
1570     } elsif ($c =~ m/^Connected to /) {
1571
1572         # Connected to tor-jail[10.0.0.2]:9050.
1573
1574         $c = highlight_matched_host($c, '(?<=\[)[^\]]+');
1575         $c = highlight_matched_host($c, '(?<=Connected to )[^\[\s]+');
1576         $c =~ s@(?<=\]:)(\d+)@$h{'Number'}$1$h{'Standard'}@;
1577
1578     } elsif ($c =~ m/^Could not connect to /) {
1579
1580         # Could not connect to [10.0.0.1]:80.
1581
1582         $c = highlight_matched_host($c, '(?<=\[)[^\]]+');
1583         $c =~ s@(?<=\]:)(\d+)@$h{'Number'}$1$h{'Standard'}@;
1584
1585     } elsif ($c =~ m/^Waiting for the next client request/ or
1586              $c =~ m/^The connection on server socket/ or
1587              $c =~ m/^Client request arrived in time or the client closed the connection/) {
1588
1589         # Waiting for the next client request on socket 3. Keeping the server \
1590         #  socket 12 to a.fsdn.com open.
1591         # The connection on server socket 6 to upload.wikimedia.org isn't reusable. Closing.
1592         # Client request arrived in time or the client closed the connection on socket 12.
1593
1594         $c =~ s@(?<=on socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1595         $c =~ s@(?<=server socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1596         $c = highlight_matched_host($c, '(?<=to )[^\s]+');
1597
1598     } elsif ($c =~ m/^Marking the server socket/) {
1599
1600         # Marking the server socket 7 tainted.
1601
1602         $c =~ s@(?<=server socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1603
1604     } elsif ($c =~ m/^Reduced expected bytes to /) {
1605
1606         # Reduced expected bytes to 0 to account for the 1542 ones we already got.
1607         $c =~ s@(?<=bytes to )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1608         $c =~ s@(?<=for the )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1609
1610     } elsif ($c =~ m/^The client closed socket /) {
1611
1612         # The client closed socket 2 while the server socket 4 is still open.
1613         $c =~ s@(?<=closed socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1614         $c =~ s@(?<=server socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1615
1616     } elsif ($c =~ m/^Expected client content length set /) {
1617
1618         # Expected client content length set to 667325411 after reading 4999 bytes.
1619         $c =~ s@(?<=set to )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1620         $c =~ s@(?<=reading )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1621
1622     } elsif ($c =~ m/^Waiting for up to /) {
1623
1624         # Waiting for up to 4999 bytes from the client.
1625         $c =~ s@(?<=up to )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1626
1627     } elsif ($c =~ m/^Looks like we rea/ or
1628              $c =~ m/^Unsetting keep-alive flag/ or
1629              $c =~ m/^No connections to wait/ or
1630              $c =~ m/^Complete client request received/ or
1631              $c =~ m/^Possible pipeline attempt detected./ or
1632              $c =~ m/^POST request detected. The connection will not be kept alive./ or
1633              $c =~ m/^The server still wants to talk, but the client hung up on us./ or
1634              $c =~ m/^The server didn't specify how long the connection will stay open/ or
1635              $c =~ m/^There might be a request body. The connection will not be kept alive/ or
1636              $c =~ m/^Stopping to watch the client socket. There's already another request waiting./ or
1637              $c =~ m/^Done reading from the client\.$/) {
1638
1639         # Looks like we reached the end of the last chunk. We better stop reading.
1640         # Looks like we read the end of the last chunk together with the server \
1641         #  headers. We better stop reading.
1642         # Unsetting keep-alive flag.
1643         # No connections to wait for left.
1644         # Client request arrived in time or the client closed the connection.
1645         # Complete client request received
1646         # Possible pipeline attempt detected. The connection will not be \
1647         #  kept alive and we will only serve the first request.
1648         # POST request detected. The connection will not be kept alive.
1649         # The server still wants to talk, but the client hung up on us.
1650         # The server didn't specify how long the connection will stay open. Assume it's only a second.
1651         # There might be a request body. The connection will not be kept alive.
1652         # Stopping to watch the client socket. There's already another request waiting.
1653         # Done reading from the client\.
1654
1655     } else {
1656
1657         found_unknown_content($c);
1658
1659     }
1660
1661     return $c;
1662 }
1663
1664
1665 sub handle_loglevel_info ($) {
1666
1667     my $c = shift;
1668
1669     if ($c =~ m/^Rewrite detected:/) {
1670
1671         # Rewrite detected: GET http://10.0.0.2:88/blah.txt HTTP/1.1
1672         $c = highlight_matched_request_line($c, '(?<=^Rewrite detected: ).*');
1673
1674     } elsif ($c =~ m/^Decompress(ing deflated|ion didn)/ or
1675              $c =~ m/^Compressed content detected/ or
1676              $c =~ m/^Tagger/
1677             ) {
1678         # Decompressing deflated iob: 117
1679         # Decompression didn't result in any content.
1680         # Compressed content detected, content filtering disabled. Consider recompiling Privoxy\
1681         #  with zlib support or enable the prevent-compression action.
1682         # Tagger 'complete-url' created empty tag. Ignored.
1683
1684         # Ignored for now
1685
1686     } elsif ($c =~ m/^(Re)?loading configuration file /) {
1687
1688         # loading configuration file '/usr/local/etc/privoxy/config':
1689         # Reloading configuration file '/usr/local/etc/privoxy/config'
1690         $c =~ s@(?<=loading configuration file \')([^\']*)@$h{'file'}$1$h{'Standard'}@;
1691
1692     } elsif ($c =~ m/^exiting by signal/) {
1693
1694         # exiting by signal 15 .. bye
1695         $c =~ s@(?<=exiting by signal )(\d+)@$h{'signal'}$1$h{'Standard'}@;
1696
1697     } elsif ($c =~ m/^Privoxy version/) {
1698
1699         # Privoxy version 3.0.7
1700         $c =~ s@(?<=^Privoxy version )(\d+\.\d+\.\d+)$@$h{'version'}$1$h{'Standard'}@;
1701
1702     } elsif ($c =~ m/^Program name: /) {
1703
1704         # Program name: /usr/local/sbin/privoxy
1705         $c =~ s@(?<=Program name: )(.*)@$h{'program-name'}$1$h{'Standard'}@;
1706
1707     } elsif ($c =~ m/^Listening on port /) {
1708
1709         # Listening on port 8118 on IP address 10.0.0.1
1710         $c =~ s@(?<=Listening on port )(\d+)@$h{'port'}$1$h{'Standard'}@;
1711         $c =~ s@(?<=on IP address )(.*)@$h{'ip-address'}$1$h{'Standard'}@;
1712
1713     } elsif ($c =~ m/^\(Re-\)Open(?:ing)? logfile/) {
1714
1715         # (Re-)Open logfile /var/log/privoxy/privoxy.log
1716         $c =~ s@(?<=Open logfile )(.*)@$h{'file'}$1$h{'Standard'}@;
1717
1718     } elsif ($c =~ m/^(Request from|Malformed server response detected)/) {
1719
1720         # Request from 10.0.0.1 denied. limit-connect{,} doesn't allow CONNECT requests to port 443.
1721         # Request from 10.0.0.1 marked for blocking. limit-connect{,} doesn't allow CONNECT requests to port 443.
1722         # Malformed server response detected. Downgrading to HTTP/1.0 impossible.
1723
1724         $c =~ s@(?<=Request from )([^\s]*)@$h{'ip-address'}$1$h{'Standard'}@;
1725         $c =~ s@(denied|blocking)@$h{'warning'}$1$h{'Standard'}@;
1726         $c =~ s@(CONNECT)@$h{'method'}$1$h{'Standard'}@;
1727         $c =~ s@(?<=to port )(\d+)@$h{'port'}$1$h{'Standard'}@;
1728
1729     } elsif ($c =~ m/^Status code/) {
1730
1731         # Status code 304 implies no body.
1732         $c =~ s@(?<=Status code )(\d+)@$h{'status-code'}$1$h{'Standard'}@;
1733
1734     } elsif ($c =~ m/^Method/) {
1735
1736         # Method HEAD implies no body.
1737         $c =~ s@(?<=Method )([^\s]+)@$h{'method'}$1$h{'Standard'}@;
1738
1739     } elsif ($c =~ m/^Buffer limit reached while extending /) {
1740
1741         # Buffer limit reached while extending the buffer (iob). Needed: 4197470. Limit: 4194304
1742         $c =~ s@(?<=Needed: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1743         $c =~ s@(?<=Limit: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1744
1745     } elsif ($c =~ m/^No logfile configured/ or
1746              $c =~ m/^Malformerd HTTP headers detected and MS IIS5 hack enabled/ or
1747              $c =~ m/^Invalid \"chunked\" transfer/ or
1748              $c =~ m/^Support for/ or
1749              $c =~ m/^Flushing header and buffers/
1750              ) {
1751
1752         # No logfile configured. Please enable it before reporting any problems.
1753         # Malformerd HTTP headers detected and MS IIS5 hack enabled. Expect an invalid \
1754         #  response or even no response at all.
1755         # No logfile configured. Logging disabled.
1756         # Invalid "chunked" transfer encoding detected and ignored.
1757         # Support for 'Connection: keep-alive' is experimental, incomplete and\
1758         #  known not to work properly in some situations.
1759         # Flushing header and buffers. Stepping back from filtering.
1760
1761     } else {
1762
1763         found_unknown_content($c);
1764
1765     }
1766
1767     return $c;
1768 }
1769
1770 sub handle_loglevel_cgi ($) {
1771
1772     my $c = shift;
1773
1774     if ($c =~ m/^Granting access to/) {
1775
1776         #Granting access to http://config.privoxy.org/send-stylesheet, referrer http://p.p/ is trustworthy.
1777
1778     } elsif ($c =~ m/^Substituting: s(.)/) {
1779
1780         # Substituting: s/@else-not-FEATURE_ZLIB@.*@endif-FEATURE_ZLIB@//sigTU
1781         # XXX: prone to span several lines
1782
1783         my $delimiter = $1;
1784         #$c =~ s@(?<=failed: )(.*)@$h{'error'}$1$h{'Standard'}@;
1785         $c =~ s@(?!<=\\)($delimiter)@$h{'pcrs-delimiter'}$1$h{'Standard'}@g; # XXX: Too aggressive
1786         #$c =~ s@(?!<=\\)($1)@$h{'pcrs-delimiter'}$1$h{'Standard'}@g;
1787     }
1788
1789     return $c;
1790 }
1791
1792 sub handle_loglevel_force ($) {
1793
1794     my $c = shift;
1795
1796     if ($c =~ m/^Ignored force prefix in request:/) {
1797
1798         # Ignored force prefix in request: "GET http://10.0.0.1/PRIVOXY-FORCE/block HTTP/1.1"
1799         $c =~ s@^(Ignored)@$h{'ignored'}$1$h{'Standard'}@;
1800         $c = highlight_matched_request_line($c, '(?<=request: ")[^"]*');
1801
1802     } elsif ($c =~ m/^Enforcing request:/) {
1803
1804         # Enforcing request: "GET http://10.0.0.1/block HTTP/1.1".
1805         $c = highlight_matched_request_line($c, '(?<=request: ")[^"]*');
1806
1807     } else {
1808
1809         found_unknown_content($c);
1810
1811     }
1812
1813     return $c;
1814 }
1815
1816 sub handle_loglevel_error ($) {
1817
1818     my $c = shift;
1819
1820     if ($c =~ m/^Empty server or forwarder response received on socket \d+./) {
1821
1822         # Empty server or forwarder response received on socket 4.
1823         # Empty server or forwarder response received on socket 3. \
1824         #  Closing client socket 15 without sending data.
1825         $c =~ s@(?<=on socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1826         $c =~ s@(?<=client socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1827     }
1828     # XXX: There are probably more messages that deserve highlighting.
1829
1830     return $c;
1831 }
1832
1833
1834 sub handle_loglevel_ignore ($) {
1835     return shift;
1836 }
1837
1838 sub gather_loglevel_request_stats ($$) {
1839     my $c = shift;
1840     my $thread = shift;
1841     our %stats;
1842
1843     $stats{requests}++;
1844 }
1845
1846 sub gather_loglevel_crunch_stats ($$) {
1847     my $c = shift;
1848     my $thread = shift;
1849     our %stats;
1850
1851     $stats{requests}++;
1852     $stats{crunches}++;
1853 }
1854
1855
1856 sub gather_loglevel_error_stats ($$) {
1857
1858     my $c = shift;
1859     my $thread = shift;
1860     our %stats;
1861     our %thread_data;
1862
1863     if ($c =~ m/^Empty server or forwarder response received on socket \d+./) {
1864
1865         # Empty server or forwarder response received on socket 4.
1866         $stats{'empty-responses'}++;
1867         if ($thread_data{$thread}{'new_connection'}) {
1868             $stats{'empty-responses-on-new-connections'}++;
1869         } else {
1870             $stats{'empty-responses-on-reused-connections'}++;
1871         }
1872     }
1873 }
1874
1875 sub gather_loglevel_connect_stats ($$) {
1876
1877     my $c = shift;
1878     my $thread = shift;
1879     our %thread_data;
1880     our %stats;
1881
1882     if ($c =~ m/^via ([^\s]+) to: [^\s]+/) {
1883
1884         # Connect: via 10.0.0.1:8123 to: www.example.org.noconnect
1885         $thread_data{$thread}{'forwarder'} = $1; # XXX: is this missue?
1886
1887     } elsif ($c =~ m/^to ([^\s]*)$/) {
1888
1889         # Connect: to lists.sourceforge.net:443
1890
1891         $thread_data{$thread}{'forwarder'} = 'direct connection';
1892
1893     } elsif ($c =~ m/^Created new connection to/) {
1894
1895         # Created new connection to www.privoxy.org:80 on socket 11.
1896
1897         $thread_data{$thread}{'new_connection'} = 1;
1898
1899     } elsif ($c =~ m/^Reusing server socket \d./ or
1900              $c =~ m/^Found reusable socket/) {
1901
1902         # Reusing server socket 4. Opened for 10.0.0.1.
1903         # Found reusable socket 9 for www.privoxy.org:80 in slot 0.
1904
1905         $thread_data{$thread}{'new_connection'} = 0;
1906         $stats{'reused-connections'}++;
1907     }
1908 }
1909
1910 sub gather_loglevel_header_stats ($) {
1911
1912     my $c = shift;
1913     my $thread = shift;
1914     our %stats;
1915
1916     if ($c =~ m/^A HTTP\/1\.1 response without/ or
1917         $c =~ m/^Keeping the server header 'Connection: keep-alive' around./)
1918     {
1919         # A HTTP/1.1 response without Connection header implies keep-alive.
1920         # Keeping the server header 'Connection: keep-alive' around.
1921         $stats{'server-keep-alive'}++;
1922     }
1923 }
1924
1925 sub init_stats () {
1926     our %stats = (
1927         requests => 0,
1928         crunches => 0,
1929         'server-keep-alive' => 0,
1930         'reused-connections' => 0,
1931         'empty-responses' => 0,
1932         'empty-responses-on-new-connections' => 0,
1933         'empty-responses-on-reused-connections' => 0,
1934         );
1935 }
1936
1937 sub get_percentage ($$) {
1938     my $big = shift;
1939     my $small = shift;
1940     return "NaN" if ($big eq 0);
1941     return sprintf("%.2f%%", $small / $big * 100);
1942 }
1943
1944 sub print_stats () {
1945
1946     our %stats;
1947     my $new_connections = $stats{requests} - $stats{crunches} - $stats{'reused-connections'};
1948     my $outgoing_requests = $stats{requests} - $stats{crunches};
1949
1950     if ($stats{requests} eq 0) {
1951         print "No requests yet.\n";
1952         return;
1953     }
1954
1955     print "Client requests total: " . $stats{requests} . "\n";
1956     print "Crunches: " . $stats{crunches} . " (" .
1957         get_percentage($stats{requests}, $stats{crunches}) . ")\n";
1958     print "Outgoing requests: " . $outgoing_requests . " (" .
1959         get_percentage($stats{requests}, $outgoing_requests) . ")\n";
1960     print "Server keep-alive offers: " . $stats{'server-keep-alive'} . " (" .
1961         get_percentage($stats{requests}, $stats{'server-keep-alive'}) . ")\n";
1962     print "New outgoing connections: " . $new_connections . " (" .
1963         get_percentage($stats{requests}, $new_connections) . ")\n";
1964     print "Reused connections: " . $stats{'reused-connections'} . " (" .
1965         get_percentage($stats{requests}, $stats{'reused-connections'}) . ")\n";
1966     print "Empty responses: " . $stats{'empty-responses'} . " (" .
1967         get_percentage($stats{requests}, $stats{'empty-responses'}) . ")\n";
1968     print "Empty responses on new connections: "
1969          . $stats{'empty-responses-on-new-connections'} . " (" .
1970         get_percentage($stats{requests}, $stats{'empty-responses-on-new-connections'})
1971         . ")\n";
1972     print "Empty responses on reused connections: " .
1973         $stats{'empty-responses-on-reused-connections'} . " (" .
1974         get_percentage($stats{requests}, $stats{'empty-responses-on-reused-connections'}) .
1975         ")\n";
1976 }
1977
1978
1979 ################################################################################
1980 # Functions that actually print stuff
1981 ################################################################################
1982
1983 sub print_clf_message () {
1984
1985     our ($ip, $timestamp, $request_line, $status_code, $size);
1986     my $output = '';
1987
1988     return if DEBUG_SUPPRESS_LOG_MESSAGES;
1989
1990     # Rebuild highlighted
1991     $output .= $h{'Number'} . $ip . $h{'Standard'};
1992     $output .= " - - ";
1993     $output .= "[" . $h{'Timestamp'} . $timestamp . $h{'Standard'} . "]";
1994     $output .= " ";
1995     $output .= "\"" . highlight_request_line("$request_line") . "\"";
1996     $output .= " ";
1997     $output .= $h{'Status'} . $status_code . $h{'Standard'};
1998     $output .= " ";
1999     $output .= $h{'Number'} . $size . $h{'Standard'};
2000     $output .= $line_end;
2001
2002     print $output;
2003 }
2004
2005 sub print_non_clf_message ($) {
2006
2007     my $content = shift;
2008     my $msec_string = "." . $req{$t}{'msecs'} unless $no_msecs_mode;
2009     my $line_start = $html_output_mode ? '' : $h{"Standard"};
2010
2011     return if DEBUG_SUPPRESS_LOG_MESSAGES;
2012
2013     print $line_start
2014         . $time_colours[$time_colour_index % 2]
2015         . $req{$t}{'time-stamp'}
2016         . $msec_string
2017         . $h{Standard} . " "
2018         . $thread_colours{$t}
2019         . $t
2020         . $h{Standard}
2021         . " "
2022         . $h{$req{$t}{'log-level'}}
2023         . $req{$t}{'log-level'}
2024         . $h{Standard}
2025         . ": "
2026         . $content
2027         . $line_end;
2028 }
2029
2030 sub parse_loop () {
2031
2032     my ($day, $time_stamp, $thread, $log_level, $content, $c, $msecs);
2033     my $last_msecs  = 0;
2034     my $last_thread = 0;
2035     my $last_timestamp = 0;
2036     my $filters_that_did_nothing;
2037     my $key;
2038     my $time_colour;
2039     $time_colour = paint_it('white');
2040
2041     my %log_level_handlers = (
2042         'Re-Filter'         => \&handle_loglevel_re_filter,
2043         'Header'            => \&handle_loglevel_header,
2044         'Connect'           => \&handle_loglevel_connect,
2045         'Redirect'          => \&handle_loglevel_redirect,
2046         'Request'           => \&handle_loglevel_request,
2047         'Crunch'            => \&handle_loglevel_crunch,
2048         'Gif-Deanimate'     => \&handle_loglevel_gif_deanimate,
2049         'Info'              => \&handle_loglevel_info,
2050         'CGI'               => \&handle_loglevel_cgi,
2051         'Force'             => \&handle_loglevel_force,
2052         'Error'             => \&handle_loglevel_error,
2053         'Fatal error'       => \&handle_loglevel_ignore,
2054         'Writing'           => \&handle_loglevel_ignore,
2055         'Unknown log level' => \&handle_loglevel_ignore,
2056     );
2057
2058     while (<>) {
2059
2060         if (m/^(\w{3} \d{2}) (\d\d:\d\d:\d\d)\.?(\d+)? (?:Privoxy\()?([^\)\s]*)[\)]? ([\w -]*): (.*?)\r?$/) {
2061             $thread = $t = $4;
2062             $req{$t}{'day'} = $day = $1;
2063             $req{$t}{'time-stamp'} = $time_stamp = $2;
2064             $req{$t}{'msecs'} = $msecs = $3 ? $3 : 0; # Only the cool kids have micro second resolution;
2065             $req{$t}{'log-level'} = $log_level = $5;
2066             $req{$t}{'content'} = $content = $c = $6;
2067             $req{$t}{'log-message'} = $_;
2068             $no_special_header_highlighting = 0;
2069
2070             if (defined($log_level_handlers{$log_level})) {
2071
2072                 $content = $log_level_handlers{$log_level}($content);
2073
2074             } else {
2075
2076                 die "No handler found for log level \"$log_level\"\n";
2077             }
2078
2079             # Highlight Truncations
2080             if (length($_) > 4000) {
2081                 $content =~ s@(too long, truncated)]$@$h{'Truncation'}$1$h{'Standard'}]@g;
2082             }
2083
2084             next unless $content;
2085
2086             # Register threads to keep the colour constant
2087             if (!defined($thread_colours{$thread})) {
2088                 $thread_colours{$thread} = $all_colours[$thread_colour_index % @all_colours];
2089                 $thread_colour_index++;
2090             }
2091
2092             # Switch timestamp colour if timestamps differ
2093             if (($msecs ne $last_msecs) || ($time_stamp ne $last_timestamp)) {
2094                debug_message("Tick tack!") if DEBUG_TICKS;
2095                $time_colour = $time_colours[$time_colour_index % 2];
2096                $time_colour_index++;
2097                $last_msecs = $msecs;
2098                $last_timestamp = $time_stamp;
2099             }
2100
2101             $last_thread = $thread;
2102
2103             print_non_clf_message($content);
2104
2105         } elsif (m/^((?:\d+\.\d+\.\d+\.\d+|[:\d]+)) - - \[(.*)\] "(.*)" (\d+) (\d+)/) {
2106
2107             # LOG_LEVEL_CLF lines look like this
2108             # 61.152.239.32 - - [04/Mar/2007:18:28:23 +0100] "GET \
2109             #  http://ad.yieldmanager.com/imp?z=1&Z=120x600&s=109339&u=http%3A%2F%2Fwww.365loan.co.uk%2F&r=1\
2110             #  HTTP/1.1" 403 1730
2111             our ($ip, $timestamp, $request_line, $status_code, $size) = ($1, $2, $3, $4, $5);
2112
2113             print_clf_message();
2114
2115         } else {
2116
2117             # Some Privoxy log messages span more than one line,
2118             # usually to dump lots of content that doesn't need any syntax highlighting.
2119             # XXX: add mechanism to forward these lines to the right handler anyway.
2120             chomp();
2121             unless (DEBUG_SUPPRESS_LOG_MESSAGES or (SUPPRESS_EMPTY_LINES and m/^\s+$/)) {
2122                 print and print get_line_end(); # unless (SUPPRESS_EMPTY_LINES and m/^\s+$/);
2123             }
2124         }
2125     }
2126 }
2127
2128 sub stats_loop () {
2129
2130     my ($day, $time_stamp, $thread, $log_level, $content, $c, $msecs);
2131     my %log_level_handlers = (
2132          'Re-Filter'         => \&handle_loglevel_ignore,
2133          'Header'            => \&gather_loglevel_header_stats,
2134          'Connect'           => \&gather_loglevel_connect_stats,
2135          'Redirect'          => \&handle_loglevel_ignore,
2136          'Request'           => \&gather_loglevel_request_stats,
2137          'Crunch'            => \&gather_loglevel_crunch_stats,
2138          'Gif-Deanimate'     => \&handle_loglevel_ignore,
2139          'Info'              => \&handle_loglevel_ignore,
2140          'CGI'               => \&handle_loglevel_ignore,
2141          'Force'             => \&handle_loglevel_ignore,
2142          'Error'             => \&gather_loglevel_error_stats,
2143          'Fatal error'       => \&handle_loglevel_ignore,
2144          'Writing'           => \&handle_loglevel_ignore,
2145          'Unknown log level' => \&handle_loglevel_ignore
2146     );
2147
2148     while (<>) {
2149         if (m/^(\w{3} \d{2}) (\d\d:\d\d:\d\d)\.?(\d+)? (?:Privoxy\()?([^\)\s]*)[\)]? ([\w -]*): (.*?)\r?$/) {
2150             $day = $1;
2151             $time_stamp = $2;
2152             $msecs = $3 ? $3 : 0;
2153             $log_level = $5;
2154             $content = $c = $6;
2155             $thread = $4;
2156
2157             if (defined($log_level_handlers{$log_level})) {
2158
2159                 $content = $log_level_handlers{$log_level}($content, $thread);
2160
2161             } else {
2162
2163                 die "No handler found for log level \"$log_level\"\n";
2164
2165             }
2166         }
2167     }
2168
2169     print_stats();
2170
2171 }
2172
2173 sub VersionMessage {
2174     my $version_message;
2175
2176     $version_message .= 'Privoxy-Log-Parser ' . PRIVOXY_LOG_PARSER_VERSION  . "\n";
2177     $version_message .= 'Copyright (C) 2007-2009 Fabian Keil <fk@fabiankeil.de>' . "\n";
2178     $version_message .= 'http://www.fabiankeil.de/sourcecode/privoxy-log-parser/' . "\n";
2179
2180     print $version_message;
2181 }
2182
2183 sub get_cli_options () {
2184
2185     our %cli_options = (
2186         'html-output'              => CLI_OPTION_DEFAULT_TO_HTML_OUTPUT,
2187         'title'                    => CLI_OPTION_TITLE,
2188         'no-syntax-highlighting'   => CLI_OPTION_NO_SYNTAX_HIGHLIGHTING,
2189         'no-embedded-css'          => CLI_OPTION_NO_EMBEDDED_CSS,
2190         'no-msecs'                 => CLI_OPTION_NO_MSECS,
2191         'show-ineffective-filters' => CLI_OPTION_SHOW_INEFFECTIVE_FILTERS,
2192         'accept-unknown-messages'  => CLI_OPTION_ACCEPT_UNKNOWN_MESSAGES,
2193         'statistics'               => CLI_OPTION_STATISTICS,
2194     );
2195
2196     GetOptions (
2197         'html-output'              => \$cli_options{'html-output'},
2198         'title'                    => \$cli_options{'title'},
2199         'no-syntax-highlighting'   => \$cli_options{'no-syntax-highlighting'},
2200         'no-embedded-css'          => \$cli_options{'no-embedded-css'},
2201         'no-msecs'                 => \$cli_options{'no-msecs'},
2202         'show-ineffective-filters' => \$cli_options{'show-ineffective-filters'},
2203         'accept-unknown-messages'  => \$cli_options{'accept-unknown-messages'},
2204         'statistics'               => \$cli_options{'statistics'},
2205         'version'                  => sub { VersionMessage && exit(0) },
2206         'help'                     => \&help,
2207    ) or exit(1);
2208
2209    $html_output_mode = cli_option_is_set('html-output');
2210    $no_msecs_mode = cli_option_is_set('no-msecs');
2211    $line_end = get_line_end();
2212 }
2213
2214 sub help () {
2215
2216     our %cli_options;
2217
2218     VersionMessage();
2219
2220     print << "    EOF"
2221
2222 Options and their default values if they have any:
2223     [--accept-unknown-messages]
2224     [--html-output]
2225     [--no-embedded-css]
2226     [--no-msecs]
2227     [--no-syntax-highlighting]
2228     [--show-ineffective-filters]
2229     [--statistics]
2230     [--title $cli_options{'title'}]
2231     [--version]
2232 see "perldoc $0" for more information
2233     EOF
2234     ;
2235     exit(0);
2236 }
2237
2238 ################################################################################
2239 # main
2240 ################################################################################
2241 sub main () {
2242
2243     get_cli_options();
2244     set_background(DEFAULT_BACKGROUND);
2245     prepare_our_stuff();
2246
2247     print_intro();
2248
2249     if (cli_option_is_set('statistics')) {
2250         stats_loop();
2251     } else {
2252         parse_loop();
2253     }
2254
2255     print_outro();
2256 }
2257
2258 main();
2259
2260 =head1 NAME
2261
2262 B<privoxy-log-parser> - A parser and syntax-highlighter for Privoxy log messages
2263
2264 =head1 SYNOPSIS
2265
2266 B<privoxy-log-parser> [B<--accept-unknown-messages>] [B<--html-output>]
2267 [B<--no-msecs>] [B<--no-syntax-higlighting>] [B<--show-ineffective-filters>]
2268 [B<--version>]
2269
2270 =head1 DESCRIPTION
2271
2272 B<privoxy-log-parser> reads Privoxy log messages and
2273
2274 - syntax-highlights recognized lines,
2275
2276 - reformats some of them for easier comprehension,
2277
2278 - filters out less useful messages, and
2279
2280 - (in some cases) calculates additional information,
2281   like the compression ratio or how a filter affected
2282   the content size.
2283
2284 With B<privoxy-log-parser> you should be able to increase Privoxy's log level
2285 without getting confused by the resulting amount of output. For example for
2286 "debug 64" B<privoxy-log-parser> will (by default) only show messages that
2287 affect the content. If a filter doesn't cause any hits, B<privoxy-log-parser>
2288 will hide the "filter foo caused 0 hits" message.
2289
2290 =head1 OPTIONS
2291
2292 [B<--accept-unknown-messages>] Don't print warnings in case of unknown messages,
2293 just don't highlight them.
2294
2295 [B<--html-output>] Use HTML and CSS for the syntax highlighting. If this option is
2296 omitted, ANSI escape sequences are used unless B<--no-syntax-highlighting> is active.
2297 This option is only intended to make embedding log excerpts in web pages easier.
2298 It does not escape any input!
2299
2300 [B<--no-msecs>] Don't expect milisecond resolution
2301
2302 [B<--no-syntax-highlighting>] Disable syntax-highlighting. Useful when
2303 the filtered output is piped into less in which case the ANSI control
2304 codes don't work, or if the terminal itself doesn't support the control
2305 codes.
2306
2307 [B<--show-ineffective-filters>] Don't suppress log lines for filters
2308 that didn't modify the content.
2309
2310 [B<--statistics>] Gather various statistics instead of syntax highlighting
2311 log messages. This is an experimental feature, if the results look wrong
2312 they very well might be. Also note that the results a pretty much guaranteed
2313 to be incorrect if Privoxy and Privoxy-Log-Parser aren't in sync.
2314
2315 [B<--version>] Print version and exit.
2316
2317 =head1 EXAMPLES
2318
2319 To monitor a log file:
2320
2321 tail -F /usr/jails/privoxy-jail/var/log/privoxy/privoxy.log | B<privoxy-log-parser>
2322
2323 Replace '-F' with '-f' if your tail implementation lacks '-F' support
2324 or if the log won't get rotated anyway. The log file location depends
2325 on your system (Doh!).
2326
2327 To monitor Privoxy without having it write to a log file:
2328
2329 privoxy --no-daemon /usr/jails/privoxy-jail/usr/local/etc/privoxy/config 2>&1 | B<privoxy-log-parser>
2330
2331 Again, the config file location depends on your system. Output redirection
2332 depends on your shell, the above works with bourne shells.
2333
2334 To read a processed Privoxy log file from top to bottom, letting the content
2335 scroll by slightly faster than you can read:
2336
2337 B<privoxy-log-parser> < /usr/jails/privoxy-jail/var/log/privoxy/privoxy.log
2338
2339 This is probably only useful to fill screens in the background of haxor movies.
2340
2341 =head1 CAVEATS
2342
2343 Syntax highlighting with ANSI escape sequences will look strange
2344 if your background color isn't black.
2345
2346 Some messages aren't recognized yet and will not be fully highlighted.
2347
2348 B<privoxy-log-parser> is developed with Privoxy 3.0.7 or later in mind,
2349 using earlier Privoxy versions will probably result in an increased amount
2350 of unrecognized log lines.
2351
2352 Privoxy's log files tend to be rather large. If you use HTML
2353 highlighting some browsers can't handle them, get confused and
2354 will eventually crash because of segmentation faults or unexpected
2355 exceptions. This is a problem in the browser and not B<privoxy-log-parser>'s
2356 fault.
2357
2358 =head1 BUGS
2359
2360 Many settings can't be controlled through command line options yet.
2361
2362 =head1 SEE ALSO
2363
2364 privoxy(1)
2365
2366 =head1 AUTHOR
2367
2368 Fabian Keil <fk@fabiankeil.de>
2369
2370 =cut