tools/privoxy-log-parser.pl

   1 #!/usr/bin/perl
   2
   3 ################################################################################
   4 # privoxy-log-parser
   5 #
   6 # A parser for Privoxy log messages. For incomplete documentation run
   7 # perldoc privoxy-log-parser(.pl), for fancy screenshots see:
   8 #
   9 # http://www.fabiankeil.de/sourcecode/privoxy-log-parser/
  10 #
  11 # $Id: privoxy-log-parser.pl,v 1.91 2010/08/28 13:21:24 fabiankeil Exp $
  12 #
  13 # TODO:
  14 #       - LOG_LEVEL_CGI, LOG_LEVEL_ERROR, LOG_LEVEL_WRITE content highlighting
  15 #       - create fancy statistics
  16 #       - grep through Privoxy sources to find unsupported log messages
  17 #       - hunt down substitutions that match content from variables which
  18 #         can contain stuff like ()?'[]
  19 #       - replace $h{'foo'} with h('foo') where possible
  20 #       - hunt down XXX comments instead of just creating them
  21 #       - add example log lines for every regex and mark them up for
  22 #         regression testing
  23 #       - Handle incomplete input without Perl warning about undefined variables.
  24 #       - Use generic highlighting function that takes a regex and the
  25 #         hash key as input.
  26 #       - Add --compress and --decompress options.
  27 #
  28 # Copyright (c) 2007-2010 Fabian Keil <fk@fabiankeil.de>
  29 #
  30 # Permission to use, copy, modify, and distribute this software for any
  31 # purpose with or without fee is hereby granted, provided that the above
  32 # copyright notice and this permission notice appear in all copies.
  33 #
  34 # THE SOFTWARE IS PROVIDED "AS IS" AND THE AUTHOR DISCLAIMS ALL WARRANTIES
  35 # WITH REGARD TO THIS SOFTWARE INCLUDING ALL IMPLIED WARRANTIES OF
  36 # MERCHANTABILITY AND FITNESS. IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR
  37 # ANY SPECIAL, DIRECT, INDIRECT, OR CONSEQUENTIAL DAMAGES OR ANY DAMAGES
  38 # WHATSOEVER RESULTING FROM LOSS OF USE, DATA OR PROFITS, WHETHER IN AN
  39 # ACTION OF CONTRACT, NEGLIGENCE OR OTHER TORTIOUS ACTION, ARISING OUT OF
  40 # OR IN CONNECTION WITH THE USE OR PERFORMANCE OF THIS SOFTWARE.
  41 ################################################################################
  42
  43 use strict;
  44 use warnings;
  45 use Getopt::Long;
  46
  47 use constant {
  48     PRIVOXY_LOG_PARSER_VERSION => '0.6',
  49     # Feel free to mess with these ...
  50     DEFAULT_BACKGROUND => 'black',  # Choose registered colour (like 'black')
  51     DEFAULT_TEXT_COLOUR => 'white', # Choose registered colour (like 'black')
  52     HEADER_DEFAULT_COLOUR => 'yellow',
  53     REGISTER_HEADERS_WITH_THE_SAME_COLOUR => 1,
  54
  55     CLI_OPTION_DEFAULT_TO_HTML_OUTPUT => 0,
  56     CLI_OPTION_TITLE => 'Privoxy-Log-Parser in da house',
  57     CLI_OPTION_NO_EMBEDDED_CSS => 0,
  58     CLI_OPTION_NO_MSECS => 0,
  59     CLI_OPTION_NO_SYNTAX_HIGHLIGHTING => 0,
  60     CLI_OPTION_SHORTEN_THREAD_IDS => 0,
  61     CLI_OPTION_SHOW_INEFFECTIVE_FILTERS => 0,
  62     CLI_OPTION_ACCEPT_UNKNOWN_MESSAGES => 0,
  63     CLI_OPTION_STATISTICS => 0,
  64     CLI_OPTION_URL_STATISTICS_THRESHOLD => 5,
  65
  66     SUPPRESS_SUCCEEDED_FILTER_ADDITIONS => 1,
  67     SHOW_SCAN_INTRO => 0,
  68     SHOW_FILTER_READIN_IN => 0,
  69     SUPPRESS_EMPTY_LINES => 1,
  70     SUPPRESS_SUCCESSFUL_CONNECTIONS => 1,
  71     SUPPRESS_ACCEPTED_CONNECTIONS => 1,
  72     SUPPRESS_GIF_NOT_CHANGED => 1,
  73     SUPPRESS_NEED_TO_DE_CHUNK_FIRST => 1,
  74
  75     DEBUG_HEADER_REGISTERING => 0,
  76     DEBUG_HEADER_HIGHLIGHTING => 0,
  77     DEBUG_TICKS => 0,
  78     DEBUG_PAINT_IT => 0,
  79     DEBUG_SUPPRESS_LOG_MESSAGES => 0,
  80
  81     PUNISH_MISSING_LOG_KNOWLEDGE_WITH_DEATH => 0,
  82     PUNISH_MISSING_HIGHLIGHT_KNOWLEDGE_WITH_DEATH => 1,
  83
  84     LOG_UNPARSED_LINES_TO_EXTRA_FILE => 0,
  85     ERROR_LOG_FILE => '/var/log/privoxy-log-parser',
  86
  87     # You better leave these alone unless you know what you're doing.
  88     COLOUR_RESET      => "\033[0;0m",
  89     ESCAPE => "\033[",
  90 };
  91
  92 # For performance reasons, these are global.
  93
  94 my $t;
  95 my %req; # request data from previous lines
  96 my %h;
  97 my %thread_colours;
  98 my @all_colours;
  99 my @time_colours;
 100 my $thread_colour_index = 0;
 101 my $header_colour_index = 0;
 102 my $time_colour_index = 0;
 103 my %header_colours;
 104 my $no_special_header_highlighting;
 105 my %reason_colours;
 106 my %h_colours;
 107 my $header_highlight_regex = '';
 108
 109 my $html_output_mode;
 110 my $no_msecs_mode; # XXX: should probably be removed
 111 my $shorten_thread_ids;
 112 my $line_end;
 113
 114 sub prepare_our_stuff () {
 115
 116     # Syntax Higlight hash
 117     @all_colours = (
 118         'red', 'green', 'brown', 'blue', 'purple', 'cyan',
 119         'light_gray', 'light_red', 'light_green', 'yellow',
 120         'light_blue', 'pink', 'light_cyan', 'white'
 121     );
 122
 123     %h = (
 124         # LOG_LEVEL
 125         Info            => 'blue',
 126         Header          => 'green',
 127         Filter          => 'purple', # XXX: Used?
 128         'Re-Filter'     => 'purple',
 129         Connect         => 'brown',
 130         Request         => 'light_cyan',
 131         CGI             => 'light_green',
 132         Redirect        => 'cyan',
 133         Error           => 'light_red',
 134         Crunch          => 'cyan',
 135         'Fatal error'   => 'light_red',
 136         'Gif-Deanimate' => 'blue',
 137         Force           => 'red',
 138         Writing         => 'light_green',
 139         Received        => 'yellow',
 140         # ----------------------
 141         URL                  => 'yellow',
 142         path                 => 'brown',
 143         request_             => 'brown', # host+path but no protocol
 144         'ip-address'         => 'yellow',
 145         Number               => 'yellow',
 146         Standard             => 'reset',
 147         Truncation           => 'light_red',
 148         Status               => 'brown',
 149         Timestamp            => 'brown',
 150         Crunching            => 'light_red',
 151         crunched             => 'light_red',
 152         'Request-Line'       => 'pink',
 153         method               => 'purple',
 154         destination          => 'yellow',
 155         'http-version'       => 'pink',
 156         'crunch-pattern'     => 'pink',
 157         not                  => 'brown',
 158         file                 => 'brown',
 159         signal               => 'yellow',
 160         version              => 'green',
 161         'program-name'       => 'cyan',
 162         port                 => 'red',
 163         host                 => 'red',
 164         warning              => 'light_red',
 165         debug                => 'light_red',
 166         filter               => 'green',
 167         tag                  => 'green',
 168         tagger               => 'green',
 169         'status-message'     => 'light_cyan',
 170         'status-code'        => 'yellow',
 171         'invalid-request'    => 'light_red',
 172         'hits'               => 'yellow',
 173         error                => 'light_red',
 174         'rewritten-URL'      => 'light_red',
 175         'pcrs-delimiter'     => 'light_red',
 176         'ignored'            => 'light_red',
 177         'action-bits-update' => 'light_red',
 178         'configuration-line' => 'red',
 179         'content-type'       => 'yellow',
 180     );
 181
 182     %h_colours = %h;
 183
 184     # Header colours need their own hash so the keys can be accessed properly
 185     %header_colours = (
 186         # Prefilled with headers that should not appear with default header colours
 187         Cookie => 'light_red',
 188         'Set-Cookie' => 'light_red',
 189         Warning => 'light_red',
 190         Default => HEADER_DEFAULT_COLOUR,
 191     );
 192
 193     # Crunch reasons need their own hash as well
 194     %reason_colours = (
 195         'Unsupported HTTP feature'               => 'light_red',
 196         Blocked                                  => 'light_red',
 197         Untrusted                                => 'light_red',
 198         Redirected                               => 'green',
 199         'CGI Call'                               => 'white',
 200         'DNS failure'                            => 'red',
 201         'Forwarding failed'                      => 'light_red',
 202         'Connection failure'                     => 'light_red',
 203         'Out of memory (may mask other reasons)' => 'light_red',
 204         'No reason recorded'                     => 'light_red',
 205     );
 206
 207     @time_colours = ('white', 'light_gray');
 208
 209     # Translate highlight strings into highlight code
 210     prepare_highlight_hash(\%header_colours);
 211     prepare_highlight_hash(\%reason_colours);
 212     prepare_highlight_hash(\%h);
 213     prepare_colour_array(\@all_colours);
 214     prepare_colour_array(\@time_colours);
 215     init_css_colours();
 216
 217     init_stats();
 218 }
 219
 220 sub paint_it ($) {
 221 ###############################################################
 222 # Takes a colour string and returns an ANSI escape sequence
 223 # (unless --no-syntax-highlighting is used).
 224 # XXX: The Rolling Stones reference has to go.
 225 ###############################################################
 226
 227     my $colour = shift @_;
 228
 229     return "" if cli_option_is_set('no-syntax-highlighting');
 230
 231     my %light = (
 232         black       => 0,
 233         red         => 0,
 234         green       => 0,
 235         brown       => 0,
 236         blue        => 0,
 237         purple      => 0,
 238         cyan        => 0,
 239         light_gray  => 0,
 240         gray        => 0,
 241         dark_gray   => 1,
 242         light_red   => 1,
 243         light_green => 1,
 244         yellow      => 1,
 245         light_blue  => 1,
 246         pink        => 1,
 247         light_cyan  => 1,
 248         white       => 1,
 249     );
 250
 251     my %text = (
 252         black       => 30,
 253         red         => 31,
 254         green       => 32,
 255         brown       => 33,
 256         blue        => 34,
 257         purple      => 35,
 258         cyan        => 36,
 259         gray        => 37,
 260         light_gray  => 37,
 261         dark_gray   => 30,
 262         light_red   => 31,
 263         light_green => 32,
 264         yellow      => 33,
 265         light_blue  => 34,
 266         pink        => 35,
 267         light_cyan  => 36,
 268         white       => 37,
 269     );
 270
 271     my $bg_code = get_background();
 272     my $colour_code;
 273     our $default = default_colours();
 274
 275     if (defined($text{$colour})) {
 276         $colour_code  = ESCAPE;
 277         $colour_code .= $text{$colour};
 278         $colour_code .= ";";
 279         $colour_code .= $light{$colour} ? "1" : "2";
 280         $colour_code .= ";";
 281         $colour_code .= $bg_code;
 282         $colour_code .= "m";
 283         debug_message $colour . " is \'" . $colour_code . $colour . $default . "\'" if DEBUG_PAINT_IT;
 284
 285     } elsif ($colour =~ /reset/) {
 286
 287         $colour_code = default_colours();
 288
 289     } else {
 290
 291         die "What's $colour supposed to mean?\n";
 292     }
 293
 294     return $colour_code;
 295 }
 296
 297 sub get_semantic_html_markup ($) {
 298 ###############################################################
 299 # Takes a string and returns a span element
 300 ###############################################################
 301
 302     my $type = shift @_;
 303     my $code;
 304
 305     if ($type =~ /Standard/) {
 306         $code = '</span>';
 307     } else {
 308         $type = lc($type);
 309         $code = '<span title="' . $type . '" class="' . $type . '">';
 310     }
 311
 312     return $code;
 313 }
 314
 315 sub cli_option_is_set ($) {
 316
 317     our %cli_options;
 318     my $cli_option = shift;
 319
 320     die "Unknown CLI option: $cli_option" unless defined $cli_options{$cli_option};
 321
 322     return $cli_options{$cli_option};
 323 }
 324
 325 sub get_html_title () {
 326
 327     our %cli_options;
 328     return $cli_options{'title'};
 329
 330 }
 331
 332 sub init_css_colours() {
 333
 334     our %css_colours = (
 335         black       => "000",
 336         red         => "F00",
 337         green       => "0F0",
 338         brown       => "C90",
 339         blue        => "0F0",
 340         purple      => "F06", # XXX: wrong
 341         cyan        => "F09", # XXX: wrong
 342         light_gray  => "999",
 343         gray        => "333",
 344         dark_gray   => "222",
 345         light_red   => "F33",
 346         light_green => "33F",
 347         yellow      => "FF0",
 348         light_blue  => "30F",
 349         pink        => "F0F",
 350         light_cyan  => "66F",
 351         white       => "FFF",
 352     );
 353 }
 354
 355 sub get_css_colour ($) {
 356
 357    our %css_colours;
 358    my $colour = shift;
 359
 360    die "What's $colour supposed to mean?\n" unless defined($css_colours{$colour});
 361
 362    return '#' . $css_colours{$colour};
 363 }
 364
 365 sub get_css_line ($) {
 366
 367     my $class = shift;
 368     my $css_line;
 369
 370     $css_line .= '.' . lc($class) . ' {'; # XXX: lc() shouldn't be necessary
 371     die "What's $class supposed to mean?\n" unless defined($h_colours{$class});
 372     $css_line .= 'color:' . get_css_colour($h_colours{$class}) . ';';
 373     $css_line .= 'background-color:' . get_css_colour(DEFAULT_BACKGROUND) . ';';
 374     $css_line .= '}' . "\n";
 375
 376     return $css_line;
 377 }
 378
 379 sub get_css_line_for_colour ($) {
 380
 381     my $colour = shift;
 382     my $css_line;
 383
 384     $css_line .= '.' . lc($colour) . ' {'; # XXX: lc() shouldn't be necessary
 385     $css_line .= 'color:' . get_css_colour($colour) . ';';
 386     $css_line .= 'background-color:' . get_css_colour(DEFAULT_BACKGROUND) . ';';
 387     $css_line .= '}' . "\n";
 388
 389     return $css_line;
 390 }
 391
 392 # XXX: Wrong solution
 393 sub get_missing_css_lines () {
 394
 395     my $css_line;
 396
 397     $css_line .= '.' . 'default' . ' {';
 398     $css_line .= 'color:' . HEADER_DEFAULT_COLOUR . ';';
 399     $css_line .= 'background-color:' . get_css_colour(DEFAULT_BACKGROUND) . ';';
 400     $css_line .= '}' . "\n";
 401
 402     return $css_line;
 403 }
 404
 405 sub get_css () {
 406
 407     our %css_colours; #XXX: Wrong solution
 408
 409     my $css = '';
 410
 411     $css .= '.privoxy-log {';
 412     $css .= 'color:' . get_css_colour(DEFAULT_TEXT_COLOUR) . ';';
 413     $css .= 'background-color:' . get_css_colour(DEFAULT_BACKGROUND) . ';';
 414     $css .= '}' . "\n";
 415
 416     foreach my $key (keys %h_colours) {
 417
 418         next if ($h_colours{$key} =~ m/reset/); #XXX: Wrong solution.
 419         $css .= get_css_line($key);
 420
 421     }
 422
 423     foreach my $colour (keys %css_colours) {
 424
 425         $css .= get_css_line_for_colour($colour);
 426
 427     }
 428
 429     $css .= get_missing_css_lines(); #XXX: Wrong solution
 430
 431     return $css;
 432 }
 433
 434 sub print_intro () {
 435
 436     my $intro = '';
 437
 438     if (cli_option_is_set('html-output')) {
 439
 440         my $title = get_html_title();
 441
 442         $intro .= '<html><head>';
 443         $intro .= '<title>' . $title . '</title>';
 444         $intro .= '<style>' . get_css() . '</style>' unless cli_option_is_set('no-embedded-css');
 445         $intro .= '</head><body>';
 446         $intro .= '<h1>' . $title . '</h1><p class="privoxy-log">';
 447
 448         print $intro;
 449     }
 450 }
 451
 452 sub print_outro () {
 453
 454     my $outro = '';
 455
 456     if (cli_option_is_set('html-output')) {
 457
 458         $outro = '</p></body></html>';
 459         print $outro;
 460
 461     }
 462 }
 463
 464 sub get_line_end () {
 465     return cli_option_is_set('html-output') ? "<br>\n" : "\n";
 466 }
 467
 468 sub get_colour_html_markup ($) {
 469 ###############################################################
 470 # Takes a colour string a span element. XXX: WHAT?
 471 # XXX: This function shouldn't be necessary, the
 472 # markup should always be semantically correct.
 473 ###############################################################
 474
 475     my $type = shift @_;
 476     my $code;
 477
 478     if ($type =~ /Standard/) {
 479         $code = '</span>';
 480     } else {
 481         $code = '<span class="' . lc($type) . '">';
 482     }
 483
 484     return $code;
 485 }
 486
 487 sub default_colours () {
 488     # XXX: Properly
 489     our $bg_code;
 490     return reset_colours();
 491 }
 492
 493 sub show_colours () {
 494     # XXX: Implement
 495 }
 496
 497 sub reset_colours () {
 498     return ESCAPE . "0m";
 499 }
 500
 501 sub set_background ($){
 502
 503     my $colour = shift;
 504     our $bg_code;
 505     my %backgrounds = (
 506               black       => "40",
 507               red         => "41",
 508               green       => "42",
 509               brown       => "43",
 510               blue        => "44",
 511               magenta     => "45",
 512               cyan        => "46",
 513               white       => "47",
 514               default     => "49",
 515     );
 516
 517     if (defined($backgrounds{$colour})) {
 518         $bg_code = $backgrounds{$colour};
 519     } else {
 520         die "Invalid background colour: " . $colour;
 521     }
 522 }
 523
 524 sub get_background (){
 525     return our $bg_code;
 526 }
 527
 528 sub prepare_highlight_hash ($) {
 529     my $ref = shift;
 530
 531     foreach my $key (keys %$ref) {
 532         $$ref{$key} = $html_output_mode ?
 533             get_semantic_html_markup($key) :
 534             paint_it($$ref{$key});
 535     }
 536 }
 537
 538 sub prepare_colour_array ($) {
 539     my $ref = shift;
 540
 541     foreach my $i (0 ... @$ref - 1) {
 542         $$ref[$i] = $html_output_mode ?
 543             get_colour_html_markup($$ref[$i]) :
 544             paint_it($$ref[$i]);
 545     }
 546 }
 547
 548 sub found_unknown_content ($) {
 549
 550     my $unknown = shift;
 551     my $message;
 552
 553     return if cli_option_is_set('accept-unknown-messages');
 554
 555     return if ($unknown =~ /\[too long, truncated\]$/);
 556
 557     $message = "found_unknown_content: Don't know how to highlight: ";
 558     # Break line so the log file can later be parsed as Privoxy log file again
 559     $message .= '"' . $unknown . '"' . " in:\n";
 560     $message .= $req{$t}{'log-message'};
 561     debug_message($message);
 562     log_parse_error($req{$t}{'log-message'});
 563
 564     die "Unworthy content parser" if PUNISH_MISSING_LOG_KNOWLEDGE_WITH_DEATH;
 565 }
 566
 567 sub log_parse_error ($) {
 568
 569     my $message = shift;
 570
 571     if (LOG_UNPARSED_LINES_TO_EXTRA_FILE) {
 572         open(ERRORLOG, ">>" . ERROR_LOG_FILE) || die "Writing " . ERROR_LOG_FILE . " failed";
 573         print ERRORLOG $message;
 574         close(ERRORLOG);
 575     }
 576 }
 577
 578 sub debug_message (@) {
 579     my @message = @_;
 580
 581     print $h{'debug'} . "@message" . $h{'Standard'} . "\n";
 582 }
 583
 584 ################################################################################
 585 # highlighter functions that aren't loglevel-specific
 586 ################################################################################
 587
 588 sub h ($) {
 589
 590     # Get highlight marker
 591     my $highlight = shift; # XXX: Stupid name;
 592     my $result = '';
 593     my $message;
 594
 595     if (defined($highlight)) {
 596
 597         $result = $h{$highlight};
 598
 599     } else {
 600
 601         $message = "h: Don't recognize highlighter $highlight.";
 602         debug_message($message);
 603         log_parser_error($message);
 604         die "Unworthy highlighter function" if PUNISH_MISSING_HIGHLIGHT_KNOWLEDGE_WITH_DEATH;
 605     }
 606
 607     return $result;
 608 }
 609
 610 sub highlight_known_headers ($) {
 611
 612     my $content = shift;
 613
 614     debug_message("Searching $content for things to highlight.") if DEBUG_HEADER_HIGHLIGHTING;
 615
 616     if ($content =~ m/(?<=\s)($header_highlight_regex):/) {
 617         my $header = $1;
 618         $content =~ s@(?<=[\s|'])($header)(?=:)@$header_colours{$header}$1$h{'Standard'}@ig;
 619         debug_message("Highlighted '$header' in '$content'") if DEBUG_HEADER_HIGHLIGHTING;
 620     }
 621
 622     return $content;
 623 }
 624
 625 sub highlight_matched_request_line ($$) {
 626
 627     my $result = shift; # XXX: Stupid name;
 628     my $regex = shift;
 629     if ($result =~ m@(.*)($regex)(.*)@) {
 630         $result = $1 . highlight_request_line($2) . $3
 631     }
 632     return $result;
 633 }
 634
 635 sub highlight_request_line ($) {
 636
 637     my $rl = shift;
 638     my ($method, $url, $http_version);
 639
 640     #GET http://images.sourceforge.net/sfx/icon_warning.gif HTTP/1.1
 641     if ($rl =~ m/Invalid request/) {
 642
 643         $rl = h('invalid-request') . $rl . h('Standard');
 644
 645     } elsif ($rl =~ m/^([-\w]+) (.*) (HTTP\/\d\.\d)/) {
 646
 647         # XXX: might not match in case of HTTP method fuzzing.
 648         # XXX: save these: ($method, $path, $http_version) = ($1, $2, $3);
 649         $rl =~ s@^(\w+)@$h{'method'}$1$h{'Standard'}@;
 650         if ($rl =~ /http:\/\//) {
 651             $rl = highlight_matched_url($rl, '[^\s]*(?=\sHTTP)');
 652         } else {
 653             $rl = highlight_matched_pattern($rl, 'request_', '[^\s]*(?=\sHTTP)');
 654         }
 655
 656         $rl =~ s@(HTTP\/\d\.\d)$@$h{'http-version'}$1$h{'Standard'}@;
 657
 658     } elsif ($rl =~ m/\.\.\. \[too long, truncated\]$/) {
 659
 660         $rl =~ s@^(\w+)@$h{'method'}$1$h{'Standard'}@;
 661         $rl = highlight_matched_url($rl, '[^\s]*(?=\.\.\.)');
 662
 663     } elsif ($rl =~ m/^ $/) {
 664
 665         $rl = h('error') . "No request line specified!" . h('Standard');
 666
 667     } else {
 668
 669         debug_message ("Can't parse request line: $rl");
 670
 671     }
 672
 673     return $rl;
 674 }
 675
 676 sub highlight_response_line ($) {
 677
 678     my $rl = shift;
 679     my ($http_version, $status_code, $status_message);
 680
 681     #HTTP/1.1 200 OK
 682     #ICY 200 OK
 683
 684     # TODO: Mark different status codes differently
 685
 686     if ($rl =~ m/((?:HTTP\/\d\.\d|ICY)) (\d+) (.*)/) {
 687         ($http_version, $status_code, $status_message) = ($1, $2, $3);
 688     } else {
 689         debug_message ("Can't parse response line: $rl") and die 'Fix this';
 690     }
 691
 692     # Rebuild highlighted
 693     $rl= "";
 694     $rl .= h('http-version') . $http_version . h('Standard');
 695     $rl .= " ";
 696     $rl .= h('status-code') . $status_code . h('Standard');
 697     $rl .= " ";
 698     $rl .= h('status-message') . $status_message . h('Standard');
 699
 700     return $rl;
 701 }
 702
 703 sub highlight_matched_url ($$) {
 704
 705     my $result = shift; # XXX: Stupid name;
 706     my $regex = shift;
 707
 708     #print "Got $result, regex ($regex)\n";
 709
 710     if ($result =~ m@(.*?)($regex)(.*)@) {
 711         $result = $1 . highlight_url($2) . $3;
 712         #print "Now the result is $result\n";
 713     }
 714
 715     return $result;
 716 }
 717
 718 sub highlight_matched_host ($$) {
 719
 720     my ($result, $regex) = @_; # XXX: result ist stupid name;
 721
 722     if ($result =~ m@(.*?)($regex)(.*)@) {
 723         $result = $1 . $h{host} . $2 . $h{Standard} . $3;
 724     }
 725
 726     return $result;
 727 }
 728
 729 sub highlight_matched_pattern ($$$) {
 730
 731     my $result = shift; # XXX: Stupid name;
 732     my $key = shift;
 733     my $regex = shift;
 734
 735     die "Unknown key $key" unless defined $h{$key};
 736
 737     if ($result =~ m@(.*?)($regex)(.*)@) {
 738         $result = $1 . h($key) . $2 . h('Standard') . $3;
 739     }
 740
 741     return $result;
 742 }
 743
 744 sub highlight_matched_path ($$) {
 745
 746     my $result = shift; # XXX: Stupid name;
 747     my $regex = shift;
 748
 749     if ($result =~ m@(.*?)($regex)(.*)@) {
 750         $result = $1 . h('path') . $2 . h('Standard') . $3;
 751     }
 752
 753     return $result;
 754 }
 755
 756 sub highlight_url ($) {
 757
 758     my $url = shift;
 759
 760     if ($html_output_mode) {
 761
 762         $url = '<a href="' . $url . '">' . $url . '</a>';
 763
 764     } else {
 765
 766         $url = h('URL') . $url . h('Standard');
 767
 768     }
 769
 770     return $url;
 771 }
 772
 773 sub update_header_highlight_regex ($) {
 774
 775     my $header = shift;
 776     my $headers = join ('|', keys %header_colours);
 777
 778     $header_highlight_regex = qr/$headers/;
 779     print "Registering '$header'\n" if DEBUG_HEADER_HIGHLIGHTING;
 780 }
 781
 782 ################################################################################
 783 # loglevel-specific highlighter functions
 784 ################################################################################
 785
 786 sub handle_loglevel_header ($) {
 787
 788     my $c = shift;
 789
 790     if ($c =~ /^scan:/) {
 791
 792         if ($c =~ m/^scan: ([^: ]+):/) {
 793
 794             # Register new headers
 795             # scan: Accept: image/png,image/*;q=0.8,*/*;q=0.5
 796             my $header = $1;
 797             if (!defined($header_colours{$header}) and $header =~ /^[\d\w-]*$/) {
 798                 debug_message "Registering previously unknown header $1" if DEBUG_HEADER_REGISTERING;
 799
 800                 if (REGISTER_HEADERS_WITH_THE_SAME_COLOUR) {
 801                     $header_colours{$header} =  $header_colours{'Default'};
 802                 } else {
 803                     $header_colours{$header} = $all_colours[$header_colour_index % @all_colours];
 804                     $header_colour_index++;
 805                 }
 806                 update_header_highlight_regex($header);
 807             }
 808
 809         } elsif ($c =~ m/^(scan: )(\w+ .+ HTTP\/\d\.\d)/) {
 810
 811             # scan: HTTP/1.1 200 OK
 812             $c = $1 . highlight_request_line($2);
 813
 814         } elsif ($c =~ m/^(scan: )((?:HTTP\/\d\.\d|ICY) (\d+) (.*))/) {
 815
 816             # Server response line
 817             $req{$t}{'response_line'} = $2;
 818             $req{$t}{'status_code'} = $3;
 819             $req{$t}{'status_message'} = $4;
 820             $c = $1 . highlight_response_line($req{$t}{'response_line'});
 821         }
 822
 823     } elsif ($c =~ m/^Crunching (?:server|client) header: .* \(contains: ([^\)]*)\)/) {
 824
 825         # Crunching server header: Set-Cookie: trac_form_token=d5308c34e16d15e9e301a456; (contains: Cookie:)
 826         $c =~ s@(?<=contains: )($1)@$h{'crunch-pattern'}$1$h{'Standard'}@;
 827         $c =~ s@(Crunching)@$h{$1}$1$h{'Standard'}@;
 828
 829     } elsif ($c =~ m/^New host is: ([^\s]*)\./) {
 830
 831         # New host is: trac.vidalia-project.net. Crunching Referer: http://www.vidalia-project.net/!
 832         $c = highlight_matched_host($c, '(?<=New host is: )[^\s]+(?=\.)');
 833         $c = highlight_matched_url($c, '(?<=Crunching Referer: )[^\s!]+');
 834
 835     } elsif ($c =~ m/^Text mode enabled by force. (Take cover)!/) {
 836
 837         # Text mode enabled by force. Take cover!
 838         $c =~ s@($1)@$h{'warning'}$1$h{'Standard'}@;
 839
 840     } elsif ($c =~ m/^(New HTTP Request-Line: )(.*)/) {
 841
 842         # New HTTP Request-Line: GET http://www.privoxy.org/ HTTP/1.1
 843         $c = $1 . highlight_request_line($2);
 844
 845     } elsif ($c =~ m/^Adjust(ed)? Content-Length to \d+/) {
 846
 847         # Adjusted Content-Length to 2132
 848         # Adjust Content-Length to 33533
 849         $c =~ s@(?<=Content-Length to )(\d+)@$h{'Number'}$1$h{'Standard'}@;
 850         $c = highlight_known_headers($c);
 851
 852     } elsif ($c =~ m/^Destination extracted from "Host:" header. New request URL:/) {
 853
 854         # Destination extracted from "Host:" header. New request URL: http://www.cccmz.de/~ridcully/blog/
 855         $c = highlight_matched_url($c, '(?<=New request URL: ).*');
 856
 857     } elsif ($c =~ m/^Couldn\'t parse:/) {
 858
 859         # XXX: These should probable be logged with LOG_LEVEL_ERROR
 860         # Couldn't parse: If-Modified-Since: Wed, 21 Mar 2007 16:34:50 GMT (crunching!)
 861         # Couldn't parse: at, 24 Mar 2007 13:46:21 GMT in If-Modified-Since: Sat, 24 Mar 2007 13:46:21 GMT (crunching!)
 862         $c =~ s@^(Couldn\'t parse)@$h{'error'}$1$h{'Standard'}@;
 863
 864     } elsif ($c =~ /^Tagger \'([^\']*)\' added tag \'([^\']*)\'/ or
 865              $c =~ m/^Adding tag \'([^\']*)\' created by header tagger \'([^\']*)\'/) {
 866
 867         # Adding tag 'GET request' created by header tagger 'method-man' (XXX: no longer used)
 868         # Tagger 'revalidation' added tag 'REVALIDATION-REQUEST'. No action bit update necessary.
 869         # Tagger 'revalidation' added tag 'REVALIDATION-REQUEST'. Action bits updated accordingly.
 870
 871         # XXX: Save tag and tagger
 872
 873         $c =~ s@(?<=^Tagger \')([^\']*)@$h{'tagger'}$1$h{'Standard'}@;
 874         $c =~ s@(?<=added tag \')([^\']*)@$h{'tag'}$1$h{'Standard'}@;
 875         $c =~ s@(?<=Action bits )(updated)@$h{'action-bits-update'}$1$h{'Standard'}@;
 876         $no_special_header_highlighting = 1;
 877
 878     } elsif ($c =~ /^Tagger \'([^\']*)\' didn['']t add tag \'([^\']*)\'/) {
 879
 880         # Tagger 'revalidation' didn't add tag 'REVALIDATION-REQUEST'. Tag already present
 881         # XXX: Save tag and tagger
 882
 883         $c =~ s@(?<=^Tagger \')([^\']*)@$h{'tag'}$1$h{'Standard'}@;
 884         $c =~ s@(?<=didn['']t add tag \')([^\']*)@$h{'tagger'}$1$h{'Standard'}@;
 885
 886     } elsif ($c =~ m/^(?:scan:|Randomiz|addh:|Adding:|Removing:|Referer:|Modified:|Accept-Language header|[Cc]ookie)/
 887           or $c =~ m/^(Text mode is already enabled|Denied request with NULL byte|Replaced:|add-unique:)/
 888           or $c =~ m/^(Crunched (incoming|outgoing) cookie|Suppressed offer|Accepted the client)/
 889           or $c =~ m/^(addh-unique|Referer forged to)/
 890           or $c =~ m/^Downgraded answer to HTTP\/1.0/
 891           or $c =~ m/^Parameter: \+hide-referrer\{[^\}]*\} is a bad idea, but I don\'t care./
 892           or $c =~ m/^Referer (?:overwritten|replaced) with: Referer: / #XXX: should this be highlighted?
 893           or $c =~ m/^Referer crunched!/
 894           or $c =~ m/^crunched x-forwarded-for!/
 895           or $c =~ m/^crunched From!/
 896           or $c =~ m/^ modified$/
 897           or $c =~ m/^Content filtering is enabled. Crunching:/
 898           or $c =~ m/^force-text-mode overruled the client/
 899           or $c =~ m/^Server time in the future\./
 900           or $c =~ m/^content-disposition header crunched and replaced with:/i
 901           or $c =~ m/^Reducing white space in /
 902           or $c =~ m/^Ignoring single quote in /
 903           or $c =~ m/^Converting tab to space in /
 904           or $c =~ m/A HTTP\/1\.1 response without/
 905           or $c =~ m/Disabled filter mode on behalf of the client/
 906           or $c =~ m/Keeping the (?:server|client) header /
 907           or $c =~ m/Content modified with no Content-Length header set/
 908           or $c =~ m/^Appended client IP address to/
 909           or $c =~ m/^Removing 'Connection: close' to imply keep-alive./
 910           or $c =~ m/^keep-alive support is disabled/
 911           or $c =~ m/^Continue hack in da house/
 912             )
 913     {
 914         # XXX: Some of these may need highlighting
 915
 916         # Modified: User-Agent: Mozilla/5.0 (X11; U; SunOS i86pc; pl-PL; rv:1.8.1.1) Gecko/20070214 Firefox/2.0.0.1
 917         # Accept-Language header crunched and replaced with: Accept-Language: pl-pl
 918         # cookie 'Set-Cookie: eZSessionCookie=07bfec287c197440d299f81580593c3d; \
 919         #  expires=Thursday, 12-Apr-07 15:16:18 GMT; path=/' send by \
 920         #  http://wirres.net/article/articleview/4265/1/6/ appears to be using time format 1 (XXX: gone with the wind)
 921         # Cookie rewritten to a temporary one: Set-Cookie: NSC_gffe-iuuq-mc-wtfswfs=8efb33a53660;path=/
 922         # Text mode is already enabled
 923         # Denied request with NULL byte(s) turned into line break(s)
 924         # Replaced: 'Connection: Yo, home to Bel Air' with 'Connection: close'
 925         # addh-unique: Host: people.freebsd.org
 926         # Suppressed offer to compress content
 927         # Crunched incoming cookie -- yum!
 928         # Accepted the client's request to fetch without filtering.
 929         # Crunched outgoing cookie: Cookie: PREF=ID=6cf0abd347b30262:TM=1173357617:LM=1173357617:S=jZypyyJ7LPiwFi1_
 930         # addh-unique: Host: subkeys.pgp.net:11371
 931         # Referer forged to: Referer: http://10.0.0.1/
 932         # Downgraded answer to HTTP/1.0
 933         # Parameter: +hide-referrer{pille-palle} is a bad idea, but I don't care.
 934         # Referer overwritten with: Referer: pille-palle
 935         # Referer replaced with: Referer: pille-palle
 936         # crunched x-forwarded-for!
 937         # crunched From!
 938         #  modified # XXX: pretty stupid log message
 939         # Content filtering is enabled. Crunching: 'Range: 1234-5678' to prevent range-mismatch problems
 940         # force-text-mode overruled the client's request to fetch without filtering!
 941         # Server time in the future.
 942         # content-disposition header crunched and replaced with: content-disposition: filename=baz
 943         # Content-Disposition header crunched and replaced with: content-disposition: filename=baz
 944         # Reducing white space in 'X-LWS-Test: "This  is  quoted" this is not "this  is  " but " this again   is  not'
 945         # Ignoring single quote in 'X-LWS-Test: "This  is  quoted" this is not "this  is  " but "  this again   is  not'
 946         # Converting tab to space in 'X-LWS-Test:   "This  is  quoted" this   is  not "this  is  "  but  "\
 947         #  this again   is  not'
 948         # A HTTP/1.1 response without Connection header implies keep-alive.
 949         # Disabled filter mode on behalf of the client.
 950         # Keeping the server header 'Connection: keep-alive' around.
 951         # Keeping the client header 'Connection: close' around. The connection will not be kept alive.
 952         # Keeping the client header 'Connection: keep-alive' around. The connection will be kept alive if possible.
 953         # Content modified with no Content-Length header set. Creating a fake one for adjustment later on.
 954         # Appended client IP address to X-Forwarded-For: 10.0.0.2, 10.0.0.1
 955         # Removing 'Connection: close' to imply keep-alive.
 956         # keep-alive support is disabled. Crunching: Keep-Alive: 300.
 957         # Continue hack in da house.
 958
 959     } elsif ($c =~ m/^scanning headers for:/) {
 960
 961         return '' unless SHOW_SCAN_INTRO;
 962
 963     } elsif ($c =~ m/^[Cc]runch(ing|ed)|crumble crunched:/) {
 964         # crunched User-Agent!
 965         # Crunching: Content-Encoding: gzip
 966
 967         $c =~ s@(Crunching|crunched)@$h{$1}$1$h{'Standard'}@;
 968
 969     } elsif ($c =~ m/^Offending request data with NULL bytes turned into \'°\' characters:/) {
 970
 971         # Offending request data with NULL bytes turned into '°' characters: °°n°°(°°°
 972
 973         $c = h('warning') . $c . h('Standard');
 974
 975     } elsif ($c =~ m/^(Transforming \")(.*?)(\" to \")(.*?)(\")/) {
 976
 977         # Transforming "Proxy-Authenticate: Basic realm="Correos Proxy Server"" to\
 978         #  "Proxy-Authenticate: Basic realm="Correos Proxy Server""
 979
 980        $c =~ s@(?<=^Transforming \")(.*)(?=\" to)@$h{'Header'}$1$h{'Standard'}@;
 981        $c =~ s@(?<=to \")(.*)(?=\")@$h{'Header'}$1$h{'Standard'}@;
 982
 983     } elsif ($c =~ m/^Removing empty header/) {
 984
 985         # Removing empty header
 986         # Ignore for now
 987
 988     } elsif ($c =~ m/^Content-Type: .* not replaced/) {
 989
 990         # Content-Type: application/octet-stream not replaced. It doesn't look like text.\
 991         #  Enable force-text-mode if you know what you're doing.
 992         # XXX: Could highlight more here.
 993         $c =~ s@(?<=^Content-Type: )(.*)(?= not replaced)@$h{'content-type'}$1$h{'Standard'}@;
 994
 995     } elsif ($c =~ m/^(Server|Client) keep-alive timeout is/) {
 996
 997        # Server keep-alive timeout is 5. Sticking with 10.
 998        # Client keep-alive timeout is 20. Sticking with 10.
 999
1000        $c =~ s@(?<=timeout is )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1001        $c =~ s@(?<=Sticking with )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1002
1003     } elsif ($c =~ m/^Reducing keep-alive timeout/) {
1004
1005        # Reducing keep-alive timeout from 60 to 10.
1006
1007        $c =~ s@(?<= from )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1008        $c =~ s@(?<= to )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1009
1010     } else {
1011
1012         found_unknown_content($c);
1013     }
1014
1015     # Highlight headers
1016     unless ($c =~ m/^Transforming/) {
1017         $c = highlight_known_headers($c) unless $no_special_header_highlighting;
1018     }
1019
1020     return $c;
1021 }
1022
1023 sub handle_loglevel_re_filter ($) {
1024
1025     my $content = shift;
1026     my $c = $content;
1027     my $key;
1028
1029     if ($c =~ m/^(?:re_)?filtering ([^\s]+) \(size (\d+)\) with (?:filter )?\'?([^\s]+?)\'? produced (\d+) hits \(new size (\d+)\)/) {
1030
1031         # XXX: only the second version gets highlighted properly.
1032         # re_filtering www.lfk.de/favicon.ico (size 209) with filter untrackable-hulk produced 0 hits (new size 209).
1033         # filtering aci.blogg.de/ (size 37988) with 'blogg.de' produced 3 hits (new size 38057)
1034         $req{$t}{'content_source'} = $1;
1035         $req{$t}{'content_size'}   = $2;
1036         $req{$t}{'content_filter'} = $3;
1037         $req{$t}{'content_hits'}   = $4;
1038         $req{$t}{'new_content_size'} = $5;
1039         $req{$t}{'content_size_change'} = $req{$t}{'new_content_size'} - $req{$t}{'content_size'};
1040         #return '' if ($req{$t}{'content_hits'} == 0 && !cli_option_is_set('show-ineffective-filters'));
1041         if ($req{$t}{'content_hits'} == 0 and
1042             not (cli_option_is_set('show-ineffective-filters')
1043                  or ($req{$t}{'content_filter'} =~ m/^privoxy-filter-test$/))) {
1044                 return '';
1045         }
1046
1047         $c =~ s@(?<=\(size )(\d+)\)(?= with)@$h{'Number'}$1$h{'Standard'}@;
1048         $c =~ s@(?<=\(new size )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1049         $c =~ s@(?<=produced )(\d+)(?= hits)@$h{'Number'}$1$h{'Standard'}@;
1050
1051         $c =~ s@([^\s]+?)(\'? produced)@$h{'filter'}$1$h{'Standard'}$2@;
1052         $c = highlight_matched_host($c, '(?<=filtering )[^\s]+');
1053
1054         $c =~ s@\.$@ @;
1055         $c .= "(" . $h{'Number'};
1056         $c .= "+" if ($req{$t}{'content_size_change'} >= 0);
1057         $c .= $req{$t}{'content_size_change'} . $h{'Standard'} . ")";
1058         $content = $c;
1059
1060   } elsif ($c =~ /\.{3}$/
1061         and $c =~ m/^(?:re_)?filtering \'?(.*?)\'? \(size (\d*)\) with (?:filter )?\'?([^\s]*?)\'? ?\.{3}$/) {
1062
1063         # Used by Privoxy 3.0.5 and 3.0.6:
1064         # XXX: Fill in ...
1065         # Used by Privoxy 3.0.7:
1066         # filtering 'Connection: close' (size 17) with 'generic-content-ads' ...
1067
1068         $req{$t}{'filtered_header'} = $1;
1069         $req{$t}{'old_header_size'} = $2;
1070         $req{$t}{'header_filter_name'} = $3;
1071
1072         unless (cli_option_is_set('show-ineffective-filters') or
1073                 $req{$t}{'header_filter_name'} =~ m/^privoxy-filter-test$/) {
1074             return '';
1075         }
1076         $content =~ s@(?<=\(size )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1077         $content =~ s@($req{$t}{'header_filter_name'})@$h{'filter'}$1$h{'Standard'}@;
1078
1079     } elsif ($c =~ m/^ ?\.\.\. ?produced (\d*) hits \(new size (\d*)\)\./) {
1080
1081         # ...produced 0 hits (new size 23).
1082         #... produced 1 hits (new size 54).
1083
1084         $req{$t}{'header_filter_hits'} = $1;
1085         $req{$t}{'new_header_size'} = $2;
1086
1087         unless (cli_option_is_set('show-ineffective-filters') or
1088                 (defined($req{$t}{'header_filter_name'}) and
1089                  $req{$t}{'header_filter_name'} =~ m/^privoxy-filter-test$/)) {
1090
1091             if ($req{$t}{'header_filter_hits'} == 0 and
1092                 not (defined($req{$t}{'header_filter_name'}) and
1093                  $req{$t}{'header_filter_name'} =~ m/^privoxy-filter-test$/)) {
1094                 return '';
1095             }
1096             # Reformat including information from the intro
1097             $c = "'" . h('filter') . $req{$t}{'header_filter_name'} . h('Standard') . "'";
1098             $c .= " hit ";
1099             # XXX: Hide behind constant, it may be interesting if LOG_LEVEL_HEADER isn't enabled as well.
1100             # $c .= $req{$t}{'filtered_header'} . " ";
1101             $c .= h('Number') . $req{$t}{'header_filter_hits'}. h('Standard');
1102             $c .= ($req{$t}{'header_filter_hits'} == 1) ? " time, " : " times, ";
1103
1104             if ($req{$t}{'old_header_size'} !=  $req{$t}{'new_header_size'}) {
1105
1106                 $c .= "changing size from ";
1107                 $c .=  h('Number') . $req{$t}{'old_header_size'} . h('Standard');
1108                 $c .= " to ";
1109                 $c .= h('Number') . $req{$t}{'new_header_size'} . h('Standard');
1110                 $c .= ".";
1111
1112             } else {
1113
1114                 $c .= "keeping the size at " . $req{$t}{'old_header_size'};
1115
1116             }
1117
1118             # Highlight from last line (XXX: What?)
1119             # $c =~ s@(?<=produced )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1120             # $c =~ s@($req{$t}{'header_filter_name'})@$h{'filter'}$1$h{'Standard'}@;
1121
1122         } else {
1123
1124            # XXX: Untested
1125            $c =~ s@(?<=produced )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1126            $c =~ s@(?<=new size )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1127
1128         }
1129         $content = $c;
1130
1131     } elsif ($c =~ m/^(Tagger|Filter) ([^\s]*) has empty joblist. Nothing to do./) {
1132
1133         # Filter privoxy-filter-test has empty joblist. Nothing to do.
1134         # Tagger variable-test has empty joblist. Nothing to do.
1135
1136         $content =~ s@(?<=$1 )([^\s]*)@$h{'filter'}$1$h{'Standard'}@;
1137
1138     } elsif ($c =~ m/^De-chunking successful. Shrunk from (\d+) to (\d+)/) {
1139
1140         $req{$t}{'chunked-size'} = $1;
1141         $req{$t}{'dechunked-size'} = $2;
1142         $req{$t}{'dechunk-change'} = $req{$t}{'dechunked-size'} - $req{$t}{'chunked-size'};
1143
1144         $content .= " (" . h('Number') . $req{$t}{'dechunk-change'} . h('Standard') . ")";
1145
1146         $content =~ s@(?<=from )($req{$t}{'chunked-size'})@$h{'Number'}$1$h{'Standard'}@;
1147         $content =~ s@(?<=to )($req{$t}{'dechunked-size'})@$h{'Number'}$1$h{'Standard'}@;
1148
1149     } elsif ($c =~ m/^Decompression successful. Old size: (\d+), new size: (\d+)./) {
1150
1151         # Decompression successful. Old size: 670, new size: 1166.
1152
1153         $req{$t}{'size-compressed'} = $1;
1154         $req{$t}{'size-decompressed'} = $2;
1155         $req{$t}{'decompression-gain'} = $req{$t}{'size-decompressed'} - $req{$t}{'size-compressed'};
1156
1157         $content =~ s@(?<=Old size: )($req{$t}{'size-compressed'})@$h{'Number'}$1$h{'Standard'}@;
1158         $content =~ s@(?<=new size: )($req{$t}{'size-decompressed'})@$h{'Number'}$1$h{'Standard'}@;
1159
1160         # XXX: Create sub get_percentage()
1161         if ($req{$t}{'size-decompressed'}) {
1162             $req{$t}{'decompression-gain-percent'} =
1163                 $req{$t}{'decompression-gain'} / $req{$t}{'size-decompressed'} * 100;
1164
1165             $content .= " (saved: ";
1166             #$content .= h('Number') . $req{$t}{'decompression-gain'} . h('Standard');
1167             #$content .= "/";
1168             $content .= h('Number') . sprintf("%.2f%%", $req{$t}{'decompression-gain-percent'}) . h('Standard');
1169             $content .= ")";
1170         }
1171
1172     } elsif ($c =~ m/^(Need to de-chunk first)/) {
1173
1174         # Need to de-chunk first
1175         return '' if SUPPRESS_NEED_TO_DE_CHUNK_FIRST;
1176
1177     } elsif ($c =~ m/^(Adding (?:dynamic )?re_filter job)/) {
1178
1179         return ''  if (SUPPRESS_SUCCEEDED_FILTER_ADDITIONS && m/succeeded/);
1180
1181         # Adding re_filter job ...
1182         # Adding dynamic re_filter job s@^(?:\w*)\s+.*\s+HTTP/\d\.\d\s*@IP-ADDRESS: $origin@D\
1183         #  to filter client-ip-address succeeded.
1184
1185     } elsif ($c =~ m/^Reading in filter/) {
1186
1187         return '' unless SHOW_FILTER_READIN_IN;
1188
1189     } else {
1190
1191         found_unknown_content($content);
1192
1193     }
1194
1195     return $content;
1196 }
1197
1198 sub handle_loglevel_redirect ($) {
1199
1200     my $c = shift;
1201
1202     if ($c =~ m/^Decoding "([^""]*)"/) {
1203
1204          $req{$t}{'original-destination'} = $1;
1205          $c = highlight_matched_path($c, '(?<=Decoding ")[^"]*');
1206          $c =~ s@\"@@g;
1207
1208     } elsif ($c =~ m/^Checking/) {
1209
1210          # Checking /_ylt=A0geu.Z76BRGR9k/**http://search.yahoo.com/search?p=view+odb+presentation+on+freebsd\
1211          #  &ei=UTF-8&xargs=0&pstart=1&fr=moz2&b=11 for redirects.
1212
1213          # TODO: Change colour if really url-decoded
1214          $req{$t}{'decoded-original-destination'} = $1;
1215          $c = highlight_matched_path($c, '(?<=Checking ")[^"]*');
1216          $c =~ s@\"@@g;
1217
1218     } elsif ($c =~ m/^pcrs command "([^""]*)" changed /) {
1219
1220         # pcrs command "s@&from=rss@@" changed \
1221         #  "http://it.slashdot.org/article.pl?sid=07/03/02/1657247&from=rss"\
1222         #  to "http://it.slashdot.org/article.pl?sid=07/03/02/1657247" (1 hit).
1223         $c =~ s@(?<=pcrs command )"([^""]*)"@$h{'filter'}$1$h{'Standard'}@;
1224         $c = highlight_matched_url($c, '(?<=changed ")[^""]*');
1225         $c =~ s@(?<=changed )"([^""]*)"@$1@; # Remove quotes
1226         $c = highlight_matched_url($c, '(?<=to ")[^""]*');
1227         $c =~ s@(?<=to )"([^""]*)"@$1@; # Remove quotes
1228         $c =~ s@(\d+)(?= hits?)@$h{'hits'}$1$h{'Standard'}@;
1229
1230     } elsif ($c =~ m/^pcrs command "([^""]*)" didn\'t change/) {
1231
1232         # pcrs command "s@^http://([^.]+?)/?$@http://www.bing.com/search?q=$1@" didn't \
1233         #  change "http://www.example.org/".
1234         $c =~ s@(?<=pcrs command )"([^""]*)"@$h{'filter'}$1$h{'Standard'}@;
1235         $c = highlight_matched_url($c, '(?<=change ")[^""]*');
1236
1237     } elsif ($c =~ m/(^New URL is: )(.*)/) {
1238
1239         # New URL is: http://it.slashdot.org/article.pl?sid=07/03/04/1511210
1240         # XXX: Use URL highlighter
1241         # XXX: Save?
1242         $c = $1 . h('rewritten-URL') . $2 . h('Standard');
1243
1244     } elsif ($c =~ m/No pcrs command recognized, assuming that/) {
1245         # No pcrs command recognized, assuming that "http://config.privoxy.org/user-manual/favicon.png"\
1246         #  is already properly formatted.
1247         # XXX: assume the same?
1248         $c = highlight_matched_url($c, '(?<=assuming that \")[^"]*');
1249
1250     } else {
1251
1252         found_unknown_content($c);
1253
1254     }
1255
1256     return $c;
1257 }
1258
1259 sub handle_loglevel_gif_deanimate ($) {
1260
1261     my $content = shift;
1262
1263     if ($content =~ m/Success! GIF shrunk from (\d+) bytes to (\d+)\./) {
1264
1265         my $bytes_from = $1;
1266         my $bytes_to = $2;
1267         # Gif-Deanimate: Success! GIF shrunk from 205 bytes to 133.
1268         $content =~ s@$bytes_from@$h{'Number'}$bytes_from$h{'Standard'}@;
1269         # XXX: Do we need g in case of ($1 == $2)?
1270         $content =~ s@$bytes_to@$h{'Number'}$bytes_to$h{'Standard'}@;
1271
1272     } elsif ($content =~ m/GIF (not) changed/) {
1273
1274         # Gif-Deanimate: GIF not changed.
1275         return '' if SUPPRESS_GIF_NOT_CHANGED;
1276         $content =~ s@($1)@$h{'not'}$1$h{'Standard'}@;
1277
1278     } elsif ($content =~ m/^failed! \(gif parsing\)/) {
1279
1280         # failed! (gif parsing)
1281         # XXX: Replace this error message with something less stupid
1282         $content =~ s@(failed!)@$h{'error'}$1$h{'Standard'}@;
1283
1284     } elsif ($content =~ m/^Need to de-chunk first/) {
1285
1286         # Need to de-chunk first
1287         return '' if SUPPRESS_NEED_TO_DE_CHUNK_FIRST;
1288
1289     } elsif ($content =~ m/^(?:No GIF header found|failed while parsing)/) {
1290
1291         # No GIF header found (XXX: Did I ever commit this?)
1292         # failed while parsing 195 134747048 (XXX: never commited)
1293
1294         # Ignore these for now
1295
1296     } else {
1297
1298         found_unknown_content($content);
1299
1300     }
1301
1302     return $content;
1303 }
1304
1305 sub handle_loglevel_request ($) {
1306
1307     my $content = shift;
1308
1309     if ($content =~ m/crunch! /) {
1310
1311         # config.privoxy.org/send-stylesheet crunch! (CGI Call)
1312
1313         # Highlight crunch reasons
1314         foreach my $reason (keys %reason_colours) {
1315             $content =~ s@\(($reason)\)@$reason_colours{$reason}($1)$h{'Standard'}@g;
1316         }
1317         # Highlight request URL domain and ditch 'crunch!'
1318         $content = highlight_matched_pattern($content, 'request_', '[^ ]*(?= crunch!)');
1319         $content =~ s@ crunch!@@;
1320
1321     } elsif ($content =~ m/\[too long, truncated\]$/) {
1322
1323         # config.privoxy.org/edit-actions-submit?f=3&v=1176116716&s=7&Submit=Submit[...]&filter... [too long, truncated]
1324         $content = highlight_matched_pattern($content, 'request_', '^.*(?=\.\.\. \[too long, truncated\]$)');
1325
1326     } elsif ($content =~ m/(.*)/) { # XXX: Pretty stupid
1327
1328         # trac.vidalia-project.net/wiki/Volunteer?format=txt
1329         $content = h('request_') . $content . h('Standard');
1330
1331     } else {  # XXX: Nop
1332
1333         found_unknown_content($content);
1334
1335     }
1336
1337     return $content;
1338 }
1339
1340 sub handle_loglevel_crunch ($) {
1341
1342     my $content = shift;
1343
1344     # Highlight crunch reason
1345     foreach my $reason (keys %reason_colours) {
1346         $content =~ s@($reason)@$reason_colours{$reason}$1$h{'Standard'}@g;
1347     }
1348
1349     if ($content =~ m/\[too long, truncated\]$/) {
1350
1351         # Blocked: config.privoxy.org/edit-actions-submit?f=3&v=1176116716&s=7&Submit=Submit\
1352         #  [...]&filter... [too long, truncated]
1353         $content = highlight_matched_pattern($content, 'request_', '^.*(?=\.\.\. \[too long, truncated\]$)');
1354
1355     } else {
1356
1357         # Blocked: http://ads.example.org/
1358         $content = highlight_matched_pattern($content, 'request_', '(?<=: ).*');
1359     }
1360
1361     return $content;
1362 }
1363
1364 sub handle_loglevel_connect ($) {
1365
1366     my $c = shift;
1367
1368     if ($c =~ m/^via [^\s]+ to: [^\s]+/) {
1369
1370         # Connect: via 10.0.0.1:8123 to: www.example.org.noconnect
1371
1372         $c = highlight_matched_host($c, '(?<=via )[^\s]+');
1373         $c = highlight_matched_host($c, '(?<=to: )[^\s]+');
1374
1375     } elsif ($c =~ m/^connect to: .* failed: .*/) {
1376
1377         # connect to: www.example.org.noconnect failed: Operation not permitted
1378
1379         $c = highlight_matched_host($c, '(?<=connect to: )[^\s]+');
1380
1381         $c =~ s@(?<=failed: )(.*)@$h{'error'}$1$h{'Standard'}@;
1382
1383     } elsif ($c =~ m/^to ([^\s]*)( successful)?$/) {
1384
1385         # Connect: to www.nzherald.co.nz successful
1386         # Connect: to archiv.radiotux.de
1387
1388         return '' if SUPPRESS_SUCCESSFUL_CONNECTIONS;
1389         $c = highlight_matched_host($c, '(?<=to )[^\s]+');
1390
1391     } elsif ($c =~ m/^to ([^\s]*)$/) {
1392
1393         # Connect: to lists.sourceforge.net:443
1394
1395         $c = highlight_matched_host($c, '(?<=to )[^\s]+');
1396
1397     } elsif ($c =~ m/^accepted connection from .*/ or
1398              $c =~ m/^OK/) {
1399
1400         # accepted connection from 10.0.0.1
1401         # Privoxy 3.0.6 and earlier just say:
1402         # OK
1403         return '' if SUPPRESS_ACCEPTED_CONNECTIONS;
1404         $c = highlight_matched_host($c, '(?<=connection from ).*');
1405
1406     } elsif ($c =~ m/^write header to: .* failed:/) {
1407
1408         # write header to: 10.0.0.1 failed: Broken pipe
1409
1410         $c = highlight_matched_host($c, '(?<=write header to: )[^\s]*');
1411         $c =~ s@(?<=failed: )(.*)@$h{'Error'}$1$h{'Standard'}@;
1412
1413     } elsif ($c =~ m/^write header to client failed:/) {
1414
1415         # write header to client failed: Broken pipe
1416         # XXX: Stil in use?
1417         $c =~ s@(?<=failed: )(.*)@$h{'Error'}$1$h{'Standard'}@;
1418
1419     } elsif ($c =~ m/^socks4_connect:/) {
1420
1421         # socks4_connect: SOCKS request rejected or failed.
1422         $c =~ s@(?<=socks4_connect: )(.*)@$h{'Error'}$1$h{'Standard'}@;
1423
1424     } elsif ($c =~ m/^Listening for new connections/ or
1425              $c =~ m/^accept connection/) {
1426         # XXX: Highlight?
1427         # Privoxy versions above 3.0.6 say:
1428         # Listening for new connections ...
1429         # earlier versions say:
1430         # accept connection ...
1431         return '';
1432
1433     } elsif ($c =~ m/^accept failed:/) {
1434
1435         $c =~ s@(?<=accept failed: )(.*)@$h{'Error'}$1$h{'Standard'}@;
1436
1437     } elsif ($c =~ m/^Overriding forwarding settings/) {
1438
1439         # Overriding forwarding settings based on 'forward 10.0.0.1:8123'
1440         $c =~ s@(?<=based on \')(.*)(?=\')@$h{'configuration-line'}$1$h{'Standard'}@;
1441
1442     } elsif ($c =~ m/^Denying suspicious CONNECT request from/) {
1443
1444         # Denying suspicious CONNECT request from 10.0.0.1
1445         $c = highlight_matched_host($c, '(?<=from )[^\s]+'); # XXX: not an URL
1446
1447     } elsif ($c =~ m/^socks5_connect:/) {
1448
1449         $c =~ s@(?<=socks5_connect: )(.*)@$h{'error'}$1$h{'Standard'}@;
1450
1451     } elsif ($c =~ m/^Created new connection to/) {
1452
1453         # Created new connection to www.privoxy.org:80 on socket 11.
1454         $c = highlight_matched_host($c, '(?<=connection to )[^\s]+');
1455         $c =~ s@(?<=on socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1456
1457     } elsif ($c =~ m/^Found reusable socket/) {
1458
1459         # Found reusable socket 9 for www.privoxy.org:80 in slot 0.
1460         # 3.0.15 and later:
1461         # Found reusable socket 8 for www.privoxy.org:80 in slot 2.\
1462         #  Timestamp made 0 seconds ago. Timeout: 1. Latency: 0.
1463         $c =~ s@(?<=Found reusable socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1464         $c = highlight_matched_host($c, '(?<=for )[^\s]+');
1465         $c =~ s@(?<=in slot )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1466         $c =~ s@(?<=made )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1467         $c =~ s@(?<=Timeout: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1468         $c =~ s@(?<=Latency: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1469
1470     } elsif ($c =~ m/^Marking open socket/) {
1471
1472         # Marking open socket 9 for www.privoxy.org:80 in slot 0 as unused.
1473         $c =~ s@(?<=Marking open socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1474         $c = highlight_matched_host($c, '(?<=for )[^\s]+');
1475         $c =~ s@(?<=in slot )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1476
1477     } elsif ($c =~ m/^No reusable/) {
1478
1479         # No reusable socket for addons.mozilla.org:443 found. Opening a new one.
1480         $c = highlight_matched_host($c, '(?<=for )[^\s]+');
1481
1482     } elsif ($c =~ m/^(Remembering|Forgetting) socket/) {
1483
1484         # Remembering socket 13 for www.privoxy.org:80 in slot 0.
1485         # Forgetting socket 38 for www.privoxy.org:80 in slot 5.
1486
1487         $c =~ s@(?<=socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1488         $c = highlight_matched_host($c, '(?<=for )[^\s]+');
1489         $c =~ s@(?<=in slot )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1490
1491     } elsif ($c =~ m/^Socket/) {
1492
1493         # Socket 16 already forgotten or never remembered.
1494         $c =~ s@(?<=Socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1495
1496     } elsif ($c =~ m/^The connection to/) {
1497
1498         # The connection to www.privoxy.org:80 in slot 6 timed out. Closing socket 19. Timeout is: 61.
1499         # 3.0.15 and later:
1500         # The connection to 1.bp.blogspot.com:80 in slot 0 timed out. Closing socket 5.\
1501         #  Timeout is: 1. Assumed latency: 4.
1502         # The connection to 10.0.0.1:80 in slot 0 is no longer usable. Closing socket 4.
1503         $c = highlight_matched_host($c, '(?<=connection to )[^\s]+');
1504         $c =~ s@(?<=in slot )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1505         $c =~ s@(?<=Closing socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1506         $c =~ s@(?<=Timeout is: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1507         $c =~ s@(?<=Assumed latency: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1508
1509     } elsif ($c =~ m/^Stopped waiting for the request line./) {
1510
1511         # Stopped waiting for the request line. Timeout: 121.
1512         $c =~ s@(?<=Timeout: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1513
1514     } elsif ($c =~ m/^Waiting for \d/) {
1515
1516         # Waiting for 1 connections to timeout.
1517         $c =~ s@(?<=^Waiting for )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1518
1519     } elsif ($c =~ m/^Initialized/) {
1520
1521         # Initialized 20 socket slots.
1522         $c =~ s@(?<=Initialized )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1523
1524     } elsif ($c =~ m/^Done reading from server/) {
1525
1526         # Done reading from server. Expected content length: 24892. \
1527         #  Actual content length: 24892. Most recently received: 4412.
1528         # 3.0.15 and later:
1529         # Done reading from server. Expected content length: 24892. \
1530         #  Actual content length: 24892. Bytes most recently read: 4412.
1531         # Done reading from server. Content length: 6018 as expected. \
1532         #  Bytes most recently read: 294.
1533         $c =~ s@(?<=ontent length: )(\d+)@$h{'Number'}$1$h{'Standard'}@g;
1534         $c =~ s@(?<=received: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1535         $c =~ s@(?<=read: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1536
1537     } elsif ($c =~ m/^Continuing buffering headers/) {
1538
1539         # Continuing buffering headers. byte_count: 19. header_offset: 517. len: 536.
1540         $c =~ s@(?<=byte_count: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1541         $c =~ s@(?<=header_offset: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1542         $c =~ s@(?<=len: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1543         # 3.0.15 and later:
1544         # Continuing buffering headers. Bytes most recently read: %d.
1545         $c =~ s@(?<=read: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1546
1547     } elsif ($c =~ m/^Received \d+ bytes while/) {
1548
1549         # Received 206 bytes while expecting 12103.
1550         $c =~ s@(?<=Received )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1551         $c =~ s@(?<=expecting )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1552
1553     } elsif ($c =~ m/^(Rejecting c|C)onnection from/) {
1554
1555         # Connection from 81.163.28.218 dropped due to ACL
1556         # Rejecting connection from 178.63.152.227. Maximum number of connections reached.
1557         $c =~ s@(?<=onnection from )((?:\d+\.?){3}\d+)@$h{'Number'}$1$h{'Standard'}@;
1558
1559     } elsif ($c =~ m/^(?:Reusing|Closing) server socket \d./ or
1560              $c =~ m/^No additional client request/) {
1561
1562         # Reusing server socket 4. Opened for 10.0.0.1.
1563         # Closing server socket 2. Opened for 10.0.0.1.
1564         # No additional client request received in time. \
1565         #  Closing server socket 4, initially opened for 10.0.0.1.
1566         # No additional client request received in time on socket 29.
1567
1568         $c =~ s@(?<= socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1569         $c = highlight_matched_host($c, '(?<=for )[^\s]+(?=\.$)');
1570
1571     } elsif ($c =~ m/^Connected to /) {
1572
1573         # Connected to tor-jail[10.0.0.2]:9050.
1574
1575         $c = highlight_matched_host($c, '(?<=\[)[^\]]+');
1576         $c = highlight_matched_host($c, '(?<=Connected to )[^\[\s]+');
1577         $c =~ s@(?<=\]:)(\d+)@$h{'Number'}$1$h{'Standard'}@;
1578
1579     } elsif ($c =~ m/^Could not connect to /) {
1580
1581         # Could not connect to [10.0.0.1]:80.
1582
1583         $c = highlight_matched_host($c, '(?<=\[)[^\]]+');
1584         $c =~ s@(?<=\]:)(\d+)@$h{'Number'}$1$h{'Standard'}@;
1585
1586     } elsif ($c =~ m/^Waiting for the next client request/ or
1587              $c =~ m/^The connection on server socket/ or
1588              $c =~ m/^Client request arrived in time or the client closed the connection/) {
1589
1590         # Waiting for the next client request on socket 3. Keeping the server \
1591         #  socket 12 to a.fsdn.com open.
1592         # The connection on server socket 6 to upload.wikimedia.org isn't reusable. Closing.
1593         # Client request arrived in time or the client closed the connection on socket 12.
1594
1595         $c =~ s@(?<=on socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1596         $c =~ s@(?<=server socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1597         $c = highlight_matched_host($c, '(?<=to )[^\s]+');
1598
1599     } elsif ($c =~ m/^Marking the server socket/) {
1600
1601         # Marking the server socket 7 tainted.
1602
1603         $c =~ s@(?<=server socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1604
1605     } elsif ($c =~ m/^Reduced expected bytes to /) {
1606
1607         # Reduced expected bytes to 0 to account for the 1542 ones we already got.
1608         $c =~ s@(?<=bytes to )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1609         $c =~ s@(?<=for the )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1610
1611     } elsif ($c =~ m/^The client closed socket /) {
1612
1613         # The client closed socket 2 while the server socket 4 is still open.
1614         $c =~ s@(?<=closed socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1615         $c =~ s@(?<=server socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1616
1617     } elsif ($c =~ m/^Expected client content length set /) {
1618
1619         # Expected client content length set to 667325411 after reading 4999 bytes.
1620         $c =~ s@(?<=set to )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1621         $c =~ s@(?<=reading )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1622
1623     } elsif ($c =~ m/^Waiting for up to /) {
1624
1625         # Waiting for up to 4999 bytes from the client.
1626         $c =~ s@(?<=up to )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1627
1628     } elsif ($c =~ m/^Looks like we / or
1629              $c =~ m/^Unsetting keep-alive flag/ or
1630              $c =~ m/^No connections to wait/ or
1631              $c =~ m/^Complete client request received/ or
1632              $c =~ m/^Possible pipeline attempt detected./ or
1633              $c =~ m/^POST request detected. The connection will not be kept alive./ or
1634              $c =~ m/^The server still wants to talk, but the client hung up on us./ or
1635              $c =~ m/^The server didn't specify how long the connection will stay open/ or
1636              $c =~ m/^There might be a request body. The connection will not be kept alive/ or
1637              $c =~ m/^Stopping to watch the client socket. There's already another request waiting./ or
1638              $c =~ m/^Done reading from the client\.$/) {
1639
1640         # Looks like we reached the end of the last chunk. We better stop reading.
1641         # Looks like we read the end of the last chunk together with the server \
1642         #  headers. We better stop reading.
1643         # Looks like we got the last chunk together with the server headers. \
1644         #  We better stop reading.
1645         # Unsetting keep-alive flag.
1646         # No connections to wait for left.
1647         # Client request arrived in time or the client closed the connection.
1648         # Complete client request received
1649         # Possible pipeline attempt detected. The connection will not be \
1650         #  kept alive and we will only serve the first request.
1651         # POST request detected. The connection will not be kept alive.
1652         # The server still wants to talk, but the client hung up on us.
1653         # The server didn't specify how long the connection will stay open. Assume it's only a second.
1654         # There might be a request body. The connection will not be kept alive.
1655         # Stopping to watch the client socket. There's already another request waiting.
1656         # Done reading from the client\.
1657
1658     } else {
1659
1660         found_unknown_content($c);
1661
1662     }
1663
1664     return $c;
1665 }
1666
1667
1668 sub handle_loglevel_info ($) {
1669
1670     my $c = shift;
1671
1672     if ($c =~ m/^Rewrite detected:/) {
1673
1674         # Rewrite detected: GET http://10.0.0.2:88/blah.txt HTTP/1.1
1675         $c = highlight_matched_request_line($c, '(?<=^Rewrite detected: ).*');
1676
1677     } elsif ($c =~ m/^Decompress(ing deflated|ion didn)/ or
1678              $c =~ m/^Compressed content detected/ or
1679              $c =~ m/^Tagger/
1680             ) {
1681         # Decompressing deflated iob: 117
1682         # Decompression didn't result in any content.
1683         # Compressed content detected, content filtering disabled. Consider recompiling Privoxy\
1684         #  with zlib support or enable the prevent-compression action.
1685         # Tagger 'complete-url' created empty tag. Ignored.
1686
1687         # Ignored for now
1688
1689     } elsif ($c =~ m/^(Re)?loading configuration file /) {
1690
1691         # loading configuration file '/usr/local/etc/privoxy/config':
1692         # Reloading configuration file '/usr/local/etc/privoxy/config'
1693         $c =~ s@(?<=loading configuration file \')([^\']*)@$h{'file'}$1$h{'Standard'}@;
1694
1695     } elsif ($c =~ m/^Loading (actions|filter) file: /) {
1696
1697         # Loading actions file: /usr/local/etc/privoxy/default.action
1698         # Loading filter file: /usr/local/etc/privoxy/default.filter
1699         $c =~ s@(?<= file: )(.*)$@$h{'file'}$1$h{'Standard'}@;
1700
1701     } elsif ($c =~ m/^exiting by signal/) {
1702
1703         # exiting by signal 15 .. bye
1704         $c =~ s@(?<=exiting by signal )(\d+)@$h{'signal'}$1$h{'Standard'}@;
1705
1706     } elsif ($c =~ m/^Privoxy version/) {
1707
1708         # Privoxy version 3.0.7
1709         $c =~ s@(?<=^Privoxy version )(\d+\.\d+\.\d+)$@$h{'version'}$1$h{'Standard'}@;
1710
1711     } elsif ($c =~ m/^Program name: /) {
1712
1713         # Program name: /usr/local/sbin/privoxy
1714         $c =~ s@(?<=Program name: )(.*)@$h{'program-name'}$1$h{'Standard'}@;
1715
1716     } elsif ($c =~ m/^Listening on port /) {
1717
1718         # Listening on port 8118 on IP address 10.0.0.1
1719         $c =~ s@(?<=Listening on port )(\d+)@$h{'port'}$1$h{'Standard'}@;
1720         $c =~ s@(?<=on IP address )(.*)@$h{'ip-address'}$1$h{'Standard'}@;
1721
1722     } elsif ($c =~ m/^\(Re-\)Open(?:ing)? logfile/) {
1723
1724         # (Re-)Open logfile /var/log/privoxy/privoxy.log
1725         $c =~ s@(?<=Open logfile )(.*)@$h{'file'}$1$h{'Standard'}@;
1726
1727     } elsif ($c =~ m/^(Request from|Malformed server response detected)/) {
1728
1729         # Request from 10.0.0.1 denied. limit-connect{,} doesn't allow CONNECT requests to port 443.
1730         # Request from 10.0.0.1 marked for blocking. limit-connect{,} doesn't allow CONNECT requests to port 443.
1731         # Malformed server response detected. Downgrading to HTTP/1.0 impossible.
1732
1733         $c =~ s@(?<=Request from )([^\s]*)@$h{'ip-address'}$1$h{'Standard'}@;
1734         $c =~ s@(denied|blocking)@$h{'warning'}$1$h{'Standard'}@;
1735         $c =~ s@(CONNECT)@$h{'method'}$1$h{'Standard'}@;
1736         $c =~ s@(?<=to port )(\d+)@$h{'port'}$1$h{'Standard'}@;
1737
1738     } elsif ($c =~ m/^Status code/) {
1739
1740         # Status code 304 implies no body.
1741         $c =~ s@(?<=Status code )(\d+)@$h{'status-code'}$1$h{'Standard'}@;
1742
1743     } elsif ($c =~ m/^Method/) {
1744
1745         # Method HEAD implies no body.
1746         $c =~ s@(?<=Method )([^\s]+)@$h{'method'}$1$h{'Standard'}@;
1747
1748     } elsif ($c =~ m/^Buffer limit reached while extending /) {
1749
1750         # Buffer limit reached while extending the buffer (iob). Needed: 4197470. Limit: 4194304
1751         $c =~ s@(?<=Needed: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1752         $c =~ s@(?<=Limit: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1753
1754     } elsif ($c =~ m/^No logfile configured/ or
1755              $c =~ m/^Malformerd HTTP headers detected and MS IIS5 hack enabled/ or
1756              $c =~ m/^Invalid \"chunked\" transfer/ or
1757              $c =~ m/^Support for/ or
1758              $c =~ m/^Flushing header and buffers/ or
1759              $c =~ m/^Can not resolve/
1760              ) {
1761
1762         # No logfile configured. Please enable it before reporting any problems.
1763         # Malformerd HTTP headers detected and MS IIS5 hack enabled. Expect an invalid \
1764         #  response or even no response at all.
1765         # No logfile configured. Logging disabled.
1766         # Invalid "chunked" transfer encoding detected and ignored.
1767         # Support for 'Connection: keep-alive' is experimental, incomplete and\
1768         #  known not to work properly in some situations.
1769         # Flushing header and buffers. Stepping back from filtering.
1770         # Can not resolve doesnotexist: hostname nor servname provided, or not known
1771
1772     } else {
1773
1774         found_unknown_content($c);
1775
1776     }
1777
1778     return $c;
1779 }
1780
1781 sub handle_loglevel_cgi ($) {
1782
1783     my $c = shift;
1784
1785     if ($c =~ m/^Granting access to/) {
1786
1787         #Granting access to http://config.privoxy.org/send-stylesheet, referrer http://p.p/ is trustworthy.
1788
1789     } elsif ($c =~ m/^Substituting: s(.)/) {
1790
1791         # Substituting: s/@else-not-FEATURE_ZLIB@.*@endif-FEATURE_ZLIB@//sigTU
1792         # XXX: prone to span several lines
1793
1794         my $delimiter = $1;
1795         #$c =~ s@(?<=failed: )(.*)@$h{'error'}$1$h{'Standard'}@;
1796         $c =~ s@(?!<=\\)($delimiter)@$h{'pcrs-delimiter'}$1$h{'Standard'}@g; # XXX: Too aggressive
1797         #$c =~ s@(?!<=\\)($1)@$h{'pcrs-delimiter'}$1$h{'Standard'}@g;
1798     }
1799
1800     return $c;
1801 }
1802
1803 sub handle_loglevel_force ($) {
1804
1805     my $c = shift;
1806
1807     if ($c =~ m/^Ignored force prefix in request:/) {
1808
1809         # Ignored force prefix in request: "GET http://10.0.0.1/PRIVOXY-FORCE/block HTTP/1.1"
1810         $c =~ s@^(Ignored)@$h{'ignored'}$1$h{'Standard'}@;
1811         $c = highlight_matched_request_line($c, '(?<=request: ")[^"]*');
1812
1813     } elsif ($c =~ m/^Enforcing request:/) {
1814
1815         # Enforcing request: "GET http://10.0.0.1/block HTTP/1.1".
1816         $c = highlight_matched_request_line($c, '(?<=request: ")[^"]*');
1817
1818     } else {
1819
1820         found_unknown_content($c);
1821
1822     }
1823
1824     return $c;
1825 }
1826
1827 sub handle_loglevel_error ($) {
1828
1829     my $c = shift;
1830
1831     if ($c =~ m/^Empty server or forwarder response received on socket \d+./) {
1832
1833         # Empty server or forwarder response received on socket 4.
1834         # Empty server or forwarder response received on socket 3. \
1835         #  Closing client socket 15 without sending data.
1836         $c =~ s@(?<=on socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1837         $c =~ s@(?<=client socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1838     }
1839     # XXX: There are probably more messages that deserve highlighting.
1840
1841     return $c;
1842 }
1843
1844
1845 sub handle_loglevel_ignore ($) {
1846     return shift;
1847 }
1848
1849 sub gather_loglevel_request_stats ($$) {
1850     my $c = shift;
1851     my $thread = shift;
1852     our %stats;
1853
1854     $stats{requests}++;
1855 }
1856
1857 sub gather_loglevel_crunch_stats ($$) {
1858     my $c = shift;
1859     my $thread = shift;
1860     our %stats;
1861
1862     $stats{requests}++;
1863     $stats{crunches}++;
1864 }
1865
1866
1867 sub gather_loglevel_error_stats ($$) {
1868
1869     my $c = shift;
1870     my $thread = shift;
1871     our %stats;
1872     our %thread_data;
1873
1874     if ($c =~ m/^Empty server or forwarder response received on socket \d+./) {
1875
1876         # Empty server or forwarder response received on socket 4.
1877         $stats{'empty-responses'}++;
1878         if ($thread_data{$thread}{'new_connection'}) {
1879             $stats{'empty-responses-on-new-connections'}++;
1880         } else {
1881             $stats{'empty-responses-on-reused-connections'}++;
1882         }
1883     }
1884 }
1885
1886 sub gather_loglevel_connect_stats ($$) {
1887
1888     my ($c, $thread) = @_;
1889     our %thread_data;
1890     our %stats;
1891
1892     if ($c =~ m/^via ([^\s]+) to: [^\s]+/) {
1893
1894         # Connect: via 10.0.0.1:8123 to: www.example.org.noconnect
1895         $thread_data{$thread}{'forwarder'} = $1; # XXX: is this missue?
1896
1897     } elsif ($c =~ m/^to ([^\s]*)$/) {
1898
1899         # Connect: to lists.sourceforge.net:443
1900
1901         $thread_data{$thread}{'forwarder'} = 'direct connection';
1902
1903     } elsif ($c =~ m/^Created new connection to/) {
1904
1905         # Created new connection to www.privoxy.org:80 on socket 11.
1906
1907         $thread_data{$thread}{'new_connection'} = 1;
1908
1909     } elsif ($c =~ m/^Reusing server socket \d./ or
1910              $c =~ m/^Found reusable socket/) {
1911
1912         # Reusing server socket 4. Opened for 10.0.0.1.
1913         # Found reusable socket 9 for www.privoxy.org:80 in slot 0.
1914
1915         $thread_data{$thread}{'new_connection'} = 0;
1916         $stats{'reused-connections'}++;
1917     }
1918 }
1919
1920 sub gather_loglevel_header_stats ($$) {
1921
1922     my ($c, $thread) = @_;
1923     our %stats;
1924
1925     if ($c =~ m/^A HTTP\/1\.1 response without/ or
1926         $c =~ m/^Keeping the server header 'Connection: keep-alive' around./)
1927     {
1928         # A HTTP/1.1 response without Connection header implies keep-alive.
1929         # Keeping the server header 'Connection: keep-alive' around.
1930         $stats{'server-keep-alive'}++;
1931
1932     } elsif ($c =~ m/^scan: ((\w+) (.+) (HTTP\/\d\.\d))/) {
1933
1934         # scan: HTTP/1.1 200 OK
1935         $stats{'method'}{$2}++;
1936         $stats{'ressource'}{$3}++;
1937         $stats{'http-version'}{$4}++;
1938     }
1939 }
1940
1941 sub init_stats () {
1942     our %stats = (
1943         requests => 0,
1944         crunches => 0,
1945         'server-keep-alive' => 0,
1946         'reused-connections' => 0,
1947         'empty-responses' => 0,
1948         'empty-responses-on-new-connections' => 0,
1949         'empty-responses-on-reused-connections' => 0,
1950         );
1951 }
1952
1953 sub get_percentage ($$) {
1954     my $big = shift;
1955     my $small = shift;
1956     return "NaN" if ($big eq 0);
1957     return sprintf("%.2f%%", $small / $big * 100);
1958 }
1959
1960 sub print_stats () {
1961
1962     our %stats;
1963     our %cli_options;
1964     my $new_connections = $stats{requests} - $stats{crunches} - $stats{'reused-connections'};
1965     my $outgoing_requests = $stats{requests} - $stats{crunches};
1966
1967     if ($stats{requests} eq 0) {
1968         print "No requests yet.\n";
1969         return;
1970     }
1971
1972     print "Client requests total: " . $stats{requests} . "\n";
1973     print "Crunches: " . $stats{crunches} . " (" .
1974         get_percentage($stats{requests}, $stats{crunches}) . ")\n";
1975     print "Outgoing requests: " . $outgoing_requests . " (" .
1976         get_percentage($stats{requests}, $outgoing_requests) . ")\n";
1977     print "Server keep-alive offers: " . $stats{'server-keep-alive'} . " (" .
1978         get_percentage($stats{requests}, $stats{'server-keep-alive'}) . ")\n";
1979     print "New outgoing connections: " . $new_connections . " (" .
1980         get_percentage($stats{requests}, $new_connections) . ")\n";
1981     print "Reused connections: " . $stats{'reused-connections'} . " (" .
1982         get_percentage($stats{requests}, $stats{'reused-connections'}) . ")\n";
1983     print "Empty responses: " . $stats{'empty-responses'} . " (" .
1984         get_percentage($stats{requests}, $stats{'empty-responses'}) . ")\n";
1985     print "Empty responses on new connections: "
1986          . $stats{'empty-responses-on-new-connections'} . " (" .
1987         get_percentage($stats{requests}, $stats{'empty-responses-on-new-connections'})
1988         . ")\n";
1989     print "Empty responses on reused connections: " .
1990         $stats{'empty-responses-on-reused-connections'} . " (" .
1991         get_percentage($stats{requests}, $stats{'empty-responses-on-reused-connections'}) .
1992         ")\n";
1993
1994     if ($stats{method} eq 0) {
1995         print "No response lines parsed yet yet.\n";
1996         return;
1997     }
1998     print "Method distribution:\n";
1999     foreach my $method (sort {$stats{'method'}{$b} <=> $stats{'method'}{$a}} keys %{$stats{'method'}}) {
2000         printf "%8d : %-8s\n", $stats{'method'}{$method}, $method;
2001     }
2002     print "Client HTTP versions:\n";
2003     foreach my $http_version (sort {$stats{'http-version'}{$b} <=> $stats{'http-version'}{$a}} keys %{$stats{'http-version'}}) {
2004         printf "%d : %s\n",  $stats{'http-version'}{$http_version}, $http_version;
2005     }
2006
2007     if ($cli_options{'url-statistics-threshold'} == 0) {
2008         print "URL statistics are disabled. Increase --url-statistics-threshold to enable them.\n";
2009     } else {
2010         print "Requested URLs:\n";
2011         foreach my $ressource (sort {$stats{'ressource'}{$b} <=> $stats{'ressource'}{$a}} keys %{$stats{'ressource'}}) {
2012             if ($stats{'ressource'}{$ressource} < $cli_options{'url-statistics-threshold'}) {
2013                 print "Skipped statistics for URLs below the treshold.\n";
2014                 last;
2015             }
2016             printf "%d : %s\n", $stats{'ressource'}{$ressource}, $ressource;
2017         }
2018     }
2019 }
2020
2021
2022 ################################################################################
2023 # Functions that actually print stuff
2024 ################################################################################
2025
2026 sub print_clf_message () {
2027
2028     our ($ip, $timestamp, $request_line, $status_code, $size);
2029     my $output = '';
2030
2031     return if DEBUG_SUPPRESS_LOG_MESSAGES;
2032
2033     # Rebuild highlighted
2034     $output .= $h{'Number'} . $ip . $h{'Standard'};
2035     $output .= " - - ";
2036     $output .= "[" . $h{'Timestamp'} . $timestamp . $h{'Standard'} . "]";
2037     $output .= " ";
2038     $output .= "\"" . highlight_request_line("$request_line") . "\"";
2039     $output .= " ";
2040     $output .= $h{'Status'} . $status_code . $h{'Standard'};
2041     $output .= " ";
2042     $output .= $h{'Number'} . $size . $h{'Standard'};
2043     $output .= $line_end;
2044
2045     print $output;
2046 }
2047
2048 sub print_non_clf_message ($) {
2049
2050     my $content = shift;
2051     my $msec_string = "." . $req{$t}{'msecs'} unless $no_msecs_mode;
2052     my $line_start = $html_output_mode ? '' : $h{"Standard"};
2053
2054     return if DEBUG_SUPPRESS_LOG_MESSAGES;
2055
2056     print $line_start
2057         . $time_colours[$time_colour_index % 2]
2058         . $req{$t}{'time-stamp'}
2059         . $msec_string
2060         . $h{Standard} . " "
2061         . $thread_colours{$t}
2062         . $t
2063         . $h{Standard}
2064         . " "
2065         . $h{$req{$t}{'log-level'}}
2066         . $req{$t}{'log-level'}
2067         . $h{Standard}
2068         . ": "
2069         . $content
2070         . $line_end;
2071 }
2072
2073 sub shorten_thread_id ($) {
2074
2075     my $thread_id = shift;
2076
2077     our %short_thread_ids;
2078     our $max_threadid;
2079
2080     unless (defined $short_thread_ids{$thread_id}) {
2081         $short_thread_ids{$thread_id} = sprintf "%.3d", $max_threadid++;
2082     }
2083
2084     return $short_thread_ids{$thread_id}
2085 }
2086
2087 sub parse_loop () {
2088
2089     my ($day, $time_stamp, $thread, $log_level, $content, $c, $msecs);
2090     my $last_msecs  = 0;
2091     my $last_thread = 0;
2092     my $last_timestamp = 0;
2093     my $filters_that_did_nothing;
2094     my $key;
2095     my $time_colour;
2096     $time_colour = paint_it('white');
2097
2098     my %log_level_handlers = (
2099         'Re-Filter'         => \&handle_loglevel_re_filter,
2100         'Header'            => \&handle_loglevel_header,
2101         'Connect'           => \&handle_loglevel_connect,
2102         'Redirect'          => \&handle_loglevel_redirect,
2103         'Request'           => \&handle_loglevel_request,
2104         'Crunch'            => \&handle_loglevel_crunch,
2105         'Gif-Deanimate'     => \&handle_loglevel_gif_deanimate,
2106         'Info'              => \&handle_loglevel_info,
2107         'CGI'               => \&handle_loglevel_cgi,
2108         'Force'             => \&handle_loglevel_force,
2109         'Error'             => \&handle_loglevel_error,
2110         'Fatal error'       => \&handle_loglevel_ignore,
2111         'Writing'           => \&handle_loglevel_ignore,
2112         'Received'          => \&handle_loglevel_ignore,
2113         'Unknown log level' => \&handle_loglevel_ignore,
2114     );
2115
2116     while (<>) {
2117
2118         if (m/^(\w{3} \d{2}) (\d\d:\d\d:\d\d)\.?(\d+)? (?:Privoxy\()?([^\)\s]*)[\)]? ([\w -]*): (.*?)\r?$/) {
2119             $thread = $t = ($shorten_thread_ids) ? shorten_thread_id($4) : $4;
2120             $req{$t}{'day'} = $day = $1;
2121             $req{$t}{'time-stamp'} = $time_stamp = $2;
2122             $req{$t}{'msecs'} = $msecs = $3 ? $3 : 0; # Only the cool kids have micro second resolution;
2123             $req{$t}{'log-level'} = $log_level = $5;
2124             $req{$t}{'content'} = $content = $c = $6;
2125             $req{$t}{'log-message'} = $_;
2126             $no_special_header_highlighting = 0;
2127
2128             if (defined($log_level_handlers{$log_level})) {
2129
2130                 $content = $log_level_handlers{$log_level}($content);
2131
2132             } else {
2133
2134                 die "No handler found for log level \"$log_level\"\n";
2135             }
2136
2137             # Highlight Truncations
2138             if (length($_) > 4000) {
2139                 $content =~ s@(too long, truncated)]$@$h{'Truncation'}$1$h{'Standard'}]@g;
2140             }
2141
2142             next unless $content;
2143
2144             # Register threads to keep the colour constant
2145             if (!defined($thread_colours{$thread})) {
2146                 $thread_colours{$thread} = $all_colours[$thread_colour_index % @all_colours];
2147                 $thread_colour_index++;
2148             }
2149
2150             # Switch timestamp colour if timestamps differ
2151             if (($msecs ne $last_msecs) || ($time_stamp ne $last_timestamp)) {
2152                debug_message("Tick tack!") if DEBUG_TICKS;
2153                $time_colour = $time_colours[$time_colour_index % 2];
2154                $time_colour_index++;
2155                $last_msecs = $msecs;
2156                $last_timestamp = $time_stamp;
2157             }
2158
2159             $last_thread = $thread;
2160
2161             print_non_clf_message($content);
2162
2163         } elsif (m/^((?:\d+\.\d+\.\d+\.\d+|[:\d]+)) - - \[(.*)\] "(.*)" (\d+) (\d+)/) {
2164
2165             # LOG_LEVEL_CLF lines look like this
2166             # 61.152.239.32 - - [04/Mar/2007:18:28:23 +0100] "GET \
2167             #  http://ad.yieldmanager.com/imp?z=1&Z=120x600&s=109339&u=http%3A%2F%2Fwww.365loan.co.uk%2F&r=1\
2168             #  HTTP/1.1" 403 1730
2169             our ($ip, $timestamp, $request_line, $status_code, $size) = ($1, $2, $3, $4, $5);
2170
2171             print_clf_message();
2172
2173         } else {
2174
2175             # Some Privoxy log messages span more than one line,
2176             # usually to dump lots of content that doesn't need any syntax highlighting.
2177             # XXX: add mechanism to forward these lines to the right handler anyway.
2178             chomp();
2179             unless (DEBUG_SUPPRESS_LOG_MESSAGES or (SUPPRESS_EMPTY_LINES and m/^\s+$/)) {
2180                 print and print get_line_end(); # unless (SUPPRESS_EMPTY_LINES and m/^\s+$/);
2181             }
2182         }
2183     }
2184 }
2185
2186 sub stats_loop () {
2187
2188     my ($day, $time_stamp, $msecs, $thread, $log_level, $content);
2189     my %log_level_handlers = (
2190          'Re-Filter'         => \&handle_loglevel_ignore,
2191          'Header'            => \&gather_loglevel_header_stats,
2192          'Connect'           => \&gather_loglevel_connect_stats,
2193          'Redirect'          => \&handle_loglevel_ignore,
2194          'Request'           => \&gather_loglevel_request_stats,
2195          'Crunch'            => \&gather_loglevel_crunch_stats,
2196          'Gif-Deanimate'     => \&handle_loglevel_ignore,
2197          'Info'              => \&handle_loglevel_ignore,
2198          'CGI'               => \&handle_loglevel_ignore,
2199          'Force'             => \&handle_loglevel_ignore,
2200          'Error'             => \&gather_loglevel_error_stats,
2201          'Fatal error'       => \&handle_loglevel_ignore,
2202          'Writing'           => \&handle_loglevel_ignore,
2203          'Unknown log level' => \&handle_loglevel_ignore
2204     );
2205
2206     while (<>) {
2207         if (m/^(\w{3} \d{2}) (\d\d:\d\d:\d\d)\.?(\d+)? (?:Privoxy\()?([^\)\s]*)[\)]? ([\w -]*): (.*?)\r?$/) {
2208             $day = $1;
2209             $time_stamp = $2;
2210             $msecs = $3 ? $3 : 0;
2211             $thread = $4;
2212             $log_level = $5;
2213             $content = $6;
2214
2215             if (defined($log_level_handlers{$log_level})) {
2216
2217                 $content = $log_level_handlers{$log_level}($content, $thread);
2218
2219             } else {
2220
2221                 die "No handler found for log level \"$log_level\"\n";
2222
2223             }
2224         }
2225     }
2226
2227     print_stats();
2228
2229 }
2230
2231 sub VersionMessage {
2232     my $version_message;
2233
2234     $version_message .= 'Privoxy-Log-Parser ' . PRIVOXY_LOG_PARSER_VERSION  . "\n";
2235     $version_message .= 'Copyright (C) 2007-2010 Fabian Keil <fk@fabiankeil.de>' . "\n";
2236     $version_message .= 'http://www.fabiankeil.de/sourcecode/privoxy-log-parser/' . "\n";
2237
2238     print $version_message;
2239 }
2240
2241 sub get_cli_options () {
2242
2243     our %cli_options = (
2244         'html-output'              => CLI_OPTION_DEFAULT_TO_HTML_OUTPUT,
2245         'title'                    => CLI_OPTION_TITLE,
2246         'no-syntax-highlighting'   => CLI_OPTION_NO_SYNTAX_HIGHLIGHTING,
2247         'no-embedded-css'          => CLI_OPTION_NO_EMBEDDED_CSS,
2248         'no-msecs'                 => CLI_OPTION_NO_MSECS,
2249         'shorten-thread-ids'       => CLI_OPTION_SHORTEN_THREAD_IDS,
2250         'show-ineffective-filters' => CLI_OPTION_SHOW_INEFFECTIVE_FILTERS,
2251         'accept-unknown-messages'  => CLI_OPTION_ACCEPT_UNKNOWN_MESSAGES,
2252         'statistics'               => CLI_OPTION_STATISTICS,
2253         'url-statistics-threshold'  => CLI_OPTION_URL_STATISTICS_THRESHOLD,
2254     );
2255
2256     GetOptions (
2257         'html-output'              => \$cli_options{'html-output'},
2258         'title'                    => \$cli_options{'title'},
2259         'no-syntax-highlighting'   => \$cli_options{'no-syntax-highlighting'},
2260         'no-embedded-css'          => \$cli_options{'no-embedded-css'},
2261         'no-msecs'                 => \$cli_options{'no-msecs'},
2262         'shorten-thread-ids'       => \$cli_options{'shorten-thread-ids'},
2263         'show-ineffective-filters' => \$cli_options{'show-ineffective-filters'},
2264         'accept-unknown-messages'  => \$cli_options{'accept-unknown-messages'},
2265         'statistics'               => \$cli_options{'statistics'},
2266         'url-statistics-threshold=s'=> \$cli_options{'url-statistics-threshold'},
2267         'version'                  => sub { VersionMessage && exit(0) },
2268         'help'                     => \&help,
2269    ) or exit(1);
2270
2271    $html_output_mode = cli_option_is_set('html-output');
2272    $no_msecs_mode = cli_option_is_set('no-msecs');
2273    $shorten_thread_ids = cli_option_is_set('shorten-thread-ids');
2274    $line_end = get_line_end();
2275 }
2276
2277 sub help () {
2278
2279     our %cli_options;
2280
2281     VersionMessage();
2282
2283     print << "    EOF"
2284
2285 Options and their default values if they have any:
2286     [--accept-unknown-messages]
2287     [--html-output]
2288     [--no-embedded-css]
2289     [--no-msecs]
2290     [--no-syntax-highlighting]
2291     [--shorten-thread-ids]
2292     [--show-ineffective-filters]
2293     [--statistics]
2294     [--url-statistics-threshold $cli_options{'url-statistics-threshold'}]
2295     [--title $cli_options{'title'}]
2296     [--version]
2297 see "perldoc $0" for more information
2298     EOF
2299     ;
2300     exit(0);
2301 }
2302
2303 ################################################################################
2304 # main
2305 ################################################################################
2306 sub main () {
2307
2308     get_cli_options();
2309     set_background(DEFAULT_BACKGROUND);
2310     prepare_our_stuff();
2311
2312     print_intro();
2313
2314     if (cli_option_is_set('statistics')) {
2315         stats_loop();
2316     } else {
2317         parse_loop();
2318     }
2319
2320     print_outro();
2321 }
2322
2323 main();
2324
2325 =head1 NAME
2326
2327 B<privoxy-log-parser> - A parser and syntax-highlighter for Privoxy log messages
2328
2329 =head1 SYNOPSIS
2330
2331 B<privoxy-log-parser> [B<--accept-unknown-messages>] [B<--html-output>]
2332 [B<--no-msecs>] [B<--no-syntax-higlighting>] [B<--statistics>]
2333 [B<--shorten-thread-ids>] [B<--show-ineffective-filters>]
2334 [B<--url-statistics-threshold>] [B<--version>]
2335
2336 =head1 DESCRIPTION
2337
2338 B<privoxy-log-parser> reads Privoxy log messages and
2339
2340 - syntax-highlights recognized lines,
2341
2342 - reformats some of them for easier comprehension,
2343
2344 - filters out less useful messages, and
2345
2346 - (in some cases) calculates additional information,
2347   like the compression ratio or how a filter affected
2348   the content size.
2349
2350 With B<privoxy-log-parser> you should be able to increase Privoxy's log level
2351 without getting confused by the resulting amount of output. For example for
2352 "debug 64" B<privoxy-log-parser> will (by default) only show messages that
2353 affect the content. If a filter doesn't cause any hits, B<privoxy-log-parser>
2354 will hide the "filter foo caused 0 hits" message.
2355
2356 =head1 OPTIONS
2357
2358 [B<--accept-unknown-messages>] Don't print warnings in case of unknown messages,
2359 just don't highlight them.
2360
2361 [B<--html-output>] Use HTML and CSS for the syntax highlighting. If this option is
2362 omitted, ANSI escape sequences are used unless B<--no-syntax-highlighting> is active.
2363 This option is only intended to make embedding log excerpts in web pages easier.
2364 It does not escape any input!
2365
2366 [B<--no-msecs>] Don't expect milisecond resolution
2367
2368 [B<--no-syntax-highlighting>] Disable syntax-highlighting. Useful when
2369 the filtered output is piped into less in which case the ANSI control
2370 codes don't work, or if the terminal itself doesn't support the control
2371 codes.
2372
2373 [B<--shorten-thread-ids>] Shorten the thread ids to a three-digit decimal number.
2374 Note that the mapping from thread ids to shortened ids is created at run-time
2375 and thus varies with the input.
2376
2377 [B<--show-ineffective-filters>] Don't suppress log lines for filters
2378 that didn't modify the content.
2379
2380 [B<--statistics>] Gather various statistics instead of syntax highlighting
2381 log messages. This is an experimental feature, if the results look wrong
2382 they very well might be. Also note that the results are pretty much guaranteed
2383 to be incorrect if Privoxy and Privoxy-Log-Parser aren't in sync.
2384
2385 [B<--url-statistics-threshold>] Only show the request count for a ressource
2386 if it's above the given threshold.
2387
2388 [B<--version>] Print version and exit.
2389
2390 =head1 EXAMPLES
2391
2392 To monitor a log file:
2393
2394 tail -F /usr/jails/privoxy-jail/var/log/privoxy/privoxy.log | B<privoxy-log-parser>
2395
2396 Replace '-F' with '-f' if your tail implementation lacks '-F' support
2397 or if the log won't get rotated anyway. The log file location depends
2398 on your system (Doh!).
2399
2400 To monitor Privoxy without having it write to a log file:
2401
2402 privoxy --no-daemon /usr/jails/privoxy-jail/usr/local/etc/privoxy/config 2>&1 | B<privoxy-log-parser>
2403
2404 Again, the config file location depends on your system. Output redirection
2405 depends on your shell, the above works with bourne shells.
2406
2407 To read a processed Privoxy log file from top to bottom, letting the content
2408 scroll by slightly faster than you can read:
2409
2410 B<privoxy-log-parser> < /usr/jails/privoxy-jail/var/log/privoxy/privoxy.log
2411
2412 This is probably only useful to fill screens in the background of haxor movies.
2413
2414 =head1 CAVEATS
2415
2416 Syntax highlighting with ANSI escape sequences will look strange
2417 if your background color isn't black.
2418
2419 Some messages aren't recognized yet and will not be fully highlighted.
2420
2421 B<privoxy-log-parser> is developed with Privoxy 3.0.7 or later in mind,
2422 using earlier Privoxy versions will probably result in an increased amount
2423 of unrecognized log lines.
2424
2425 Privoxy's log files tend to be rather large. If you use HTML
2426 highlighting some browsers can't handle them, get confused and
2427 will eventually crash because of segmentation faults or unexpected
2428 exceptions. This is a problem in the browser and not B<privoxy-log-parser>'s
2429 fault.
2430
2431 =head1 BUGS
2432
2433 Many settings can't be controlled through command line options yet.
2434
2435 =head1 SEE ALSO
2436
2437 privoxy(1)
2438
2439 =head1 AUTHOR
2440
2441 Fabian Keil <fk@fabiankeil.de>
2442
2443 =cut