tools/privoxy-log-parser.pl

   1 #!/usr/bin/perl
   2
   3 ################################################################################
   4 # privoxy-log-parser
   5 #
   6 # A parser for Privoxy log messages. For incomplete documentation run
   7 # perldoc privoxy-log-parser(.pl), for fancy screenshots see:
   8 #
   9 # https://www.fabiankeil.de/sourcecode/privoxy-log-parser/
  10 #
  11 # TODO:
  12 #       - LOG_LEVEL_CGI, LOG_LEVEL_ERROR, LOG_LEVEL_WRITE content highlighting
  13 #       - create fancy statistics
  14 #       - grep through Privoxy sources to find unsupported log messages
  15 #       - hunt down substitutions that match content from variables which
  16 #         can contain stuff like ()?'[]
  17 #       - replace $h{'foo'} with h('foo') where possible
  18 #       - hunt down XXX comments instead of just creating them
  19 #       - add example log lines for every regex and mark them up for
  20 #         regression testing
  21 #       - Handle incomplete input without Perl warning about undefined variables.
  22 #       - Use generic highlighting function that takes a regex and the
  23 #         hash key as input.
  24 #       - Add --compress and --decompress options.
  25 #
  26 # Copyright (c) 2007-2020 Fabian Keil <fk@fabiankeil.de>
  27 #
  28 # Permission to use, copy, modify, and distribute this software for any
  29 # purpose with or without fee is hereby granted, provided that the above
  30 # copyright notice and this permission notice appear in all copies.
  31 #
  32 # THE SOFTWARE IS PROVIDED "AS IS" AND THE AUTHOR DISCLAIMS ALL WARRANTIES
  33 # WITH REGARD TO THIS SOFTWARE INCLUDING ALL IMPLIED WARRANTIES OF
  34 # MERCHANTABILITY AND FITNESS. IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR
  35 # ANY SPECIAL, DIRECT, INDIRECT, OR CONSEQUENTIAL DAMAGES OR ANY DAMAGES
  36 # WHATSOEVER RESULTING FROM LOSS OF USE, DATA OR PROFITS, WHETHER IN AN
  37 # ACTION OF CONTRACT, NEGLIGENCE OR OTHER TORTIOUS ACTION, ARISING OUT OF
  38 # OR IN CONNECTION WITH THE USE OR PERFORMANCE OF THIS SOFTWARE.
  39 ################################################################################
  40
  41 use strict;
  42 use warnings;
  43 use Getopt::Long;
  44
  45 use constant {
  46     PRIVOXY_LOG_PARSER_VERSION => '0.9.2',
  47     # Feel free to mess with these ...
  48     DEFAULT_BACKGROUND => 'black',  # Choose registered colour (like 'black')
  49     DEFAULT_TEXT_COLOUR => 'white', # Choose registered colour (like 'black')
  50     HEADER_DEFAULT_COLOUR => 'yellow',
  51     REGISTER_HEADERS_WITH_THE_SAME_COLOUR => 1,
  52
  53     CLI_OPTION_DEFAULT_TO_HTML_OUTPUT => 0,
  54     CLI_OPTION_TITLE => 'Privoxy-Log-Parser in da house',
  55     CLI_OPTION_KEEP_DATE => 0,
  56     CLI_OPTION_NO_EMBEDDED_CSS => 0,
  57     CLI_OPTION_NO_MSECS => 0,
  58     CLI_OPTION_NO_SYNTAX_HIGHLIGHTING => 0,
  59     CLI_OPTION_SHORTEN_THREAD_IDS => 0,
  60     CLI_OPTION_SHOW_INEFFECTIVE_FILTERS => 0,
  61     CLI_OPTION_STATISTICS => 0,
  62     CLI_OPTION_STRICT_CHECKS => 0,
  63     CLI_OPTION_UNBREAK_LINES_ONLY => 0,
  64     CLI_OPTION_URL_STATISTICS_THRESHOLD => 0,
  65     CLI_OPTION_HOST_STATISTICS_THRESHOLD => 0,
  66     CLI_OPTION_SHOW_COMPLETE_REQUEST_DISTRIBUTION => 0,
  67
  68     SUPPRESS_SUCCEEDED_FILTER_ADDITIONS => 1,
  69     SHOW_SCAN_INTRO => 0,
  70     SHOW_FILTER_READIN_IN => 0,
  71     SUPPRESS_EMPTY_LINES => 1,
  72     SUPPRESS_SUCCESSFUL_CONNECTIONS => 1,
  73     SUPPRESS_GIF_NOT_CHANGED => 1,
  74     SUPPRESS_NEED_TO_DE_CHUNK_FIRST => 1,
  75
  76     DEBUG_HEADER_REGISTERING => 0,
  77     DEBUG_HEADER_HIGHLIGHTING => 0,
  78     DEBUG_TICKS => 0,
  79     DEBUG_PAINT_IT => 0,
  80     DEBUG_SUPPRESS_LOG_MESSAGES => 0,
  81
  82     PUNISH_MISSING_LOG_KNOWLEDGE_WITH_DEATH => 0,
  83     PUNISH_MISSING_HIGHLIGHT_KNOWLEDGE_WITH_DEATH => 1,
  84
  85     LOG_UNPARSED_LINES_TO_EXTRA_FILE => 0,
  86     ERROR_LOG_FILE => '/var/log/privoxy-log-parser',
  87
  88     # You better leave these alone unless you know what you're doing.
  89     COLOUR_RESET      => "\033[0;0m",
  90     ESCAPE => "\033[",
  91 };
  92
  93 # For performance reasons, these are global.
  94
  95 my $t;
  96 my %req; # request data from previous lines
  97 my %h;
  98 my %thread_colours;
  99 my @all_colours;
 100 my @time_colours;
 101 my $thread_colour_index = 0;
 102 my $header_colour_index = 0;
 103 my $time_colour_index = 0;
 104 my %header_colours;
 105 my $no_special_header_highlighting;
 106 my %reason_colours;
 107 my %h_colours;
 108 my $header_highlight_regex = '';
 109
 110 my $html_output_mode;
 111 my $keep_date_mode;
 112 my $no_msecs_mode; # XXX: should probably be removed
 113 my $shorten_thread_ids;
 114 my $line_end;
 115
 116 sub prepare_our_stuff() {
 117
 118     # Syntax Higlight hash
 119     @all_colours = (
 120         'red', 'green', 'brown', 'blue', 'purple', 'cyan',
 121         'light_gray', 'light_red', 'light_green', 'yellow',
 122         'light_blue', 'pink', 'light_cyan', 'white'
 123     );
 124
 125     %h = (
 126         # LOG_LEVEL
 127         Info            => 'blue',
 128         Header          => 'green',
 129         Filter          => 'purple', # XXX: Used?
 130         'Re-Filter'     => 'purple',
 131         Connect         => 'brown',
 132         Request         => 'light_cyan',
 133         Tagging         => 'purple',
 134         CGI             => 'light_green',
 135         Redirect        => 'cyan',
 136         Error           => 'light_red',
 137         Crunch          => 'cyan',
 138         'Fatal error'   => 'light_red',
 139         'Gif-Deanimate' => 'blue',
 140         Force           => 'red',
 141         Writing         => 'light_green',
 142         Received        => 'yellow',
 143         Actions         => 'yellow',
 144         # ----------------------
 145         URL                  => 'yellow',
 146         path                 => 'brown',
 147         request_             => 'brown', # host+path but no protocol
 148         'ip-address'         => 'yellow',
 149         Number               => 'yellow',
 150         Standard             => 'reset',
 151         Truncation           => 'light_red',
 152         Status               => 'brown',
 153         Timestamp            => 'brown',
 154         Crunching            => 'light_red',
 155         crunched             => 'light_red',
 156         'Request-Line'       => 'pink',
 157         method               => 'purple',
 158         destination          => 'yellow',
 159         'http-version'       => 'pink',
 160         'crunch-pattern'     => 'pink',
 161         not                  => 'brown',
 162         file                 => 'brown',
 163         signal               => 'yellow',
 164         version              => 'green',
 165         'program-name'       => 'cyan',
 166         port                 => 'red',
 167         host                 => 'red',
 168         warning              => 'light_red',
 169         debug                => 'light_red',
 170         filter               => 'green',
 171         tag                  => 'green',
 172         tagger               => 'green',
 173         'status-message'     => 'light_cyan',
 174         'status-code'        => 'yellow',
 175         'invalid-request'    => 'light_red',
 176         'hits'               => 'yellow',
 177         error                => 'light_red',
 178         'rewritten-URL'      => 'light_red',
 179         'pcrs-delimiter'     => 'light_red',
 180         'ignored'            => 'light_red',
 181         'action-bits-update' => 'light_red',
 182         'configuration-line' => 'red',
 183         'content-type'       => 'yellow',
 184         'HOST'               => HEADER_DEFAULT_COLOUR,
 185     );
 186
 187     %h_colours = %h;
 188
 189     # Header colours need their own hash so the keys can be accessed properly
 190     %header_colours = (
 191         # Prefilled with headers that should not appear with default header colours
 192         Cookie => 'light_red',
 193         'Set-Cookie' => 'light_red',
 194         Warning => 'light_red',
 195         Default => HEADER_DEFAULT_COLOUR,
 196     );
 197
 198     # Crunch reasons need their own hash as well
 199     %reason_colours = (
 200         'Unsupported HTTP feature'               => 'light_red',
 201         Blocked                                  => 'light_red',
 202         Untrusted                                => 'light_red',
 203         Redirected                               => 'green',
 204         'CGI Call'                               => 'white',
 205         'DNS failure'                            => 'red',
 206         'Forwarding failed'                      => 'light_red',
 207         'Connection failure'                     => 'light_red',
 208         'Out of memory (may mask other reasons)' => 'light_red',
 209         'No reason recorded'                     => 'light_red',
 210     );
 211
 212     @time_colours = ('white', 'light_gray');
 213
 214     # Translate highlight strings into highlight code
 215     prepare_highlight_hash(\%header_colours);
 216     prepare_highlight_hash(\%reason_colours);
 217     prepare_highlight_hash(\%h);
 218     prepare_colour_array(\@all_colours);
 219     prepare_colour_array(\@time_colours);
 220     init_css_colours();
 221
 222     init_stats();
 223 }
 224
 225 sub paint_it($) {
 226 ###############################################################
 227 # Takes a colour string and returns an ANSI escape sequence
 228 # (unless --no-syntax-highlighting is used).
 229 # XXX: The Rolling Stones reference has to go.
 230 ###############################################################
 231
 232     my $colour = shift;
 233
 234     return "" if cli_option_is_set('no-syntax-highlighting');
 235
 236     my %light = (
 237         black       => 0,
 238         red         => 0,
 239         green       => 0,
 240         brown       => 0,
 241         blue        => 0,
 242         purple      => 0,
 243         cyan        => 0,
 244         light_gray  => 0,
 245         gray        => 0,
 246         dark_gray   => 1,
 247         light_red   => 1,
 248         light_green => 1,
 249         yellow      => 1,
 250         light_blue  => 1,
 251         pink        => 1,
 252         light_cyan  => 1,
 253         white       => 1,
 254     );
 255
 256     my %text = (
 257         black       => 30,
 258         red         => 31,
 259         green       => 32,
 260         brown       => 33,
 261         blue        => 34,
 262         purple      => 35,
 263         cyan        => 36,
 264         gray        => 37,
 265         light_gray  => 37,
 266         dark_gray   => 30,
 267         light_red   => 31,
 268         light_green => 32,
 269         yellow      => 33,
 270         light_blue  => 34,
 271         pink        => 35,
 272         light_cyan  => 36,
 273         white       => 37,
 274     );
 275
 276     my $bg_code = get_background();
 277     my $colour_code;
 278     our $default = default_colours();
 279
 280     if (defined($text{$colour})) {
 281         $colour_code  = ESCAPE;
 282         $colour_code .= $text{$colour};
 283         $colour_code .= ";";
 284         $colour_code .= $light{$colour} ? "1" : "2";
 285         $colour_code .= ";";
 286         $colour_code .= $bg_code;
 287         $colour_code .= "m";
 288         debug_message $colour . " is \'" . $colour_code . $colour . $default . "\'" if DEBUG_PAINT_IT;
 289
 290     } elsif ($colour =~ /reset/) {
 291
 292         $colour_code = default_colours();
 293
 294     } else {
 295
 296         die "What's $colour supposed to mean?\n";
 297     }
 298
 299     return $colour_code;
 300 }
 301
 302 sub get_semantic_html_markup($) {
 303 ###############################################################
 304 # Takes a string and returns a span element
 305 ###############################################################
 306
 307     my $type = shift;
 308     my $code;
 309
 310     if ($type =~ /Standard/) {
 311         $code = '</span>';
 312     } else {
 313         $type = lc($type);
 314         $code = '<span title="' . $type . '" class="' . $type . '">';
 315     }
 316
 317     return $code;
 318 }
 319
 320 sub cli_option_is_set($) {
 321
 322     our %cli_options;
 323     my $cli_option = shift;
 324
 325     die "Unknown CLI option: $cli_option" unless defined $cli_options{$cli_option};
 326
 327     return $cli_options{$cli_option};
 328 }
 329
 330 sub get_html_title() {
 331
 332     our %cli_options;
 333     return $cli_options{'title'};
 334
 335 }
 336
 337 sub init_css_colours() {
 338
 339     our %css_colours = (
 340         black       => "000",
 341         red         => "F00",
 342         green       => "0F0",
 343         brown       => "C90",
 344         blue        => "0F0",
 345         purple      => "F06", # XXX: wrong
 346         cyan        => "F09", # XXX: wrong
 347         light_gray  => "999",
 348         gray        => "333",
 349         dark_gray   => "222",
 350         light_red   => "F33",
 351         light_green => "33F",
 352         yellow      => "FF0",
 353         light_blue  => "30F",
 354         pink        => "F0F",
 355         light_cyan  => "66F",
 356         white       => "FFF",
 357     );
 358 }
 359
 360 sub get_css_colour($) {
 361
 362    our %css_colours;
 363    my $colour = shift;
 364
 365    die "What's $colour supposed to mean?\n" unless defined($css_colours{$colour});
 366
 367    return '#' . $css_colours{$colour};
 368 }
 369
 370 sub get_css_line($) {
 371
 372     my $class = shift;
 373     my $css_line;
 374
 375     $css_line .= '.' . lc($class) . ' {'; # XXX: lc() shouldn't be necessary
 376     die "What's $class supposed to mean?\n" unless defined($h_colours{$class});
 377     $css_line .= 'color:' . get_css_colour($h_colours{$class}) . ';';
 378     $css_line .= 'background-color:' . get_css_colour(DEFAULT_BACKGROUND) . ';';
 379     $css_line .= '}' . "\n";
 380
 381     return $css_line;
 382 }
 383
 384 sub get_css_line_for_colour($) {
 385
 386     my $colour = shift;
 387     my $css_line;
 388
 389     $css_line .= '.' . lc($colour) . ' {'; # XXX: lc() shouldn't be necessary
 390     $css_line .= 'color:' . get_css_colour($colour) . ';';
 391     $css_line .= 'background-color:' . get_css_colour(DEFAULT_BACKGROUND) . ';';
 392     $css_line .= '}' . "\n";
 393
 394     return $css_line;
 395 }
 396
 397 # XXX: Wrong solution
 398 sub get_missing_css_lines() {
 399
 400     my $css_line;
 401
 402     $css_line .= '.' . 'default' . ' {';
 403     $css_line .= 'color:' . HEADER_DEFAULT_COLOUR . ';';
 404     $css_line .= 'background-color:' . get_css_colour(DEFAULT_BACKGROUND) . ';';
 405     $css_line .= '}' . "\n";
 406
 407     return $css_line;
 408 }
 409
 410 sub get_css() {
 411
 412     our %css_colours; #XXX: Wrong solution
 413
 414     my $css = '';
 415
 416     $css .= '.privoxy-log {';
 417     $css .= 'color:' . get_css_colour(DEFAULT_TEXT_COLOUR) . ';';
 418     $css .= 'background-color:' . get_css_colour(DEFAULT_BACKGROUND) . ';';
 419     $css .= '}' . "\n";
 420
 421     foreach my $key (keys %h_colours) {
 422
 423         next if ($h_colours{$key} =~ m/reset/); #XXX: Wrong solution.
 424         $css .= get_css_line($key);
 425
 426     }
 427
 428     foreach my $colour (keys %css_colours) {
 429
 430         $css .= get_css_line_for_colour($colour);
 431
 432     }
 433
 434     $css .= get_missing_css_lines(); #XXX: Wrong solution
 435
 436     return $css;
 437 }
 438
 439 sub print_intro() {
 440
 441     my $intro = '';
 442
 443     if (cli_option_is_set('html-output')) {
 444
 445         my $title = get_html_title();
 446
 447         $intro .= '<html><head>';
 448         $intro .= '<title>' . $title . '</title>';
 449         $intro .= '<style>' . get_css() . '</style>' unless cli_option_is_set('no-embedded-css');
 450         $intro .= '</head><body>';
 451         $intro .= '<h1>' . $title . '</h1><p class="privoxy-log">';
 452
 453         print $intro;
 454     }
 455 }
 456
 457 sub print_outro() {
 458
 459     my $outro = '';
 460
 461     if (cli_option_is_set('html-output')) {
 462
 463         $outro = '</p></body></html>';
 464         print $outro;
 465
 466     }
 467 }
 468
 469 sub get_line_end() {
 470     return cli_option_is_set('html-output') ? "<br>\n" : "\n";
 471 }
 472
 473 sub get_colour_html_markup($) {
 474 ###############################################################
 475 # Takes a colour string a span element. XXX: WHAT?
 476 # XXX: This function shouldn't be necessary, the
 477 # markup should always be semantically correct.
 478 ###############################################################
 479
 480     my $type = shift;
 481     my $code;
 482
 483     if ($type =~ /Standard/) {
 484         $code = '</span>';
 485     } else {
 486         $code = '<span class="' . lc($type) . '">';
 487     }
 488
 489     return $code;
 490 }
 491
 492 sub default_colours() {
 493     # XXX: Properly
 494     our $bg_code;
 495     return reset_colours();
 496 }
 497
 498 sub show_colours() {
 499     # XXX: Implement
 500 }
 501
 502 sub reset_colours() {
 503     return ESCAPE . "0m";
 504 }
 505
 506 sub set_background($) {
 507
 508     my $colour = shift;
 509     our $bg_code;
 510     my %backgrounds = (
 511               black       => "40",
 512               red         => "41",
 513               green       => "42",
 514               brown       => "43",
 515               blue        => "44",
 516               magenta     => "45",
 517               cyan        => "46",
 518               white       => "47",
 519               default     => "49",
 520     );
 521
 522     if (defined($backgrounds{$colour})) {
 523         $bg_code = $backgrounds{$colour};
 524     } else {
 525         die "Invalid background colour: " . $colour;
 526     }
 527 }
 528
 529 sub get_background() {
 530     return our $bg_code;
 531 }
 532
 533 sub prepare_highlight_hash($) {
 534     my $ref = shift;
 535
 536     foreach my $key (keys %$ref) {
 537         $$ref{$key} = $html_output_mode ?
 538             get_semantic_html_markup($key) :
 539             paint_it($$ref{$key});
 540     }
 541 }
 542
 543 sub prepare_colour_array($) {
 544     my $ref = shift;
 545
 546     foreach my $i (0 ... @$ref - 1) {
 547         $$ref[$i] = $html_output_mode ?
 548             get_colour_html_markup($$ref[$i]) :
 549             paint_it($$ref[$i]);
 550     }
 551 }
 552
 553 sub found_unknown_content($) {
 554
 555     my $unknown = shift;
 556     my $message;
 557
 558     return unless cli_option_is_set('strict-checks');
 559
 560     return if ($unknown =~ /\[too long, truncated\]$/);
 561
 562     $message = "found_unknown_content: Don't know how to highlight: ";
 563     # Break line so the log file can later be parsed as Privoxy log file again
 564     $message .= '"' . $unknown . '"' . " in:\n";
 565     $message .= $req{$t}{'log-message'};
 566     debug_message($message);
 567     log_parse_error($req{$t}{'log-message'});
 568
 569     die "Unworthy content parser" if PUNISH_MISSING_LOG_KNOWLEDGE_WITH_DEATH;
 570 }
 571
 572 sub log_parse_error($) {
 573
 574     my $message = shift;
 575
 576     if (LOG_UNPARSED_LINES_TO_EXTRA_FILE) {
 577         open(my $errorlog_fd, ">>", ERROR_LOG_FILE) || die "Writing " . ERROR_LOG_FILE . " failed";
 578         print $errorlog_fd $message;
 579         close($errorlog_fd);
 580     }
 581 }
 582
 583 sub debug_message(@) {
 584     my @message = @_;
 585
 586     print $h{'debug'} . "@message" . $h{'Standard'} . "\n";
 587 }
 588
 589 ################################################################################
 590 # highlighter functions that aren't loglevel-specific
 591 ################################################################################
 592
 593 sub h($) {
 594
 595     # Get highlight marker
 596     my $highlight = shift; # XXX: Stupid name;
 597     my $result = '';
 598     my $message;
 599
 600     if (defined($highlight)) {
 601
 602         $result = $h{$highlight};
 603
 604     } else {
 605
 606         $message = "h: Don't recognize highlighter $highlight.";
 607         debug_message($message);
 608         log_parser_error($message);
 609         die "Unworthy highlighter function" if PUNISH_MISSING_HIGHLIGHT_KNOWLEDGE_WITH_DEATH;
 610     }
 611
 612     return $result;
 613 }
 614
 615 sub highlight_known_headers($) {
 616
 617     my $content = shift;
 618
 619     debug_message("Searching $content for things to highlight.") if DEBUG_HEADER_HIGHLIGHTING;
 620
 621     if ($content =~ m/(?<=\s)($header_highlight_regex):/) {
 622         my $header = $1;
 623         $content =~ s@(?<=[\s|'])($header)(?=:)@$header_colours{$header}$1$h{'Standard'}@ig;
 624         debug_message("Highlighted '$header' in '$content'") if DEBUG_HEADER_HIGHLIGHTING;
 625     }
 626
 627     return $content;
 628 }
 629
 630 sub highlight_matched_request_line($$) {
 631
 632     my $result = shift; # XXX: Stupid name;
 633     my $regex = shift;
 634     if ($result =~ m@(.*)($regex)(.*)@) {
 635         $result = $1 . highlight_request_line($2) . $3
 636     }
 637     return $result;
 638 }
 639
 640 sub highlight_request_line($) {
 641
 642     my $rl = shift;
 643     my ($method, $url, $http_version);
 644
 645     #GET http://images.sourceforge.net/sfx/icon_warning.gif HTTP/1.1
 646     if ($rl =~ m/Invalid request/) {
 647
 648         $rl = h('invalid-request') . $rl . h('Standard');
 649
 650     } elsif ($rl =~ m/^([-\w]+) (.*) (HTTP\/\d+\.\d+)/) {
 651
 652         # XXX: might not match in case of HTTP method fuzzing.
 653         # XXX: save these: ($method, $path, $http_version) = ($1, $2, $3);
 654         $rl =~ s@^(\w+)@$h{'method'}$1$h{'Standard'}@;
 655         if ($rl =~ /http:\/\//) {
 656             $rl = highlight_matched_url($rl, '[^\s]*(?=\sHTTP)');
 657         } else {
 658             $rl = highlight_matched_pattern($rl, 'request_', '[^\s]*(?=\sHTTP)');
 659         }
 660
 661         $rl =~ s@(HTTP\/\d\.\d)$@$h{'http-version'}$1$h{'Standard'}@;
 662
 663     } elsif ($rl =~ m/\.\.\. \[too long, truncated\]$/) {
 664
 665         $rl =~ s@^(\w+)@$h{'method'}$1$h{'Standard'}@;
 666         $rl = highlight_matched_url($rl, '[^\s]*(?=\.\.\.)');
 667
 668     } elsif ($rl =~ m/^ $/) {
 669
 670         $rl = h('error') . "No request line specified!" . h('Standard');
 671
 672     } else {
 673
 674         debug_message ("Can't parse request line: $rl");
 675
 676     }
 677
 678     return $rl;
 679 }
 680
 681 sub highlight_response_line($) {
 682
 683     my $rl = shift;
 684     my ($http_version, $status_code, $status_message);
 685
 686     #HTTP/1.1 200 OK
 687     #ICY 200 OK
 688
 689     # TODO: Mark different status codes differently
 690
 691     if ($rl =~ m/((?:HTTP\/\d\.\d|ICY)) (\d+) (.*)/) {
 692         ($http_version, $status_code, $status_message) = ($1, $2, $3);
 693     } else {
 694         debug_message ("Can't parse response line: $rl") and die 'Fix this';
 695     }
 696
 697     # Rebuild highlighted
 698     $rl= "";
 699     $rl .= h('http-version') . $http_version . h('Standard');
 700     $rl .= " ";
 701     $rl .= h('status-code') . $status_code . h('Standard');
 702     $rl .= " ";
 703     $rl .= h('status-message') . $status_message . h('Standard');
 704
 705     return $rl;
 706 }
 707
 708 sub highlight_matched_url($$) {
 709
 710     my $result = shift; # XXX: Stupid name;
 711     my $regex = shift;
 712
 713     #print "Got $result, regex ($regex)\n";
 714
 715     if ($result =~ m@(.*?)($regex)(.*)@) {
 716         $result = $1 . highlight_url($2) . $3;
 717         #print "Now the result is $result\n";
 718     }
 719
 720     return $result;
 721 }
 722
 723 sub highlight_matched_host($$) {
 724
 725     my ($result, $regex) = @_; # XXX: result ist stupid name;
 726
 727     if ($result =~ m@(.*?)($regex)(.*)@) {
 728         $result = $1 . $h{host} . $2 . $h{Standard} . $3;
 729     }
 730
 731     return $result;
 732 }
 733
 734 sub highlight_matched_pattern($$$) {
 735
 736     my $result = shift; # XXX: Stupid name;
 737     my $key = shift;
 738     my $regex = shift;
 739
 740     die "Unknown key $key" unless defined $h{$key};
 741
 742     if ($result =~ m@(.*?)($regex)(.*)@) {
 743         $result = $1 . h($key) . $2 . h('Standard') . $3;
 744     }
 745
 746     return $result;
 747 }
 748
 749 sub highlight_matched_path($$) {
 750
 751     my $result = shift; # XXX: Stupid name;
 752     my $regex = shift;
 753
 754     if ($result =~ m@(.*?)($regex)(.*)@) {
 755         $result = $1 . h('path') . $2 . h('Standard') . $3;
 756     }
 757
 758     return $result;
 759 }
 760
 761 sub highlight_url($) {
 762
 763     my $url = shift;
 764
 765     if ($html_output_mode) {
 766
 767         $url = '<a href="' . $url . '">' . $url . '</a>';
 768
 769     } else {
 770
 771         $url = h('URL') . $url . h('Standard');
 772
 773     }
 774
 775     return $url;
 776 }
 777
 778 sub update_header_highlight_regex($) {
 779
 780     my $header = shift;
 781     my $headers = join ('|', keys %header_colours);
 782
 783     $header_highlight_regex = qr/$headers/;
 784     print "Registering '$header'\n" if DEBUG_HEADER_HIGHLIGHTING;
 785 }
 786
 787 ################################################################################
 788 # loglevel-specific highlighter functions
 789 ################################################################################
 790
 791 sub handle_loglevel_header($) {
 792
 793     my $c = shift;
 794
 795     if ($c =~ /^scan:/) {
 796
 797         if ($c =~ m/^scan: ([^: ]+):/) {
 798
 799             # Register new headers
 800             # scan: Accept: image/png,image/*;q=0.8,*/*;q=0.5
 801             my $header = $1;
 802             if (!defined($header_colours{$header}) and $header =~ /^[\d\w-]*$/) {
 803                 debug_message "Registering previously unknown header $1" if DEBUG_HEADER_REGISTERING;
 804
 805                 if (REGISTER_HEADERS_WITH_THE_SAME_COLOUR) {
 806                     $header_colours{$header} =  $header_colours{'Default'};
 807                 } else {
 808                     $header_colours{$header} = $all_colours[$header_colour_index % @all_colours];
 809                     $header_colour_index++;
 810                 }
 811                 update_header_highlight_regex($header);
 812             }
 813
 814         } elsif ($c =~ m/^(scan: )(\w+ .+ HTTP\/\d\.\d)/) {
 815
 816             # scan: GET http://p.p/ HTTP/1.1
 817             $c = $1 . highlight_request_line($2);
 818
 819         } elsif ($c =~ m/^(scan: )((?:HTTP\/\d\.\d|ICY) (\d+) (.*))/) {
 820
 821             # scan: HTTP/1.1 200 OK
 822             $req{$t}{'response_line'} = $2;
 823             $req{$t}{'status_code'} = $3;
 824             $req{$t}{'status_message'} = $4;
 825             $c = $1 . highlight_response_line($req{$t}{'response_line'});
 826         }
 827
 828     } elsif ($c =~ m/^Crunching (?:server|client) header: .* \(contains: ([^\)]*)\)/) {
 829
 830         # Crunching server header: Set-Cookie: trac_form_token=d5308c34e16d15e9e301a456; (contains: Cookie:)
 831         $c =~ s@(?<=contains: )($1)@$h{'crunch-pattern'}$1$h{'Standard'}@;
 832         $c =~ s@(Crunching)@$h{$1}$1$h{'Standard'}@;
 833
 834     } elsif ($c =~ m/^New host is: ([^\s]*)\./) {
 835
 836         # New host is: trac.vidalia-project.net. Crunching Referer: http://www.vidalia-project.net/!
 837         $c = highlight_matched_host($c, '(?<=New host is: )[^\s]+(?=\.)');
 838         $c = highlight_matched_url($c, '(?<=Crunching Referer: )[^\s!]+');
 839
 840     } elsif ($c =~ m/^Text mode enabled by force. (Take cover)!/) {
 841
 842         # Text mode enabled by force. Take cover!
 843         $c =~ s@($1)@$h{'warning'}$1$h{'Standard'}@;
 844
 845     } elsif ($c =~ m/^(New HTTP Request-Line: )(.*)/) {
 846
 847         # New HTTP Request-Line: GET http://www.privoxy.org/ HTTP/1.1
 848         $c = $1 . highlight_request_line($2);
 849
 850     } elsif ($c =~ m/^Adjust(ed)? Content-Length to \d+/) {
 851
 852         # Adjusted Content-Length to 2132
 853         # Adjust Content-Length to 33533
 854         $c =~ s@(?<=Content-Length to )(\d+)@$h{'Number'}$1$h{'Standard'}@;
 855         $c = highlight_known_headers($c);
 856
 857     } elsif ($c =~ m/^Destination extracted from "Host:" header. New request URL:/) {
 858
 859         # Destination extracted from "Host:" header. New request URL: http://www.cccmz.de/~ridcully/blog/
 860         $c = highlight_matched_url($c, '(?<=New request URL: ).*');
 861
 862     } elsif ($c =~ m/^Couldn\'t parse:/) {
 863
 864         # XXX: These should probable be logged with LOG_LEVEL_ERROR
 865         # Couldn't parse: If-Modified-Since: Wed, 21 Mar 2007 16:34:50 GMT (crunching!)
 866         # Couldn't parse: at, 24 Mar 2007 13:46:21 GMT in If-Modified-Since: Sat, 24 Mar 2007 13:46:21 GMT (crunching!)
 867         $c =~ s@^(Couldn\'t parse)@$h{'error'}$1$h{'Standard'}@;
 868
 869     } elsif ($c =~ /^Tagger \'([^\']*)\' added tag \'([^\']*)\'/ or
 870              $c =~ m/^Adding tag \'([^\']*)\' created by header tagger \'([^\']*)\'/) {
 871
 872         # Adding tag 'GET request' created by header tagger 'method-man' (XXX: no longer used)
 873         # Tagger 'revalidation' added tag 'REVALIDATION-REQUEST'. No action bit update necessary.
 874         # Tagger 'revalidation' added tag 'REVALIDATION-REQUEST'. Action bits updated accordingly.
 875
 876         # XXX: Save tag and tagger
 877
 878         $c =~ s@(?<=^Tagger \')([^\']*)@$h{'tagger'}$1$h{'Standard'}@;
 879         $c =~ s@(?<=added tag \')([^\']*)@$h{'tag'}$1$h{'Standard'}@;
 880         $c =~ s@(?<=Action bits )(updated)@$h{'action-bits-update'}$1$h{'Standard'}@;
 881         $no_special_header_highlighting = 1;
 882
 883     } elsif ($c =~ /^Tagger \'([^\']*)\' didn['']t add tag \'([^\']*)\'/) {
 884
 885         # Tagger 'revalidation' didn't add tag 'REVALIDATION-REQUEST'. Tag already present
 886         # XXX: Save tag and tagger
 887
 888         $c =~ s@(?<=^Tagger \')([^\']*)@$h{'tag'}$1$h{'Standard'}@;
 889         $c =~ s@(?<=didn['']t add tag \')([^\']*)@$h{'tagger'}$1$h{'Standard'}@;
 890
 891     } elsif ($c =~ m/^(?:scan:|Randomiz|addh:|Adding:|Removing:|Referer:|Modified:|Accept-Language header|[Cc]ookie)/
 892           or $c =~ m/^(Text mode is already enabled|Denied request with NULL byte|Replaced:|add-unique:)/
 893           or $c =~ m/^(Crunched (incoming|outgoing) cookie|Suppressed offer|Accepted the client)/
 894           or $c =~ m/^(addh-unique|Referer forged to)/
 895           or $c =~ m/^Downgraded answer to HTTP\/1.0/
 896           or $c =~ m/^Parameter: \+hide-referrer\{[^\}]*\} is a bad idea, but I don\'t care./
 897           or $c =~ m/^Referer (?:overwritten|replaced) with: Referer: / #XXX: should this be highlighted?
 898           or $c =~ m/^Referer crunched!/
 899           or $c =~ m/^crunched x-forwarded-for!/
 900           or $c =~ m/^crunched From!/
 901           or $c =~ m/^ modified$/
 902           or $c =~ m/^Content filtering is enabled. Crunching:/
 903           or $c =~ m/^force-text-mode overruled the client/
 904           or $c =~ m/^Server time in the future\./
 905           or $c =~ m/^content-disposition header crunched and replaced with:/i
 906           or $c =~ m/^Reducing white space in /
 907           or $c =~ m/^Ignoring single quote in /
 908           or $c =~ m/^Converting tab to space in /
 909           or $c =~ m/A HTTP\/1\.1 response without/
 910           or $c =~ m/Disabled filter mode on behalf of the client/
 911           or $c =~ m/Keeping the (?:server|client) header /
 912           or $c =~ m/Content modified with no Content-Length header set/
 913           or $c =~ m/^Appended client IP address to/
 914           or $c =~ m/^Removing 'Connection: close' to imply keep-alive./
 915           or $c =~ m/^keep-alive support is disabled/
 916           or $c =~ m/^Continue hack in da house/
 917           or $c =~ m/^Merged multiple header lines to:/
 918           or $c =~ m/^Added header: /
 919           or $c =~ m/^Enlisting (?:sorted|left-over) header/
 920           or $c =~ m/^Multiple Content-Type headers detected. Removing and ignoring: Content-Type:/
 921             )
 922     {
 923         # XXX: Some of these may need highlighting
 924
 925         # Modified: User-Agent: Mozilla/5.0 (X11; U; SunOS i86pc; pl-PL; rv:1.8.1.1) Gecko/20070214 Firefox/2.0.0.1
 926         # Accept-Language header crunched and replaced with: Accept-Language: pl-pl
 927         # cookie 'Set-Cookie: eZSessionCookie=07bfec287c197440d299f81580593c3d; \
 928         #  expires=Thursday, 12-Apr-07 15:16:18 GMT; path=/' send by \
 929         #  http://wirres.net/article/articleview/4265/1/6/ appears to be using time format 1 (XXX: gone with the wind)
 930         # Cookie rewritten to a temporary one: Set-Cookie: NSC_gffe-iuuq-mc-wtfswfs=8efb33a53660;path=/
 931         # Text mode is already enabled
 932         # Denied request with NULL byte(s) turned into line break(s)
 933         # Replaced: 'Connection: Yo, home to Bel Air' with 'Connection: close'
 934         # addh-unique: Host: people.freebsd.org
 935         # Suppressed offer to compress content
 936         # Crunched incoming cookie -- yum!
 937         # Accepted the client's request to fetch without filtering.
 938         # Crunched outgoing cookie: Cookie: PREF=ID=6cf0abd347b30262:TM=1173357617:LM=1173357617:S=jZypyyJ7LPiwFi1_
 939         # addh-unique: Host: subkeys.pgp.net:11371
 940         # Referer forged to: Referer: http://10.0.0.1/
 941         # Downgraded answer to HTTP/1.0
 942         # Parameter: +hide-referrer{pille-palle} is a bad idea, but I don't care.
 943         # Referer overwritten with: Referer: pille-palle
 944         # Referer replaced with: Referer: pille-palle
 945         # crunched x-forwarded-for!
 946         # crunched From!
 947         #  modified # XXX: pretty stupid log message
 948         # Content filtering is enabled. Crunching: 'Range: 1234-5678' to prevent range-mismatch problems
 949         # force-text-mode overruled the client's request to fetch without filtering!
 950         # Server time in the future.
 951         # content-disposition header crunched and replaced with: content-disposition: filename=baz
 952         # Content-Disposition header crunched and replaced with: content-disposition: filename=baz
 953         # Reducing white space in 'X-LWS-Test: "This  is  quoted" this is not "this  is  " but " this again   is  not'
 954         # Ignoring single quote in 'X-LWS-Test: "This  is  quoted" this is not "this  is  " but "  this again   is  not'
 955         # Converting tab to space in 'X-LWS-Test:   "This  is  quoted" this   is  not "this  is  "  but  "\
 956         #  this again   is  not'
 957         # A HTTP/1.1 response without Connection header implies keep-alive.
 958         # Disabled filter mode on behalf of the client.
 959         # Keeping the server header 'Connection: keep-alive' around.
 960         # Keeping the client header 'Connection: close' around. The connection will not be kept alive.
 961         # Keeping the client header 'Connection: keep-alive' around. The connection will be kept alive if possible.
 962         # Content modified with no Content-Length header set. Creating a fake one for adjustment later on.
 963         # Appended client IP address to X-Forwarded-For: 10.0.0.2, 10.0.0.1
 964         # Removing 'Connection: close' to imply keep-alive.
 965         # keep-alive support is disabled. Crunching: Keep-Alive: 300.
 966         # Continue hack in da house.
 967         # Merged multiple header lines to: 'X-FORWARDED-PROTO: http X-HOST: 127.0.0.1'
 968         # Added header: Content-Encoding: deflate
 969         # Enlisting sorted header User-Agent: Mozilla/5.0 (X11; SunOS i86pc; rv:10.0.3) Gecko/20100101 Firefox/10.0.3
 970         # Enlisting left-over header Connection: close
 971         # Multiple Content-Type headers detected. Removing and ignoring: Content-Type: text/html
 972
 973     } elsif ($c =~ m/^scanning headers for:/) {
 974
 975         return '' unless SHOW_SCAN_INTRO;
 976
 977     } elsif ($c =~ m/^[Cc]runch(ing|ed)|crumble crunched:/) {
 978         # crunched User-Agent!
 979         # Crunching: Content-Encoding: gzip
 980
 981         $c =~ s@(Crunching|crunched)@$h{$1}$1$h{'Standard'}@;
 982
 983     } elsif ($c =~ m/^Offending request data with NULL bytes turned into \'°\' characters:/) {
 984
 985         # Offending request data with NULL bytes turned into '°' characters: °°n°°(°°°
 986
 987         $c = h('warning') . $c . h('Standard');
 988
 989     } elsif ($c =~ m/^(Transforming \")(.*?)(\" to \")(.*?)(\")/) {
 990
 991         # Transforming "Proxy-Authenticate: Basic realm="Correos Proxy Server"" to\
 992         #  "Proxy-Authenticate: Basic realm="Correos Proxy Server""
 993
 994        $c =~ s@(?<=^Transforming \")(.*)(?=\" to)@$h{'Header'}$1$h{'Standard'}@;
 995        $c =~ s@(?<=to \")(.*)(?=\")@$h{'Header'}$1$h{'Standard'}@;
 996
 997     } elsif ($c =~ m/^Removing empty header/) {
 998
 999         # Removing empty header
1000         # Ignore for now
1001
1002     } elsif ($c =~ m/^Content-Type: .* not replaced/) {
1003
1004         # Content-Type: application/octet-stream not replaced. It doesn't look like text.\
1005         #  Enable force-text-mode if you know what you're doing.
1006         # XXX: Could highlight more here.
1007         $c =~ s@(?<=^Content-Type: )(.*)(?= not replaced)@$h{'content-type'}$1$h{'Standard'}@;
1008
1009     } elsif ($c =~ m/^(Server|Client) keep-alive timeout is/) {
1010
1011        # Server keep-alive timeout is 5. Sticking with 10.
1012        # Client keep-alive timeout is 20. Sticking with 10.
1013
1014        $c =~ s@(?<=timeout is )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1015        $c =~ s@(?<=Sticking with )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1016
1017     } elsif ($c =~ m/^Reducing keep-alive timeout/) {
1018
1019        # Reducing keep-alive timeout from 60 to 10.
1020
1021        $c =~ s@(?<= from )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1022        $c =~ s@(?<= to )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1023
1024     } elsif ($c =~ m/^Killed all-caps Host header line: HOST:/) {
1025
1026        # Killed all-caps Host header line: HOST: bestproxydb.com
1027        $c = highlight_matched_host($c, '(?<=HOST: )[^\s]+');
1028        $c = highlight_matched_pattern($c, 'HOST', 'HOST');
1029
1030     } else {
1031
1032         found_unknown_content($c);
1033     }
1034
1035     # Highlight headers
1036     unless ($c =~ m/^Transforming/) {
1037         $c = highlight_known_headers($c) unless $no_special_header_highlighting;
1038     }
1039
1040     return $c;
1041 }
1042
1043 sub handle_loglevel_re_filter($) {
1044
1045     my $content = shift;
1046     my $c = $content;
1047     my $key;
1048
1049     if ($c =~ m/^(?:re_)?filtering ([^\s]+) \(size (\d+)\) with (?:filter )?\'?([^\s]+?)\'? produced (\d+) hits \(new size (\d+)\)/) {
1050
1051         # XXX: only the second version gets highlighted properly.
1052         # re_filtering www.lfk.de/favicon.ico (size 209) with filter untrackable-hulk produced 0 hits (new size 209).
1053         # filtering aci.blogg.de/ (size 37988) with 'blogg.de' produced 3 hits (new size 38057)
1054         $req{$t}{'content_source'} = $1;
1055         $req{$t}{'content_size'}   = $2;
1056         $req{$t}{'content_filter'} = $3;
1057         $req{$t}{'content_hits'}   = $4;
1058         $req{$t}{'new_content_size'} = $5;
1059         $req{$t}{'content_size_change'} = $req{$t}{'new_content_size'} - $req{$t}{'content_size'};
1060         #return '' if ($req{$t}{'content_hits'} == 0 && !cli_option_is_set('show-ineffective-filters'));
1061         if ($req{$t}{'content_hits'} == 0 and
1062             not (cli_option_is_set('show-ineffective-filters')
1063                  or ($req{$t}{'content_filter'} =~ m/^privoxy-filter-test$/))) {
1064                 return '';
1065         }
1066
1067         $c =~ s@(?<=\(size )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1068         $c =~ s@(?<=\(new size )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1069         $c =~ s@(?<=produced )(\d+)(?= hits)@$h{'Number'}$1$h{'Standard'}@;
1070
1071         $c =~ s@([^\s]+?)(\'? produced)@$h{'filter'}$1$h{'Standard'}$2@;
1072         $c = highlight_matched_host($c, '(?<=filtering )[^\s]+');
1073
1074         $c =~ s@\.$@ @;
1075         $c .= "(" . $h{'Number'};
1076         $c .= "+" if ($req{$t}{'content_size_change'} >= 0);
1077         $c .= $req{$t}{'content_size_change'} . $h{'Standard'} . ")";
1078         $content = $c;
1079
1080   } elsif ($c =~ /\.{3}$/
1081         and $c =~ m/^(?:re_)?filtering \'?(.*?)\'? \(size (\d*)\) with (?:filter )?\'?([^\s]*?)\'? ?\.{3}$/) {
1082
1083         # Used by Privoxy 3.0.5 and 3.0.6:
1084         # XXX: Fill in ...
1085         # Used by Privoxy 3.0.7:
1086         # filtering 'Connection: close' (size 17) with 'generic-content-ads' ...
1087
1088         $req{$t}{'filtered_header'} = $1;
1089         $req{$t}{'old_header_size'} = $2;
1090         $req{$t}{'header_filter_name'} = $3;
1091
1092         unless (cli_option_is_set('show-ineffective-filters') or
1093                 $req{$t}{'header_filter_name'} =~ m/^privoxy-filter-test$/) {
1094             return '';
1095         }
1096         $content =~ s@(?<=\(size )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1097         $content =~ s@($req{$t}{'header_filter_name'})@$h{'filter'}$1$h{'Standard'}@;
1098
1099     } elsif ($c =~ m/^ ?\.\.\. ?produced (\d*) hits \(new size (\d*)\)\./) {
1100
1101         # ...produced 0 hits (new size 23).
1102         #... produced 1 hits (new size 54).
1103
1104         $req{$t}{'header_filter_hits'} = $1;
1105         $req{$t}{'new_header_size'} = $2;
1106
1107         unless (cli_option_is_set('show-ineffective-filters') or
1108                 (defined($req{$t}{'header_filter_name'}) and
1109                  $req{$t}{'header_filter_name'} =~ m/^privoxy-filter-test$/)) {
1110
1111             if ($req{$t}{'header_filter_hits'} == 0 and
1112                 not (defined($req{$t}{'header_filter_name'}) and
1113                  $req{$t}{'header_filter_name'} =~ m/^privoxy-filter-test$/)) {
1114                 return '';
1115             }
1116             # Reformat including information from the intro
1117             $c = "'" . h('filter') . $req{$t}{'header_filter_name'} . h('Standard') . "'";
1118             $c .= " hit ";
1119             # XXX: Hide behind constant, it may be interesting if LOG_LEVEL_HEADER isn't enabled as well.
1120             # $c .= $req{$t}{'filtered_header'} . " ";
1121             $c .= h('Number') . $req{$t}{'header_filter_hits'}. h('Standard');
1122             $c .= ($req{$t}{'header_filter_hits'} == 1) ? " time, " : " times, ";
1123
1124             if ($req{$t}{'old_header_size'} !=  $req{$t}{'new_header_size'}) {
1125
1126                 $c .= "changing size from ";
1127                 $c .=  h('Number') . $req{$t}{'old_header_size'} . h('Standard');
1128                 $c .= " to ";
1129                 $c .= h('Number') . $req{$t}{'new_header_size'} . h('Standard');
1130                 $c .= ".";
1131
1132             } else {
1133
1134                 $c .= "keeping the size at " . $req{$t}{'old_header_size'};
1135
1136             }
1137
1138             # Highlight from last line (XXX: What?)
1139             # $c =~ s@(?<=produced )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1140             # $c =~ s@($req{$t}{'header_filter_name'})@$h{'filter'}$1$h{'Standard'}@;
1141
1142         } else {
1143
1144            # XXX: Untested
1145            $c =~ s@(?<=produced )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1146            $c =~ s@(?<=new size )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1147
1148         }
1149         $content = $c;
1150
1151     } elsif ($c =~ m/^(Tagger|Filter) ([^\s]*) has empty joblist. Nothing to do./) {
1152
1153         # Filter privoxy-filter-test has empty joblist. Nothing to do.
1154         # Tagger variable-test has empty joblist. Nothing to do.
1155
1156         $content =~ s@(?<=$1 )([^\s]*)@$h{'filter'}$1$h{'Standard'}@;
1157
1158     } elsif ($c =~ m/^De-chunking successful. Shrunk from (\d+) to (\d+)/) {
1159
1160         $req{$t}{'chunked-size'} = $1;
1161         $req{$t}{'dechunked-size'} = $2;
1162         $req{$t}{'dechunk-change'} = $req{$t}{'dechunked-size'} - $req{$t}{'chunked-size'};
1163
1164         $content .= " (" . h('Number') . $req{$t}{'dechunk-change'} . h('Standard') . ")";
1165
1166         $content =~ s@(?<=from )($req{$t}{'chunked-size'})@$h{'Number'}$1$h{'Standard'}@;
1167         $content =~ s@(?<=to )($req{$t}{'dechunked-size'})@$h{'Number'}$1$h{'Standard'}@;
1168
1169     } elsif ($c =~ m/^Decompression successful. Old size: (\d+), new size: (\d+)./) {
1170
1171         # Decompression successful. Old size: 670, new size: 1166.
1172
1173         $req{$t}{'size-compressed'} = $1;
1174         $req{$t}{'size-decompressed'} = $2;
1175         $req{$t}{'decompression-gain'} = $req{$t}{'size-decompressed'} - $req{$t}{'size-compressed'};
1176
1177         $content =~ s@(?<=Old size: )($req{$t}{'size-compressed'})@$h{'Number'}$1$h{'Standard'}@;
1178         $content =~ s@(?<=new size: )($req{$t}{'size-decompressed'})@$h{'Number'}$1$h{'Standard'}@;
1179
1180         # XXX: Create sub get_percentage()
1181         if ($req{$t}{'size-decompressed'}) {
1182             $req{$t}{'decompression-gain-percent'} =
1183                 $req{$t}{'decompression-gain'} / $req{$t}{'size-decompressed'} * 100;
1184
1185             $content .= " (saved: ";
1186             #$content .= h('Number') . $req{$t}{'decompression-gain'} . h('Standard');
1187             #$content .= "/";
1188             $content .= h('Number') . sprintf("%.2f%%", $req{$t}{'decompression-gain-percent'}) . h('Standard');
1189             $content .= ")";
1190         }
1191
1192     } elsif ($c =~ m/^(Need to de-chunk first)/) {
1193
1194         # Need to de-chunk first
1195         return '' if SUPPRESS_NEED_TO_DE_CHUNK_FIRST;
1196
1197     } elsif ($c =~ m/^(Adding (?:dynamic )?re_filter job)/) {
1198
1199         return ''  if (SUPPRESS_SUCCEEDED_FILTER_ADDITIONS && m/succeeded/);
1200
1201         # Adding re_filter job ...
1202         # Adding dynamic re_filter job s@^(?:\w*)\s+.*\s+HTTP/\d\.\d\s*@IP-ADDRESS: $origin@D\
1203         #  to filter client-ip-address succeeded.
1204
1205     } elsif ($c =~ m/^Compressed content from /) {
1206
1207         # Compressed content from 29258 to 8630 bytes. Compression level: 3
1208         $content =~ s@(?<=from )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1209         $content =~ s@(?<=to )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1210         $content =~ s@(?<=level: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1211
1212     } elsif ($c =~ m/^Reading in filter/) {
1213
1214         return '' unless SHOW_FILTER_READIN_IN;
1215
1216     } elsif ($c =~ m/^Decompression didn't result/) {
1217
1218         # Decompression didn't result in any content.
1219
1220         # Nothing to highlight.
1221
1222     } else {
1223
1224         found_unknown_content($content);
1225
1226     }
1227
1228     return $content;
1229 }
1230
1231 sub handle_loglevel_redirect($) {
1232
1233     my $c = shift;
1234
1235     if ($c =~ m/^Decoding "([^""]*)"/) {
1236
1237          $req{$t}{'original-destination'} = $1;
1238          $c = highlight_matched_path($c, '(?<=Decoding ")[^"]*');
1239          $c =~ s@\"@@g;
1240
1241     } elsif ($c =~ m/^Checking/) {
1242
1243          # Checking /_ylt=A0geu.Z76BRGR9k/**http://search.yahoo.com/search?p=view+odb+presentation+on+freebsd\
1244          #  &ei=UTF-8&xargs=0&pstart=1&fr=moz2&b=11 for redirects.
1245
1246          # TODO: Change colour if really url-decoded
1247          $req{$t}{'decoded-original-destination'} = $1;
1248          $c = highlight_matched_path($c, '(?<=Checking ")[^"]*');
1249          $c =~ s@\"@@g;
1250
1251     } elsif ($c =~ m/^pcrs command "([^""]*)" changed /) {
1252
1253         # pcrs command "s@&from=rss@@" changed \
1254         #  "http://it.slashdot.org/article.pl?sid=07/03/02/1657247&from=rss"\
1255         #  to "http://it.slashdot.org/article.pl?sid=07/03/02/1657247" (1 hit).
1256         $c =~ s@(?<=pcrs command )"([^""]*)"@$h{'filter'}$1$h{'Standard'}@;
1257         $c = highlight_matched_url($c, '(?<=changed ")[^""]*');
1258         $c =~ s@(?<=changed )"([^""]*)"@$1@; # Remove quotes
1259         $c = highlight_matched_url($c, '(?<=to ")[^""]*');
1260         $c =~ s@(?<=to )"([^""]*)"@$1@; # Remove quotes
1261         $c =~ s@(\d+)(?= hits?)@$h{'hits'}$1$h{'Standard'}@;
1262
1263     } elsif ($c =~ m/^pcrs command "([^""]*)" didn\'t change/) {
1264
1265         # pcrs command "s@^http://([^.]+?)/?$@http://www.bing.com/search?q=$1@" didn't \
1266         #  change "http://www.example.org/".
1267         $c =~ s@(?<=pcrs command )"([^""]*)"@$h{'filter'}$1$h{'Standard'}@;
1268         $c = highlight_matched_url($c, '(?<=change ")[^""]*');
1269
1270     } elsif ($c =~ m/(^New URL is: )(.*)/) {
1271
1272         # New URL is: http://it.slashdot.org/article.pl?sid=07/03/04/1511210
1273         # XXX: Use URL highlighter
1274         # XXX: Save?
1275         $c = $1 . h('rewritten-URL') . $2 . h('Standard');
1276
1277     } elsif ($c =~ m/No pcrs command recognized, assuming that/) {
1278         # No pcrs command recognized, assuming that "http://config.privoxy.org/user-manual/favicon.png"\
1279         #  is already properly formatted.
1280         # XXX: assume the same?
1281         $c = highlight_matched_url($c, '(?<=assuming that \")[^"]*');
1282
1283     } elsif ($c =~ m/^Percent-encoding redirect/) {
1284
1285         # Percent-encoding redirect URL: http://www.example.org/\x02
1286         $c = highlight_matched_url($c, '(?<=redirect URL: ).*');
1287
1288     } else {
1289
1290         found_unknown_content($c);
1291
1292     }
1293
1294     return $c;
1295 }
1296
1297 sub handle_loglevel_gif_deanimate($) {
1298
1299     my $content = shift;
1300
1301     if ($content =~ m/Success! GIF shrunk from (\d+) bytes to (\d+)\./) {
1302
1303         my $bytes_from = $1;
1304         my $bytes_to = $2;
1305         # Gif-Deanimate: Success! GIF shrunk from 205 bytes to 133.
1306         $content =~ s@$bytes_from@$h{'Number'}$bytes_from$h{'Standard'}@;
1307         # XXX: Do we need g in case of ($1 == $2)?
1308         $content =~ s@$bytes_to@$h{'Number'}$bytes_to$h{'Standard'}@;
1309
1310     } elsif ($content =~ m/GIF (not) changed/) {
1311
1312         # Gif-Deanimate: GIF not changed.
1313         return '' if SUPPRESS_GIF_NOT_CHANGED;
1314         $content =~ s@($1)@$h{'not'}$1$h{'Standard'}@;
1315
1316     } elsif ($content =~ m/^failed! \(gif parsing\)/) {
1317
1318         # failed! (gif parsing)
1319         # XXX: Replace this error message with something less stupid
1320         $content =~ s@(failed!)@$h{'error'}$1$h{'Standard'}@;
1321
1322     } elsif ($content =~ m/^Need to de-chunk first/) {
1323
1324         # Need to de-chunk first
1325         return '' if SUPPRESS_NEED_TO_DE_CHUNK_FIRST;
1326
1327     } elsif ($content =~ m/^(?:No GIF header found|failed while parsing)/) {
1328
1329         # No GIF header found (XXX: Did I ever commit this?)
1330         # failed while parsing 195 134747048 (XXX: never committed)
1331
1332         # Ignore these for now
1333
1334     } else {
1335
1336         found_unknown_content($content);
1337
1338     }
1339
1340     return $content;
1341 }
1342
1343 sub handle_loglevel_request($) {
1344
1345     my $content = shift;
1346
1347     if ($content =~ m/crunch! /) {
1348
1349         # config.privoxy.org/send-stylesheet crunch! (CGI Call)
1350
1351         # Highlight crunch reasons
1352         foreach my $reason (keys %reason_colours) {
1353             $content =~ s@\(($reason)\)@$reason_colours{$reason}($1)$h{'Standard'}@g;
1354         }
1355         # Highlight request URL domain and ditch 'crunch!'
1356         $content = highlight_matched_pattern($content, 'request_', '[^ ]*(?= crunch!)');
1357         $content =~ s@ crunch!@@;
1358
1359     } elsif ($content =~ m/\[too long, truncated\]$/) {
1360
1361         # config.privoxy.org/edit-actions-submit?f=3&v=1176116716&s=7&Submit=Submit[...]&filter... [too long, truncated]
1362         $content = highlight_matched_pattern($content, 'request_', '^.*(?=\.\.\. \[too long, truncated\]$)');
1363
1364     } elsif ($content =~ m/(.*)/) { # XXX: Pretty stupid
1365
1366         # trac.vidalia-project.net/wiki/Volunteer?format=txt
1367         $content = h('request_') . $content . h('Standard');
1368
1369     } else {  # XXX: Nop
1370
1371         found_unknown_content($content);
1372
1373     }
1374
1375     return $content;
1376 }
1377
1378 sub handle_loglevel_crunch($) {
1379
1380     my $content = shift;
1381
1382     # Highlight crunch reason
1383     foreach my $reason (keys %reason_colours) {
1384         $content =~ s@($reason)@$reason_colours{$reason}$1$h{'Standard'}@g;
1385     }
1386
1387     if ($content =~ m/\[too long, truncated\]$/) {
1388
1389         # Blocked: config.privoxy.org/edit-actions-submit?f=3&v=1176116716&s=7&Submit=Submit\
1390         #  [...]&filter... [too long, truncated]
1391         $content = highlight_matched_pattern($content, 'request_', '^.*(?=\.\.\. \[too long, truncated\]$)');
1392
1393     } else {
1394
1395         # Blocked: http://ads.example.org/
1396         $content = highlight_matched_pattern($content, 'request_', '(?<=: ).*');
1397     }
1398
1399     return $content;
1400 }
1401
1402 sub handle_loglevel_connect($) {
1403
1404     my $c = shift;
1405
1406     if ($c =~ m/^via [^\s]+ to: [^\s]+/) {
1407
1408         # Connect: via 10.0.0.1:8123 to: www.example.org.noconnect
1409
1410         $c = highlight_matched_host($c, '(?<=via )[^\s]+');
1411         $c = highlight_matched_host($c, '(?<=to: )[^\s]+');
1412
1413     } elsif ($c =~ m/^connect to: .* failed: .*/) {
1414
1415         # connect to: www.example.org.noconnect failed: Operation not permitted
1416
1417         $c = highlight_matched_host($c, '(?<=connect to: )[^\s]+');
1418
1419         $c =~ s@(?<=failed: )(.*)@$h{'error'}$1$h{'Standard'}@;
1420
1421     } elsif ($c =~ m/^to ([^\s]*)( successful)?$/) {
1422
1423         # Connect: to www.nzherald.co.nz successful
1424         # Connect: to archiv.radiotux.de
1425
1426         return '' if SUPPRESS_SUCCESSFUL_CONNECTIONS;
1427         $c = highlight_matched_host($c, '(?<=to )[^\s]+');
1428
1429     } elsif ($c =~ m/^to ([^\s]*)$/) {
1430
1431         # Connect: to lists.sourceforge.net:443
1432
1433         $c = highlight_matched_host($c, '(?<=to )[^\s]+');
1434
1435     } elsif ($c =~ m/^[Aa]ccepted connection from .*/ or
1436              $c =~ m/^OK/) {
1437
1438         # Privoxy 3.0.20:
1439         # Accepted connection from 10.0.0.1 on socket 5
1440         # Privoxy between 3.0.20 and 3.0.6:
1441         # accepted connection from 10.0.0.1( on socket 5)?
1442         # Privoxy 3.0.6 and earlier just say:
1443         # OK
1444         $c = highlight_matched_host($c, '(?<=connection from )[^ ]*');
1445         $c = highlight_matched_pattern($c, 'Number', '(?<=socket )\d+');
1446
1447     } elsif ($c =~ m/^Closing client socket/) {
1448
1449         # Closing client socket 5. Keep-alive: 0, Socket alive: 1. Data available: 0.
1450         # Privoxy 3.0.20 and later
1451         # Closing client socket 8. Keep-alive: 1. Socket alive: 0. Data available: 0. \
1452         #  Configuration file change detected: 0. Requests received: 11.
1453
1454         $c = highlight_matched_pattern($c, 'Number', '(?<=socket )\d+');
1455         $c = highlight_matched_pattern($c, 'Number', '(?<=Keep-alive: )\d+');
1456         $c = highlight_matched_pattern($c, 'Number', '(?<=Socket alive: )\d+');
1457         $c = highlight_matched_pattern($c, 'Number', '(?<=available: )\d+');
1458         $c = highlight_matched_pattern($c, 'Number', '(?<=detected: )\d+');
1459         $c = highlight_matched_pattern($c, 'Number', '(?<=received: )\d+');
1460
1461     } elsif ($c =~ m/^write header to: .* failed:/) {
1462
1463         # write header to: 10.0.0.1 failed: Broken pipe
1464
1465         $c = highlight_matched_host($c, '(?<=write header to: )[^\s]*');
1466         $c =~ s@(?<=failed: )(.*)@$h{'Error'}$1$h{'Standard'}@;
1467
1468     } elsif ($c =~ m/^write header to client failed:/) {
1469
1470         # write header to client failed: Broken pipe
1471         # XXX: Stil in use?
1472         $c =~ s@(?<=failed: )(.*)@$h{'Error'}$1$h{'Standard'}@;
1473
1474     } elsif ($c =~ m/^socks4_connect:/) {
1475
1476         # socks4_connect: SOCKS request rejected or failed.
1477         $c =~ s@(?<=socks4_connect: )(.*)@$h{'Error'}$1$h{'Standard'}@;
1478
1479     } elsif ($c =~ m/^Listening for new connections/ or
1480              $c =~ m/^accept connection/) {
1481         # XXX: Highlight?
1482         # Privoxy versions above 3.0.6 say:
1483         # Listening for new connections ...
1484         # earlier versions say:
1485         # accept connection ...
1486         return '';
1487
1488     } elsif ($c =~ m/^accept failed:/) {
1489
1490         $c =~ s@(?<=accept failed: )(.*)@$h{'Error'}$1$h{'Standard'}@;
1491
1492     } elsif ($c =~ m/^Overriding forwarding settings/) {
1493
1494         # Overriding forwarding settings based on 'forward 10.0.0.1:8123'
1495         $c =~ s@(?<=based on \')(.*)(?=\')@$h{'configuration-line'}$1$h{'Standard'}@;
1496
1497     } elsif ($c =~ m/^Denying suspicious CONNECT request from/) {
1498
1499         # Denying suspicious CONNECT request from 10.0.0.1
1500         $c = highlight_matched_host($c, '(?<=from )[^\s]+'); # XXX: not an URL
1501
1502     } elsif ($c =~ m/^socks5_connect:/) {
1503
1504         $c =~ s@(?<=socks5_connect: )(.*)@$h{'error'}$1$h{'Standard'}@;
1505
1506     } elsif ($c =~ m/^Created new connection to/) {
1507
1508         # Created new connection to www.privoxy.org:80 on socket 11.
1509         $c = highlight_matched_host($c, '(?<=connection to )[^\s]+');
1510         $c =~ s@(?<=on socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1511
1512     } elsif ($c =~ m/^Found reusable socket/) {
1513
1514         # Found reusable socket 9 for www.privoxy.org:80 in slot 0.
1515         # 3.0.15 and later:
1516         # Found reusable socket 8 for www.privoxy.org:80 in slot 2.\
1517         #  Timestamp made 0 seconds ago. Timeout: 1. Latency: 0.
1518         $c =~ s@(?<=Found reusable socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1519         $c = highlight_matched_host($c, '(?<=for )[^\s]+');
1520         $c =~ s@(?<=in slot )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1521         $c =~ s@(?<=made )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1522         $c =~ s@(?<=Timeout: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1523         $c =~ s@(?<=Latency: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1524
1525     } elsif ($c =~ m/^Marking open socket/) {
1526
1527         # Marking open socket 9 for www.privoxy.org:80 in slot 0 as unused.
1528         $c =~ s@(?<=Marking open socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1529         $c = highlight_matched_host($c, '(?<=for )[^\s]+');
1530         $c =~ s@(?<=in slot )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1531
1532     } elsif ($c =~ m/^No reusable/) {
1533
1534         # No reusable socket for addons.mozilla.org:443 found. Opening a new one.
1535         $c = highlight_matched_host($c, '(?<=for )[^\s]+');
1536
1537     } elsif ($c =~ m/^(Remembering|Forgetting) socket/) {
1538
1539         # Remembering socket 13 for www.privoxy.org:80 in slot 0.
1540         # Forgetting socket 38 for www.privoxy.org:80 in slot 5.
1541
1542         $c =~ s@(?<=socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1543         $c = highlight_matched_host($c, '(?<=for )[^\s]+');
1544         $c =~ s@(?<=in slot )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1545
1546     } elsif ($c =~ m/^Socket/) {
1547
1548         # Socket 16 already forgotten or never remembered.
1549         $c =~ s@(?<=Socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1550
1551     } elsif ($c =~ m/^The connection to/) {
1552
1553         # The connection to www.privoxy.org:80 in slot 6 timed out. Closing socket 19. Timeout is: 61.
1554         # 3.0.15 and later:
1555         # The connection to 1.bp.blogspot.com:80 in slot 0 timed out. Closing socket 5.\
1556         #  Timeout is: 1. Assumed latency: 4.
1557         # The connection to 10.0.0.1:80 in slot 0 is no longer usable. Closing socket 4.
1558         $c = highlight_matched_host($c, '(?<=connection to )[^\s]+');
1559         $c =~ s@(?<=in slot )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1560         $c =~ s@(?<=Closing socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1561         $c =~ s@(?<=Timeout is: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1562         $c =~ s@(?<=Assumed latency: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1563
1564     } elsif ($c =~ m/^Stopped waiting for the request line/ or
1565              $c =~ m/^No request line on socket \d received in time/ or
1566              $c =~ m/^The client side of the connection on socket \d/) {
1567
1568         # Stopped waiting for the request line. Timeout: 121.
1569         # Privoxy 3.0.19 and later:
1570         # No request line on socket 5 received in time. Timeout: 1.
1571         # The client side of the connection on socket 5 got closed \
1572         #  without sending a complete request line.
1573         $c =~ s@(?<=Timeout: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1574         $c =~ s@(?<=socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1575
1576     } elsif ($c =~ m/^Waiting for \d/) {
1577
1578         # Waiting for 1 connections to timeout.
1579         $c =~ s@(?<=^Waiting for )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1580
1581     } elsif ($c =~ m/^Initialized/) {
1582
1583         # Initialized 20 socket slots.
1584         $c =~ s@(?<=Initialized )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1585
1586     } elsif ($c =~ m/^Done reading from server/) {
1587
1588         # Done reading from server. Expected content length: 24892. \
1589         #  Actual content length: 24892. Most recently received: 4412.
1590         # 3.0.15 and later:
1591         # Done reading from server. Expected content length: 24892. \
1592         #  Actual content length: 24892. Bytes most recently read: 4412.
1593         # Done reading from server. Content length: 6018 as expected. \
1594         #  Bytes most recently read: 294.
1595         $c =~ s@(?<=ontent length: )(\d+)@$h{'Number'}$1$h{'Standard'}@g;
1596         $c =~ s@(?<=received: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1597         $c =~ s@(?<=read: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1598
1599     } elsif ($c =~ m/^Continuing buffering (?:server )?headers/) {
1600
1601         # Continuing buffering headers. byte_count: 19. header_offset: 517. len: 536.
1602         $c =~ s@(?<=byte_count: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1603         $c =~ s@(?<=header_offset: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1604         $c =~ s@(?<=len: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1605         # 3.0.15 up to 3.0.19:
1606         # Continuing buffering headers. Bytes most recently read: 498.
1607         $c =~ s@(?<=read: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1608         # 3.0.20 and later:
1609         # Continuing buffering server headers from socket 5. Bytes most recently read: 498.
1610         $c =~ s@(?<=socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1611
1612     } elsif ($c =~ m/^Received \d+ bytes while/) {
1613
1614         # Received 206 bytes while expecting 12103.
1615         $c =~ s@(?<=Received )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1616         $c =~ s@(?<=expecting )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1617
1618     } elsif ($c =~ m/^(Rejecting c|C)onnection from/) {
1619
1620         # Connection from 81.163.28.218 dropped due to ACL
1621         # Rejecting connection from 178.63.152.227. Maximum number of connections reached.
1622         # Connection from 192.168.2.1 on 127.0.1.1:8118 (socket 3) dropped due to ACL
1623         $c = highlight_matched_host($c, '(?<=onnection from )[\d.:]+');
1624         $c = highlight_matched_host($c, '(?<=on )[\d.:]+');
1625         $c =~ s@(?<=socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1626
1627     } elsif ($c =~ m/^(?:Reusing|Closing) server socket / or
1628              $c =~ m/^No additional client request/) {
1629
1630         # Reusing server socket 4. Opened for 10.0.0.1.
1631         # Closing server socket 2. Opened for 10.0.0.1.
1632         # No additional client request received in time. \
1633         #  Closing server socket 4, initially opened for 10.0.0.1.
1634         # No additional client request received in time on socket 29.
1635         # Privoxy 3.0.20 and later
1636         # Reusing server socket 7 connected to www.privoxy.org. Total requests: 2.
1637         # Closing server socket 6 connected to d.asset.soup.io. Keep-alive: 0.\
1638         #  Tainted: 1. Socket alive: 1. Timeout: 60. Configuration file change detected: 0.
1639         # Reusing server socket 35 connected to nl.wikipedia.org. Requests already sent: 5.
1640
1641         $c =~ s@(?<= socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1642         $c = highlight_matched_host($c, '(?<=for )[^\s]+(?=\.)');
1643         $c = highlight_matched_host($c, '(?<=connected to )[^\s]+(?=\.)');
1644         for my $number_pattern ('requests', 'Keep-alive', 'Tainted', ' alive', 'Timeout', 'detected') {
1645             $c = highlight_matched_pattern($c, 'Number', '(?<='. $number_pattern . ': )\d+');
1646         }
1647         $c =~ s@(?<=already sent: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1648
1649     } elsif ($c =~ m/^Connected to /) {
1650
1651         # Connected to tor-jail[10.0.0.2]:9050.
1652
1653         $c = highlight_matched_host($c, '(?<=\[)[^\]]+');
1654         $c = highlight_matched_host($c, '(?<=Connected to )[^\[\s]+');
1655         $c =~ s@(?<=\]:)(\d+)@$h{'Number'}$1$h{'Standard'}@;
1656
1657     } elsif ($c =~ m/^Could not connect to /) {
1658
1659         # Could not connect to [10.0.0.1]:80.
1660
1661         $c = highlight_matched_host($c, '(?<=\[)[^\]]+');
1662         $c =~ s@(?<=\]:)(\d+)@$h{'Number'}$1$h{'Standard'}@;
1663
1664     } elsif ($c =~ m/^Waiting for the next client request/ or
1665              $c =~ m/^The connection on server socket/ or
1666              $c =~ m/^Client request (?:\d+ )?(?:arrived in time|has been pipelined) /) {
1667
1668         # Waiting for the next client request on socket 3. Keeping the server \
1669         #  socket 12 to a.fsdn.com open.
1670         # The connection on server socket 6 to upload.wikimedia.org isn't reusable. Closing.
1671         # Privoxy 3.0.20 and later:
1672         # Client request 4 arrived in time on socket 7.
1673         # Used by Privoxy 3.0.18 and 3.0.19:
1674         # Client request arrived in time on socket 21.
1675         # Used by earlier version:
1676         # Client request arrived in time or the client closed the connection on socket 12.
1677         # Client request 8 has been pipelined on socket 7 and the socket is still alive.
1678
1679         $c =~ s@(?<=request )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1680         $c =~ s@(?<=on socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1681         $c =~ s@(?<=server socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1682         $c = highlight_matched_host($c, '(?<=to )[^\s]+');
1683
1684     } elsif ($c =~ m/^Marking the server socket/) {
1685
1686         # Marking the server socket 7 tainted.
1687
1688         $c =~ s@(?<=server socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1689
1690     } elsif ($c =~ m/^Reduced expected bytes to /) {
1691
1692         # Reduced expected bytes to 0 to account for the 1542 ones we already got.
1693         $c =~ s@(?<=bytes to )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1694         $c =~ s@(?<=for the )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1695
1696     } elsif ($c =~ m/^The client closed socket /) {
1697
1698         # The client closed socket 2 while the server socket 4 is still open.
1699         $c =~ s@(?<=closed socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1700         $c =~ s@(?<=server socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1701
1702     } elsif ($c =~ m/^Expected client content length set /) {
1703
1704         # Expected client content length set to 667325411 after reading 4999 bytes.
1705         $c =~ s@(?<=set to )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1706         $c =~ s@(?<=reading )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1707
1708     } elsif ($c =~ m/^Reducing expected bytes to /) {
1709
1710         # Reducing expected bytes to 0. Marking the server socket tainted after throwing 4 bytes away.
1711         $c =~ s@(?<=bytes to )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1712         $c =~ s@(?<=after throwing )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1713
1714     } elsif ($c =~ m/^Waiting for up to /) {
1715
1716         # Waiting for up to 4999 bytes from the client.
1717         $c =~ s@(?<=up to )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1718
1719     } elsif ($c =~ m/^Optimistically sending /) {
1720
1721         # Optimistically sending 318 bytes of client headers intended for www.privoxy.org
1722         $c =~ s@(?<=sending )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1723         $c = highlight_matched_host($c, '(?<=for )[^\s]+');
1724
1725     } elsif ($c =~ m/^Stopping to watch the client socket/) {
1726
1727         # Stopping to watch the client socket. There's already another request waiting.
1728         # Privoxy 3.0.20 and later:
1729         # Stopping to watch the client socket 5. There's already another request waiting.
1730         $c =~ s@(?<=client socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1731
1732     } elsif ($c =~ m/^Drained \d+ bytes before closing/) {
1733
1734         # Drained 180 bytes before closing socket 6
1735         $c =~ s@(?<=Drained )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1736         $c =~ s@(?<=socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1737
1738     } elsif ($c =~ m/^Tainting client socket/ or
1739              $c =~ m/^Failed to shutdown socket/) {
1740
1741         # Tainting client socket 7 due to unread data.
1742         # Failed to shutdown socket 11: Connection reset by peer
1743
1744         $c =~ s@(?<=socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1745
1746     } elsif ($c =~ m/^Shifting \d+ pipelined bytes/) {
1747
1748         # Shifting 360 pipelined bytes by 360 bytes
1749         $c =~ s@(?<=Shifting )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1750         $c =~ s@(?<=by )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1751
1752     } elsif ($c =~ m/^Flushed (\d+) bytes of request body while expecting (\d+)/) {
1753
1754         # Flushed 30 bytes of request body while expecting 30
1755         $c =~ s@(?<=Flushed )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1756         $c =~ s@(?<=expecting )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1757
1758     } elsif ($c =~ m/^Performing the TLS\/SSL handshake with client. Hash of host:/) {
1759
1760         # Performing the TLS/SSL handshake with client. Hash of host: bab5296b25e256c7b06b92b17b56bcae
1761         $c = highlight_matched_host($c, '(?<=Hash of host: ).+');
1762
1763     } elsif ($c =~ m/^Forwarding \d+ bytes of encrypted POST data/) {
1764
1765         # Forwarding 1954 bytes of encrypted POST data
1766         $c =~ s@(?<=Forwarding )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1767
1768     } elsif ($c =~ m/^Forwarded the last \d+ bytes/) {
1769
1770         # Forwarded the last 1954 bytes
1771         $c =~ s@(?<=the last )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1772
1773     } elsif ($c =~ m/^Waiting for the next client connection. Currently active threads:/) {
1774
1775         # Waiting for the next client connection. Currently active threads: 30
1776         $c =~ s@(?<=threads: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1777
1778     } elsif ($c =~ m/^Data arrived in time on client socket/) {
1779
1780         # Data arrived in time on client socket 6. Requests so far: 3
1781         $c =~ s@(?<=client socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1782         $c =~ s@(?<=Requests so far: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1783
1784     } elsif ($c =~ m/^Dropping the client connection on socket/) {
1785
1786         # Dropping the client connection on socket 71. The server connection has not been established yet.
1787         $c =~ s@(?<=on socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1788
1789     } elsif ($c =~ m/^The client socket \d+ has become unusable while the server/) {
1790
1791         # The client socket 16 has become unusable while the server socket 24 is still open.
1792         $c =~ s@(?<=client socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1793         $c =~ s@(?<=server socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1794
1795     } elsif ($c =~ m/^Looks like we / or
1796              $c =~ m/^Unsetting keep-alive flag/ or
1797              $c =~ m/^No connections to wait/ or
1798              $c =~ m/^Complete client request received/ or
1799              $c =~ m/^Possible pipeline attempt detected./ or
1800              $c =~ m/^POST request detected. The connection will not be kept alive./ or
1801              $c =~ m/^The server still wants to talk, but the client hung up on us./ or
1802              $c =~ m/^The server didn't specify how long the connection will stay open/ or
1803              $c =~ m/^There might be a request body. The connection will not be kept alive/ or
1804              $c =~ m/^There better be a request body./ or
1805              $c =~ m/^Done reading from the client\.$/) {
1806
1807         # Looks like we reached the end of the last chunk. We better stop reading.
1808         # Looks like we read the end of the last chunk together with the server \
1809         #  headers. We better stop reading.
1810         # Looks like we got the last chunk together with the server headers. \
1811         #  We better stop reading.
1812         # Unsetting keep-alive flag.
1813         # No connections to wait for left.
1814         # Client request arrived in time or the client closed the connection.
1815         # Complete client request received
1816         # Possible pipeline attempt detected. The connection will not be \
1817         #  kept alive and we will only serve the first request.
1818         # POST request detected. The connection will not be kept alive.
1819         # The server still wants to talk, but the client hung up on us.
1820         # The server didn't specify how long the connection will stay open. Assume it's only a second.
1821         # There might be a request body. The connection will not be kept alive.
1822         # Privoxy 3.0.20 and later
1823         # There better be a request body.
1824         # Done reading from the client.
1825
1826     } else {
1827
1828         found_unknown_content($c);
1829
1830     }
1831
1832     return $c;
1833 }
1834
1835
1836 sub handle_loglevel_info($) {
1837
1838     my $c = shift;
1839
1840     if ($c =~ m/^Rewrite detected:/) {
1841
1842         # Rewrite detected: GET http://10.0.0.2:88/blah.txt HTTP/1.1
1843         $c = highlight_matched_request_line($c, '(?<=^Rewrite detected: ).*');
1844
1845     } elsif ($c =~ m/^Decompress(ing deflated|ion didn)/ or
1846              $c =~ m/^Compressed content detected/ or
1847              $c =~ m/^SDCH-compressed content detected/ or
1848              $c =~ m/^Tagger/
1849             ) {
1850         # Decompressing deflated iob: 117
1851         # Decompression didn't result in any content.
1852         # Compressed content detected, content filtering disabled. Consider recompiling Privoxy\
1853         #  with zlib support or enable the prevent-compression action.
1854         # SDCH-compressed content detected, content filtering disabled.\
1855         #  Consider suppressing SDCH offers made by the client.
1856         # Tagger 'complete-url' created empty tag. Ignored.
1857
1858         # Ignored for now
1859
1860     } elsif ($c =~ m/^(Re)?loading configuration file /) {
1861
1862         # loading configuration file '/usr/local/etc/privoxy/config':
1863         # Reloading configuration file '/usr/local/etc/privoxy/config'
1864         $c =~ s@(?<=loading configuration file \')([^\']*)@$h{'file'}$1$h{'Standard'}@;
1865
1866     } elsif ($c =~ m/^Loading (actions|filter|trust) file: /) {
1867
1868         # Loading actions file: /usr/local/etc/privoxy/default.action
1869         # Loading filter file: /usr/local/etc/privoxy/default.filter
1870         # Loading trust file: /usr/local/etc/privoxy/trust
1871
1872         $c =~ s@(?<= file: )(.*)$@$h{'file'}$1$h{'Standard'}@;
1873
1874     } elsif ($c =~ m/^exiting by signal/) {
1875
1876         # exiting by signal 15 .. bye
1877         $c =~ s@(?<=exiting by signal )(\d+)@$h{'signal'}$1$h{'Standard'}@;
1878
1879     } elsif ($c =~ m/^Privoxy version/) {
1880
1881         # Privoxy version 3.0.7
1882         $c =~ s@(?<=^Privoxy version )(\d+\.\d+\.\d+)$@$h{'version'}$1$h{'Standard'}@;
1883
1884     } elsif ($c =~ m/^Program name: /) {
1885
1886         # Program name: /usr/local/sbin/privoxy
1887         $c =~ s@(?<=Program name: )(.*)@$h{'program-name'}$1$h{'Standard'}@;
1888
1889     } elsif ($c =~ m/^Listening on port /) {
1890
1891         # Listening on port 8118 on IP address 10.0.0.1
1892         $c =~ s@(?<=Listening on port )(\d+)@$h{'port'}$1$h{'Standard'}@;
1893         $c =~ s@(?<=on IP address )(.*)@$h{'ip-address'}$1$h{'Standard'}@;
1894
1895     } elsif ($c =~ m/^\(Re-\)Open(?:ing)? logfile/) {
1896
1897         # (Re-)Open logfile /var/log/privoxy/privoxy.log
1898         $c =~ s@(?<=Open logfile )(.*)@$h{'file'}$1$h{'Standard'}@;
1899
1900     } elsif ($c =~ m/^(Request from|Malformed server response detected)/) {
1901
1902         # Request from 10.0.0.1 denied. limit-connect{,} doesn't allow CONNECT requests to port 443.
1903         # Request from 10.0.0.1 marked for blocking. limit-connect{,} doesn't allow CONNECT requests to port 443.
1904         # 3.0.18 and later:
1905         # Request from 10.0.0.1 marked for blocking. limit-connect{0} doesn't allow CONNECT requests to www.example.org:443
1906         # Malformed server response detected. Downgrading to HTTP/1.0 impossible.
1907
1908         $c =~ s@(?<=Request from )([^\s]*)@$h{'ip-address'}$1$h{'Standard'}@;
1909         $c =~ s@(denied|blocking)@$h{'warning'}$1$h{'Standard'}@;
1910         $c =~ s@(CONNECT)@$h{'method'}$1$h{'Standard'}@;
1911         $c =~ s@(?<=to port )(\d+)@$h{'port'}$1$h{'Standard'}@;
1912         $c =~ s@(?<=to )([^\s]+)@$h{'request_'}$1$h{'Standard'}@;
1913
1914     } elsif ($c =~ m/^Status code/) {
1915
1916         # Status code 304 implies no body.
1917         $c =~ s@(?<=Status code )(\d+)@$h{'status-code'}$1$h{'Standard'}@;
1918
1919     } elsif ($c =~ m/^Method/) {
1920
1921         # Method HEAD implies no body.
1922         $c =~ s@(?<=Method )([^\s]+)@$h{'method'}$1$h{'Standard'}@;
1923
1924     } elsif ($c =~ m/^Buffer limit reached while extending /) {
1925
1926         # Buffer limit reached while extending the buffer (iob). Needed: 4197470. Limit: 4194304
1927         $c =~ s@(?<=Needed: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1928         $c =~ s@(?<=Limit: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1929
1930     } elsif ($c =~ m/^File modification detected: /) {
1931
1932         # File modification detected: /usr/local/etc/privoxy/user-agent.action
1933         $c =~ s@(?<= detected: )(.*)$@$h{'file'}$1$h{'Standard'}@;
1934
1935     } elsif ($c =~ m/^No logfile configured/ or
1936              $c =~ m/^Malformerd HTTP headers detected and MS IIS5 hack enabled/ or
1937              $c =~ m/^Invalid \"chunked\" transfer/ or
1938              $c =~ m/^Support for/ or
1939              $c =~ m/^Flushing header and buffers/ or
1940              $c =~ m/^Can not resolve/
1941              ) {
1942
1943         # No logfile configured. Please enable it before reporting any problems.
1944         # Malformerd HTTP headers detected and MS IIS5 hack enabled. Expect an invalid \
1945         #  response or even no response at all.
1946         # No logfile configured. Logging disabled.
1947         # Invalid "chunked" transfer encoding detected and ignored.
1948         # Support for 'Connection: keep-alive' is experimental, incomplete and\
1949         #  known not to work properly in some situations.
1950         # Flushing header and buffers. Stepping back from filtering.
1951         # Can not resolve doesnotexist: hostname nor servname provided, or not known
1952
1953     } else {
1954
1955         found_unknown_content($c);
1956
1957     }
1958
1959     return $c;
1960 }
1961
1962 sub handle_loglevel_cgi($) {
1963
1964     my $c = shift;
1965
1966     if ($c =~ m/^Granting access to/) {
1967
1968         #Granting access to http://config.privoxy.org/send-stylesheet, referrer http://p.p/ is trustworthy.
1969
1970     } elsif ($c =~ m/^Substituting: s(.)/) {
1971
1972         # Substituting: s/@else-not-FEATURE_ZLIB@.*@endif-FEATURE_ZLIB@//sigTU
1973         # XXX: prone to span several lines
1974
1975         my $delimiter = $1;
1976         #$c =~ s@(?<=failed: )(.*)@$h{'error'}$1$h{'Standard'}@;
1977         $c =~ s@(?!<=\\)($delimiter)@$h{'pcrs-delimiter'}$1$h{'Standard'}@g; # XXX: Too aggressive
1978         #$c =~ s@(?!<=\\)($1)@$h{'pcrs-delimiter'}$1$h{'Standard'}@g;
1979     }
1980
1981     return $c;
1982 }
1983
1984 sub handle_loglevel_force($) {
1985
1986     my $c = shift;
1987
1988     if ($c =~ m/^Ignored force prefix in request:/) {
1989
1990         # Ignored force prefix in request: "GET http://10.0.0.1/PRIVOXY-FORCE/block HTTP/1.1"
1991         $c =~ s@^(Ignored)@$h{'ignored'}$1$h{'Standard'}@;
1992         $c = highlight_matched_request_line($c, '(?<=request: ")[^"]*');
1993
1994     } elsif ($c =~ m/^Enforcing request:/) {
1995
1996         # Enforcing request: "GET http://10.0.0.1/block HTTP/1.1".
1997         $c = highlight_matched_request_line($c, '(?<=request: ")[^"]*');
1998
1999     } else {
2000
2001         found_unknown_content($c);
2002
2003     }
2004
2005     return $c;
2006 }
2007
2008 sub handle_loglevel_error($) {
2009
2010     my $c = shift;
2011
2012     if ($c =~ m/^(?:Empty|No) server or forwarder response received on socket \d+\./) {
2013
2014         # Empty server or forwarder response received on socket 4.
2015         # Empty server or forwarder response received on socket 3. \
2016         #  Closing client socket 15 without sending data.
2017         # Used by Privoxy 3.0.18 and later:
2018         # No server or forwarder response received on socket 8. \
2019         #  Closing client socket 10 without sending data.
2020
2021         $c =~ s@(?<=on socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
2022         $c =~ s@(?<=client socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
2023
2024     } elsif ($c =~ m/^Didn't receive data in time:/) {
2025
2026         # Didn't receive data in time: a.fsdn.com:443
2027         $c =~ s@(?<=in time: )(.*)@$h{'destination'}$1$h{'Standard'}@;
2028     }
2029
2030     # XXX: There are probably more messages that deserve highlighting.
2031
2032     return $c;
2033 }
2034
2035
2036 sub handle_loglevel_ignore($) {
2037     return shift;
2038 }
2039
2040 sub gather_loglevel_clf_stats($) {
2041
2042     my $content = shift;
2043     my ($method, $resource, $http_version, $status_code, $size);
2044     our %stats;
2045     our %cli_options;
2046
2047     # +0200] "GET https://www.youtube.com/watch?v=JmcA9LIIXWw HTTP/1.1" 200 68004
2048     # +0200] "VERSION-CONTROL http://p.p/ HTTP/1.1" 200 2787
2049     $content =~ m/^[+-]\d{4}\] "([^ ]+) (.+) (HTTP\/\d\.\d)" (\d+) (\d+)/;
2050     $method       = $1;
2051     $resource     = $2;
2052     $http_version = $3;
2053     $status_code  = $4;
2054     $size         = $5;
2055
2056     $stats{requests_clf}++;
2057
2058     unless (defined $method) {
2059         # +0200] "Invalid request" 400 0
2060         return if ($content =~ m/^[+-]\d{4}\] "Invalid request"/);
2061         print("Failed to parse: $content\n");
2062         return;
2063     }
2064     $stats{'method'}{$method}++;
2065     if ($cli_options{'url-statistics-threshold'} != 0) {
2066         $stats{'resource'}{$resource}++;
2067     }
2068     $stats{'http-version'}{$http_version}++;
2069
2070     if ($cli_options{'host-statistics-threshold'} != 0) {
2071         $resource =~ m@(?:https?://)?([^/]+)/?@;
2072         $stats{'hosts'}{$1}++;
2073     }
2074     $stats{'content-size-total'} += $size;
2075     $stats{'status-code'}{$status_code}++;
2076 }
2077
2078 sub gather_loglevel_request_stats($$) {
2079     my $c = shift;
2080     my $thread = shift;
2081     our %stats;
2082
2083     $stats{requests}++;
2084 }
2085
2086 sub gather_loglevel_crunch_stats($$) {
2087     my $c = shift;
2088     my $thread = shift;
2089     our %stats;
2090
2091     $stats{crunches}++;
2092
2093     if ($c =~ m/^Redirected:/) {
2094         # Redirected: http://www.example.org/http://p.p/
2095         $stats{'fast-redirections'}++;
2096
2097     } elsif ($c =~ m/^Blocked:/) {
2098         # Blocked: blogger.googleusercontent.com:443
2099         $stats{'blocked'}++;
2100
2101     } elsif ($c =~ m/^Connection timeout:/) {
2102         # Connection timeout: http://c.tile.openstreetmap.org/18/136116/87842.png
2103         $stats{'connection-timeout'}++;
2104
2105     } elsif ($c =~ m/^Connection failure:/) {
2106         # Connection failure: http://127.0.0.1:8080/
2107         $stats{'connection-failure'}++;
2108     }
2109 }
2110
2111
2112 sub gather_loglevel_error_stats($$) {
2113
2114     my $c = shift;
2115     my $thread = shift;
2116     our %stats;
2117     our %thread_data;
2118
2119     if ($c =~ m/^Empty server or forwarder response received on socket \d+./) {
2120
2121         # Empty server or forwarder response received on socket 4.
2122         $stats{'empty-responses'}++;
2123         if ($thread_data{$thread}{'new_connection'}) {
2124             $stats{'empty-responses-on-new-connections'}++;
2125         } else {
2126             $stats{'empty-responses-on-reused-connections'}++;
2127         }
2128     }
2129 }
2130
2131 sub gather_loglevel_connect_stats($$) {
2132
2133     my ($c, $thread) = @_;
2134     our %thread_data;
2135     our %stats;
2136
2137     if ($c =~ m/^via ([^\s]+) to: [^\s]+/) {
2138
2139         # Connect: via 10.0.0.1:8123 to: www.example.org.noconnect
2140         $thread_data{$thread}{'forwarder'} = $1; # XXX: is this missue?
2141
2142     } elsif ($c =~ m/^to ([^\s]*)$/) {
2143
2144         # Connect: to lists.sourceforge.net:443
2145
2146         $thread_data{$thread}{'forwarder'} = 'direct connection';
2147
2148     } elsif ($c =~ m/^Created new connection to/) {
2149
2150         # Created new connection to www.privoxy.org:80 on socket 11.
2151
2152         $thread_data{$thread}{'new_connection'} = 1;
2153
2154     } elsif ($c =~ m/^Reusing server socket \d./ or
2155              $c =~ m/^Found reusable socket/) {
2156
2157         # Reusing server socket 4. Opened for 10.0.0.1.
2158         # Found reusable socket 9 for www.privoxy.org:80 in slot 0.
2159
2160         $thread_data{$thread}{'new_connection'} = 0;
2161         $stats{'reused-connections'}++;
2162
2163     } elsif ($c =~ m/^Closing client socket \d+. .* Requests received: (\d+)\.$/) {
2164
2165         # Closing client socket 12. Keep-alive: 1. Socket alive: 1. Data available: 0. \
2166         #  Configuration file change detected: 0. Requests received: 14.
2167
2168         $stats{'client-requests-on-connection'}{$1}++;
2169         $stats{'closed-client-connections'}++;
2170     }
2171 }
2172
2173 sub gather_loglevel_header_stats($$) {
2174
2175     my ($c, $thread) = @_;
2176     our %stats;
2177     our %cli_options;
2178
2179     if ($c =~ m/^A HTTP\/1\.1 response without/ or
2180         $c =~ m/^Keeping the server header 'Connection: keep-alive' around./)
2181     {
2182         # A HTTP/1.1 response without Connection header implies keep-alive.
2183         # Keeping the server header 'Connection: keep-alive' around.
2184         $stats{'server-keep-alive'}++;
2185     }
2186 }
2187
2188 sub init_stats() {
2189     our %stats = (
2190         requests => 0,
2191         requests_clf => 0,
2192         crunches => 0,
2193         'server-keep-alive' => 0,
2194         'reused-connections' => 0,
2195         'empty-responses' => 0,
2196         'empty-responses-on-new-connections' => 0,
2197         'empty-responses-on-reused-connections' => 0,
2198         'fast-redirections' => 0,
2199         'blocked' => 0,
2200         'connection-failure' => 0,
2201         'connection-timeout' => 0,
2202         'reused-connections' => 0,
2203         'server-keep-alive' => 0,
2204         'closed-client-connections' => 0,
2205         'content-size-total' => 0,
2206         );
2207         $stats{'client-requests-on-connection'}{1} = 0;
2208 }
2209
2210 sub get_percentage($$) {
2211     my $big = shift;
2212     my $small = shift;
2213
2214     # If small is 0 the percentage is always 0%.
2215     # Make sure it works even if big is 0 as well.
2216     return "0.00%" if ($small eq 0);
2217
2218     # Prevent division by zero.
2219     # XXX: Is this still supposed to be reachable?
2220     return "NaN" if ($big eq 0);
2221
2222     return sprintf("%.2f%%", $small / $big * 100);
2223 }
2224
2225 sub print_stats() {
2226
2227     our %stats;
2228     our %cli_options;
2229     my $new_connections = $stats{requests} - $stats{crunches} - $stats{'reused-connections'};
2230     my $client_requests_checksum = 0;
2231     my $requests_total;
2232
2233     if ($stats{requests_clf} && $stats{requests}
2234         && $stats{requests_clf} != $stats{requests}) {
2235         print "Inconsistent request counts: " . $stats{requests} . "/" . $stats{requests_clf} . "\n";
2236     }
2237
2238     # To get the total number of requests we can use either the number
2239     # of Common-Log-Format lines or the number of "Request:" messages.
2240     # We prefer the number of CLF lines if available because using
2241     # it works when analysing old log files from Privoxy versions before 3.0.29.
2242     # In Privoxy 3.0.28 and earlier "Request:" messages excluded
2243     # crunched messages.
2244     $requests_total = $stats{requests_clf} ? $stats{requests_clf} : $stats{requests};
2245
2246     if ($requests_total eq 0) {
2247         print "No requests yet.\n";
2248         return;
2249     }
2250
2251     print "Client requests total: " . $requests_total . "\n";
2252     if ($stats{crunches}) {
2253         my $outgoing_requests = $requests_total - $stats{crunches};
2254         print "Crunches: " . $stats{crunches} . " (" .
2255             get_percentage($requests_total, $stats{crunches}) . ")\n";
2256         print "Blocks: " . $stats{'blocked'} . " (" .
2257             get_percentage($requests_total, $stats{'blocked'}) . ")\n";
2258         print "Fast redirections: " . $stats{'fast-redirections'} . " (" .
2259             get_percentage($requests_total, $stats{'fast-redirections'}) . ")\n";
2260         print "Connection timeouts: " . $stats{'connection-timeout'} . " (" .
2261             get_percentage($requests_total, $stats{'connection-timeout'}) . ")\n";
2262         print "Connection failures: " . $stats{'connection-failure'} . " (" .
2263             get_percentage($requests_total, $stats{'connection-failure'}) . ")\n";
2264         print "Outgoing requests: " . $outgoing_requests . " (" .
2265             get_percentage($requests_total, $outgoing_requests) . ")\n";
2266     } else {
2267         print "No crunches detected. Is 'debug 1024' enabled?\n";
2268     }
2269
2270     print "Server keep-alive offers: " . $stats{'server-keep-alive'} . " (" .
2271         get_percentage($requests_total, $stats{'server-keep-alive'}) . ")\n";
2272     print "New outgoing connections: " . $new_connections . " (" .
2273         get_percentage($requests_total, $new_connections) . ")\n";
2274     print "Reused connections: " . $stats{'reused-connections'} . " (" .
2275         get_percentage($requests_total, $stats{'reused-connections'}) .
2276         "; server offers accepted: " .
2277         get_percentage($stats{'server-keep-alive'}, $stats{'reused-connections'}) . ")\n";
2278     print "Empty responses: " . $stats{'empty-responses'} . " (" .
2279         get_percentage($requests_total, $stats{'empty-responses'}) . ")\n";
2280     print "Empty responses on new connections: "
2281          . $stats{'empty-responses-on-new-connections'} . " (" .
2282         get_percentage($requests_total, $stats{'empty-responses-on-new-connections'})
2283         . ")\n";
2284     print "Empty responses on reused connections: " .
2285         $stats{'empty-responses-on-reused-connections'} . " (" .
2286         get_percentage($requests_total, $stats{'empty-responses-on-reused-connections'}) .
2287         ")\n";
2288     print "Client connections: " .  $stats{'closed-client-connections'} . "\n";
2289     if ($stats{'content-size-total'}) {
2290         print "Bytes of content transfered to the client: " .  $stats{'content-size-total'} . "\n";
2291     }
2292     my $lines_printed = 0;
2293     print "Client requests per connection distribution:\n";
2294     foreach my $client_requests (sort {
2295         $stats{'client-requests-on-connection'}{$b} <=> $stats{'client-requests-on-connection'}{$a}}
2296                                   keys %{$stats{'client-requests-on-connection'}
2297                                   })
2298     {
2299         my $count = $stats{'client-requests-on-connection'}{$client_requests};
2300         $client_requests_checksum += $count * $client_requests;
2301         if ($cli_options{'show-complete-request-distribution'} or ($lines_printed < 10)) {
2302             printf "%8d: %d\n", $count, $client_requests;
2303             $lines_printed++;
2304         }
2305     }
2306     unless ($cli_options{'show-complete-request-distribution'}) {
2307         printf "Enable --show-complete-request-distribution to get less common numbers as well.\n";
2308     }
2309     # Due to log rotation we may not have a complete picture for all the requests
2310     printf "Improperly accounted requests: ~%d\n", abs($requests_total - $client_requests_checksum);
2311
2312     if (exists $stats{method}) {
2313         print "Method distribution:\n";
2314         foreach my $method (sort {$stats{'method'}{$b} <=> $stats{'method'}{$a}} keys %{$stats{'method'}}) {
2315             printf "%8d : %-8s\n", $stats{'method'}{$method}, $method;
2316         }
2317     } else {
2318         print "Method distribution unknown. No CLF message parsed yet. Is 'debug 512' enabled?\n";
2319     }
2320     if (exists $stats{'http-version'}) {
2321         print "Client HTTP versions:\n";
2322         foreach my $http_version (sort {$stats{'http-version'}{$b} <=> $stats{'http-version'}{$a}} keys %{$stats{'http-version'}}) {
2323             printf "%8d : %-8s\n",  $stats{'http-version'}{$http_version}, $http_version;
2324         }
2325     } else {
2326         print "HTTP version distribution unknown. No CLF message parsed yet. Is 'debug 512' enabled?\n";
2327     }
2328     if (exists $stats{'status-code'}) {
2329         print "HTTP status codes:\n";
2330         foreach my $status_code (sort {$stats{'status-code'}{$b} <=> $stats{'status-code'}{$a}} keys %{$stats{'status-code'}}) {
2331             printf "%8d : %-8d\n",  $stats{'status-code'}{$status_code}, $status_code;
2332         }
2333     } else {
2334         print "Status code distribution unknown. No CLF message parsed yet. Is 'debug 512' enabled?\n";
2335     }
2336
2337     if ($cli_options{'url-statistics-threshold'} == 0) {
2338         print "URL statistics are disabled. Increase --url-statistics-threshold to enable them.\n";
2339     } else {
2340         print "Requested URLs:\n";
2341         foreach my $resource (sort {$stats{'resource'}{$b} <=> $stats{'resource'}{$a}} keys %{$stats{'resource'}}) {
2342             if ($stats{'resource'}{$resource} < $cli_options{'url-statistics-threshold'}) {
2343                 print "Skipped statistics for URLs below the treshold.\n";
2344                 last;
2345             }
2346             printf "%d : %s\n", $stats{'resource'}{$resource}, $resource;
2347         }
2348     }
2349
2350     if ($cli_options{'host-statistics-threshold'} == 0) {
2351         print "Host statistics are disabled. Increase --host-statistics-threshold to enable them.\n";
2352     } else {
2353         print "Requested Hosts:\n";
2354         foreach my $host (sort {$stats{'hosts'}{$b} <=> $stats{'hosts'}{$a}} keys %{$stats{'hosts'}}) {
2355             if ($stats{'hosts'}{$host} < $cli_options{'host-statistics-threshold'}) {
2356                 print "Skipped statistics for Hosts below the treshold.\n";
2357                 last;
2358             }
2359             printf "%d : %s\n", $stats{'hosts'}{$host}, $host;
2360         }
2361     }
2362 }
2363
2364
2365 ################################################################################
2366 # Functions that actually print stuff
2367 ################################################################################
2368
2369 sub print_clf_message() {
2370
2371     our ($ip, $timestamp, $request_line, $status_code, $size);
2372     my $output = '';
2373
2374     return if DEBUG_SUPPRESS_LOG_MESSAGES;
2375
2376     # Rebuild highlighted
2377     $output .= $h{'Number'} . $ip . $h{'Standard'};
2378     $output .= " - - ";
2379     $output .= "[" . $h{'Timestamp'} . $timestamp . $h{'Standard'} . "]";
2380     $output .= " ";
2381     $output .= "\"" . highlight_request_line("$request_line") . "\"";
2382     $output .= " ";
2383     $output .= $h{'Status'} . $status_code . $h{'Standard'};
2384     $output .= " ";
2385     $output .= $h{'Number'} . $size . $h{'Standard'};
2386     $output .= $line_end;
2387
2388     print $output;
2389 }
2390
2391 sub print_non_clf_message($) {
2392
2393     my $content = shift;
2394     my $date_string = $keep_date_mode ? $req{$t}{'day'} . ' ' : '';
2395     my $msec_string = $no_msecs_mode ? '' : '.' . $req{$t}{'msecs'};
2396     my $line_start = $html_output_mode ? '' : $h{"Standard"};
2397
2398     return if DEBUG_SUPPRESS_LOG_MESSAGES;
2399
2400     print $line_start
2401         . $date_string
2402         . $time_colours[$time_colour_index % 2]
2403         . $req{$t}{'time-stamp'}
2404         . $msec_string
2405         . $h{Standard} . " "
2406         . $thread_colours{$t}
2407         . $t
2408         . $h{Standard}
2409         . " "
2410         . $h{$req{$t}{'log-level'}}
2411         . $req{$t}{'log-level'}
2412         . $h{Standard}
2413         . ": "
2414         . $content
2415         . $line_end;
2416 }
2417
2418 sub shorten_thread_id($) {
2419
2420     my $thread_id = shift;
2421
2422     our %short_thread_ids;
2423     our $max_threadid;
2424
2425     unless (defined $short_thread_ids{$thread_id}) {
2426         $short_thread_ids{$thread_id} = sprintf "%.3d", $max_threadid++;
2427     }
2428
2429     return $short_thread_ids{$thread_id}
2430 }
2431
2432 sub parse_loop() {
2433
2434     my ($day, $time_stamp, $thread, $log_level, $content, $c, $msecs);
2435     my $last_msecs  = 0;
2436     my $last_thread = 0;
2437     my $last_timestamp = 0;
2438     my $filters_that_did_nothing;
2439     my $key;
2440     my $time_colour;
2441     $time_colour = paint_it('white');
2442
2443     my %log_level_handlers = (
2444         'Re-Filter'         => \&handle_loglevel_re_filter,
2445         'Header'            => \&handle_loglevel_header,
2446         'Connect'           => \&handle_loglevel_connect,
2447         'Redirect'          => \&handle_loglevel_redirect,
2448         'Request'           => \&handle_loglevel_request,
2449         'Crunch'            => \&handle_loglevel_crunch,
2450         'Gif-Deanimate'     => \&handle_loglevel_gif_deanimate,
2451         'Info'              => \&handle_loglevel_info,
2452         'CGI'               => \&handle_loglevel_cgi,
2453         'Force'             => \&handle_loglevel_force,
2454         'Error'             => \&handle_loglevel_error,
2455         'Fatal error'       => \&handle_loglevel_ignore,
2456         'Writing'           => \&handle_loglevel_ignore,
2457         'Received'          => \&handle_loglevel_ignore,
2458         'Tagging'           => \&handle_loglevel_ignore,
2459         'Actions'           => \&handle_loglevel_ignore,
2460         'Unknown log level' => \&handle_loglevel_ignore,
2461     );
2462
2463     while (<>) {
2464
2465         if (m/^(\d{4}-\d{2}-\d{2}|\w{3} \d{2}) (\d\d:\d\d:\d\d)\.?(\d+)? (?:Privoxy\()?([^\)\s]*)[\)]? ([\w -]*): (.*?)\r?$/) {
2466             $thread = $t = ($shorten_thread_ids) ? shorten_thread_id($4) : $4;
2467             $req{$t}{'day'} = $day = $1;
2468             $req{$t}{'time-stamp'} = $time_stamp = $2;
2469             $req{$t}{'msecs'} = $msecs = $3 ? $3 : 0; # Only the cool kids have micro second resolution;
2470             $req{$t}{'log-level'} = $log_level = $5;
2471             $req{$t}{'content'} = $content = $c = $6;
2472             $req{$t}{'log-message'} = $_;
2473             $no_special_header_highlighting = 0;
2474
2475             if (defined($log_level_handlers{$log_level})) {
2476
2477                 $content = $log_level_handlers{$log_level}($content);
2478
2479             } else {
2480
2481                 die "No handler found for log level \"$log_level\"\n";
2482             }
2483
2484             # Highlight Truncations
2485             if (length($_) > 4000) {
2486                 $content =~ s@(too long, truncated)]$@$h{'Truncation'}$1$h{'Standard'}]@g;
2487             }
2488
2489             next unless $content;
2490
2491             # Register threads to keep the colour constant
2492             if (!defined($thread_colours{$thread})) {
2493                 $thread_colours{$thread} = $all_colours[$thread_colour_index % @all_colours];
2494                 $thread_colour_index++;
2495             }
2496
2497             # Switch timestamp colour if timestamps differ
2498             if (($msecs ne $last_msecs) || ($time_stamp ne $last_timestamp)) {
2499                debug_message("Tick tack!") if DEBUG_TICKS;
2500                $time_colour = $time_colours[$time_colour_index % 2];
2501                $time_colour_index++;
2502                $last_msecs = $msecs;
2503                $last_timestamp = $time_stamp;
2504             }
2505
2506             $last_thread = $thread;
2507
2508             print_non_clf_message($content);
2509
2510         } elsif (m/^((?:\d+\.\d+\.\d+\.\d+|[:\d]+)) - - \[(.*)\] "(.*)" (\d+) (\d+)/) {
2511
2512             # LOG_LEVEL_CLF lines look like this
2513             # 61.152.239.32 - - [04/Mar/2007:18:28:23 +0100] "GET \
2514             #  http://ad.yieldmanager.com/imp?z=1&Z=120x600&s=109339&u=http%3A%2F%2Fwww.365loan.co.uk%2F&r=1\
2515             #  HTTP/1.1" 403 1730
2516             our ($ip, $timestamp, $request_line, $status_code, $size) = ($1, $2, $3, $4, $5);
2517
2518             print_clf_message();
2519
2520         } else {
2521
2522             # Some Privoxy log messages span more than one line,
2523             # usually to dump lots of content that doesn't need any syntax highlighting.
2524             # XXX: add mechanism to forward these lines to the right handler anyway.
2525             chomp();
2526             unless (DEBUG_SUPPRESS_LOG_MESSAGES or (SUPPRESS_EMPTY_LINES and m/^\s+$/)) {
2527                 print and print get_line_end(); # unless (SUPPRESS_EMPTY_LINES and m/^\s+$/);
2528             }
2529         }
2530     }
2531 }
2532
2533 sub stats_loop() {
2534
2535     my ($day, $time_stamp, $msecs, $thread, $log_level, $content);
2536     my $strict_checks = cli_option_is_set('strict-checks');
2537     my %log_level_handlers = (
2538          'Connect:'           => \&gather_loglevel_connect_stats,
2539          'Crunch:'            => \&gather_loglevel_crunch_stats,
2540          'Error:'             => \&gather_loglevel_error_stats,
2541          'Header:'            => \&gather_loglevel_header_stats,
2542          'Request:'           => \&gather_loglevel_request_stats,
2543     );
2544     my %ignored_log_levels = (
2545          'Actions:'           => \&handle_loglevel_ignore,
2546          'CGI:'               => \&handle_loglevel_ignore,
2547          'Fatal error:'       => \&handle_loglevel_ignore,
2548          'Force:'             => \&handle_loglevel_ignore,
2549          'Gif-Deanimate:'     => \&handle_loglevel_ignore,
2550          'Info:'              => \&handle_loglevel_ignore,
2551          'Re-Filter:'         => \&handle_loglevel_ignore,
2552          'Received:'          => \&handle_loglevel_ignore,
2553          'Redirect:'          => \&handle_loglevel_ignore,
2554          'Unknown log level:' => \&handle_loglevel_ignore,
2555          'Writing:'           => \&handle_loglevel_ignore,
2556          'Tagging:'           => \&handle_loglevel_ignore,
2557     );
2558
2559     while (<>) {
2560         (undef, $time_stamp, $thread, $log_level, $content) = split(/ /, $_, 5);
2561
2562
2563         next if (not defined($log_level));
2564
2565         if ($time_stamp eq "-") {
2566
2567             gather_loglevel_clf_stats($content);
2568
2569         } elsif (defined($log_level_handlers{$log_level})) {
2570
2571             $content = $log_level_handlers{$log_level}($content, $thread);
2572
2573         } elsif ($strict_checks and not defined($ignored_log_levels{$log_level})) {
2574
2575             die "No handler found for: $_";
2576         }
2577     }
2578
2579     print_stats();
2580
2581 }
2582
2583 sub unbreak_lines_only_loop() {
2584     my $log_messages_reached = 0;
2585     while (<>) {
2586         chomp;
2587
2588             # Log level other than LOG_LEVEL_CLF?
2589         if (m/^(\d{4}-\d{2}-\d{2}|\w{3} \d{2}) (\d\d:\d\d:\d\d)\.?(\d+)? (?:Privoxy\()?([^\)\s]*)[\)]? ([\w -]*): (.*?)\r?$/ or
2590             # LOG_LEVEL_CLF?
2591             m/^((?:\d+\.\d+\.\d+\.\d+)) - - \[(.*)\] "(.*)" (\d+) (\d+)/) {
2592             $log_messages_reached = 1;
2593             print "\n";
2594
2595         } else {
2596             # Wrapped message
2597             $_ = "\n". $_  if /^(?:\d+\.\d+\.\d+\.\d+)/;
2598             $_ = " " . $_;
2599         }
2600         s@<BR>$@@;
2601         print;
2602         print "\n" unless $log_messages_reached;
2603     }
2604     print "\n";
2605 }
2606
2607 sub VersionMessage {
2608     my $version_message;
2609
2610     $version_message .= 'Privoxy-Log-Parser ' . PRIVOXY_LOG_PARSER_VERSION  . "\n";
2611     $version_message .= 'https://www.fabiankeil.de/sourcecode/privoxy-log-parser/' . "\n";
2612
2613     print $version_message;
2614 }
2615
2616 sub get_cli_options() {
2617
2618     our %cli_options = (
2619         'html-output'              => CLI_OPTION_DEFAULT_TO_HTML_OUTPUT,
2620         'title'                    => CLI_OPTION_TITLE,
2621         'keep-date'                => CLI_OPTION_KEEP_DATE,
2622         'no-syntax-highlighting'   => CLI_OPTION_NO_SYNTAX_HIGHLIGHTING,
2623         'no-embedded-css'          => CLI_OPTION_NO_EMBEDDED_CSS,
2624         'no-msecs'                 => CLI_OPTION_NO_MSECS,
2625         'shorten-thread-ids'       => CLI_OPTION_SHORTEN_THREAD_IDS,
2626         'show-ineffective-filters' => CLI_OPTION_SHOW_INEFFECTIVE_FILTERS,
2627         'statistics'               => CLI_OPTION_STATISTICS,
2628         'strict-checks'            => CLI_OPTION_STRICT_CHECKS,
2629         'url-statistics-threshold' => CLI_OPTION_URL_STATISTICS_THRESHOLD,
2630         'unbreak-lines-only'       => CLI_OPTION_UNBREAK_LINES_ONLY,
2631         'host-statistics-threshold'=> CLI_OPTION_HOST_STATISTICS_THRESHOLD,
2632         'show-complete-request-distribution' => CLI_OPTION_SHOW_COMPLETE_REQUEST_DISTRIBUTION,
2633     );
2634
2635     GetOptions (
2636         'html-output'              => \$cli_options{'html-output'},
2637         'title'                    => \$cli_options{'title'},
2638         'keep-date'                => \$cli_options{'keep-date'},
2639         'no-syntax-highlighting'   => \$cli_options{'no-syntax-highlighting'},
2640         'no-embedded-css'          => \$cli_options{'no-embedded-css'},
2641         'no-msecs'                 => \$cli_options{'no-msecs'},
2642         'shorten-thread-ids'       => \$cli_options{'shorten-thread-ids'},
2643         'show-ineffective-filters' => \$cli_options{'show-ineffective-filters'},
2644         'statistics'               => \$cli_options{'statistics'},
2645         'strict-checks'            => \$cli_options{'strict-checks'},
2646         'unbreak-lines-only'       => \$cli_options{'unbreak-lines-only'},
2647         'url-statistics-threshold=i'=> \$cli_options{'url-statistics-threshold'},
2648         'host-statistics-threshold=i'=> \$cli_options{'host-statistics-threshold'},
2649         'show-complete-request-distribution' => \$cli_options{'show-complete-request-distribution'},
2650         'version'                  => sub { VersionMessage && exit(0) },
2651         'help'                     => \&help,
2652    ) or exit(1);
2653
2654    $html_output_mode = cli_option_is_set('html-output');
2655    $no_msecs_mode = cli_option_is_set('no-msecs');
2656    $keep_date_mode = cli_option_is_set('keep-date');
2657    $shorten_thread_ids = cli_option_is_set('shorten-thread-ids');
2658    $line_end = get_line_end();
2659 }
2660
2661 sub help() {
2662
2663     our %cli_options;
2664
2665     VersionMessage();
2666
2667     print << "    EOF"
2668
2669 Options and their default values if they have any:
2670     [--host-statistics-threshold $cli_options{'host-statistics-threshold'}]
2671     [--html-output]
2672     [--no-embedded-css]
2673     [--no-msecs]
2674     [--no-syntax-highlighting]
2675     [--shorten-thread-ids]
2676     [--show-ineffective-filters]
2677     [--show-complete-request-distribution]
2678     [--statistics]
2679     [--unbreak-lines-only]
2680     [--url-statistics-threshold $cli_options{'url-statistics-threshold'}]
2681     [--title $cli_options{'title'}]
2682     [--version]
2683 see "perldoc $0" for more information
2684     EOF
2685     ;
2686     exit(0);
2687 }
2688
2689 ################################################################################
2690 # main
2691 ################################################################################
2692 sub main() {
2693
2694     get_cli_options();
2695     set_background(DEFAULT_BACKGROUND);
2696     prepare_our_stuff();
2697
2698     print_intro();
2699
2700     # XXX: should explicitly reject incompatible argument combinations
2701     if (cli_option_is_set('unbreak-lines-only')) {
2702         unbreak_lines_only_loop();
2703     } elsif (cli_option_is_set('statistics')) {
2704         stats_loop();
2705     } else {
2706         parse_loop();
2707     }
2708
2709     print_outro();
2710 }
2711
2712 main();
2713
2714 =head1 NAME
2715
2716 B<privoxy-log-parser> - A parser and syntax-highlighter for Privoxy log messages
2717
2718 =head1 SYNOPSIS
2719
2720 B<privoxy-log-parser> [B<--html-output>]
2721 [B<--no-msecs>] [B<--no-syntax-higlighting>] [B<--statistics>]
2722 [B<--shorten-thread-ids>] [B<--show-ineffective-filters>]
2723 [B<--url-statistics-threshold>] [B<--version>]
2724
2725 =head1 DESCRIPTION
2726
2727 B<privoxy-log-parser> reads Privoxy log messages and
2728
2729 - syntax-highlights recognized lines,
2730
2731 - reformats some of them for easier comprehension,
2732
2733 - filters out less useful messages, and
2734
2735 - (in some cases) calculates additional information,
2736   like the compression ratio or how a filter affected
2737   the content size.
2738
2739 With B<privoxy-log-parser> you should be able to increase Privoxy's log level
2740 without getting confused by the resulting amount of output. For example for
2741 "debug 64" B<privoxy-log-parser> will (by default) only show messages that
2742 affect the content. If a filter doesn't cause any hits, B<privoxy-log-parser>
2743 will hide the "filter foo caused 0 hits" message.
2744
2745 =head1 OPTIONS
2746
2747 [B<--host-statistics-threshold>] Only show the request count for a host
2748 if it's above or equal to the given threshold. If the threshold is 0, host
2749 statistics are disabled.
2750
2751 [B<--html-output>] Use HTML and CSS for the syntax highlighting. If this option is
2752 omitted, ANSI escape sequences are used unless B<--no-syntax-highlighting> is active.
2753 This option is only intended to make embedding log excerpts in web pages easier.
2754 It does not escape any input!
2755
2756 [B<--keep-date>] Don't remove the date when printing highlighted log messages.
2757 Useful when parsing multiple log files at once.
2758
2759 [B<--no-msecs>] Don't expect milisecond resolution
2760
2761 [B<--no-syntax-highlighting>] Disable syntax-highlighting. Useful when
2762 the filtered output is piped into less in which case the ANSI control
2763 codes don't work, or if the terminal itself doesn't support the control
2764 codes.
2765
2766 [B<--shorten-thread-ids>] Shorten the thread ids to a three-digit decimal number.
2767 Note that the mapping from thread ids to shortened ids is created at run-time
2768 and thus varies with the input.
2769
2770 [B<--show-ineffective-filters>] Don't suppress log lines for filters
2771 that didn't modify the content.
2772
2773 [B<--show-complete-request-distribution>] Show the complete client request
2774 distribution in the B<--statistics> output. Without this option only the
2775 ten most common numbers are shown.
2776
2777 [B<--statistics>] Gather various statistics instead of syntax highlighting
2778 log messages. This is an experimental feature, if the results look wrong
2779 they very well might be. Also note that the results are pretty much guaranteed
2780 to be incorrect if Privoxy and Privoxy-Log-Parser aren't in sync.
2781
2782 [B<--strict-checks>] When generating statistics, look more careful at the
2783 input data and abort if it is unexpected, even if it doesn't affect the
2784 results. Significantly slows the parsing down and is not expected to catch
2785 any problems that matter.
2786 When highlighting, print warnings in case of unknown messages which can't be
2787 properly highlighted.
2788
2789 [B<--unbreak-lines-only>] Tries to fix lines that got messed up by a broken or
2790 interestingly configured mail client and thus are no longer recognized properly.
2791 Only fixes some breakage, but may be good enough or at least better than nothing.
2792 Doesn't do anything else, so you probably want to pipe the output into
2793 B<privoxy-log-parser> again.
2794
2795 [B<--url-statistics-threshold>] Only show the request count for a resource
2796 if it's above or equal to the given threshold. If the threshold is 0, URL
2797 statistics are disabled.
2798
2799 [B<--version>] Print version and exit.
2800
2801 =head1 EXAMPLES
2802
2803 To monitor a log file:
2804
2805 tail -F /usr/jails/privoxy-jail/var/log/privoxy/privoxy.log | B<privoxy-log-parser>
2806
2807 Replace '-F' with '-f' if your tail implementation lacks '-F' support
2808 or if the log won't get rotated anyway. The log file location depends
2809 on your system (Doh!).
2810
2811 To monitor Privoxy without having it write to a log file:
2812
2813 privoxy --no-daemon /usr/jails/privoxy-jail/usr/local/etc/privoxy/config 2>&1 | B<privoxy-log-parser>
2814
2815 Again, the config file location depends on your system. Output redirection
2816 depends on your shell, the above works with bourne shells.
2817
2818 To read a processed Privoxy log file from top to bottom, letting the content
2819 scroll by slightly faster than you can read:
2820
2821 B<privoxy-log-parser> < /usr/jails/privoxy-jail/var/log/privoxy/privoxy.log
2822
2823 This is probably only useful to fill screens in the background of haxor movies.
2824
2825 =head1 CAVEATS
2826
2827 Syntax highlighting with ANSI escape sequences will look strange
2828 if your background color isn't black.
2829
2830 Some messages aren't recognized yet and will not be fully highlighted.
2831
2832 B<privoxy-log-parser> is developed with Privoxy 3.0.7 or later in mind,
2833 using earlier Privoxy versions will probably result in an increased amount
2834 of unrecognized log lines.
2835
2836 Privoxy's log files tend to be rather large. If you use HTML
2837 highlighting some browsers can't handle them, get confused and
2838 will eventually crash because of segmentation faults or unexpected
2839 exceptions. This is a problem in the browser and not B<privoxy-log-parser>'s
2840 fault.
2841
2842 =head1 BUGS
2843
2844 Many settings can't be controlled through command line options yet.
2845
2846 =head1 SEE ALSO
2847
2848 privoxy(1)
2849
2850 =head1 AUTHOR
2851
2852 Fabian Keil <fk@fabiankeil.de>
2853
2854 =cut