tools/privoxy-log-parser.pl

   1 #!/usr/bin/perl
   2
   3 ################################################################################
   4 # privoxy-log-parser
   5 #
   6 # A parser for Privoxy log messages. For incomplete documentation run
   7 # perldoc privoxy-log-parser(.pl), for fancy screenshots see:
   8 #
   9 # http://www.fabiankeil.de/sourcecode/privoxy-log-parser/
  10 #
  11 # $Id: privoxy-log-parser.pl,v 1.146 2012/12/20 17:02:30 fabiankeil Exp $
  12 #
  13 # TODO:
  14 #       - LOG_LEVEL_CGI, LOG_LEVEL_ERROR, LOG_LEVEL_WRITE content highlighting
  15 #       - create fancy statistics
  16 #       - grep through Privoxy sources to find unsupported log messages
  17 #       - hunt down substitutions that match content from variables which
  18 #         can contain stuff like ()?'[]
  19 #       - replace $h{'foo'} with h('foo') where possible
  20 #       - hunt down XXX comments instead of just creating them
  21 #       - add example log lines for every regex and mark them up for
  22 #         regression testing
  23 #       - Handle incomplete input without Perl warning about undefined variables.
  24 #       - Use generic highlighting function that takes a regex and the
  25 #         hash key as input.
  26 #       - Add --compress and --decompress options.
  27 #
  28 # Copyright (c) 2007-2010 Fabian Keil <fk@fabiankeil.de>
  29 #
  30 # Permission to use, copy, modify, and distribute this software for any
  31 # purpose with or without fee is hereby granted, provided that the above
  32 # copyright notice and this permission notice appear in all copies.
  33 #
  34 # THE SOFTWARE IS PROVIDED "AS IS" AND THE AUTHOR DISCLAIMS ALL WARRANTIES
  35 # WITH REGARD TO THIS SOFTWARE INCLUDING ALL IMPLIED WARRANTIES OF
  36 # MERCHANTABILITY AND FITNESS. IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR
  37 # ANY SPECIAL, DIRECT, INDIRECT, OR CONSEQUENTIAL DAMAGES OR ANY DAMAGES
  38 # WHATSOEVER RESULTING FROM LOSS OF USE, DATA OR PROFITS, WHETHER IN AN
  39 # ACTION OF CONTRACT, NEGLIGENCE OR OTHER TORTIOUS ACTION, ARISING OUT OF
  40 # OR IN CONNECTION WITH THE USE OR PERFORMANCE OF THIS SOFTWARE.
  41 ################################################################################
  42
  43 use strict;
  44 use warnings;
  45 use Getopt::Long;
  46
  47 use constant {
  48     PRIVOXY_LOG_PARSER_VERSION => '0.7',
  49     # Feel free to mess with these ...
  50     DEFAULT_BACKGROUND => 'black',  # Choose registered colour (like 'black')
  51     DEFAULT_TEXT_COLOUR => 'white', # Choose registered colour (like 'black')
  52     HEADER_DEFAULT_COLOUR => 'yellow',
  53     REGISTER_HEADERS_WITH_THE_SAME_COLOUR => 1,
  54
  55     CLI_OPTION_DEFAULT_TO_HTML_OUTPUT => 0,
  56     CLI_OPTION_TITLE => 'Privoxy-Log-Parser in da house',
  57     CLI_OPTION_NO_EMBEDDED_CSS => 0,
  58     CLI_OPTION_NO_MSECS => 0,
  59     CLI_OPTION_NO_SYNTAX_HIGHLIGHTING => 0,
  60     CLI_OPTION_SHORTEN_THREAD_IDS => 0,
  61     CLI_OPTION_SHOW_INEFFECTIVE_FILTERS => 0,
  62     CLI_OPTION_ACCEPT_UNKNOWN_MESSAGES => 0,
  63     CLI_OPTION_STATISTICS => 0,
  64     CLI_OPTION_UNBREAK_LINES_ONLY => 0,
  65     CLI_OPTION_URL_STATISTICS_THRESHOLD => 0,
  66     CLI_OPTION_HOST_STATISTICS_THRESHOLD => 0,
  67
  68     SUPPRESS_SUCCEEDED_FILTER_ADDITIONS => 1,
  69     SHOW_SCAN_INTRO => 0,
  70     SHOW_FILTER_READIN_IN => 0,
  71     SUPPRESS_EMPTY_LINES => 1,
  72     SUPPRESS_SUCCESSFUL_CONNECTIONS => 1,
  73     SUPPRESS_GIF_NOT_CHANGED => 1,
  74     SUPPRESS_NEED_TO_DE_CHUNK_FIRST => 1,
  75
  76     DEBUG_HEADER_REGISTERING => 0,
  77     DEBUG_HEADER_HIGHLIGHTING => 0,
  78     DEBUG_TICKS => 0,
  79     DEBUG_PAINT_IT => 0,
  80     DEBUG_SUPPRESS_LOG_MESSAGES => 0,
  81
  82     PUNISH_MISSING_LOG_KNOWLEDGE_WITH_DEATH => 0,
  83     PUNISH_MISSING_HIGHLIGHT_KNOWLEDGE_WITH_DEATH => 1,
  84
  85     LOG_UNPARSED_LINES_TO_EXTRA_FILE => 0,
  86     ERROR_LOG_FILE => '/var/log/privoxy-log-parser',
  87
  88     # You better leave these alone unless you know what you're doing.
  89     COLOUR_RESET      => "\033[0;0m",
  90     ESCAPE => "\033[",
  91 };
  92
  93 # For performance reasons, these are global.
  94
  95 my $t;
  96 my %req; # request data from previous lines
  97 my %h;
  98 my %thread_colours;
  99 my @all_colours;
 100 my @time_colours;
 101 my $thread_colour_index = 0;
 102 my $header_colour_index = 0;
 103 my $time_colour_index = 0;
 104 my %header_colours;
 105 my $no_special_header_highlighting;
 106 my %reason_colours;
 107 my %h_colours;
 108 my $header_highlight_regex = '';
 109
 110 my $html_output_mode;
 111 my $no_msecs_mode; # XXX: should probably be removed
 112 my $shorten_thread_ids;
 113 my $line_end;
 114
 115 sub prepare_our_stuff () {
 116
 117     # Syntax Higlight hash
 118     @all_colours = (
 119         'red', 'green', 'brown', 'blue', 'purple', 'cyan',
 120         'light_gray', 'light_red', 'light_green', 'yellow',
 121         'light_blue', 'pink', 'light_cyan', 'white'
 122     );
 123
 124     %h = (
 125         # LOG_LEVEL
 126         Info            => 'blue',
 127         Header          => 'green',
 128         Filter          => 'purple', # XXX: Used?
 129         'Re-Filter'     => 'purple',
 130         Connect         => 'brown',
 131         Request         => 'light_cyan',
 132         CGI             => 'light_green',
 133         Redirect        => 'cyan',
 134         Error           => 'light_red',
 135         Crunch          => 'cyan',
 136         'Fatal error'   => 'light_red',
 137         'Gif-Deanimate' => 'blue',
 138         Force           => 'red',
 139         Writing         => 'light_green',
 140         Received        => 'yellow',
 141         Actions         => 'yellow',
 142         # ----------------------
 143         URL                  => 'yellow',
 144         path                 => 'brown',
 145         request_             => 'brown', # host+path but no protocol
 146         'ip-address'         => 'yellow',
 147         Number               => 'yellow',
 148         Standard             => 'reset',
 149         Truncation           => 'light_red',
 150         Status               => 'brown',
 151         Timestamp            => 'brown',
 152         Crunching            => 'light_red',
 153         crunched             => 'light_red',
 154         'Request-Line'       => 'pink',
 155         method               => 'purple',
 156         destination          => 'yellow',
 157         'http-version'       => 'pink',
 158         'crunch-pattern'     => 'pink',
 159         not                  => 'brown',
 160         file                 => 'brown',
 161         signal               => 'yellow',
 162         version              => 'green',
 163         'program-name'       => 'cyan',
 164         port                 => 'red',
 165         host                 => 'red',
 166         warning              => 'light_red',
 167         debug                => 'light_red',
 168         filter               => 'green',
 169         tag                  => 'green',
 170         tagger               => 'green',
 171         'status-message'     => 'light_cyan',
 172         'status-code'        => 'yellow',
 173         'invalid-request'    => 'light_red',
 174         'hits'               => 'yellow',
 175         error                => 'light_red',
 176         'rewritten-URL'      => 'light_red',
 177         'pcrs-delimiter'     => 'light_red',
 178         'ignored'            => 'light_red',
 179         'action-bits-update' => 'light_red',
 180         'configuration-line' => 'red',
 181         'content-type'       => 'yellow',
 182         'HOST'               => HEADER_DEFAULT_COLOUR,
 183     );
 184
 185     %h_colours = %h;
 186
 187     # Header colours need their own hash so the keys can be accessed properly
 188     %header_colours = (
 189         # Prefilled with headers that should not appear with default header colours
 190         Cookie => 'light_red',
 191         'Set-Cookie' => 'light_red',
 192         Warning => 'light_red',
 193         Default => HEADER_DEFAULT_COLOUR,
 194     );
 195
 196     # Crunch reasons need their own hash as well
 197     %reason_colours = (
 198         'Unsupported HTTP feature'               => 'light_red',
 199         Blocked                                  => 'light_red',
 200         Untrusted                                => 'light_red',
 201         Redirected                               => 'green',
 202         'CGI Call'                               => 'white',
 203         'DNS failure'                            => 'red',
 204         'Forwarding failed'                      => 'light_red',
 205         'Connection failure'                     => 'light_red',
 206         'Out of memory (may mask other reasons)' => 'light_red',
 207         'No reason recorded'                     => 'light_red',
 208     );
 209
 210     @time_colours = ('white', 'light_gray');
 211
 212     # Translate highlight strings into highlight code
 213     prepare_highlight_hash(\%header_colours);
 214     prepare_highlight_hash(\%reason_colours);
 215     prepare_highlight_hash(\%h);
 216     prepare_colour_array(\@all_colours);
 217     prepare_colour_array(\@time_colours);
 218     init_css_colours();
 219
 220     init_stats();
 221 }
 222
 223 sub paint_it ($) {
 224 ###############################################################
 225 # Takes a colour string and returns an ANSI escape sequence
 226 # (unless --no-syntax-highlighting is used).
 227 # XXX: The Rolling Stones reference has to go.
 228 ###############################################################
 229
 230     my $colour = shift;
 231
 232     return "" if cli_option_is_set('no-syntax-highlighting');
 233
 234     my %light = (
 235         black       => 0,
 236         red         => 0,
 237         green       => 0,
 238         brown       => 0,
 239         blue        => 0,
 240         purple      => 0,
 241         cyan        => 0,
 242         light_gray  => 0,
 243         gray        => 0,
 244         dark_gray   => 1,
 245         light_red   => 1,
 246         light_green => 1,
 247         yellow      => 1,
 248         light_blue  => 1,
 249         pink        => 1,
 250         light_cyan  => 1,
 251         white       => 1,
 252     );
 253
 254     my %text = (
 255         black       => 30,
 256         red         => 31,
 257         green       => 32,
 258         brown       => 33,
 259         blue        => 34,
 260         purple      => 35,
 261         cyan        => 36,
 262         gray        => 37,
 263         light_gray  => 37,
 264         dark_gray   => 30,
 265         light_red   => 31,
 266         light_green => 32,
 267         yellow      => 33,
 268         light_blue  => 34,
 269         pink        => 35,
 270         light_cyan  => 36,
 271         white       => 37,
 272     );
 273
 274     my $bg_code = get_background();
 275     my $colour_code;
 276     our $default = default_colours();
 277
 278     if (defined($text{$colour})) {
 279         $colour_code  = ESCAPE;
 280         $colour_code .= $text{$colour};
 281         $colour_code .= ";";
 282         $colour_code .= $light{$colour} ? "1" : "2";
 283         $colour_code .= ";";
 284         $colour_code .= $bg_code;
 285         $colour_code .= "m";
 286         debug_message $colour . " is \'" . $colour_code . $colour . $default . "\'" if DEBUG_PAINT_IT;
 287
 288     } elsif ($colour =~ /reset/) {
 289
 290         $colour_code = default_colours();
 291
 292     } else {
 293
 294         die "What's $colour supposed to mean?\n";
 295     }
 296
 297     return $colour_code;
 298 }
 299
 300 sub get_semantic_html_markup ($) {
 301 ###############################################################
 302 # Takes a string and returns a span element
 303 ###############################################################
 304
 305     my $type = shift;
 306     my $code;
 307
 308     if ($type =~ /Standard/) {
 309         $code = '</span>';
 310     } else {
 311         $type = lc($type);
 312         $code = '<span title="' . $type . '" class="' . $type . '">';
 313     }
 314
 315     return $code;
 316 }
 317
 318 sub cli_option_is_set ($) {
 319
 320     our %cli_options;
 321     my $cli_option = shift;
 322
 323     die "Unknown CLI option: $cli_option" unless defined $cli_options{$cli_option};
 324
 325     return $cli_options{$cli_option};
 326 }
 327
 328 sub get_html_title () {
 329
 330     our %cli_options;
 331     return $cli_options{'title'};
 332
 333 }
 334
 335 sub init_css_colours() {
 336
 337     our %css_colours = (
 338         black       => "000",
 339         red         => "F00",
 340         green       => "0F0",
 341         brown       => "C90",
 342         blue        => "0F0",
 343         purple      => "F06", # XXX: wrong
 344         cyan        => "F09", # XXX: wrong
 345         light_gray  => "999",
 346         gray        => "333",
 347         dark_gray   => "222",
 348         light_red   => "F33",
 349         light_green => "33F",
 350         yellow      => "FF0",
 351         light_blue  => "30F",
 352         pink        => "F0F",
 353         light_cyan  => "66F",
 354         white       => "FFF",
 355     );
 356 }
 357
 358 sub get_css_colour ($) {
 359
 360    our %css_colours;
 361    my $colour = shift;
 362
 363    die "What's $colour supposed to mean?\n" unless defined($css_colours{$colour});
 364
 365    return '#' . $css_colours{$colour};
 366 }
 367
 368 sub get_css_line ($) {
 369
 370     my $class = shift;
 371     my $css_line;
 372
 373     $css_line .= '.' . lc($class) . ' {'; # XXX: lc() shouldn't be necessary
 374     die "What's $class supposed to mean?\n" unless defined($h_colours{$class});
 375     $css_line .= 'color:' . get_css_colour($h_colours{$class}) . ';';
 376     $css_line .= 'background-color:' . get_css_colour(DEFAULT_BACKGROUND) . ';';
 377     $css_line .= '}' . "\n";
 378
 379     return $css_line;
 380 }
 381
 382 sub get_css_line_for_colour ($) {
 383
 384     my $colour = shift;
 385     my $css_line;
 386
 387     $css_line .= '.' . lc($colour) . ' {'; # XXX: lc() shouldn't be necessary
 388     $css_line .= 'color:' . get_css_colour($colour) . ';';
 389     $css_line .= 'background-color:' . get_css_colour(DEFAULT_BACKGROUND) . ';';
 390     $css_line .= '}' . "\n";
 391
 392     return $css_line;
 393 }
 394
 395 # XXX: Wrong solution
 396 sub get_missing_css_lines () {
 397
 398     my $css_line;
 399
 400     $css_line .= '.' . 'default' . ' {';
 401     $css_line .= 'color:' . HEADER_DEFAULT_COLOUR . ';';
 402     $css_line .= 'background-color:' . get_css_colour(DEFAULT_BACKGROUND) . ';';
 403     $css_line .= '}' . "\n";
 404
 405     return $css_line;
 406 }
 407
 408 sub get_css () {
 409
 410     our %css_colours; #XXX: Wrong solution
 411
 412     my $css = '';
 413
 414     $css .= '.privoxy-log {';
 415     $css .= 'color:' . get_css_colour(DEFAULT_TEXT_COLOUR) . ';';
 416     $css .= 'background-color:' . get_css_colour(DEFAULT_BACKGROUND) . ';';
 417     $css .= '}' . "\n";
 418
 419     foreach my $key (keys %h_colours) {
 420
 421         next if ($h_colours{$key} =~ m/reset/); #XXX: Wrong solution.
 422         $css .= get_css_line($key);
 423
 424     }
 425
 426     foreach my $colour (keys %css_colours) {
 427
 428         $css .= get_css_line_for_colour($colour);
 429
 430     }
 431
 432     $css .= get_missing_css_lines(); #XXX: Wrong solution
 433
 434     return $css;
 435 }
 436
 437 sub print_intro () {
 438
 439     my $intro = '';
 440
 441     if (cli_option_is_set('html-output')) {
 442
 443         my $title = get_html_title();
 444
 445         $intro .= '<html><head>';
 446         $intro .= '<title>' . $title . '</title>';
 447         $intro .= '<style>' . get_css() . '</style>' unless cli_option_is_set('no-embedded-css');
 448         $intro .= '</head><body>';
 449         $intro .= '<h1>' . $title . '</h1><p class="privoxy-log">';
 450
 451         print $intro;
 452     }
 453 }
 454
 455 sub print_outro () {
 456
 457     my $outro = '';
 458
 459     if (cli_option_is_set('html-output')) {
 460
 461         $outro = '</p></body></html>';
 462         print $outro;
 463
 464     }
 465 }
 466
 467 sub get_line_end () {
 468     return cli_option_is_set('html-output') ? "<br>\n" : "\n";
 469 }
 470
 471 sub get_colour_html_markup ($) {
 472 ###############################################################
 473 # Takes a colour string a span element. XXX: WHAT?
 474 # XXX: This function shouldn't be necessary, the
 475 # markup should always be semantically correct.
 476 ###############################################################
 477
 478     my $type = shift;
 479     my $code;
 480
 481     if ($type =~ /Standard/) {
 482         $code = '</span>';
 483     } else {
 484         $code = '<span class="' . lc($type) . '">';
 485     }
 486
 487     return $code;
 488 }
 489
 490 sub default_colours () {
 491     # XXX: Properly
 492     our $bg_code;
 493     return reset_colours();
 494 }
 495
 496 sub show_colours () {
 497     # XXX: Implement
 498 }
 499
 500 sub reset_colours () {
 501     return ESCAPE . "0m";
 502 }
 503
 504 sub set_background ($){
 505
 506     my $colour = shift;
 507     our $bg_code;
 508     my %backgrounds = (
 509               black       => "40",
 510               red         => "41",
 511               green       => "42",
 512               brown       => "43",
 513               blue        => "44",
 514               magenta     => "45",
 515               cyan        => "46",
 516               white       => "47",
 517               default     => "49",
 518     );
 519
 520     if (defined($backgrounds{$colour})) {
 521         $bg_code = $backgrounds{$colour};
 522     } else {
 523         die "Invalid background colour: " . $colour;
 524     }
 525 }
 526
 527 sub get_background (){
 528     return our $bg_code;
 529 }
 530
 531 sub prepare_highlight_hash ($) {
 532     my $ref = shift;
 533
 534     foreach my $key (keys %$ref) {
 535         $$ref{$key} = $html_output_mode ?
 536             get_semantic_html_markup($key) :
 537             paint_it($$ref{$key});
 538     }
 539 }
 540
 541 sub prepare_colour_array ($) {
 542     my $ref = shift;
 543
 544     foreach my $i (0 ... @$ref - 1) {
 545         $$ref[$i] = $html_output_mode ?
 546             get_colour_html_markup($$ref[$i]) :
 547             paint_it($$ref[$i]);
 548     }
 549 }
 550
 551 sub found_unknown_content ($) {
 552
 553     my $unknown = shift;
 554     my $message;
 555
 556     return if cli_option_is_set('accept-unknown-messages');
 557
 558     return if ($unknown =~ /\[too long, truncated\]$/);
 559
 560     $message = "found_unknown_content: Don't know how to highlight: ";
 561     # Break line so the log file can later be parsed as Privoxy log file again
 562     $message .= '"' . $unknown . '"' . " in:\n";
 563     $message .= $req{$t}{'log-message'};
 564     debug_message($message);
 565     log_parse_error($req{$t}{'log-message'});
 566
 567     die "Unworthy content parser" if PUNISH_MISSING_LOG_KNOWLEDGE_WITH_DEATH;
 568 }
 569
 570 sub log_parse_error ($) {
 571
 572     my $message = shift;
 573
 574     if (LOG_UNPARSED_LINES_TO_EXTRA_FILE) {
 575         open(my $errorlog_fd, ">>", ERROR_LOG_FILE) || die "Writing " . ERROR_LOG_FILE . " failed";
 576         print $errorlog_fd $message;
 577         close($errorlog_fd);
 578     }
 579 }
 580
 581 sub debug_message (@) {
 582     my @message = @_;
 583
 584     print $h{'debug'} . "@message" . $h{'Standard'} . "\n";
 585 }
 586
 587 ################################################################################
 588 # highlighter functions that aren't loglevel-specific
 589 ################################################################################
 590
 591 sub h ($) {
 592
 593     # Get highlight marker
 594     my $highlight = shift; # XXX: Stupid name;
 595     my $result = '';
 596     my $message;
 597
 598     if (defined($highlight)) {
 599
 600         $result = $h{$highlight};
 601
 602     } else {
 603
 604         $message = "h: Don't recognize highlighter $highlight.";
 605         debug_message($message);
 606         log_parser_error($message);
 607         die "Unworthy highlighter function" if PUNISH_MISSING_HIGHLIGHT_KNOWLEDGE_WITH_DEATH;
 608     }
 609
 610     return $result;
 611 }
 612
 613 sub highlight_known_headers ($) {
 614
 615     my $content = shift;
 616
 617     debug_message("Searching $content for things to highlight.") if DEBUG_HEADER_HIGHLIGHTING;
 618
 619     if ($content =~ m/(?<=\s)($header_highlight_regex):/) {
 620         my $header = $1;
 621         $content =~ s@(?<=[\s|'])($header)(?=:)@$header_colours{$header}$1$h{'Standard'}@ig;
 622         debug_message("Highlighted '$header' in '$content'") if DEBUG_HEADER_HIGHLIGHTING;
 623     }
 624
 625     return $content;
 626 }
 627
 628 sub highlight_matched_request_line ($$) {
 629
 630     my $result = shift; # XXX: Stupid name;
 631     my $regex = shift;
 632     if ($result =~ m@(.*)($regex)(.*)@) {
 633         $result = $1 . highlight_request_line($2) . $3
 634     }
 635     return $result;
 636 }
 637
 638 sub highlight_request_line ($) {
 639
 640     my $rl = shift;
 641     my ($method, $url, $http_version);
 642
 643     #GET http://images.sourceforge.net/sfx/icon_warning.gif HTTP/1.1
 644     if ($rl =~ m/Invalid request/) {
 645
 646         $rl = h('invalid-request') . $rl . h('Standard');
 647
 648     } elsif ($rl =~ m/^([-\w]+) (.*) (HTTP\/\d\.\d)/) {
 649
 650         # XXX: might not match in case of HTTP method fuzzing.
 651         # XXX: save these: ($method, $path, $http_version) = ($1, $2, $3);
 652         $rl =~ s@^(\w+)@$h{'method'}$1$h{'Standard'}@;
 653         if ($rl =~ /http:\/\//) {
 654             $rl = highlight_matched_url($rl, '[^\s]*(?=\sHTTP)');
 655         } else {
 656             $rl = highlight_matched_pattern($rl, 'request_', '[^\s]*(?=\sHTTP)');
 657         }
 658
 659         $rl =~ s@(HTTP\/\d\.\d)$@$h{'http-version'}$1$h{'Standard'}@;
 660
 661     } elsif ($rl =~ m/\.\.\. \[too long, truncated\]$/) {
 662
 663         $rl =~ s@^(\w+)@$h{'method'}$1$h{'Standard'}@;
 664         $rl = highlight_matched_url($rl, '[^\s]*(?=\.\.\.)');
 665
 666     } elsif ($rl =~ m/^ $/) {
 667
 668         $rl = h('error') . "No request line specified!" . h('Standard');
 669
 670     } else {
 671
 672         debug_message ("Can't parse request line: $rl");
 673
 674     }
 675
 676     return $rl;
 677 }
 678
 679 sub highlight_response_line ($) {
 680
 681     my $rl = shift;
 682     my ($http_version, $status_code, $status_message);
 683
 684     #HTTP/1.1 200 OK
 685     #ICY 200 OK
 686
 687     # TODO: Mark different status codes differently
 688
 689     if ($rl =~ m/((?:HTTP\/\d\.\d|ICY)) (\d+) (.*)/) {
 690         ($http_version, $status_code, $status_message) = ($1, $2, $3);
 691     } else {
 692         debug_message ("Can't parse response line: $rl") and die 'Fix this';
 693     }
 694
 695     # Rebuild highlighted
 696     $rl= "";
 697     $rl .= h('http-version') . $http_version . h('Standard');
 698     $rl .= " ";
 699     $rl .= h('status-code') . $status_code . h('Standard');
 700     $rl .= " ";
 701     $rl .= h('status-message') . $status_message . h('Standard');
 702
 703     return $rl;
 704 }
 705
 706 sub highlight_matched_url ($$) {
 707
 708     my $result = shift; # XXX: Stupid name;
 709     my $regex = shift;
 710
 711     #print "Got $result, regex ($regex)\n";
 712
 713     if ($result =~ m@(.*?)($regex)(.*)@) {
 714         $result = $1 . highlight_url($2) . $3;
 715         #print "Now the result is $result\n";
 716     }
 717
 718     return $result;
 719 }
 720
 721 sub highlight_matched_host ($$) {
 722
 723     my ($result, $regex) = @_; # XXX: result ist stupid name;
 724
 725     if ($result =~ m@(.*?)($regex)(.*)@) {
 726         $result = $1 . $h{host} . $2 . $h{Standard} . $3;
 727     }
 728
 729     return $result;
 730 }
 731
 732 sub highlight_matched_pattern ($$$) {
 733
 734     my $result = shift; # XXX: Stupid name;
 735     my $key = shift;
 736     my $regex = shift;
 737
 738     die "Unknown key $key" unless defined $h{$key};
 739
 740     if ($result =~ m@(.*?)($regex)(.*)@) {
 741         $result = $1 . h($key) . $2 . h('Standard') . $3;
 742     }
 743
 744     return $result;
 745 }
 746
 747 sub highlight_matched_path ($$) {
 748
 749     my $result = shift; # XXX: Stupid name;
 750     my $regex = shift;
 751
 752     if ($result =~ m@(.*?)($regex)(.*)@) {
 753         $result = $1 . h('path') . $2 . h('Standard') . $3;
 754     }
 755
 756     return $result;
 757 }
 758
 759 sub highlight_url ($) {
 760
 761     my $url = shift;
 762
 763     if ($html_output_mode) {
 764
 765         $url = '<a href="' . $url . '">' . $url . '</a>';
 766
 767     } else {
 768
 769         $url = h('URL') . $url . h('Standard');
 770
 771     }
 772
 773     return $url;
 774 }
 775
 776 sub update_header_highlight_regex ($) {
 777
 778     my $header = shift;
 779     my $headers = join ('|', keys %header_colours);
 780
 781     $header_highlight_regex = qr/$headers/;
 782     print "Registering '$header'\n" if DEBUG_HEADER_HIGHLIGHTING;
 783 }
 784
 785 ################################################################################
 786 # loglevel-specific highlighter functions
 787 ################################################################################
 788
 789 sub handle_loglevel_header ($) {
 790
 791     my $c = shift;
 792
 793     if ($c =~ /^scan:/) {
 794
 795         if ($c =~ m/^scan: ([^: ]+):/) {
 796
 797             # Register new headers
 798             # scan: Accept: image/png,image/*;q=0.8,*/*;q=0.5
 799             my $header = $1;
 800             if (!defined($header_colours{$header}) and $header =~ /^[\d\w-]*$/) {
 801                 debug_message "Registering previously unknown header $1" if DEBUG_HEADER_REGISTERING;
 802
 803                 if (REGISTER_HEADERS_WITH_THE_SAME_COLOUR) {
 804                     $header_colours{$header} =  $header_colours{'Default'};
 805                 } else {
 806                     $header_colours{$header} = $all_colours[$header_colour_index % @all_colours];
 807                     $header_colour_index++;
 808                 }
 809                 update_header_highlight_regex($header);
 810             }
 811
 812         } elsif ($c =~ m/^(scan: )(\w+ .+ HTTP\/\d\.\d)/) {
 813
 814             # scan: GET http://p.p/ HTTP/1.1
 815             $c = $1 . highlight_request_line($2);
 816
 817         } elsif ($c =~ m/^(scan: )((?:HTTP\/\d\.\d|ICY) (\d+) (.*))/) {
 818
 819             # scan: HTTP/1.1 200 OK
 820             $req{$t}{'response_line'} = $2;
 821             $req{$t}{'status_code'} = $3;
 822             $req{$t}{'status_message'} = $4;
 823             $c = $1 . highlight_response_line($req{$t}{'response_line'});
 824         }
 825
 826     } elsif ($c =~ m/^Crunching (?:server|client) header: .* \(contains: ([^\)]*)\)/) {
 827
 828         # Crunching server header: Set-Cookie: trac_form_token=d5308c34e16d15e9e301a456; (contains: Cookie:)
 829         $c =~ s@(?<=contains: )($1)@$h{'crunch-pattern'}$1$h{'Standard'}@;
 830         $c =~ s@(Crunching)@$h{$1}$1$h{'Standard'}@;
 831
 832     } elsif ($c =~ m/^New host is: ([^\s]*)\./) {
 833
 834         # New host is: trac.vidalia-project.net. Crunching Referer: http://www.vidalia-project.net/!
 835         $c = highlight_matched_host($c, '(?<=New host is: )[^\s]+(?=\.)');
 836         $c = highlight_matched_url($c, '(?<=Crunching Referer: )[^\s!]+');
 837
 838     } elsif ($c =~ m/^Text mode enabled by force. (Take cover)!/) {
 839
 840         # Text mode enabled by force. Take cover!
 841         $c =~ s@($1)@$h{'warning'}$1$h{'Standard'}@;
 842
 843     } elsif ($c =~ m/^(New HTTP Request-Line: )(.*)/) {
 844
 845         # New HTTP Request-Line: GET http://www.privoxy.org/ HTTP/1.1
 846         $c = $1 . highlight_request_line($2);
 847
 848     } elsif ($c =~ m/^Adjust(ed)? Content-Length to \d+/) {
 849
 850         # Adjusted Content-Length to 2132
 851         # Adjust Content-Length to 33533
 852         $c =~ s@(?<=Content-Length to )(\d+)@$h{'Number'}$1$h{'Standard'}@;
 853         $c = highlight_known_headers($c);
 854
 855     } elsif ($c =~ m/^Destination extracted from "Host:" header. New request URL:/) {
 856
 857         # Destination extracted from "Host:" header. New request URL: http://www.cccmz.de/~ridcully/blog/
 858         $c = highlight_matched_url($c, '(?<=New request URL: ).*');
 859
 860     } elsif ($c =~ m/^Couldn\'t parse:/) {
 861
 862         # XXX: These should probable be logged with LOG_LEVEL_ERROR
 863         # Couldn't parse: If-Modified-Since: Wed, 21 Mar 2007 16:34:50 GMT (crunching!)
 864         # Couldn't parse: at, 24 Mar 2007 13:46:21 GMT in If-Modified-Since: Sat, 24 Mar 2007 13:46:21 GMT (crunching!)
 865         $c =~ s@^(Couldn\'t parse)@$h{'error'}$1$h{'Standard'}@;
 866
 867     } elsif ($c =~ /^Tagger \'([^\']*)\' added tag \'([^\']*)\'/ or
 868              $c =~ m/^Adding tag \'([^\']*)\' created by header tagger \'([^\']*)\'/) {
 869
 870         # Adding tag 'GET request' created by header tagger 'method-man' (XXX: no longer used)
 871         # Tagger 'revalidation' added tag 'REVALIDATION-REQUEST'. No action bit update necessary.
 872         # Tagger 'revalidation' added tag 'REVALIDATION-REQUEST'. Action bits updated accordingly.
 873
 874         # XXX: Save tag and tagger
 875
 876         $c =~ s@(?<=^Tagger \')([^\']*)@$h{'tagger'}$1$h{'Standard'}@;
 877         $c =~ s@(?<=added tag \')([^\']*)@$h{'tag'}$1$h{'Standard'}@;
 878         $c =~ s@(?<=Action bits )(updated)@$h{'action-bits-update'}$1$h{'Standard'}@;
 879         $no_special_header_highlighting = 1;
 880
 881     } elsif ($c =~ /^Tagger \'([^\']*)\' didn['']t add tag \'([^\']*)\'/) {
 882
 883         # Tagger 'revalidation' didn't add tag 'REVALIDATION-REQUEST'. Tag already present
 884         # XXX: Save tag and tagger
 885
 886         $c =~ s@(?<=^Tagger \')([^\']*)@$h{'tag'}$1$h{'Standard'}@;
 887         $c =~ s@(?<=didn['']t add tag \')([^\']*)@$h{'tagger'}$1$h{'Standard'}@;
 888
 889     } elsif ($c =~ m/^(?:scan:|Randomiz|addh:|Adding:|Removing:|Referer:|Modified:|Accept-Language header|[Cc]ookie)/
 890           or $c =~ m/^(Text mode is already enabled|Denied request with NULL byte|Replaced:|add-unique:)/
 891           or $c =~ m/^(Crunched (incoming|outgoing) cookie|Suppressed offer|Accepted the client)/
 892           or $c =~ m/^(addh-unique|Referer forged to)/
 893           or $c =~ m/^Downgraded answer to HTTP\/1.0/
 894           or $c =~ m/^Parameter: \+hide-referrer\{[^\}]*\} is a bad idea, but I don\'t care./
 895           or $c =~ m/^Referer (?:overwritten|replaced) with: Referer: / #XXX: should this be highlighted?
 896           or $c =~ m/^Referer crunched!/
 897           or $c =~ m/^crunched x-forwarded-for!/
 898           or $c =~ m/^crunched From!/
 899           or $c =~ m/^ modified$/
 900           or $c =~ m/^Content filtering is enabled. Crunching:/
 901           or $c =~ m/^force-text-mode overruled the client/
 902           or $c =~ m/^Server time in the future\./
 903           or $c =~ m/^content-disposition header crunched and replaced with:/i
 904           or $c =~ m/^Reducing white space in /
 905           or $c =~ m/^Ignoring single quote in /
 906           or $c =~ m/^Converting tab to space in /
 907           or $c =~ m/A HTTP\/1\.1 response without/
 908           or $c =~ m/Disabled filter mode on behalf of the client/
 909           or $c =~ m/Keeping the (?:server|client) header /
 910           or $c =~ m/Content modified with no Content-Length header set/
 911           or $c =~ m/^Appended client IP address to/
 912           or $c =~ m/^Removing 'Connection: close' to imply keep-alive./
 913           or $c =~ m/^keep-alive support is disabled/
 914           or $c =~ m/^Continue hack in da house/
 915           or $c =~ m/^Merged multiple header lines to:/
 916           or $c =~ m/^Added header: /
 917           or $c =~ m/^Enlisting (?:sorted|left-over) header/
 918             )
 919     {
 920         # XXX: Some of these may need highlighting
 921
 922         # Modified: User-Agent: Mozilla/5.0 (X11; U; SunOS i86pc; pl-PL; rv:1.8.1.1) Gecko/20070214 Firefox/2.0.0.1
 923         # Accept-Language header crunched and replaced with: Accept-Language: pl-pl
 924         # cookie 'Set-Cookie: eZSessionCookie=07bfec287c197440d299f81580593c3d; \
 925         #  expires=Thursday, 12-Apr-07 15:16:18 GMT; path=/' send by \
 926         #  http://wirres.net/article/articleview/4265/1/6/ appears to be using time format 1 (XXX: gone with the wind)
 927         # Cookie rewritten to a temporary one: Set-Cookie: NSC_gffe-iuuq-mc-wtfswfs=8efb33a53660;path=/
 928         # Text mode is already enabled
 929         # Denied request with NULL byte(s) turned into line break(s)
 930         # Replaced: 'Connection: Yo, home to Bel Air' with 'Connection: close'
 931         # addh-unique: Host: people.freebsd.org
 932         # Suppressed offer to compress content
 933         # Crunched incoming cookie -- yum!
 934         # Accepted the client's request to fetch without filtering.
 935         # Crunched outgoing cookie: Cookie: PREF=ID=6cf0abd347b30262:TM=1173357617:LM=1173357617:S=jZypyyJ7LPiwFi1_
 936         # addh-unique: Host: subkeys.pgp.net:11371
 937         # Referer forged to: Referer: http://10.0.0.1/
 938         # Downgraded answer to HTTP/1.0
 939         # Parameter: +hide-referrer{pille-palle} is a bad idea, but I don't care.
 940         # Referer overwritten with: Referer: pille-palle
 941         # Referer replaced with: Referer: pille-palle
 942         # crunched x-forwarded-for!
 943         # crunched From!
 944         #  modified # XXX: pretty stupid log message
 945         # Content filtering is enabled. Crunching: 'Range: 1234-5678' to prevent range-mismatch problems
 946         # force-text-mode overruled the client's request to fetch without filtering!
 947         # Server time in the future.
 948         # content-disposition header crunched and replaced with: content-disposition: filename=baz
 949         # Content-Disposition header crunched and replaced with: content-disposition: filename=baz
 950         # Reducing white space in 'X-LWS-Test: "This  is  quoted" this is not "this  is  " but " this again   is  not'
 951         # Ignoring single quote in 'X-LWS-Test: "This  is  quoted" this is not "this  is  " but "  this again   is  not'
 952         # Converting tab to space in 'X-LWS-Test:   "This  is  quoted" this   is  not "this  is  "  but  "\
 953         #  this again   is  not'
 954         # A HTTP/1.1 response without Connection header implies keep-alive.
 955         # Disabled filter mode on behalf of the client.
 956         # Keeping the server header 'Connection: keep-alive' around.
 957         # Keeping the client header 'Connection: close' around. The connection will not be kept alive.
 958         # Keeping the client header 'Connection: keep-alive' around. The connection will be kept alive if possible.
 959         # Content modified with no Content-Length header set. Creating a fake one for adjustment later on.
 960         # Appended client IP address to X-Forwarded-For: 10.0.0.2, 10.0.0.1
 961         # Removing 'Connection: close' to imply keep-alive.
 962         # keep-alive support is disabled. Crunching: Keep-Alive: 300.
 963         # Continue hack in da house.
 964         # Merged multiple header lines to: 'X-FORWARDED-PROTO: http X-HOST: 127.0.0.1'
 965         # Added header: Content-Encoding: deflate
 966         # Enlisting sorted header User-Agent: Mozilla/5.0 (X11; SunOS i86pc; rv:10.0.3) Gecko/20100101 Firefox/10.0.3
 967         # Enlisting left-over header Connection: close
 968
 969     } elsif ($c =~ m/^scanning headers for:/) {
 970
 971         return '' unless SHOW_SCAN_INTRO;
 972
 973     } elsif ($c =~ m/^[Cc]runch(ing|ed)|crumble crunched:/) {
 974         # crunched User-Agent!
 975         # Crunching: Content-Encoding: gzip
 976
 977         $c =~ s@(Crunching|crunched)@$h{$1}$1$h{'Standard'}@;
 978
 979     } elsif ($c =~ m/^Offending request data with NULL bytes turned into \'°\' characters:/) {
 980
 981         # Offending request data with NULL bytes turned into '°' characters: °°n°°(°°°
 982
 983         $c = h('warning') . $c . h('Standard');
 984
 985     } elsif ($c =~ m/^(Transforming \")(.*?)(\" to \")(.*?)(\")/) {
 986
 987         # Transforming "Proxy-Authenticate: Basic realm="Correos Proxy Server"" to\
 988         #  "Proxy-Authenticate: Basic realm="Correos Proxy Server""
 989
 990        $c =~ s@(?<=^Transforming \")(.*)(?=\" to)@$h{'Header'}$1$h{'Standard'}@;
 991        $c =~ s@(?<=to \")(.*)(?=\")@$h{'Header'}$1$h{'Standard'}@;
 992
 993     } elsif ($c =~ m/^Removing empty header/) {
 994
 995         # Removing empty header
 996         # Ignore for now
 997
 998     } elsif ($c =~ m/^Content-Type: .* not replaced/) {
 999
1000         # Content-Type: application/octet-stream not replaced. It doesn't look like text.\
1001         #  Enable force-text-mode if you know what you're doing.
1002         # XXX: Could highlight more here.
1003         $c =~ s@(?<=^Content-Type: )(.*)(?= not replaced)@$h{'content-type'}$1$h{'Standard'}@;
1004
1005     } elsif ($c =~ m/^(Server|Client) keep-alive timeout is/) {
1006
1007        # Server keep-alive timeout is 5. Sticking with 10.
1008        # Client keep-alive timeout is 20. Sticking with 10.
1009
1010        $c =~ s@(?<=timeout is )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1011        $c =~ s@(?<=Sticking with )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1012
1013     } elsif ($c =~ m/^Reducing keep-alive timeout/) {
1014
1015        # Reducing keep-alive timeout from 60 to 10.
1016
1017        $c =~ s@(?<= from )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1018        $c =~ s@(?<= to )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1019
1020     } elsif ($c =~ m/^Killed all-caps Host header line: HOST:/) {
1021
1022        # Killed all-caps Host header line: HOST: bestproxydb.com
1023        $c = highlight_matched_host($c, '(?<=HOST: )[^\s]+');
1024        $c = highlight_matched_pattern($c, 'HOST', 'HOST');
1025
1026     } else {
1027
1028         found_unknown_content($c);
1029     }
1030
1031     # Highlight headers
1032     unless ($c =~ m/^Transforming/) {
1033         $c = highlight_known_headers($c) unless $no_special_header_highlighting;
1034     }
1035
1036     return $c;
1037 }
1038
1039 sub handle_loglevel_re_filter ($) {
1040
1041     my $content = shift;
1042     my $c = $content;
1043     my $key;
1044
1045     if ($c =~ m/^(?:re_)?filtering ([^\s]+) \(size (\d+)\) with (?:filter )?\'?([^\s]+?)\'? produced (\d+) hits \(new size (\d+)\)/) {
1046
1047         # XXX: only the second version gets highlighted properly.
1048         # re_filtering www.lfk.de/favicon.ico (size 209) with filter untrackable-hulk produced 0 hits (new size 209).
1049         # filtering aci.blogg.de/ (size 37988) with 'blogg.de' produced 3 hits (new size 38057)
1050         $req{$t}{'content_source'} = $1;
1051         $req{$t}{'content_size'}   = $2;
1052         $req{$t}{'content_filter'} = $3;
1053         $req{$t}{'content_hits'}   = $4;
1054         $req{$t}{'new_content_size'} = $5;
1055         $req{$t}{'content_size_change'} = $req{$t}{'new_content_size'} - $req{$t}{'content_size'};
1056         #return '' if ($req{$t}{'content_hits'} == 0 && !cli_option_is_set('show-ineffective-filters'));
1057         if ($req{$t}{'content_hits'} == 0 and
1058             not (cli_option_is_set('show-ineffective-filters')
1059                  or ($req{$t}{'content_filter'} =~ m/^privoxy-filter-test$/))) {
1060                 return '';
1061         }
1062
1063         $c =~ s@(?<=\(size )(\d+)\)(?= with)@$h{'Number'}$1$h{'Standard'}@;
1064         $c =~ s@(?<=\(new size )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1065         $c =~ s@(?<=produced )(\d+)(?= hits)@$h{'Number'}$1$h{'Standard'}@;
1066
1067         $c =~ s@([^\s]+?)(\'? produced)@$h{'filter'}$1$h{'Standard'}$2@;
1068         $c = highlight_matched_host($c, '(?<=filtering )[^\s]+');
1069
1070         $c =~ s@\.$@ @;
1071         $c .= "(" . $h{'Number'};
1072         $c .= "+" if ($req{$t}{'content_size_change'} >= 0);
1073         $c .= $req{$t}{'content_size_change'} . $h{'Standard'} . ")";
1074         $content = $c;
1075
1076   } elsif ($c =~ /\.{3}$/
1077         and $c =~ m/^(?:re_)?filtering \'?(.*?)\'? \(size (\d*)\) with (?:filter )?\'?([^\s]*?)\'? ?\.{3}$/) {
1078
1079         # Used by Privoxy 3.0.5 and 3.0.6:
1080         # XXX: Fill in ...
1081         # Used by Privoxy 3.0.7:
1082         # filtering 'Connection: close' (size 17) with 'generic-content-ads' ...
1083
1084         $req{$t}{'filtered_header'} = $1;
1085         $req{$t}{'old_header_size'} = $2;
1086         $req{$t}{'header_filter_name'} = $3;
1087
1088         unless (cli_option_is_set('show-ineffective-filters') or
1089                 $req{$t}{'header_filter_name'} =~ m/^privoxy-filter-test$/) {
1090             return '';
1091         }
1092         $content =~ s@(?<=\(size )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1093         $content =~ s@($req{$t}{'header_filter_name'})@$h{'filter'}$1$h{'Standard'}@;
1094
1095     } elsif ($c =~ m/^ ?\.\.\. ?produced (\d*) hits \(new size (\d*)\)\./) {
1096
1097         # ...produced 0 hits (new size 23).
1098         #... produced 1 hits (new size 54).
1099
1100         $req{$t}{'header_filter_hits'} = $1;
1101         $req{$t}{'new_header_size'} = $2;
1102
1103         unless (cli_option_is_set('show-ineffective-filters') or
1104                 (defined($req{$t}{'header_filter_name'}) and
1105                  $req{$t}{'header_filter_name'} =~ m/^privoxy-filter-test$/)) {
1106
1107             if ($req{$t}{'header_filter_hits'} == 0 and
1108                 not (defined($req{$t}{'header_filter_name'}) and
1109                  $req{$t}{'header_filter_name'} =~ m/^privoxy-filter-test$/)) {
1110                 return '';
1111             }
1112             # Reformat including information from the intro
1113             $c = "'" . h('filter') . $req{$t}{'header_filter_name'} . h('Standard') . "'";
1114             $c .= " hit ";
1115             # XXX: Hide behind constant, it may be interesting if LOG_LEVEL_HEADER isn't enabled as well.
1116             # $c .= $req{$t}{'filtered_header'} . " ";
1117             $c .= h('Number') . $req{$t}{'header_filter_hits'}. h('Standard');
1118             $c .= ($req{$t}{'header_filter_hits'} == 1) ? " time, " : " times, ";
1119
1120             if ($req{$t}{'old_header_size'} !=  $req{$t}{'new_header_size'}) {
1121
1122                 $c .= "changing size from ";
1123                 $c .=  h('Number') . $req{$t}{'old_header_size'} . h('Standard');
1124                 $c .= " to ";
1125                 $c .= h('Number') . $req{$t}{'new_header_size'} . h('Standard');
1126                 $c .= ".";
1127
1128             } else {
1129
1130                 $c .= "keeping the size at " . $req{$t}{'old_header_size'};
1131
1132             }
1133
1134             # Highlight from last line (XXX: What?)
1135             # $c =~ s@(?<=produced )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1136             # $c =~ s@($req{$t}{'header_filter_name'})@$h{'filter'}$1$h{'Standard'}@;
1137
1138         } else {
1139
1140            # XXX: Untested
1141            $c =~ s@(?<=produced )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1142            $c =~ s@(?<=new size )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1143
1144         }
1145         $content = $c;
1146
1147     } elsif ($c =~ m/^(Tagger|Filter) ([^\s]*) has empty joblist. Nothing to do./) {
1148
1149         # Filter privoxy-filter-test has empty joblist. Nothing to do.
1150         # Tagger variable-test has empty joblist. Nothing to do.
1151
1152         $content =~ s@(?<=$1 )([^\s]*)@$h{'filter'}$1$h{'Standard'}@;
1153
1154     } elsif ($c =~ m/^De-chunking successful. Shrunk from (\d+) to (\d+)/) {
1155
1156         $req{$t}{'chunked-size'} = $1;
1157         $req{$t}{'dechunked-size'} = $2;
1158         $req{$t}{'dechunk-change'} = $req{$t}{'dechunked-size'} - $req{$t}{'chunked-size'};
1159
1160         $content .= " (" . h('Number') . $req{$t}{'dechunk-change'} . h('Standard') . ")";
1161
1162         $content =~ s@(?<=from )($req{$t}{'chunked-size'})@$h{'Number'}$1$h{'Standard'}@;
1163         $content =~ s@(?<=to )($req{$t}{'dechunked-size'})@$h{'Number'}$1$h{'Standard'}@;
1164
1165     } elsif ($c =~ m/^Decompression successful. Old size: (\d+), new size: (\d+)./) {
1166
1167         # Decompression successful. Old size: 670, new size: 1166.
1168
1169         $req{$t}{'size-compressed'} = $1;
1170         $req{$t}{'size-decompressed'} = $2;
1171         $req{$t}{'decompression-gain'} = $req{$t}{'size-decompressed'} - $req{$t}{'size-compressed'};
1172
1173         $content =~ s@(?<=Old size: )($req{$t}{'size-compressed'})@$h{'Number'}$1$h{'Standard'}@;
1174         $content =~ s@(?<=new size: )($req{$t}{'size-decompressed'})@$h{'Number'}$1$h{'Standard'}@;
1175
1176         # XXX: Create sub get_percentage()
1177         if ($req{$t}{'size-decompressed'}) {
1178             $req{$t}{'decompression-gain-percent'} =
1179                 $req{$t}{'decompression-gain'} / $req{$t}{'size-decompressed'} * 100;
1180
1181             $content .= " (saved: ";
1182             #$content .= h('Number') . $req{$t}{'decompression-gain'} . h('Standard');
1183             #$content .= "/";
1184             $content .= h('Number') . sprintf("%.2f%%", $req{$t}{'decompression-gain-percent'}) . h('Standard');
1185             $content .= ")";
1186         }
1187
1188     } elsif ($c =~ m/^(Need to de-chunk first)/) {
1189
1190         # Need to de-chunk first
1191         return '' if SUPPRESS_NEED_TO_DE_CHUNK_FIRST;
1192
1193     } elsif ($c =~ m/^(Adding (?:dynamic )?re_filter job)/) {
1194
1195         return ''  if (SUPPRESS_SUCCEEDED_FILTER_ADDITIONS && m/succeeded/);
1196
1197         # Adding re_filter job ...
1198         # Adding dynamic re_filter job s@^(?:\w*)\s+.*\s+HTTP/\d\.\d\s*@IP-ADDRESS: $origin@D\
1199         #  to filter client-ip-address succeeded.
1200
1201     } elsif ($c =~ m/^Compressed content from /) {
1202
1203         # Compressed content from 29258 to 8630 bytes. Compression level: 3
1204         $content =~ s@(?<=from )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1205         $content =~ s@(?<=to )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1206         $content =~ s@(?<=level: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1207
1208     } elsif ($c =~ m/^Reading in filter/) {
1209
1210         return '' unless SHOW_FILTER_READIN_IN;
1211
1212     } else {
1213
1214         found_unknown_content($content);
1215
1216     }
1217
1218     return $content;
1219 }
1220
1221 sub handle_loglevel_redirect ($) {
1222
1223     my $c = shift;
1224
1225     if ($c =~ m/^Decoding "([^""]*)"/) {
1226
1227          $req{$t}{'original-destination'} = $1;
1228          $c = highlight_matched_path($c, '(?<=Decoding ")[^"]*');
1229          $c =~ s@\"@@g;
1230
1231     } elsif ($c =~ m/^Checking/) {
1232
1233          # Checking /_ylt=A0geu.Z76BRGR9k/**http://search.yahoo.com/search?p=view+odb+presentation+on+freebsd\
1234          #  &ei=UTF-8&xargs=0&pstart=1&fr=moz2&b=11 for redirects.
1235
1236          # TODO: Change colour if really url-decoded
1237          $req{$t}{'decoded-original-destination'} = $1;
1238          $c = highlight_matched_path($c, '(?<=Checking ")[^"]*');
1239          $c =~ s@\"@@g;
1240
1241     } elsif ($c =~ m/^pcrs command "([^""]*)" changed /) {
1242
1243         # pcrs command "s@&from=rss@@" changed \
1244         #  "http://it.slashdot.org/article.pl?sid=07/03/02/1657247&from=rss"\
1245         #  to "http://it.slashdot.org/article.pl?sid=07/03/02/1657247" (1 hit).
1246         $c =~ s@(?<=pcrs command )"([^""]*)"@$h{'filter'}$1$h{'Standard'}@;
1247         $c = highlight_matched_url($c, '(?<=changed ")[^""]*');
1248         $c =~ s@(?<=changed )"([^""]*)"@$1@; # Remove quotes
1249         $c = highlight_matched_url($c, '(?<=to ")[^""]*');
1250         $c =~ s@(?<=to )"([^""]*)"@$1@; # Remove quotes
1251         $c =~ s@(\d+)(?= hits?)@$h{'hits'}$1$h{'Standard'}@;
1252
1253     } elsif ($c =~ m/^pcrs command "([^""]*)" didn\'t change/) {
1254
1255         # pcrs command "s@^http://([^.]+?)/?$@http://www.bing.com/search?q=$1@" didn't \
1256         #  change "http://www.example.org/".
1257         $c =~ s@(?<=pcrs command )"([^""]*)"@$h{'filter'}$1$h{'Standard'}@;
1258         $c = highlight_matched_url($c, '(?<=change ")[^""]*');
1259
1260     } elsif ($c =~ m/(^New URL is: )(.*)/) {
1261
1262         # New URL is: http://it.slashdot.org/article.pl?sid=07/03/04/1511210
1263         # XXX: Use URL highlighter
1264         # XXX: Save?
1265         $c = $1 . h('rewritten-URL') . $2 . h('Standard');
1266
1267     } elsif ($c =~ m/No pcrs command recognized, assuming that/) {
1268         # No pcrs command recognized, assuming that "http://config.privoxy.org/user-manual/favicon.png"\
1269         #  is already properly formatted.
1270         # XXX: assume the same?
1271         $c = highlight_matched_url($c, '(?<=assuming that \")[^"]*');
1272
1273     } elsif ($c =~ m/^Percent-encoding redirect/) {
1274
1275         # Percent-encoding redirect URL: http://www.example.org/\x02
1276         $c = highlight_matched_url($c, '(?<=redirect URL: ).*');
1277
1278     } else {
1279
1280         found_unknown_content($c);
1281
1282     }
1283
1284     return $c;
1285 }
1286
1287 sub handle_loglevel_gif_deanimate ($) {
1288
1289     my $content = shift;
1290
1291     if ($content =~ m/Success! GIF shrunk from (\d+) bytes to (\d+)\./) {
1292
1293         my $bytes_from = $1;
1294         my $bytes_to = $2;
1295         # Gif-Deanimate: Success! GIF shrunk from 205 bytes to 133.
1296         $content =~ s@$bytes_from@$h{'Number'}$bytes_from$h{'Standard'}@;
1297         # XXX: Do we need g in case of ($1 == $2)?
1298         $content =~ s@$bytes_to@$h{'Number'}$bytes_to$h{'Standard'}@;
1299
1300     } elsif ($content =~ m/GIF (not) changed/) {
1301
1302         # Gif-Deanimate: GIF not changed.
1303         return '' if SUPPRESS_GIF_NOT_CHANGED;
1304         $content =~ s@($1)@$h{'not'}$1$h{'Standard'}@;
1305
1306     } elsif ($content =~ m/^failed! \(gif parsing\)/) {
1307
1308         # failed! (gif parsing)
1309         # XXX: Replace this error message with something less stupid
1310         $content =~ s@(failed!)@$h{'error'}$1$h{'Standard'}@;
1311
1312     } elsif ($content =~ m/^Need to de-chunk first/) {
1313
1314         # Need to de-chunk first
1315         return '' if SUPPRESS_NEED_TO_DE_CHUNK_FIRST;
1316
1317     } elsif ($content =~ m/^(?:No GIF header found|failed while parsing)/) {
1318
1319         # No GIF header found (XXX: Did I ever commit this?)
1320         # failed while parsing 195 134747048 (XXX: never committed)
1321
1322         # Ignore these for now
1323
1324     } else {
1325
1326         found_unknown_content($content);
1327
1328     }
1329
1330     return $content;
1331 }
1332
1333 sub handle_loglevel_request ($) {
1334
1335     my $content = shift;
1336
1337     if ($content =~ m/crunch! /) {
1338
1339         # config.privoxy.org/send-stylesheet crunch! (CGI Call)
1340
1341         # Highlight crunch reasons
1342         foreach my $reason (keys %reason_colours) {
1343             $content =~ s@\(($reason)\)@$reason_colours{$reason}($1)$h{'Standard'}@g;
1344         }
1345         # Highlight request URL domain and ditch 'crunch!'
1346         $content = highlight_matched_pattern($content, 'request_', '[^ ]*(?= crunch!)');
1347         $content =~ s@ crunch!@@;
1348
1349     } elsif ($content =~ m/\[too long, truncated\]$/) {
1350
1351         # config.privoxy.org/edit-actions-submit?f=3&v=1176116716&s=7&Submit=Submit[...]&filter... [too long, truncated]
1352         $content = highlight_matched_pattern($content, 'request_', '^.*(?=\.\.\. \[too long, truncated\]$)');
1353
1354     } elsif ($content =~ m/(.*)/) { # XXX: Pretty stupid
1355
1356         # trac.vidalia-project.net/wiki/Volunteer?format=txt
1357         $content = h('request_') . $content . h('Standard');
1358
1359     } else {  # XXX: Nop
1360
1361         found_unknown_content($content);
1362
1363     }
1364
1365     return $content;
1366 }
1367
1368 sub handle_loglevel_crunch ($) {
1369
1370     my $content = shift;
1371
1372     # Highlight crunch reason
1373     foreach my $reason (keys %reason_colours) {
1374         $content =~ s@($reason)@$reason_colours{$reason}$1$h{'Standard'}@g;
1375     }
1376
1377     if ($content =~ m/\[too long, truncated\]$/) {
1378
1379         # Blocked: config.privoxy.org/edit-actions-submit?f=3&v=1176116716&s=7&Submit=Submit\
1380         #  [...]&filter... [too long, truncated]
1381         $content = highlight_matched_pattern($content, 'request_', '^.*(?=\.\.\. \[too long, truncated\]$)');
1382
1383     } else {
1384
1385         # Blocked: http://ads.example.org/
1386         $content = highlight_matched_pattern($content, 'request_', '(?<=: ).*');
1387     }
1388
1389     return $content;
1390 }
1391
1392 sub handle_loglevel_connect ($) {
1393
1394     my $c = shift;
1395
1396     if ($c =~ m/^via [^\s]+ to: [^\s]+/) {
1397
1398         # Connect: via 10.0.0.1:8123 to: www.example.org.noconnect
1399
1400         $c = highlight_matched_host($c, '(?<=via )[^\s]+');
1401         $c = highlight_matched_host($c, '(?<=to: )[^\s]+');
1402
1403     } elsif ($c =~ m/^connect to: .* failed: .*/) {
1404
1405         # connect to: www.example.org.noconnect failed: Operation not permitted
1406
1407         $c = highlight_matched_host($c, '(?<=connect to: )[^\s]+');
1408
1409         $c =~ s@(?<=failed: )(.*)@$h{'error'}$1$h{'Standard'}@;
1410
1411     } elsif ($c =~ m/^to ([^\s]*)( successful)?$/) {
1412
1413         # Connect: to www.nzherald.co.nz successful
1414         # Connect: to archiv.radiotux.de
1415
1416         return '' if SUPPRESS_SUCCESSFUL_CONNECTIONS;
1417         $c = highlight_matched_host($c, '(?<=to )[^\s]+');
1418
1419     } elsif ($c =~ m/^to ([^\s]*)$/) {
1420
1421         # Connect: to lists.sourceforge.net:443
1422
1423         $c = highlight_matched_host($c, '(?<=to )[^\s]+');
1424
1425     } elsif ($c =~ m/^[Aa]ccepted connection from .*/ or
1426              $c =~ m/^OK/) {
1427
1428         # Privoxy 3.0.20:
1429         # Accepted connection from 10.0.0.1 on socket 5
1430         # Privoxy between 3.0.20 and 3.0.6:
1431         # accepted connection from 10.0.0.1( on socket 5)?
1432         # Privoxy 3.0.6 and earlier just say:
1433         # OK
1434         $c = highlight_matched_host($c, '(?<=connection from )[^ ]*');
1435         $c = highlight_matched_pattern($c, 'Number', '(?<=socket )\d+');
1436
1437     } elsif ($c =~ m/^Closing client socket/) {
1438
1439         # Closing client socket 5. Keep-alive: 0, Socket alive: 1. Data available: 0.
1440         # Privoxy 3.0.20 and later
1441         # Closing client socket 8. Keep-alive: 1. Socket alive: 0. Data available: 0. \
1442         #  Configuration file change detected: 0. Requests received: 11.
1443
1444         $c = highlight_matched_pattern($c, 'Number', '(?<=socket )\d+');
1445         $c = highlight_matched_pattern($c, 'Number', '(?<=Keep-alive: )\d+');
1446         $c = highlight_matched_pattern($c, 'Number', '(?<=Socket alive: )\d+');
1447         $c = highlight_matched_pattern($c, 'Number', '(?<=available: )\d+');
1448         $c = highlight_matched_pattern($c, 'Number', '(?<=detected: )\d+');
1449         $c = highlight_matched_pattern($c, 'Number', '(?<=received: )\d+');
1450
1451     } elsif ($c =~ m/^write header to: .* failed:/) {
1452
1453         # write header to: 10.0.0.1 failed: Broken pipe
1454
1455         $c = highlight_matched_host($c, '(?<=write header to: )[^\s]*');
1456         $c =~ s@(?<=failed: )(.*)@$h{'Error'}$1$h{'Standard'}@;
1457
1458     } elsif ($c =~ m/^write header to client failed:/) {
1459
1460         # write header to client failed: Broken pipe
1461         # XXX: Stil in use?
1462         $c =~ s@(?<=failed: )(.*)@$h{'Error'}$1$h{'Standard'}@;
1463
1464     } elsif ($c =~ m/^socks4_connect:/) {
1465
1466         # socks4_connect: SOCKS request rejected or failed.
1467         $c =~ s@(?<=socks4_connect: )(.*)@$h{'Error'}$1$h{'Standard'}@;
1468
1469     } elsif ($c =~ m/^Listening for new connections/ or
1470              $c =~ m/^accept connection/) {
1471         # XXX: Highlight?
1472         # Privoxy versions above 3.0.6 say:
1473         # Listening for new connections ...
1474         # earlier versions say:
1475         # accept connection ...
1476         return '';
1477
1478     } elsif ($c =~ m/^accept failed:/) {
1479
1480         $c =~ s@(?<=accept failed: )(.*)@$h{'Error'}$1$h{'Standard'}@;
1481
1482     } elsif ($c =~ m/^Overriding forwarding settings/) {
1483
1484         # Overriding forwarding settings based on 'forward 10.0.0.1:8123'
1485         $c =~ s@(?<=based on \')(.*)(?=\')@$h{'configuration-line'}$1$h{'Standard'}@;
1486
1487     } elsif ($c =~ m/^Denying suspicious CONNECT request from/) {
1488
1489         # Denying suspicious CONNECT request from 10.0.0.1
1490         $c = highlight_matched_host($c, '(?<=from )[^\s]+'); # XXX: not an URL
1491
1492     } elsif ($c =~ m/^socks5_connect:/) {
1493
1494         $c =~ s@(?<=socks5_connect: )(.*)@$h{'error'}$1$h{'Standard'}@;
1495
1496     } elsif ($c =~ m/^Created new connection to/) {
1497
1498         # Created new connection to www.privoxy.org:80 on socket 11.
1499         $c = highlight_matched_host($c, '(?<=connection to )[^\s]+');
1500         $c =~ s@(?<=on socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1501
1502     } elsif ($c =~ m/^Found reusable socket/) {
1503
1504         # Found reusable socket 9 for www.privoxy.org:80 in slot 0.
1505         # 3.0.15 and later:
1506         # Found reusable socket 8 for www.privoxy.org:80 in slot 2.\
1507         #  Timestamp made 0 seconds ago. Timeout: 1. Latency: 0.
1508         $c =~ s@(?<=Found reusable socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1509         $c = highlight_matched_host($c, '(?<=for )[^\s]+');
1510         $c =~ s@(?<=in slot )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1511         $c =~ s@(?<=made )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1512         $c =~ s@(?<=Timeout: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1513         $c =~ s@(?<=Latency: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1514
1515     } elsif ($c =~ m/^Marking open socket/) {
1516
1517         # Marking open socket 9 for www.privoxy.org:80 in slot 0 as unused.
1518         $c =~ s@(?<=Marking open socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1519         $c = highlight_matched_host($c, '(?<=for )[^\s]+');
1520         $c =~ s@(?<=in slot )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1521
1522     } elsif ($c =~ m/^No reusable/) {
1523
1524         # No reusable socket for addons.mozilla.org:443 found. Opening a new one.
1525         $c = highlight_matched_host($c, '(?<=for )[^\s]+');
1526
1527     } elsif ($c =~ m/^(Remembering|Forgetting) socket/) {
1528
1529         # Remembering socket 13 for www.privoxy.org:80 in slot 0.
1530         # Forgetting socket 38 for www.privoxy.org:80 in slot 5.
1531
1532         $c =~ s@(?<=socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1533         $c = highlight_matched_host($c, '(?<=for )[^\s]+');
1534         $c =~ s@(?<=in slot )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1535
1536     } elsif ($c =~ m/^Socket/) {
1537
1538         # Socket 16 already forgotten or never remembered.
1539         $c =~ s@(?<=Socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1540
1541     } elsif ($c =~ m/^The connection to/) {
1542
1543         # The connection to www.privoxy.org:80 in slot 6 timed out. Closing socket 19. Timeout is: 61.
1544         # 3.0.15 and later:
1545         # The connection to 1.bp.blogspot.com:80 in slot 0 timed out. Closing socket 5.\
1546         #  Timeout is: 1. Assumed latency: 4.
1547         # The connection to 10.0.0.1:80 in slot 0 is no longer usable. Closing socket 4.
1548         $c = highlight_matched_host($c, '(?<=connection to )[^\s]+');
1549         $c =~ s@(?<=in slot )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1550         $c =~ s@(?<=Closing socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1551         $c =~ s@(?<=Timeout is: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1552         $c =~ s@(?<=Assumed latency: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1553
1554     } elsif ($c =~ m/^Stopped waiting for the request line/ or
1555              $c =~ m/^No request line on socket \d received in time/ or
1556              $c =~ m/^The client side of the connection on socket \d/) {
1557
1558         # Stopped waiting for the request line. Timeout: 121.
1559         # Privoxy 3.0.19 and later:
1560         # No request line on socket 5 received in time. Timeout: 1.
1561         # The client side of the connection on socket 5 got closed \
1562         #  without sending a complete request line.
1563         $c =~ s@(?<=Timeout: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1564         $c =~ s@(?<=socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1565
1566     } elsif ($c =~ m/^Waiting for \d/) {
1567
1568         # Waiting for 1 connections to timeout.
1569         $c =~ s@(?<=^Waiting for )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1570
1571     } elsif ($c =~ m/^Initialized/) {
1572
1573         # Initialized 20 socket slots.
1574         $c =~ s@(?<=Initialized )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1575
1576     } elsif ($c =~ m/^Done reading from server/) {
1577
1578         # Done reading from server. Expected content length: 24892. \
1579         #  Actual content length: 24892. Most recently received: 4412.
1580         # 3.0.15 and later:
1581         # Done reading from server. Expected content length: 24892. \
1582         #  Actual content length: 24892. Bytes most recently read: 4412.
1583         # Done reading from server. Content length: 6018 as expected. \
1584         #  Bytes most recently read: 294.
1585         $c =~ s@(?<=ontent length: )(\d+)@$h{'Number'}$1$h{'Standard'}@g;
1586         $c =~ s@(?<=received: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1587         $c =~ s@(?<=read: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1588
1589     } elsif ($c =~ m/^Continuing buffering (?:server )?headers/) {
1590
1591         # Continuing buffering headers. byte_count: 19. header_offset: 517. len: 536.
1592         $c =~ s@(?<=byte_count: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1593         $c =~ s@(?<=header_offset: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1594         $c =~ s@(?<=len: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1595         # 3.0.15 up to 3.0.19:
1596         # Continuing buffering headers. Bytes most recently read: 498.
1597         $c =~ s@(?<=read: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1598         # 3.0.20 and later:
1599         # Continuing buffering server headers from socket 5. Bytes most recently read: 498.
1600         $c =~ s@(?<=socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1601
1602     } elsif ($c =~ m/^Received \d+ bytes while/) {
1603
1604         # Received 206 bytes while expecting 12103.
1605         $c =~ s@(?<=Received )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1606         $c =~ s@(?<=expecting )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1607
1608     } elsif ($c =~ m/^(Rejecting c|C)onnection from/) {
1609
1610         # Connection from 81.163.28.218 dropped due to ACL
1611         # Rejecting connection from 178.63.152.227. Maximum number of connections reached.
1612         $c =~ s@(?<=onnection from )((?:\d+\.?){3}\d+)@$h{'Number'}$1$h{'Standard'}@;
1613
1614     } elsif ($c =~ m/^(?:Reusing|Closing) server socket / or
1615              $c =~ m/^No additional client request/) {
1616
1617         # Reusing server socket 4. Opened for 10.0.0.1.
1618         # Closing server socket 2. Opened for 10.0.0.1.
1619         # No additional client request received in time. \
1620         #  Closing server socket 4, initially opened for 10.0.0.1.
1621         # No additional client request received in time on socket 29.
1622         # Privoxy 3.0.20 and later
1623         # Reusing server socket 7 connected to www.privoxy.org. Total requests: 2.
1624         # Closing server socket 6 connected to d.asset.soup.io. Keep-alive: 0.\
1625         #  Tainted: 1. Socket alive: 1. Timeout: 60. Configuration file change detected: 0.
1626
1627         $c =~ s@(?<= socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1628         $c = highlight_matched_host($c, '(?<=for )[^\s]+(?=\.)');
1629         $c = highlight_matched_host($c, '(?<=connected to )[^\s]+(?=\.)');
1630         for my $number_pattern ('requests', 'Keep-alive', 'Tainted', ' alive', 'Timeout', 'detected') {
1631             $c = highlight_matched_pattern($c, 'Number', '(?<='. $number_pattern . ': )\d+');
1632         }
1633
1634     } elsif ($c =~ m/^Connected to /) {
1635
1636         # Connected to tor-jail[10.0.0.2]:9050.
1637
1638         $c = highlight_matched_host($c, '(?<=\[)[^\]]+');
1639         $c = highlight_matched_host($c, '(?<=Connected to )[^\[\s]+');
1640         $c =~ s@(?<=\]:)(\d+)@$h{'Number'}$1$h{'Standard'}@;
1641
1642     } elsif ($c =~ m/^Could not connect to /) {
1643
1644         # Could not connect to [10.0.0.1]:80.
1645
1646         $c = highlight_matched_host($c, '(?<=\[)[^\]]+');
1647         $c =~ s@(?<=\]:)(\d+)@$h{'Number'}$1$h{'Standard'}@;
1648
1649     } elsif ($c =~ m/^Waiting for the next client request/ or
1650              $c =~ m/^The connection on server socket/ or
1651              $c =~ m/^Client request (?:\d+ )?arrived in time /) {
1652
1653         # Waiting for the next client request on socket 3. Keeping the server \
1654         #  socket 12 to a.fsdn.com open.
1655         # The connection on server socket 6 to upload.wikimedia.org isn't reusable. Closing.
1656         # Privoxy 3.0.20 and later:
1657         # Client request 4 arrived in time on socket 7.
1658         # Used by Privoxy 3.0.18 and 3.0.19:
1659         # Client request arrived in time on socket 21.
1660         # Used by earlier version:
1661         # Client request arrived in time or the client closed the connection on socket 12.
1662
1663         $c =~ s@(?<=request )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1664         $c =~ s@(?<=on socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1665         $c =~ s@(?<=server socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1666         $c = highlight_matched_host($c, '(?<=to )[^\s]+');
1667
1668     } elsif ($c =~ m/^Marking the server socket/) {
1669
1670         # Marking the server socket 7 tainted.
1671
1672         $c =~ s@(?<=server socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1673
1674     } elsif ($c =~ m/^Reduced expected bytes to /) {
1675
1676         # Reduced expected bytes to 0 to account for the 1542 ones we already got.
1677         $c =~ s@(?<=bytes to )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1678         $c =~ s@(?<=for the )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1679
1680     } elsif ($c =~ m/^The client closed socket /) {
1681
1682         # The client closed socket 2 while the server socket 4 is still open.
1683         $c =~ s@(?<=closed socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1684         $c =~ s@(?<=server socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1685
1686     } elsif ($c =~ m/^Expected client content length set /) {
1687
1688         # Expected client content length set to 667325411 after reading 4999 bytes.
1689         $c =~ s@(?<=set to )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1690         $c =~ s@(?<=reading )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1691
1692     } elsif ($c =~ m/^Reducing expected bytes to /) {
1693
1694         # Reducing expected bytes to 0. Marking the server socket tainted after throwing 4 bytes away.
1695         $c =~ s@(?<=bytes to )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1696         $c =~ s@(?<=after throwing )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1697
1698     } elsif ($c =~ m/^Waiting for up to /) {
1699
1700         # Waiting for up to 4999 bytes from the client.
1701         $c =~ s@(?<=up to )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1702
1703     } elsif ($c =~ m/^Optimistically sending /) {
1704
1705         # Optimistically sending 318 bytes of client headers intended for www.privoxy.org
1706         $c =~ s@(?<=sending )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1707         $c = highlight_matched_host($c, '(?<=for )[^\s]+');
1708
1709     } elsif ($c =~ m/^Stopping to watch the client socket/) {
1710
1711         # Stopping to watch the client socket. There's already another request waiting.
1712         # Privoxy 3.0.20 and later:
1713         # Stopping to watch the client socket 5. There's already another request waiting.
1714         $c =~ s@(?<=client socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1715
1716     } elsif ($c =~ m/^Drained \d+ bytes before closing/) {
1717
1718         # Drained 180 bytes before closing socket 6
1719         $c =~ s@(?<=Drained )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1720         $c =~ s@(?<=socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1721
1722     } elsif ($c =~ m/^Tainting client socket/) {
1723
1724         # Tainting client socket 7 due to unread data.
1725         $c =~ s@(?<=socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1726
1727     } elsif ($c =~ m/^Shifting \d+ pipelined bytes/) {
1728
1729         # Shifting 360 pipelined bytes by 360 bytes
1730         $c =~ s@(?<=Shifting )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1731         $c =~ s@(?<=by )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1732
1733     } elsif ($c =~ m/^Looks like we / or
1734              $c =~ m/^Unsetting keep-alive flag/ or
1735              $c =~ m/^No connections to wait/ or
1736              $c =~ m/^Complete client request received/ or
1737              $c =~ m/^Possible pipeline attempt detected./ or
1738              $c =~ m/^POST request detected. The connection will not be kept alive./ or
1739              $c =~ m/^The server still wants to talk, but the client hung up on us./ or
1740              $c =~ m/^The server didn't specify how long the connection will stay open/ or
1741              $c =~ m/^There might be a request body. The connection will not be kept alive/ or
1742              $c =~ m/^There better be a request body./ or
1743              $c =~ m/^Done reading from the client\.$/) {
1744
1745         # Looks like we reached the end of the last chunk. We better stop reading.
1746         # Looks like we read the end of the last chunk together with the server \
1747         #  headers. We better stop reading.
1748         # Looks like we got the last chunk together with the server headers. \
1749         #  We better stop reading.
1750         # Unsetting keep-alive flag.
1751         # No connections to wait for left.
1752         # Client request arrived in time or the client closed the connection.
1753         # Complete client request received
1754         # Possible pipeline attempt detected. The connection will not be \
1755         #  kept alive and we will only serve the first request.
1756         # POST request detected. The connection will not be kept alive.
1757         # The server still wants to talk, but the client hung up on us.
1758         # The server didn't specify how long the connection will stay open. Assume it's only a second.
1759         # There might be a request body. The connection will not be kept alive.
1760         # Privoxy 3.0.20 and later
1761         # There better be a request body.
1762         # Done reading from the client.
1763
1764     } else {
1765
1766         found_unknown_content($c);
1767
1768     }
1769
1770     return $c;
1771 }
1772
1773
1774 sub handle_loglevel_info ($) {
1775
1776     my $c = shift;
1777
1778     if ($c =~ m/^Rewrite detected:/) {
1779
1780         # Rewrite detected: GET http://10.0.0.2:88/blah.txt HTTP/1.1
1781         $c = highlight_matched_request_line($c, '(?<=^Rewrite detected: ).*');
1782
1783     } elsif ($c =~ m/^Decompress(ing deflated|ion didn)/ or
1784              $c =~ m/^Compressed content detected/ or
1785              $c =~ m/^SDCH-compressed content detected/ or
1786              $c =~ m/^Tagger/
1787             ) {
1788         # Decompressing deflated iob: 117
1789         # Decompression didn't result in any content.
1790         # Compressed content detected, content filtering disabled. Consider recompiling Privoxy\
1791         #  with zlib support or enable the prevent-compression action.
1792         # SDCH-compressed content detected, content filtering disabled.\
1793         #  Consider suppressing SDCH offers made by the client.
1794         # Tagger 'complete-url' created empty tag. Ignored.
1795
1796         # Ignored for now
1797
1798     } elsif ($c =~ m/^(Re)?loading configuration file /) {
1799
1800         # loading configuration file '/usr/local/etc/privoxy/config':
1801         # Reloading configuration file '/usr/local/etc/privoxy/config'
1802         $c =~ s@(?<=loading configuration file \')([^\']*)@$h{'file'}$1$h{'Standard'}@;
1803
1804     } elsif ($c =~ m/^Loading (actions|filter) file: /) {
1805
1806         # Loading actions file: /usr/local/etc/privoxy/default.action
1807         # Loading filter file: /usr/local/etc/privoxy/default.filter
1808         $c =~ s@(?<= file: )(.*)$@$h{'file'}$1$h{'Standard'}@;
1809
1810     } elsif ($c =~ m/^exiting by signal/) {
1811
1812         # exiting by signal 15 .. bye
1813         $c =~ s@(?<=exiting by signal )(\d+)@$h{'signal'}$1$h{'Standard'}@;
1814
1815     } elsif ($c =~ m/^Privoxy version/) {
1816
1817         # Privoxy version 3.0.7
1818         $c =~ s@(?<=^Privoxy version )(\d+\.\d+\.\d+)$@$h{'version'}$1$h{'Standard'}@;
1819
1820     } elsif ($c =~ m/^Program name: /) {
1821
1822         # Program name: /usr/local/sbin/privoxy
1823         $c =~ s@(?<=Program name: )(.*)@$h{'program-name'}$1$h{'Standard'}@;
1824
1825     } elsif ($c =~ m/^Listening on port /) {
1826
1827         # Listening on port 8118 on IP address 10.0.0.1
1828         $c =~ s@(?<=Listening on port )(\d+)@$h{'port'}$1$h{'Standard'}@;
1829         $c =~ s@(?<=on IP address )(.*)@$h{'ip-address'}$1$h{'Standard'}@;
1830
1831     } elsif ($c =~ m/^\(Re-\)Open(?:ing)? logfile/) {
1832
1833         # (Re-)Open logfile /var/log/privoxy/privoxy.log
1834         $c =~ s@(?<=Open logfile )(.*)@$h{'file'}$1$h{'Standard'}@;
1835
1836     } elsif ($c =~ m/^(Request from|Malformed server response detected)/) {
1837
1838         # Request from 10.0.0.1 denied. limit-connect{,} doesn't allow CONNECT requests to port 443.
1839         # Request from 10.0.0.1 marked for blocking. limit-connect{,} doesn't allow CONNECT requests to port 443.
1840         # 3.0.18 and later:
1841         # Request from 10.0.0.1 marked for blocking. limit-connect{0} doesn't allow CONNECT requests to www.example.org:443
1842         # Malformed server response detected. Downgrading to HTTP/1.0 impossible.
1843
1844         $c =~ s@(?<=Request from )([^\s]*)@$h{'ip-address'}$1$h{'Standard'}@;
1845         $c =~ s@(denied|blocking)@$h{'warning'}$1$h{'Standard'}@;
1846         $c =~ s@(CONNECT)@$h{'method'}$1$h{'Standard'}@;
1847         $c =~ s@(?<=to port )(\d+)@$h{'port'}$1$h{'Standard'}@;
1848         $c =~ s@(?<=to )([^\s]+)@$h{'request_'}$1$h{'Standard'}@;
1849
1850     } elsif ($c =~ m/^Status code/) {
1851
1852         # Status code 304 implies no body.
1853         $c =~ s@(?<=Status code )(\d+)@$h{'status-code'}$1$h{'Standard'}@;
1854
1855     } elsif ($c =~ m/^Method/) {
1856
1857         # Method HEAD implies no body.
1858         $c =~ s@(?<=Method )([^\s]+)@$h{'method'}$1$h{'Standard'}@;
1859
1860     } elsif ($c =~ m/^Buffer limit reached while extending /) {
1861
1862         # Buffer limit reached while extending the buffer (iob). Needed: 4197470. Limit: 4194304
1863         $c =~ s@(?<=Needed: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1864         $c =~ s@(?<=Limit: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1865
1866     } elsif ($c =~ m/^File modification detected: /) {
1867
1868         # File modification detected: /usr/local/etc/privoxy/user-agent.action
1869         $c =~ s@(?<= detected: )(.*)$@$h{'file'}$1$h{'Standard'}@;
1870
1871     } elsif ($c =~ m/^No logfile configured/ or
1872              $c =~ m/^Malformerd HTTP headers detected and MS IIS5 hack enabled/ or
1873              $c =~ m/^Invalid \"chunked\" transfer/ or
1874              $c =~ m/^Support for/ or
1875              $c =~ m/^Flushing header and buffers/ or
1876              $c =~ m/^Can not resolve/
1877              ) {
1878
1879         # No logfile configured. Please enable it before reporting any problems.
1880         # Malformerd HTTP headers detected and MS IIS5 hack enabled. Expect an invalid \
1881         #  response or even no response at all.
1882         # No logfile configured. Logging disabled.
1883         # Invalid "chunked" transfer encoding detected and ignored.
1884         # Support for 'Connection: keep-alive' is experimental, incomplete and\
1885         #  known not to work properly in some situations.
1886         # Flushing header and buffers. Stepping back from filtering.
1887         # Can not resolve doesnotexist: hostname nor servname provided, or not known
1888
1889     } else {
1890
1891         found_unknown_content($c);
1892
1893     }
1894
1895     return $c;
1896 }
1897
1898 sub handle_loglevel_cgi ($) {
1899
1900     my $c = shift;
1901
1902     if ($c =~ m/^Granting access to/) {
1903
1904         #Granting access to http://config.privoxy.org/send-stylesheet, referrer http://p.p/ is trustworthy.
1905
1906     } elsif ($c =~ m/^Substituting: s(.)/) {
1907
1908         # Substituting: s/@else-not-FEATURE_ZLIB@.*@endif-FEATURE_ZLIB@//sigTU
1909         # XXX: prone to span several lines
1910
1911         my $delimiter = $1;
1912         #$c =~ s@(?<=failed: )(.*)@$h{'error'}$1$h{'Standard'}@;
1913         $c =~ s@(?!<=\\)($delimiter)@$h{'pcrs-delimiter'}$1$h{'Standard'}@g; # XXX: Too aggressive
1914         #$c =~ s@(?!<=\\)($1)@$h{'pcrs-delimiter'}$1$h{'Standard'}@g;
1915     }
1916
1917     return $c;
1918 }
1919
1920 sub handle_loglevel_force ($) {
1921
1922     my $c = shift;
1923
1924     if ($c =~ m/^Ignored force prefix in request:/) {
1925
1926         # Ignored force prefix in request: "GET http://10.0.0.1/PRIVOXY-FORCE/block HTTP/1.1"
1927         $c =~ s@^(Ignored)@$h{'ignored'}$1$h{'Standard'}@;
1928         $c = highlight_matched_request_line($c, '(?<=request: ")[^"]*');
1929
1930     } elsif ($c =~ m/^Enforcing request:/) {
1931
1932         # Enforcing request: "GET http://10.0.0.1/block HTTP/1.1".
1933         $c = highlight_matched_request_line($c, '(?<=request: ")[^"]*');
1934
1935     } else {
1936
1937         found_unknown_content($c);
1938
1939     }
1940
1941     return $c;
1942 }
1943
1944 sub handle_loglevel_error ($) {
1945
1946     my $c = shift;
1947
1948     if ($c =~ m/^(?:Empty|No) server or forwarder response received on socket \d+\./) {
1949
1950         # Empty server or forwarder response received on socket 4.
1951         # Empty server or forwarder response received on socket 3. \
1952         #  Closing client socket 15 without sending data.
1953         # Used by Privoxy 3.0.18 and later:
1954         # No server or forwarder response received on socket 8. \
1955         #  Closing client socket 10 without sending data.
1956
1957         $c =~ s@(?<=on socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1958         $c =~ s@(?<=client socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1959
1960     } elsif ($c =~ m/^Didn't receive data in time:/) {
1961
1962         # Didn't receive data in time: a.fsdn.com:443
1963         $c =~ s@(?<=in time: )(.*)@$h{'destination'}$1$h{'Standard'}@;
1964     }
1965
1966     # XXX: There are probably more messages that deserve highlighting.
1967
1968     return $c;
1969 }
1970
1971
1972 sub handle_loglevel_ignore ($) {
1973     return shift;
1974 }
1975
1976 sub gather_loglevel_request_stats ($$) {
1977     my $c = shift;
1978     my $thread = shift;
1979     our %stats;
1980
1981     $stats{requests}++;
1982 }
1983
1984 sub gather_loglevel_crunch_stats ($$) {
1985     my $c = shift;
1986     my $thread = shift;
1987     our %stats;
1988
1989     $stats{requests}++;
1990     $stats{crunches}++;
1991
1992     if ($c =~ m/^Redirected:/) {
1993         # Redirected: http://www.example.org/http://p.p/
1994         $stats{'fast-redirections'}++;
1995
1996     } elsif ($c =~ m/^Blocked:/) {
1997         # Blocked: blogger.googleusercontent.com:443
1998         $stats{'blocked'}++;
1999     }
2000 }
2001
2002
2003 sub gather_loglevel_error_stats ($$) {
2004
2005     my $c = shift;
2006     my $thread = shift;
2007     our %stats;
2008     our %thread_data;
2009
2010     if ($c =~ m/^Empty server or forwarder response received on socket \d+./) {
2011
2012         # Empty server or forwarder response received on socket 4.
2013         $stats{'empty-responses'}++;
2014         if ($thread_data{$thread}{'new_connection'}) {
2015             $stats{'empty-responses-on-new-connections'}++;
2016         } else {
2017             $stats{'empty-responses-on-reused-connections'}++;
2018         }
2019     }
2020 }
2021
2022 sub gather_loglevel_connect_stats ($$) {
2023
2024     my ($c, $thread) = @_;
2025     our %thread_data;
2026     our %stats;
2027
2028     if ($c =~ m/^via ([^\s]+) to: [^\s]+/) {
2029
2030         # Connect: via 10.0.0.1:8123 to: www.example.org.noconnect
2031         $thread_data{$thread}{'forwarder'} = $1; # XXX: is this missue?
2032
2033     } elsif ($c =~ m/^to ([^\s]*)$/) {
2034
2035         # Connect: to lists.sourceforge.net:443
2036
2037         $thread_data{$thread}{'forwarder'} = 'direct connection';
2038
2039     } elsif ($c =~ m/^Created new connection to/) {
2040
2041         # Created new connection to www.privoxy.org:80 on socket 11.
2042
2043         $thread_data{$thread}{'new_connection'} = 1;
2044
2045     } elsif ($c =~ m/^Reusing server socket \d./ or
2046              $c =~ m/^Found reusable socket/) {
2047
2048         # Reusing server socket 4. Opened for 10.0.0.1.
2049         # Found reusable socket 9 for www.privoxy.org:80 in slot 0.
2050
2051         $thread_data{$thread}{'new_connection'} = 0;
2052         $stats{'reused-connections'}++;
2053     }
2054 }
2055
2056 sub gather_loglevel_header_stats ($$) {
2057
2058     my ($c, $thread) = @_;
2059     our %stats;
2060
2061     if ($c =~ m/^A HTTP\/1\.1 response without/ or
2062         $c =~ m/^Keeping the server header 'Connection: keep-alive' around./)
2063     {
2064         # A HTTP/1.1 response without Connection header implies keep-alive.
2065         # Keeping the server header 'Connection: keep-alive' around.
2066         $stats{'server-keep-alive'}++;
2067
2068     } elsif ($c =~ m/^scan: ((\w+) (.+) (HTTP\/\d\.\d))/) {
2069
2070         # scan: HTTP/1.1 200 OK
2071         $stats{'method'}{$2}++;
2072         $stats{'resource'}{$3}++;
2073         $stats{'http-version'}{$4}++;
2074
2075     } elsif ($c =~ m/^scan: Host: ([^\s]+)/) {
2076
2077         # scan: Host: p.p
2078         $stats{'hosts'}{$1}++;
2079     }
2080 }
2081
2082 sub init_stats () {
2083     our %stats = (
2084         requests => 0,
2085         crunches => 0,
2086         'server-keep-alive' => 0,
2087         'reused-connections' => 0,
2088         'empty-responses' => 0,
2089         'empty-responses-on-new-connections' => 0,
2090         'empty-responses-on-reused-connections' => 0,
2091         'fast-redirections' => 0,
2092         'blocked' => 0,
2093         'reused-connections' => 0,
2094         'server-keep-alive' => 0,
2095         );
2096 }
2097
2098 sub get_percentage ($$) {
2099     my $big = shift;
2100     my $small = shift;
2101
2102     # If small is 0 the percentage is always 0%.
2103     # Make sure it works even if big is 0 as well.
2104     return "0.00%" if ($small eq 0);
2105
2106     # Prevent division by zero.
2107     # XXX: Is this still supposed to be reachable?
2108     return "NaN" if ($big eq 0);
2109
2110     return sprintf("%.2f%%", $small / $big * 100);
2111 }
2112
2113 sub print_stats () {
2114
2115     our %stats;
2116     our %cli_options;
2117     my $new_connections = $stats{requests} - $stats{crunches} - $stats{'reused-connections'};
2118     my $outgoing_requests = $stats{requests} - $stats{crunches};
2119
2120     if ($stats{requests} eq 0) {
2121         print "No requests yet.\n";
2122         return;
2123     }
2124
2125     print "Client requests total: " . $stats{requests} . "\n";
2126     print "Crunches: " . $stats{crunches} . " (" .
2127         get_percentage($stats{requests}, $stats{crunches}) . ")\n";
2128     print "Blocks: " . $stats{'blocked'} . " (" .
2129         get_percentage($stats{requests}, $stats{'blocked'}) . ")\n";
2130     print "Fast redirections: " . $stats{'fast-redirections'} . " (" .
2131         get_percentage($stats{requests}, $stats{'fast-redirections'}) . ")\n";
2132     print "Outgoing requests: " . $outgoing_requests . " (" .
2133         get_percentage($stats{requests}, $outgoing_requests) . ")\n";
2134     print "Server keep-alive offers: " . $stats{'server-keep-alive'} . " (" .
2135         get_percentage($stats{requests}, $stats{'server-keep-alive'}) . ")\n";
2136     print "New outgoing connections: " . $new_connections . " (" .
2137         get_percentage($stats{requests}, $new_connections) . ")\n";
2138     print "Reused connections: " . $stats{'reused-connections'} . " (" .
2139         get_percentage($stats{requests}, $stats{'reused-connections'}) .
2140         "; server offers accepted: " .
2141         get_percentage($stats{'server-keep-alive'}, $stats{'reused-connections'}) . ")\n";
2142     print "Empty responses: " . $stats{'empty-responses'} . " (" .
2143         get_percentage($stats{requests}, $stats{'empty-responses'}) . ")\n";
2144     print "Empty responses on new connections: "
2145          . $stats{'empty-responses-on-new-connections'} . " (" .
2146         get_percentage($stats{requests}, $stats{'empty-responses-on-new-connections'})
2147         . ")\n";
2148     print "Empty responses on reused connections: " .
2149         $stats{'empty-responses-on-reused-connections'} . " (" .
2150         get_percentage($stats{requests}, $stats{'empty-responses-on-reused-connections'}) .
2151         ")\n";
2152
2153     if ($stats{method} eq 0) {
2154         print "No response lines parsed yet yet.\n";
2155         return;
2156     }
2157     print "Method distribution:\n";
2158     foreach my $method (sort {$stats{'method'}{$b} <=> $stats{'method'}{$a}} keys %{$stats{'method'}}) {
2159         printf "%8d : %-8s\n", $stats{'method'}{$method}, $method;
2160     }
2161     print "Client HTTP versions:\n";
2162     foreach my $http_version (sort {$stats{'http-version'}{$b} <=> $stats{'http-version'}{$a}} keys %{$stats{'http-version'}}) {
2163         printf "%d : %s\n",  $stats{'http-version'}{$http_version}, $http_version;
2164     }
2165
2166     if ($cli_options{'url-statistics-threshold'} == 0) {
2167         print "URL statistics are disabled. Increase --url-statistics-threshold to enable them.\n";
2168     } else {
2169         print "Requested URLs:\n";
2170         foreach my $resource (sort {$stats{'resource'}{$b} <=> $stats{'resource'}{$a}} keys %{$stats{'resource'}}) {
2171             if ($stats{'resource'}{$resource} < $cli_options{'url-statistics-threshold'}) {
2172                 print "Skipped statistics for URLs below the treshold.\n";
2173                 last;
2174             }
2175             printf "%d : %s\n", $stats{'resource'}{$resource}, $resource;
2176         }
2177     }
2178
2179     if ($cli_options{'host-statistics-threshold'} == 0) {
2180         print "Host statistics are disabled. Increase --host-statistics-threshold to enable them.\n";
2181     } else {
2182         print "Requested Hosts:\n";
2183         foreach my $host (sort {$stats{'hosts'}{$b} <=> $stats{'hosts'}{$a}} keys %{$stats{'hosts'}}) {
2184             if ($stats{'hosts'}{$host} < $cli_options{'host-statistics-threshold'}) {
2185                 print "Skipped statistics for Hosts below the treshold.\n";
2186                 last;
2187             }
2188             printf "%d : %s\n", $stats{'hosts'}{$host}, $host;
2189         }
2190     }
2191 }
2192
2193
2194 ################################################################################
2195 # Functions that actually print stuff
2196 ################################################################################
2197
2198 sub print_clf_message () {
2199
2200     our ($ip, $timestamp, $request_line, $status_code, $size);
2201     my $output = '';
2202
2203     return if DEBUG_SUPPRESS_LOG_MESSAGES;
2204
2205     # Rebuild highlighted
2206     $output .= $h{'Number'} . $ip . $h{'Standard'};
2207     $output .= " - - ";
2208     $output .= "[" . $h{'Timestamp'} . $timestamp . $h{'Standard'} . "]";
2209     $output .= " ";
2210     $output .= "\"" . highlight_request_line("$request_line") . "\"";
2211     $output .= " ";
2212     $output .= $h{'Status'} . $status_code . $h{'Standard'};
2213     $output .= " ";
2214     $output .= $h{'Number'} . $size . $h{'Standard'};
2215     $output .= $line_end;
2216
2217     print $output;
2218 }
2219
2220 sub print_non_clf_message ($) {
2221
2222     my $content = shift;
2223     my $msec_string = $no_msecs_mode ? '' : '.' . $req{$t}{'msecs'};
2224     my $line_start = $html_output_mode ? '' : $h{"Standard"};
2225
2226     return if DEBUG_SUPPRESS_LOG_MESSAGES;
2227
2228     print $line_start
2229         . $time_colours[$time_colour_index % 2]
2230         . $req{$t}{'time-stamp'}
2231         . $msec_string
2232         . $h{Standard} . " "
2233         . $thread_colours{$t}
2234         . $t
2235         . $h{Standard}
2236         . " "
2237         . $h{$req{$t}{'log-level'}}
2238         . $req{$t}{'log-level'}
2239         . $h{Standard}
2240         . ": "
2241         . $content
2242         . $line_end;
2243 }
2244
2245 sub shorten_thread_id ($) {
2246
2247     my $thread_id = shift;
2248
2249     our %short_thread_ids;
2250     our $max_threadid;
2251
2252     unless (defined $short_thread_ids{$thread_id}) {
2253         $short_thread_ids{$thread_id} = sprintf "%.3d", $max_threadid++;
2254     }
2255
2256     return $short_thread_ids{$thread_id}
2257 }
2258
2259 sub parse_loop () {
2260
2261     my ($day, $time_stamp, $thread, $log_level, $content, $c, $msecs);
2262     my $last_msecs  = 0;
2263     my $last_thread = 0;
2264     my $last_timestamp = 0;
2265     my $filters_that_did_nothing;
2266     my $key;
2267     my $time_colour;
2268     $time_colour = paint_it('white');
2269
2270     my %log_level_handlers = (
2271         'Re-Filter'         => \&handle_loglevel_re_filter,
2272         'Header'            => \&handle_loglevel_header,
2273         'Connect'           => \&handle_loglevel_connect,
2274         'Redirect'          => \&handle_loglevel_redirect,
2275         'Request'           => \&handle_loglevel_request,
2276         'Crunch'            => \&handle_loglevel_crunch,
2277         'Gif-Deanimate'     => \&handle_loglevel_gif_deanimate,
2278         'Info'              => \&handle_loglevel_info,
2279         'CGI'               => \&handle_loglevel_cgi,
2280         'Force'             => \&handle_loglevel_force,
2281         'Error'             => \&handle_loglevel_error,
2282         'Fatal error'       => \&handle_loglevel_ignore,
2283         'Writing'           => \&handle_loglevel_ignore,
2284         'Received'          => \&handle_loglevel_ignore,
2285         'Actions'           => \&handle_loglevel_ignore,
2286         'Unknown log level' => \&handle_loglevel_ignore,
2287     );
2288
2289     while (<>) {
2290
2291         if (m/^(\d{4}-\d{2}-\d{2}|\w{3} \d{2}) (\d\d:\d\d:\d\d)\.?(\d+)? (?:Privoxy\()?([^\)\s]*)[\)]? ([\w -]*): (.*?)\r?$/) {
2292             $thread = $t = ($shorten_thread_ids) ? shorten_thread_id($4) : $4;
2293             $req{$t}{'day'} = $day = $1;
2294             $req{$t}{'time-stamp'} = $time_stamp = $2;
2295             $req{$t}{'msecs'} = $msecs = $3 ? $3 : 0; # Only the cool kids have micro second resolution;
2296             $req{$t}{'log-level'} = $log_level = $5;
2297             $req{$t}{'content'} = $content = $c = $6;
2298             $req{$t}{'log-message'} = $_;
2299             $no_special_header_highlighting = 0;
2300
2301             if (defined($log_level_handlers{$log_level})) {
2302
2303                 $content = $log_level_handlers{$log_level}($content);
2304
2305             } else {
2306
2307                 die "No handler found for log level \"$log_level\"\n";
2308             }
2309
2310             # Highlight Truncations
2311             if (length($_) > 4000) {
2312                 $content =~ s@(too long, truncated)]$@$h{'Truncation'}$1$h{'Standard'}]@g;
2313             }
2314
2315             next unless $content;
2316
2317             # Register threads to keep the colour constant
2318             if (!defined($thread_colours{$thread})) {
2319                 $thread_colours{$thread} = $all_colours[$thread_colour_index % @all_colours];
2320                 $thread_colour_index++;
2321             }
2322
2323             # Switch timestamp colour if timestamps differ
2324             if (($msecs ne $last_msecs) || ($time_stamp ne $last_timestamp)) {
2325                debug_message("Tick tack!") if DEBUG_TICKS;
2326                $time_colour = $time_colours[$time_colour_index % 2];
2327                $time_colour_index++;
2328                $last_msecs = $msecs;
2329                $last_timestamp = $time_stamp;
2330             }
2331
2332             $last_thread = $thread;
2333
2334             print_non_clf_message($content);
2335
2336         } elsif (m/^((?:\d+\.\d+\.\d+\.\d+|[:\d]+)) - - \[(.*)\] "(.*)" (\d+) (\d+)/) {
2337
2338             # LOG_LEVEL_CLF lines look like this
2339             # 61.152.239.32 - - [04/Mar/2007:18:28:23 +0100] "GET \
2340             #  http://ad.yieldmanager.com/imp?z=1&Z=120x600&s=109339&u=http%3A%2F%2Fwww.365loan.co.uk%2F&r=1\
2341             #  HTTP/1.1" 403 1730
2342             our ($ip, $timestamp, $request_line, $status_code, $size) = ($1, $2, $3, $4, $5);
2343
2344             print_clf_message();
2345
2346         } else {
2347
2348             # Some Privoxy log messages span more than one line,
2349             # usually to dump lots of content that doesn't need any syntax highlighting.
2350             # XXX: add mechanism to forward these lines to the right handler anyway.
2351             chomp();
2352             unless (DEBUG_SUPPRESS_LOG_MESSAGES or (SUPPRESS_EMPTY_LINES and m/^\s+$/)) {
2353                 print and print get_line_end(); # unless (SUPPRESS_EMPTY_LINES and m/^\s+$/);
2354             }
2355         }
2356     }
2357 }
2358
2359 sub stats_loop () {
2360
2361     my ($day, $time_stamp, $msecs, $thread, $log_level, $content);
2362     my %log_level_handlers = (
2363          'Re-Filter'         => \&handle_loglevel_ignore,
2364          'Header'            => \&gather_loglevel_header_stats,
2365          'Connect'           => \&gather_loglevel_connect_stats,
2366          'Redirect'          => \&handle_loglevel_ignore,
2367          'Request'           => \&gather_loglevel_request_stats,
2368          'Crunch'            => \&gather_loglevel_crunch_stats,
2369          'Gif-Deanimate'     => \&handle_loglevel_ignore,
2370          'Info'              => \&handle_loglevel_ignore,
2371          'CGI'               => \&handle_loglevel_ignore,
2372          'Force'             => \&handle_loglevel_ignore,
2373          'Error'             => \&gather_loglevel_error_stats,
2374          'Fatal error'       => \&handle_loglevel_ignore,
2375          'Writing'           => \&handle_loglevel_ignore,
2376          'Received'          => \&handle_loglevel_ignore,
2377          'Actions'           => \&handle_loglevel_ignore,
2378          'Unknown log level' => \&handle_loglevel_ignore
2379     );
2380
2381     while (<>) {
2382         if (m/^(\d{4}-\d{2}-\d{2}|\w{3} \d{2}) (\d\d:\d\d:\d\d)\.?(\d+)? (?:Privoxy\()?([^\)\s]*)[\)]? ([\w -]*): (.*?)\r?$/) {
2383             $day = $1;
2384             $time_stamp = $2;
2385             $msecs = $3 ? $3 : 0;
2386             $thread = $4;
2387             $log_level = $5;
2388             $content = $6;
2389
2390             if (defined($log_level_handlers{$log_level})) {
2391
2392                 $content = $log_level_handlers{$log_level}($content, $thread);
2393
2394             } else {
2395
2396                 die "No handler found for log level \"$log_level\"\n";
2397
2398             }
2399         }
2400     }
2401
2402     print_stats();
2403
2404 }
2405
2406 sub unbreak_lines_only_loop() {
2407     my $log_messages_reached = 0;
2408     while (<>) {
2409         chomp;
2410
2411             # Log level other than LOG_LEVEL_CLF?
2412         if (m/^(\d{4}-\d{2}-\d{2}|\w{3} \d{2}) (\d\d:\d\d:\d\d)\.?(\d+)? (?:Privoxy\()?([^\)\s]*)[\)]? ([\w -]*): (.*?)\r?$/ or
2413             # LOG_LEVEL_CLF?
2414             m/^((?:\d+\.\d+\.\d+\.\d+)) - - \[(.*)\] "(.*)" (\d+) (\d+)/) {
2415             $log_messages_reached = 1;
2416             print "\n";
2417
2418         } else {
2419             # Wrapped message
2420             $_ = "\n". $_  if /^(?:\d+\.\d+\.\d+\.\d+)/;
2421             $_ = " " . $_;
2422         }
2423         s@<BR>$@@;
2424         print;
2425         print "\n" unless $log_messages_reached;
2426     }
2427     print "\n";
2428 }
2429
2430 sub VersionMessage {
2431     my $version_message;
2432
2433     $version_message .= 'Privoxy-Log-Parser ' . PRIVOXY_LOG_PARSER_VERSION  . "\n";
2434     $version_message .= 'Copyright (C) 2007-2010 Fabian Keil <fk@fabiankeil.de>' . "\n";
2435     $version_message .= 'http://www.fabiankeil.de/sourcecode/privoxy-log-parser/' . "\n";
2436
2437     print $version_message;
2438 }
2439
2440 sub get_cli_options () {
2441
2442     our %cli_options = (
2443         'html-output'              => CLI_OPTION_DEFAULT_TO_HTML_OUTPUT,
2444         'title'                    => CLI_OPTION_TITLE,
2445         'no-syntax-highlighting'   => CLI_OPTION_NO_SYNTAX_HIGHLIGHTING,
2446         'no-embedded-css'          => CLI_OPTION_NO_EMBEDDED_CSS,
2447         'no-msecs'                 => CLI_OPTION_NO_MSECS,
2448         'shorten-thread-ids'       => CLI_OPTION_SHORTEN_THREAD_IDS,
2449         'show-ineffective-filters' => CLI_OPTION_SHOW_INEFFECTIVE_FILTERS,
2450         'accept-unknown-messages'  => CLI_OPTION_ACCEPT_UNKNOWN_MESSAGES,
2451         'statistics'               => CLI_OPTION_STATISTICS,
2452         'url-statistics-threshold' => CLI_OPTION_URL_STATISTICS_THRESHOLD,
2453         'unbreak-lines-only'       => CLI_OPTION_UNBREAK_LINES_ONLY,
2454         'host-statistics-threshold'=> CLI_OPTION_HOST_STATISTICS_THRESHOLD,
2455     );
2456
2457     GetOptions (
2458         'html-output'              => \$cli_options{'html-output'},
2459         'title'                    => \$cli_options{'title'},
2460         'no-syntax-highlighting'   => \$cli_options{'no-syntax-highlighting'},
2461         'no-embedded-css'          => \$cli_options{'no-embedded-css'},
2462         'no-msecs'                 => \$cli_options{'no-msecs'},
2463         'shorten-thread-ids'       => \$cli_options{'shorten-thread-ids'},
2464         'show-ineffective-filters' => \$cli_options{'show-ineffective-filters'},
2465         'accept-unknown-messages'  => \$cli_options{'accept-unknown-messages'},
2466         'statistics'               => \$cli_options{'statistics'},
2467         'unbreak-lines-only'       => \$cli_options{'unbreak-lines-only'},
2468         'url-statistics-threshold=i'=> \$cli_options{'url-statistics-threshold'},
2469         'host-statistics-threshold=i'=> \$cli_options{'host-statistics-threshold'},
2470         'version'                  => sub { VersionMessage && exit(0) },
2471         'help'                     => \&help,
2472    ) or exit(1);
2473
2474    $html_output_mode = cli_option_is_set('html-output');
2475    $no_msecs_mode = cli_option_is_set('no-msecs');
2476    $shorten_thread_ids = cli_option_is_set('shorten-thread-ids');
2477    $line_end = get_line_end();
2478 }
2479
2480 sub help () {
2481
2482     our %cli_options;
2483
2484     VersionMessage();
2485
2486     print << "    EOF"
2487
2488 Options and their default values if they have any:
2489     [--accept-unknown-messages]
2490     [--host-statistics-threshold $cli_options{'host-statistics-threshold'}]
2491     [--html-output]
2492     [--no-embedded-css]
2493     [--no-msecs]
2494     [--no-syntax-highlighting]
2495     [--shorten-thread-ids]
2496     [--show-ineffective-filters]
2497     [--statistics]
2498     [--unbreak-lines-only]
2499     [--url-statistics-threshold $cli_options{'url-statistics-threshold'}]
2500     [--title $cli_options{'title'}]
2501     [--version]
2502 see "perldoc $0" for more information
2503     EOF
2504     ;
2505     exit(0);
2506 }
2507
2508 ################################################################################
2509 # main
2510 ################################################################################
2511 sub main () {
2512
2513     get_cli_options();
2514     set_background(DEFAULT_BACKGROUND);
2515     prepare_our_stuff();
2516
2517     print_intro();
2518
2519     # XXX: should explicitly reject incompatible argument combinations
2520     if (cli_option_is_set('unbreak-lines-only')) {
2521         unbreak_lines_only_loop();
2522     } elsif (cli_option_is_set('statistics')) {
2523         stats_loop();
2524     } else {
2525         parse_loop();
2526     }
2527
2528     print_outro();
2529 }
2530
2531 main();
2532
2533 =head1 NAME
2534
2535 B<privoxy-log-parser> - A parser and syntax-highlighter for Privoxy log messages
2536
2537 =head1 SYNOPSIS
2538
2539 B<privoxy-log-parser> [B<--accept-unknown-messages>] [B<--html-output>]
2540 [B<--no-msecs>] [B<--no-syntax-higlighting>] [B<--statistics>]
2541 [B<--shorten-thread-ids>] [B<--show-ineffective-filters>]
2542 [B<--url-statistics-threshold>] [B<--version>]
2543
2544 =head1 DESCRIPTION
2545
2546 B<privoxy-log-parser> reads Privoxy log messages and
2547
2548 - syntax-highlights recognized lines,
2549
2550 - reformats some of them for easier comprehension,
2551
2552 - filters out less useful messages, and
2553
2554 - (in some cases) calculates additional information,
2555   like the compression ratio or how a filter affected
2556   the content size.
2557
2558 With B<privoxy-log-parser> you should be able to increase Privoxy's log level
2559 without getting confused by the resulting amount of output. For example for
2560 "debug 64" B<privoxy-log-parser> will (by default) only show messages that
2561 affect the content. If a filter doesn't cause any hits, B<privoxy-log-parser>
2562 will hide the "filter foo caused 0 hits" message.
2563
2564 =head1 OPTIONS
2565
2566 [B<--accept-unknown-messages>] Don't print warnings in case of unknown messages,
2567 just don't highlight them.
2568
2569 [B<--host-statistics-threshold>] Only show the request count for a host
2570 if it's above or equal to the given threshold. If the threshold is 0, host
2571 statistics are disabled.
2572
2573 [B<--html-output>] Use HTML and CSS for the syntax highlighting. If this option is
2574 omitted, ANSI escape sequences are used unless B<--no-syntax-highlighting> is active.
2575 This option is only intended to make embedding log excerpts in web pages easier.
2576 It does not escape any input!
2577
2578 [B<--no-msecs>] Don't expect milisecond resolution
2579
2580 [B<--no-syntax-highlighting>] Disable syntax-highlighting. Useful when
2581 the filtered output is piped into less in which case the ANSI control
2582 codes don't work, or if the terminal itself doesn't support the control
2583 codes.
2584
2585 [B<--shorten-thread-ids>] Shorten the thread ids to a three-digit decimal number.
2586 Note that the mapping from thread ids to shortened ids is created at run-time
2587 and thus varies with the input.
2588
2589 [B<--show-ineffective-filters>] Don't suppress log lines for filters
2590 that didn't modify the content.
2591
2592 [B<--statistics>] Gather various statistics instead of syntax highlighting
2593 log messages. This is an experimental feature, if the results look wrong
2594 they very well might be. Also note that the results are pretty much guaranteed
2595 to be incorrect if Privoxy and Privoxy-Log-Parser aren't in sync.
2596
2597 [B<--unbreak-lines-only>] Tries to fix lines that got messed up by a broken or
2598 interestingly configured mail client and thus are no longer recognized properly.
2599 Only fixes some breakage, but may be good enough or at least better than nothing.
2600 Doesn't do anything else, so you probably want to pipe the output into
2601 B<privoxy-log-parser> again.
2602
2603 [B<--url-statistics-threshold>] Only show the request count for a resource
2604 if it's above or equal to the given threshold. If the threshold is 0, URL
2605 statistics are disabled.
2606
2607 [B<--version>] Print version and exit.
2608
2609 =head1 EXAMPLES
2610
2611 To monitor a log file:
2612
2613 tail -F /usr/jails/privoxy-jail/var/log/privoxy/privoxy.log | B<privoxy-log-parser>
2614
2615 Replace '-F' with '-f' if your tail implementation lacks '-F' support
2616 or if the log won't get rotated anyway. The log file location depends
2617 on your system (Doh!).
2618
2619 To monitor Privoxy without having it write to a log file:
2620
2621 privoxy --no-daemon /usr/jails/privoxy-jail/usr/local/etc/privoxy/config 2>&1 | B<privoxy-log-parser>
2622
2623 Again, the config file location depends on your system. Output redirection
2624 depends on your shell, the above works with bourne shells.
2625
2626 To read a processed Privoxy log file from top to bottom, letting the content
2627 scroll by slightly faster than you can read:
2628
2629 B<privoxy-log-parser> < /usr/jails/privoxy-jail/var/log/privoxy/privoxy.log
2630
2631 This is probably only useful to fill screens in the background of haxor movies.
2632
2633 =head1 CAVEATS
2634
2635 Syntax highlighting with ANSI escape sequences will look strange
2636 if your background color isn't black.
2637
2638 Some messages aren't recognized yet and will not be fully highlighted.
2639
2640 B<privoxy-log-parser> is developed with Privoxy 3.0.7 or later in mind,
2641 using earlier Privoxy versions will probably result in an increased amount
2642 of unrecognized log lines.
2643
2644 Privoxy's log files tend to be rather large. If you use HTML
2645 highlighting some browsers can't handle them, get confused and
2646 will eventually crash because of segmentation faults or unexpected
2647 exceptions. This is a problem in the browser and not B<privoxy-log-parser>'s
2648 fault.
2649
2650 =head1 BUGS
2651
2652 Many settings can't be controlled through command line options yet.
2653
2654 =head1 SEE ALSO
2655
2656 privoxy(1)
2657
2658 =head1 AUTHOR
2659
2660 Fabian Keil <fk@fabiankeil.de>
2661
2662 =cut