b511931b07ded5dbd8f2359b1f31c057bc2a3222
[privoxy.git] / tools / privoxy-log-parser.pl
1 #!/usr/bin/perl
2
3 ################################################################################
4 # privoxy-log-parser
5 #
6 # A parser for Privoxy log messages. For incomplete documentation run
7 # perldoc privoxy-log-parser(.pl), for fancy screenshots see:
8 #
9 # https://www.fabiankeil.de/sourcecode/privoxy-log-parser/
10 #
11 # TODO:
12 #       - LOG_LEVEL_CGI, LOG_LEVEL_ERROR, LOG_LEVEL_WRITE content highlighting
13 #       - create fancy statistics
14 #       - grep through Privoxy sources to find unsupported log messages
15 #       - hunt down substitutions that match content from variables which
16 #         can contain stuff like ()?'[]
17 #       - replace $h{'foo'} with h('foo') where possible
18 #       - hunt down XXX comments instead of just creating them
19 #       - add example log lines for every regex and mark them up for
20 #         regression testing
21 #       - Handle incomplete input without Perl warning about undefined variables.
22 #       - Use generic highlighting function that takes a regex and the
23 #         hash key as input.
24 #       - Add --compress and --decompress options.
25 #
26 # Copyright (c) 2007-2022 Fabian Keil <fk@fabiankeil.de>
27 #
28 # Permission to use, copy, modify, and distribute this software for any
29 # purpose with or without fee is hereby granted, provided that the above
30 # copyright notice and this permission notice appear in all copies.
31 #
32 # THE SOFTWARE IS PROVIDED "AS IS" AND THE AUTHOR DISCLAIMS ALL WARRANTIES
33 # WITH REGARD TO THIS SOFTWARE INCLUDING ALL IMPLIED WARRANTIES OF
34 # MERCHANTABILITY AND FITNESS. IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR
35 # ANY SPECIAL, DIRECT, INDIRECT, OR CONSEQUENTIAL DAMAGES OR ANY DAMAGES
36 # WHATSOEVER RESULTING FROM LOSS OF USE, DATA OR PROFITS, WHETHER IN AN
37 # ACTION OF CONTRACT, NEGLIGENCE OR OTHER TORTIOUS ACTION, ARISING OUT OF
38 # OR IN CONNECTION WITH THE USE OR PERFORMANCE OF THIS SOFTWARE.
39 ################################################################################
40
41 use strict;
42 use warnings;
43 use Getopt::Long;
44
45 use constant {
46     PRIVOXY_LOG_PARSER_VERSION => '0.9.5',
47     # Feel free to mess with these ...
48     DEFAULT_BACKGROUND => 'black',  # Choose registered colour (like 'black')
49     DEFAULT_TEXT_COLOUR => 'white', # Choose registered colour (like 'black')
50     HEADER_DEFAULT_COLOUR => 'yellow',
51     REGISTER_HEADERS_WITH_THE_SAME_COLOUR => 1,
52
53     CLI_OPTION_DETECT_INACTIVITY => 0,
54     CLI_OPTION_DEFAULT_TO_HTML_OUTPUT => 0,
55     CLI_OPTION_TITLE => 'Privoxy-Log-Parser in da house',
56     CLI_OPTION_INACTIVITY_THRESHOLD => 100,
57     CLI_OPTION_KEEP_DATE => 0,
58     CLI_OPTION_NO_EMBEDDED_CSS => 0,
59     CLI_OPTION_NO_MSECS => 0,
60     CLI_OPTION_NO_SYNTAX_HIGHLIGHTING => 0,
61     CLI_OPTION_SHORTEN_THREAD_IDS => 0,
62     CLI_OPTION_SHOW_INEFFECTIVE_FILTERS => 0,
63     CLI_OPTION_STATISTICS => 0,
64     CLI_OPTION_STRICT_CHECKS => 0,
65     CLI_OPTION_UNBREAK_LINES_ONLY => 0,
66     CLI_OPTION_URL_STATISTICS_THRESHOLD => 0,
67     CLI_OPTION_PASSED_REQUEST_STATISTICS_THRESHOLD => 0,
68     CLI_OPTION_HOST_STATISTICS_THRESHOLD => 0,
69     CLI_OPTION_SHOW_COMPLETE_REQUEST_DISTRIBUTION => 0,
70
71     SUPPRESS_SUCCEEDED_FILTER_ADDITIONS => 1,
72     SHOW_SCAN_INTRO => 0,
73     SHOW_FILTER_READIN_IN => 0,
74     SUPPRESS_EMPTY_LINES => 1,
75     SUPPRESS_SUCCESSFUL_CONNECTIONS => 1,
76     SUPPRESS_GIF_NOT_CHANGED => 1,
77     SUPPRESS_NEED_TO_DE_CHUNK_FIRST => 1,
78
79     DEBUG_HEADER_REGISTERING => 0,
80     DEBUG_HEADER_HIGHLIGHTING => 0,
81     DEBUG_TICKS => 0,
82     DEBUG_PAINT_IT => 0,
83     DEBUG_SUPPRESS_LOG_MESSAGES => 0,
84
85     PUNISH_MISSING_LOG_KNOWLEDGE_WITH_DEATH => 0,
86     PUNISH_MISSING_HIGHLIGHT_KNOWLEDGE_WITH_DEATH => 1,
87
88     LOG_UNPARSED_LINES_TO_EXTRA_FILE => 0,
89     ERROR_LOG_FILE => '/var/log/privoxy-log-parser',
90
91     # You better leave these alone unless you know what you're doing.
92     COLOUR_RESET      => "\033[0;0m",
93     ESCAPE => "\033[",
94 };
95
96 # For performance reasons, these are global.
97
98 my $t;
99 my %req; # request data from previous lines
100 my %h;
101 my %thread_colours;
102 my @all_colours;
103 my @time_colours;
104 my $thread_colour_index = 0;
105 my $header_colour_index = 0;
106 my $time_colour_index = 0;
107 my %header_colours;
108 my $no_special_header_highlighting;
109 my %reason_colours;
110 my %h_colours;
111 my $header_highlight_regex = '';
112
113 my $html_output_mode;
114 my $keep_date_mode;
115 my $no_msecs_mode; # XXX: should probably be removed
116 my $shorten_thread_ids;
117 my $line_end;
118
119 sub prepare_our_stuff() {
120
121     # Syntax Higlight hash
122     @all_colours = (
123         'red', 'green', 'brown', 'blue', 'purple', 'cyan',
124         'light_gray', 'light_red', 'light_green', 'yellow',
125         'light_blue', 'pink', 'light_cyan', 'white'
126     );
127
128     %h = (
129         # LOG_LEVEL
130         Info            => 'blue',
131         Header          => 'green',
132         Filter          => 'purple', # XXX: Used?
133         'Re-Filter'     => 'purple',
134         Connect         => 'brown',
135         Request         => 'light_cyan',
136         Tagging         => 'purple',
137         CGI             => 'light_green',
138         Redirect        => 'cyan',
139         Error           => 'light_red',
140         Crunch          => 'cyan',
141         'Fatal error'   => 'light_red',
142         'Gif-Deanimate' => 'blue',
143         Force           => 'red',
144         Writing         => 'light_green',
145         Received        => 'yellow',
146         Actions         => 'yellow',
147         # ----------------------
148         URL                  => 'yellow',
149         path                 => 'brown',
150         request_             => 'brown', # host+path but no protocol
151         'ip-address'         => 'yellow',
152         Number               => 'yellow',
153         Standard             => 'reset',
154         Truncation           => 'light_red',
155         Status               => 'brown',
156         Timestamp            => 'brown',
157         Crunching            => 'light_red',
158         crunched             => 'light_red',
159         'Request-Line'       => 'pink',
160         method               => 'purple',
161         destination          => 'yellow',
162         'http-version'       => 'pink',
163         'crunch-pattern'     => 'pink',
164         not                  => 'brown',
165         file                 => 'brown',
166         signal               => 'yellow',
167         version              => 'green',
168         'program-name'       => 'cyan',
169         port                 => 'red',
170         host                 => 'red',
171         warning              => 'light_red',
172         debug                => 'light_red',
173         filter               => 'green',
174         tag                  => 'green',
175         tagger               => 'green',
176         'status-message'     => 'light_cyan',
177         'status-code'        => 'yellow',
178         'invalid-request'    => 'light_red',
179         'hits'               => 'yellow',
180         error                => 'light_red',
181         'rewritten-URL'      => 'light_red',
182         'pcrs-delimiter'     => 'light_red',
183         'ignored'            => 'light_red',
184         'action-bits-update' => 'light_red',
185         'http-downgrade'     => 'light_red',
186         'configuration-line' => 'red',
187         'content-type'       => 'yellow',
188         'HOST'               => HEADER_DEFAULT_COLOUR,
189         'tls-version'        => 'pink',
190         'cipher-suite'       => 'light_cyan',
191     );
192
193     %h_colours = %h;
194
195     # Header colours need their own hash so the keys can be accessed properly
196     %header_colours = (
197         # Prefilled with headers that should not appear with default header colours
198         Cookie => 'light_red',
199         'Set-Cookie' => 'light_red',
200         Warning => 'light_red',
201         Default => HEADER_DEFAULT_COLOUR,
202     );
203
204     # Crunch reasons need their own hash as well
205     %reason_colours = (
206         'Unsupported HTTP feature'               => 'light_red',
207         Blocked                                  => 'light_red',
208         Untrusted                                => 'light_red',
209         Redirected                               => 'green',
210         'CGI Call'                               => 'white',
211         'DNS failure'                            => 'red',
212         'Forwarding failed'                      => 'light_red',
213         'Connection failure'                     => 'light_red',
214         'Out of memory (may mask other reasons)' => 'light_red',
215         'No reason recorded'                     => 'light_red',
216     );
217
218     @time_colours = ('white', 'light_gray');
219
220     # Translate highlight strings into highlight code
221     prepare_highlight_hash(\%header_colours);
222     prepare_highlight_hash(\%reason_colours);
223     prepare_highlight_hash(\%h);
224     prepare_colour_array(\@all_colours);
225     prepare_colour_array(\@time_colours);
226     init_css_colours();
227
228     init_stats();
229 }
230
231 sub paint_it($) {
232 ###############################################################
233 # Takes a colour string and returns an ANSI escape sequence
234 # (unless --no-syntax-highlighting is used).
235 # XXX: The Rolling Stones reference has to go.
236 ###############################################################
237
238     my $colour = shift;
239
240     return "" if cli_option_is_set('no-syntax-highlighting');
241
242     my %light = (
243         black       => 0,
244         red         => 0,
245         green       => 0,
246         brown       => 0,
247         blue        => 0,
248         purple      => 0,
249         cyan        => 0,
250         light_gray  => 0,
251         gray        => 0,
252         dark_gray   => 1,
253         light_red   => 1,
254         light_green => 1,
255         yellow      => 1,
256         light_blue  => 1,
257         pink        => 1,
258         light_cyan  => 1,
259         white       => 1,
260     );
261
262     my %text = (
263         black       => 30,
264         red         => 31,
265         green       => 32,
266         brown       => 33,
267         blue        => 34,
268         purple      => 35,
269         cyan        => 36,
270         gray        => 37,
271         light_gray  => 37,
272         dark_gray   => 30,
273         light_red   => 31,
274         light_green => 32,
275         yellow      => 33,
276         light_blue  => 34,
277         pink        => 35,
278         light_cyan  => 36,
279         white       => 37,
280     );
281
282     my $bg_code = get_background();
283     my $colour_code;
284     our $default = default_colours();
285
286     if (defined($text{$colour})) {
287         $colour_code  = ESCAPE;
288         $colour_code .= $text{$colour};
289         $colour_code .= ";";
290         $colour_code .= $light{$colour} ? "1" : "2";
291         $colour_code .= ";";
292         $colour_code .= $bg_code;
293         $colour_code .= "m";
294         debug_message $colour . " is \'" . $colour_code . $colour . $default . "\'" if DEBUG_PAINT_IT;
295
296     } elsif ($colour =~ /reset/) {
297
298         $colour_code = default_colours();
299
300     } else {
301
302         die "What's $colour supposed to mean?\n";
303     }
304
305     return $colour_code;
306 }
307
308 sub get_semantic_html_markup($) {
309 ###############################################################
310 # Takes a string and returns a span element
311 ###############################################################
312
313     my $type = shift;
314     my $code;
315
316     if ($type =~ /Standard/) {
317         $code = '</span>';
318     } else {
319         $type = lc($type);
320         $code = '<span title="' . $type . '" class="' . $type . '">';
321     }
322
323     return $code;
324 }
325
326 sub cli_option_is_set($) {
327
328     our %cli_options;
329     my $cli_option = shift;
330
331     die "Unknown CLI option: $cli_option" unless defined $cli_options{$cli_option};
332
333     return $cli_options{$cli_option};
334 }
335
336 sub get_html_title() {
337
338     our %cli_options;
339     return $cli_options{'title'};
340
341 }
342
343 sub init_css_colours() {
344
345     our %css_colours = (
346         black       => "000",
347         red         => "F00",
348         green       => "0F0",
349         brown       => "C90",
350         blue        => "0F0",
351         purple      => "F06", # XXX: wrong
352         cyan        => "F09", # XXX: wrong
353         light_gray  => "999",
354         gray        => "333",
355         dark_gray   => "222",
356         light_red   => "F33",
357         light_green => "33F",
358         yellow      => "FF0",
359         light_blue  => "30F",
360         pink        => "F0F",
361         light_cyan  => "66F",
362         white       => "FFF",
363     );
364 }
365
366 sub get_css_colour($) {
367
368    our %css_colours;
369    my $colour = shift;
370
371    die "What's $colour supposed to mean?\n" unless defined($css_colours{$colour});
372
373    return '#' . $css_colours{$colour};
374 }
375
376 sub get_css_line($) {
377
378     my $class = shift;
379     my $css_line;
380
381     $css_line .= '.' . lc($class) . ' {'; # XXX: lc() shouldn't be necessary
382     die "What's $class supposed to mean?\n" unless defined($h_colours{$class});
383     $css_line .= 'color:' . get_css_colour($h_colours{$class}) . ';';
384     $css_line .= 'background-color:' . get_css_colour(DEFAULT_BACKGROUND) . ';';
385     $css_line .= '}' . "\n";
386
387     return $css_line;
388 }
389
390 sub get_css_line_for_colour($) {
391
392     my $colour = shift;
393     my $css_line;
394
395     $css_line .= '.' . lc($colour) . ' {'; # XXX: lc() shouldn't be necessary
396     $css_line .= 'color:' . get_css_colour($colour) . ';';
397     $css_line .= 'background-color:' . get_css_colour(DEFAULT_BACKGROUND) . ';';
398     $css_line .= '}' . "\n";
399
400     return $css_line;
401 }
402
403 # XXX: Wrong solution
404 sub get_missing_css_lines() {
405
406     my $css_line;
407
408     $css_line .= '.' . 'default' . ' {';
409     $css_line .= 'color:' . HEADER_DEFAULT_COLOUR . ';';
410     $css_line .= 'background-color:' . get_css_colour(DEFAULT_BACKGROUND) . ';';
411     $css_line .= '}' . "\n";
412
413     return $css_line;
414 }
415
416 sub get_css() {
417
418     our %css_colours; #XXX: Wrong solution
419
420     my $css = '';
421
422     $css .= '.privoxy-log {';
423     $css .= 'color:' . get_css_colour(DEFAULT_TEXT_COLOUR) . ';';
424     $css .= 'background-color:' . get_css_colour(DEFAULT_BACKGROUND) . ';';
425     $css .= '}' . "\n";
426
427     foreach my $key (keys %h_colours) {
428
429         next if ($h_colours{$key} =~ m/reset/); #XXX: Wrong solution.
430         $css .= get_css_line($key);
431
432     }
433
434     foreach my $colour (keys %css_colours) {
435
436         $css .= get_css_line_for_colour($colour);
437
438     }
439
440     $css .= get_missing_css_lines(); #XXX: Wrong solution
441
442     return $css;
443 }
444
445 sub print_intro() {
446
447     my $intro = '';
448
449     if (cli_option_is_set('html-output')) {
450
451         my $title = get_html_title();
452
453         $intro .= '<html><head>';
454         $intro .= '<title>' . $title . '</title>';
455         $intro .= '<style>' . get_css() . '</style>' unless cli_option_is_set('no-embedded-css');
456         $intro .= '</head><body>';
457         $intro .= '<h1>' . $title . '</h1><p class="privoxy-log">';
458
459         print $intro;
460     }
461 }
462
463 sub print_outro() {
464
465     my $outro = '';
466
467     if (cli_option_is_set('html-output')) {
468
469         $outro = '</p></body></html>';
470         print $outro;
471
472     }
473 }
474
475 sub get_line_end() {
476     return cli_option_is_set('html-output') ? "<br>\n" : "\n";
477 }
478
479 sub get_colour_html_markup($) {
480 ###############################################################
481 # Takes a colour string a span element. XXX: WHAT?
482 # XXX: This function shouldn't be necessary, the
483 # markup should always be semantically correct.
484 ###############################################################
485
486     my $type = shift;
487     my $code;
488
489     if ($type =~ /Standard/) {
490         $code = '</span>';
491     } else {
492         $code = '<span class="' . lc($type) . '">';
493     }
494
495     return $code;
496 }
497
498 sub default_colours() {
499     # XXX: Properly
500     our $bg_code;
501     return reset_colours();
502 }
503
504 sub show_colours() {
505     # XXX: Implement
506 }
507
508 sub reset_colours() {
509     return ESCAPE . "0m";
510 }
511
512 sub set_background($) {
513
514     my $colour = shift;
515     our $bg_code;
516     my %backgrounds = (
517               black       => "40",
518               red         => "41",
519               green       => "42",
520               brown       => "43",
521               blue        => "44",
522               magenta     => "45",
523               cyan        => "46",
524               white       => "47",
525               default     => "49",
526     );
527
528     if (defined($backgrounds{$colour})) {
529         $bg_code = $backgrounds{$colour};
530     } else {
531         die "Invalid background colour: " . $colour;
532     }
533 }
534
535 sub get_background() {
536     return our $bg_code;
537 }
538
539 sub prepare_highlight_hash($) {
540     my $ref = shift;
541
542     foreach my $key (keys %$ref) {
543         $$ref{$key} = $html_output_mode ?
544             get_semantic_html_markup($key) :
545             paint_it($$ref{$key});
546     }
547 }
548
549 sub prepare_colour_array($) {
550     my $ref = shift;
551
552     foreach my $i (0 ... @$ref - 1) {
553         $$ref[$i] = $html_output_mode ?
554             get_colour_html_markup($$ref[$i]) :
555             paint_it($$ref[$i]);
556     }
557 }
558
559 sub found_unknown_content($) {
560
561     my $unknown = shift;
562     my $message;
563
564     return unless cli_option_is_set('strict-checks');
565
566     return if ($unknown =~ /\[too long, truncated\]$/);
567
568     $message = "found_unknown_content: Don't know how to highlight: ";
569     # Break line so the log file can later be parsed as Privoxy log file again
570     $message .= '"' . $unknown . '"' . " in:\n";
571     $message .= $req{$t}{'log-message'};
572     debug_message($message);
573     log_parse_error($req{$t}{'log-message'});
574
575     die "Unworthy content parser" if PUNISH_MISSING_LOG_KNOWLEDGE_WITH_DEATH;
576 }
577
578 sub log_parse_error($) {
579
580     my $message = shift;
581
582     if (LOG_UNPARSED_LINES_TO_EXTRA_FILE) {
583         open(my $errorlog_fd, ">>", ERROR_LOG_FILE) || die "Writing " . ERROR_LOG_FILE . " failed";
584         print $errorlog_fd $message;
585         close($errorlog_fd);
586     }
587 }
588
589 sub debug_message(@) {
590     my @message = @_;
591
592     print $h{'debug'} . "@message" . $h{'Standard'} . "\n";
593 }
594
595 ################################################################################
596 # highlighter functions that aren't loglevel-specific
597 ################################################################################
598
599 sub h($) {
600
601     # Get highlight marker
602     my $highlight = shift; # XXX: Stupid name;
603     my $result = '';
604     my $message;
605
606     if (defined($highlight)) {
607
608         $result = $h{$highlight};
609
610     } else {
611
612         $message = "h: Don't recognize highlighter $highlight.";
613         debug_message($message);
614         log_parser_error($message);
615         die "Unworthy highlighter function" if PUNISH_MISSING_HIGHLIGHT_KNOWLEDGE_WITH_DEATH;
616     }
617
618     return $result;
619 }
620
621 sub highlight_known_headers($) {
622
623     my $content = shift;
624
625     debug_message("Searching $content for things to highlight.") if DEBUG_HEADER_HIGHLIGHTING;
626
627     if ($content =~ m/(?<=\s)($header_highlight_regex):/) {
628         my $header = $1;
629         $content =~ s@(?<=[\s|'])($header)(?=:)@$header_colours{$header}$1$h{'Standard'}@ig;
630         debug_message("Highlighted '$header' in '$content'") if DEBUG_HEADER_HIGHLIGHTING;
631     }
632
633     return $content;
634 }
635
636 sub highlight_matched_request_line($$) {
637
638     my $result = shift; # XXX: Stupid name;
639     my $regex = shift;
640     if ($result =~ m@(.*)($regex)(.*)@) {
641         $result = $1 . highlight_request_line($2) . $3
642     }
643     return $result;
644 }
645
646 sub highlight_request_line($) {
647
648     my $rl = shift;
649     my ($method, $url, $http_version);
650
651     #GET http://images.sourceforge.net/sfx/icon_warning.gif HTTP/1.1
652     if ($rl =~ m/Invalid request/ or $rl =~ m/Failed reading chunked client body/) {
653
654         $rl = h('invalid-request') . $rl . h('Standard');
655
656     } elsif ($rl =~ m/^([-\w]+) (.*) (HTTP\/\d+\.\d+)/) {
657
658         # XXX: might not match in case of HTTP method fuzzing.
659         # XXX: save these: ($method, $path, $http_version) = ($1, $2, $3);
660         $rl =~ s@^(\w+)@$h{'method'}$1$h{'Standard'}@;
661         if ($rl =~ /http:\/\//) {
662             $rl = highlight_matched_url($rl, '[^\s]*(?=\sHTTP)');
663         } else {
664             $rl = highlight_matched_pattern($rl, 'request_', '[^\s]*(?=\sHTTP)');
665         }
666
667         $rl =~ s@(HTTP\/\d\.\d)$@$h{'http-version'}$1$h{'Standard'}@;
668
669     } elsif ($rl =~ m/\.\.\. \[too long, truncated\]$/) {
670
671         $rl =~ s@^(\w+)@$h{'method'}$1$h{'Standard'}@;
672         $rl = highlight_matched_url($rl, '[^\s]*(?=\.\.\.)');
673
674     } elsif ($rl =~ m/^ $/) {
675
676         $rl = h('error') . "No request line specified!" . h('Standard');
677
678     } else {
679
680         debug_message ("Can't parse request line: $rl");
681
682     }
683
684     return $rl;
685 }
686
687 sub highlight_response_line($) {
688
689     my $rl = shift;
690     my ($http_version, $status_code, $status_message);
691
692     #HTTP/1.1 200 OK
693     #ICY 200 OK
694
695     # TODO: Mark different status codes differently
696
697     if ($rl =~ m/((?:HTTP\/\d\.\d|ICY)) (\d+) (.*)/) {
698         ($http_version, $status_code, $status_message) = ($1, $2, $3);
699     } else {
700         debug_message ("Can't parse response line: $rl") and die 'Fix this';
701     }
702
703     # Rebuild highlighted
704     $rl= "";
705     $rl .= h('http-version') . $http_version . h('Standard');
706     $rl .= " ";
707     $rl .= h('status-code') . $status_code . h('Standard');
708     $rl .= " ";
709     $rl .= h('status-message') . $status_message . h('Standard');
710
711     return $rl;
712 }
713
714 sub highlight_matched_url($$) {
715
716     my $result = shift; # XXX: Stupid name;
717     my $regex = shift;
718
719     #print "Got $result, regex ($regex)\n";
720
721     if ($result =~ m@(.*?)($regex)(.*)@) {
722         $result = $1 . highlight_url($2) . $3;
723         #print "Now the result is $result\n";
724     }
725
726     return $result;
727 }
728
729 sub highlight_matched_host($$) {
730
731     my ($result, $regex) = @_; # XXX: result ist stupid name;
732
733     if ($result =~ m@(.*?)($regex)(.*)@) {
734         $result = $1 . $h{host} . $2 . $h{Standard} . $3;
735     }
736
737     return $result;
738 }
739
740 sub highlight_matched_pattern($$$) {
741
742     my $result = shift; # XXX: Stupid name;
743     my $key = shift;
744     my $regex = shift;
745
746     die "Unknown key $key" unless defined $h{$key};
747
748     if ($result =~ m@(.*?)($regex)(.*)@) {
749         $result = $1 . h($key) . $2 . h('Standard') . $3;
750     }
751
752     return $result;
753 }
754
755 sub highlight_matched_path($$) {
756
757     my $result = shift; # XXX: Stupid name;
758     my $regex = shift;
759
760     if ($result =~ m@(.*?)($regex)(.*)@) {
761         $result = $1 . h('path') . $2 . h('Standard') . $3;
762     }
763
764     return $result;
765 }
766
767 sub highlight_url($) {
768
769     my $url = shift;
770
771     if ($html_output_mode) {
772
773         $url = '<a href="' . $url . '">' . $url . '</a>';
774
775     } else {
776
777         $url = h('URL') . $url . h('Standard');
778
779     }
780
781     return $url;
782 }
783
784 sub update_header_highlight_regex($) {
785
786     my $header = shift;
787     my $headers = join ('|', keys %header_colours);
788
789     $header_highlight_regex = qr/$headers/;
790     print "Registering '$header'\n" if DEBUG_HEADER_HIGHLIGHTING;
791 }
792
793 ################################################################################
794 # loglevel-specific highlighter functions
795 ################################################################################
796
797 sub handle_loglevel_header($) {
798
799     my $c = shift;
800
801     if ($c =~ /^scan:/) {
802
803         if ($c =~ m/^scan: ([^: ]+):/) {
804
805             # Register new headers
806             # scan: Accept: image/png,image/*;q=0.8,*/*;q=0.5
807             my $header = $1;
808             if (!defined($header_colours{$header}) and $header =~ /^[\d\w-]*$/) {
809                 debug_message "Registering previously unknown header $1" if DEBUG_HEADER_REGISTERING;
810
811                 if (REGISTER_HEADERS_WITH_THE_SAME_COLOUR) {
812                     $header_colours{$header} =  $header_colours{'Default'};
813                 } else {
814                     $header_colours{$header} = $all_colours[$header_colour_index % @all_colours];
815                     $header_colour_index++;
816                 }
817                 update_header_highlight_regex($header);
818             }
819
820         } elsif ($c =~ m/^(scan: )(\w+ .+ HTTP\/\d\.\d)/) {
821
822             # scan: GET http://p.p/ HTTP/1.1
823             $c = $1 . highlight_request_line($2);
824
825         } elsif ($c =~ m/^(scan: )((?:HTTP\/\d\.\d|ICY) (\d+) (.*))/) {
826
827             # scan: HTTP/1.1 200 OK
828             $req{$t}{'response_line'} = $2;
829             $req{$t}{'status_code'} = $3;
830             $req{$t}{'status_message'} = $4;
831             $c = $1 . highlight_response_line($req{$t}{'response_line'});
832         }
833
834     } elsif ($c =~ m/^Crunching (?:server|client) header: .* \(contains: ([^\)]*)\)/) {
835
836         # Crunching server header: Set-Cookie: trac_form_token=d5308c34e16d15e9e301a456; (contains: Cookie:)
837         $c =~ s@(?<=contains: )($1)@$h{'crunch-pattern'}$1$h{'Standard'}@;
838         $c =~ s@(Crunching)@$h{$1}$1$h{'Standard'}@;
839
840     } elsif ($c =~ m/^New host is: ([^\s]*)\./) {
841
842         # New host is: trac.vidalia-project.net. Crunching Referer: http://www.vidalia-project.net/!
843         $c = highlight_matched_host($c, '(?<=New host is: )[^\s]+(?=\.)');
844         $c = highlight_matched_url($c, '(?<=Crunching Referer: )[^\s!]+');
845
846     } elsif ($c =~ m/^Text mode enabled by force. (Take cover)!/) {
847
848         # Text mode enabled by force. Take cover!
849         $c =~ s@($1)@$h{'warning'}$1$h{'Standard'}@;
850
851     } elsif ($c =~ m/^(New HTTP Request-Line: )(.*)/) {
852
853         # New HTTP Request-Line: GET http://www.privoxy.org/ HTTP/1.1
854         $c = $1 . highlight_request_line($2);
855
856     } elsif ($c =~ m/^Adjust(ed)? Content-Length to \d+/) {
857
858         # Adjusted Content-Length to 2132
859         # Adjust Content-Length to 33533
860         $c =~ s@(?<=Content-Length to )(\d+)@$h{'Number'}$1$h{'Standard'}@;
861         $c = highlight_known_headers($c);
862
863     } elsif ($c =~ m/^Destination extracted from "Host:" header. New request URL:/) {
864
865         # Destination extracted from "Host:" header. New request URL: http://www.cccmz.de/~ridcully/blog/
866         $c = highlight_matched_url($c, '(?<=New request URL: ).*');
867
868     } elsif ($c =~ m/^Couldn\'t parse:/) {
869
870         # XXX: These should probable be logged with LOG_LEVEL_ERROR
871         # Couldn't parse: If-Modified-Since: Wed, 21 Mar 2007 16:34:50 GMT (crunching!)
872         # Couldn't parse: at, 24 Mar 2007 13:46:21 GMT in If-Modified-Since: Sat, 24 Mar 2007 13:46:21 GMT (crunching!)
873         $c =~ s@^(Couldn\'t parse)@$h{'error'}$1$h{'Standard'}@;
874
875     } elsif ($c =~ /^Tagger \'([^\']*)\' added tag \'([^\']*)\'/ or
876              $c =~ m/^Adding tag \'([^\']*)\' created by header tagger \'([^\']*)\'/) {
877
878         # Adding tag 'GET request' created by header tagger 'method-man' (XXX: no longer used)
879         # Tagger 'revalidation' added tag 'REVALIDATION-REQUEST'. No action bit update necessary.
880         # Tagger 'revalidation' added tag 'REVALIDATION-REQUEST'. Action bits updated accordingly.
881
882         # XXX: Save tag and tagger
883
884         $c =~ s@(?<=^Tagger \')([^\']*)@$h{'tagger'}$1$h{'Standard'}@;
885         $c =~ s@(?<=added tag \')([^\']*)@$h{'tag'}$1$h{'Standard'}@;
886         $c =~ s@(?<=Action bits )(updated)@$h{'action-bits-update'}$1$h{'Standard'}@;
887         $no_special_header_highlighting = 1;
888
889     } elsif ($c =~ /^Tagger \'([^\']*)\' didn['']t add tag \'([^\']*)\'/) {
890
891         # Tagger 'revalidation' didn't add tag 'REVALIDATION-REQUEST'. Tag already present
892         # XXX: Save tag and tagger
893
894         $c =~ s@(?<=^Tagger \')([^\']*)@$h{'tag'}$1$h{'Standard'}@;
895         $c =~ s@(?<=didn['']t add tag \')([^\']*)@$h{'tagger'}$1$h{'Standard'}@;
896
897     } elsif ($c =~ m/^(?:scan:|Randomiz|addh:|Adding:|Removing:|Referer:|Modified:|Accept-Language header|[Cc]ookie)/
898           or $c =~ m/^(Text mode is already enabled|Denied request with NULL byte|Replaced:|add-unique:)/
899           or $c =~ m/^(Crunched (incoming|outgoing) cookie|Suppressed offer|Accepted the client)/
900           or $c =~ m/^(addh-unique|Referer forged to)/
901           or $c =~ m/^Downgraded answer to HTTP\/1.0/
902           or $c =~ m/^Parameter: \+hide-referrer\{[^\}]*\} is a bad idea, but I don\'t care./
903           or $c =~ m/^Referer (?:overwritten|replaced) with: Referer: / #XXX: should this be highlighted?
904           or $c =~ m/^Referer crunched!/
905           or $c =~ m/^crunched x-forwarded-for!/
906           or $c =~ m/^crunched From!/
907           or $c =~ m/^ modified$/
908           or $c =~ m/^Content filtering is enabled. Crunching:/
909           or $c =~ m/^force-text-mode overruled the client/
910           or $c =~ m/^Server time in the future\./
911           or $c =~ m/^content-disposition header crunched and replaced with:/i
912           or $c =~ m/^Reducing white space in /
913           or $c =~ m/^Ignoring single quote in /
914           or $c =~ m/^Converting tab to space in /
915           or $c =~ m/A HTTP\/1\.1 response without/
916           or $c =~ m/Disabled filter mode on behalf of the client/
917           or $c =~ m/Keeping the (?:server|client) header /
918           or $c =~ m/Content modified with no Content-Length header set/
919           or $c =~ m/^Appended client IP address to/
920           or $c =~ m/^Removing 'Connection: close' to imply keep-alive./
921           or $c =~ m/^keep-alive support is disabled/
922           or $c =~ m/^Continue hack in da house/
923           or $c =~ m/^Merged multiple header lines to:/
924           or $c =~ m/^Added header: /
925           or $c =~ m/^Enlisting (?:sorted|left-over) header/
926           or $c =~ m/^Multiple Content-Type headers detected. Removing and ignoring: Content-Type:/
927             )
928     {
929         # XXX: Some of these may need highlighting
930
931         # Modified: User-Agent: Mozilla/5.0 (X11; U; SunOS i86pc; pl-PL; rv:1.8.1.1) Gecko/20070214 Firefox/2.0.0.1
932         # Accept-Language header crunched and replaced with: Accept-Language: pl-pl
933         # cookie 'Set-Cookie: eZSessionCookie=07bfec287c197440d299f81580593c3d; \
934         #  expires=Thursday, 12-Apr-07 15:16:18 GMT; path=/' send by \
935         #  http://wirres.net/article/articleview/4265/1/6/ appears to be using time format 1 (XXX: gone with the wind)
936         # Cookie rewritten to a temporary one: Set-Cookie: NSC_gffe-iuuq-mc-wtfswfs=8efb33a53660;path=/
937         # Text mode is already enabled
938         # Denied request with NULL byte(s) turned into line break(s)
939         # Replaced: 'Connection: Yo, home to Bel Air' with 'Connection: close'
940         # addh-unique: Host: people.freebsd.org
941         # Suppressed offer to compress content
942         # Crunched incoming cookie -- yum!
943         # Accepted the client's request to fetch without filtering.
944         # Crunched outgoing cookie: Cookie: PREF=ID=6cf0abd347b30262:TM=1173357617:LM=1173357617:S=jZypyyJ7LPiwFi1_
945         # addh-unique: Host: subkeys.pgp.net:11371
946         # Referer forged to: Referer: http://10.0.0.1/
947         # Downgraded answer to HTTP/1.0
948         # Parameter: +hide-referrer{pille-palle} is a bad idea, but I don't care.
949         # Referer overwritten with: Referer: pille-palle
950         # Referer replaced with: Referer: pille-palle
951         # crunched x-forwarded-for!
952         # crunched From!
953         #  modified # XXX: pretty stupid log message
954         # Content filtering is enabled. Crunching: 'Range: 1234-5678' to prevent range-mismatch problems
955         # force-text-mode overruled the client's request to fetch without filtering!
956         # Server time in the future.
957         # content-disposition header crunched and replaced with: content-disposition: filename=baz
958         # Content-Disposition header crunched and replaced with: content-disposition: filename=baz
959         # Reducing white space in 'X-LWS-Test: "This  is  quoted" this is not "this  is  " but " this again   is  not'
960         # Ignoring single quote in 'X-LWS-Test: "This  is  quoted" this is not "this  is  " but "  this again   is  not'
961         # Converting tab to space in 'X-LWS-Test:   "This  is  quoted" this   is  not "this  is  "  but  "\
962         #  this again   is  not'
963         # A HTTP/1.1 response without Connection header implies keep-alive.
964         # Disabled filter mode on behalf of the client.
965         # Keeping the server header 'Connection: keep-alive' around.
966         # Keeping the client header 'Connection: close' around. The connection will not be kept alive.
967         # Keeping the client header 'Connection: keep-alive' around. The connection will be kept alive if possible.
968         # Content modified with no Content-Length header set. Creating a fake one for adjustment later on.
969         # Appended client IP address to X-Forwarded-For: 10.0.0.2, 10.0.0.1
970         # Removing 'Connection: close' to imply keep-alive.
971         # keep-alive support is disabled. Crunching: Keep-Alive: 300.
972         # Continue hack in da house.
973         # Merged multiple header lines to: 'X-FORWARDED-PROTO: http X-HOST: 127.0.0.1'
974         # Added header: Content-Encoding: deflate
975         # Enlisting sorted header User-Agent: Mozilla/5.0 (X11; SunOS i86pc; rv:10.0.3) Gecko/20100101 Firefox/10.0.3
976         # Enlisting left-over header Connection: close
977         # Multiple Content-Type headers detected. Removing and ignoring: Content-Type: text/html
978
979     } elsif ($c =~ m/^scanning headers for:/) {
980
981         return '' unless SHOW_SCAN_INTRO;
982
983     } elsif ($c =~ m/^[Cc]runch(ing|ed)|crumble crunched:/) {
984         # crunched User-Agent!
985         # Crunching: Content-Encoding: gzip
986
987         $c =~ s@(Crunching|crunched)@$h{$1}$1$h{'Standard'}@;
988
989     } elsif ($c =~ m/^Offending request data with NULL bytes turned into \'°\' characters:/) {
990
991         # Offending request data with NULL bytes turned into '°' characters: °°n°°(°°°
992
993         $c = h('warning') . $c . h('Standard');
994
995     } elsif ($c =~ m/^(Transforming \")(.*?)(\" to \")(.*?)(\")/) {
996
997         # Transforming "Proxy-Authenticate: Basic realm="Correos Proxy Server"" to\
998         #  "Proxy-Authenticate: Basic realm="Correos Proxy Server""
999
1000        $c =~ s@(?<=^Transforming \")(.*)(?=\" to)@$h{'Header'}$1$h{'Standard'}@;
1001        $c =~ s@(?<=to \")(.*)(?=\")@$h{'Header'}$1$h{'Standard'}@;
1002
1003     } elsif ($c =~ m/^Removing empty header/) {
1004
1005         # Removing empty header
1006         # Ignore for now
1007
1008     } elsif ($c =~ m/^Content-Type: .* not replaced/) {
1009
1010         # Content-Type: application/octet-stream not replaced. It doesn't look like text.\
1011         #  Enable force-text-mode if you know what you're doing.
1012         # XXX: Could highlight more here.
1013         $c =~ s@(?<=^Content-Type: )(.*)(?= not replaced)@$h{'content-type'}$1$h{'Standard'}@;
1014
1015     } elsif ($c =~ m/^(Server|Client) keep-alive timeout is/) {
1016
1017        # Server keep-alive timeout is 5. Sticking with 10.
1018        # Client keep-alive timeout is 20. Sticking with 10.
1019
1020        $c =~ s@(?<=timeout is )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1021        $c =~ s@(?<=Sticking with )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1022
1023     } elsif ($c =~ m/^Reducing keep-alive timeout/) {
1024
1025        # Reducing keep-alive timeout from 60 to 10.
1026
1027        $c =~ s@(?<= from )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1028        $c =~ s@(?<= to )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1029
1030     } elsif ($c =~ m/^Killed all-caps Host header line: HOST:/) {
1031
1032        # Killed all-caps Host header line: HOST: bestproxydb.com
1033        $c = highlight_matched_host($c, '(?<=HOST: )[^\s]+');
1034        $c = highlight_matched_pattern($c, 'HOST', 'HOST');
1035
1036     } else {
1037
1038         found_unknown_content($c);
1039     }
1040
1041     # Highlight headers
1042     unless ($c =~ m/^Transforming/) {
1043         $c = highlight_known_headers($c) unless $no_special_header_highlighting;
1044     }
1045
1046     return $c;
1047 }
1048
1049 sub handle_loglevel_re_filter($) {
1050
1051     my $content = shift;
1052     my $c = $content;
1053     my $key;
1054
1055     if ($c =~ m/^(?:re_)?filtering ([^\s]+) \(size (\d+)\) with (?:filter )?\'?([^\s]+?)\'? produced (\d+) hits \(new size (\d+)\)/) {
1056
1057         # XXX: only the second version gets highlighted properly.
1058         # re_filtering www.lfk.de/favicon.ico (size 209) with filter untrackable-hulk produced 0 hits (new size 209).
1059         # filtering aci.blogg.de/ (size 37988) with 'blogg.de' produced 3 hits (new size 38057)
1060         $req{$t}{'content_source'} = $1;
1061         $req{$t}{'content_size'}   = $2;
1062         $req{$t}{'content_filter'} = $3;
1063         $req{$t}{'content_hits'}   = $4;
1064         $req{$t}{'new_content_size'} = $5;
1065         $req{$t}{'content_size_change'} = $req{$t}{'new_content_size'} - $req{$t}{'content_size'};
1066         #return '' if ($req{$t}{'content_hits'} == 0 && !cli_option_is_set('show-ineffective-filters'));
1067         if ($req{$t}{'content_hits'} == 0 and
1068             not (cli_option_is_set('show-ineffective-filters')
1069                  or ($req{$t}{'content_filter'} =~ m/^privoxy-filter-test$/))) {
1070                 return '';
1071         }
1072
1073         $c =~ s@(?<=\(size )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1074         $c =~ s@(?<=\(new size )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1075         $c =~ s@(?<=produced )(\d+)(?= hits)@$h{'Number'}$1$h{'Standard'}@;
1076
1077         $c =~ s@([^\s]+?)(\'? produced)@$h{'filter'}$1$h{'Standard'}$2@;
1078         $c = highlight_matched_host($c, '(?<=filtering )[^\s]+');
1079
1080         $c =~ s@\.$@ @;
1081         $c .= "(" . $h{'Number'};
1082         $c .= "+" if ($req{$t}{'content_size_change'} >= 0);
1083         $c .= $req{$t}{'content_size_change'} . $h{'Standard'} . ")";
1084         $content = $c;
1085
1086     } elsif ($c =~ m/^filtering request body from client /) {
1087
1088         # filtering request body from client 127.0.0.1 (size 958) with 'null-filter' produced 0 hits (new size 958).
1089
1090         $c =~ s@(?<=from client )([^\s]+)@$h{'ip-address'}$1$h{'Standard'}@;
1091         $c =~ s@(?<=\(size )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1092         $c =~ s@([^\s]+?)(\'? produced)@$h{'filter'}$1$h{'Standard'}$2@;
1093         $c =~ s@(?<=\(new size )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1094         $c =~ s@(?<=produced )(\d+)(?= hits)@$h{'Number'}$1$h{'Standard'}@;
1095         $content = $c;
1096
1097   } elsif ($c =~ /\.{3}$/
1098         and $c =~ m/^(?:re_)?filtering \'?(.*?)\'? \(size (\d*)\) with (?:filter )?\'?([^\s]*?)\'? ?\.{3}$/) {
1099
1100         # Used by Privoxy 3.0.5 and 3.0.6:
1101         # XXX: Fill in ...
1102         # Used by Privoxy 3.0.7:
1103         # filtering 'Connection: close' (size 17) with 'generic-content-ads' ...
1104
1105         $req{$t}{'filtered_header'} = $1;
1106         $req{$t}{'old_header_size'} = $2;
1107         $req{$t}{'header_filter_name'} = $3;
1108
1109         unless (cli_option_is_set('show-ineffective-filters') or
1110                 $req{$t}{'header_filter_name'} =~ m/^privoxy-filter-test$/) {
1111             return '';
1112         }
1113         $content =~ s@(?<=\(size )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1114         $content =~ s@($req{$t}{'header_filter_name'})@$h{'filter'}$1$h{'Standard'}@;
1115
1116     } elsif ($c =~ m/^ ?\.\.\. ?produced (\d*) hits \(new size (\d*)\)\./) {
1117
1118         # ...produced 0 hits (new size 23).
1119         #... produced 1 hits (new size 54).
1120
1121         $req{$t}{'header_filter_hits'} = $1;
1122         $req{$t}{'new_header_size'} = $2;
1123
1124         unless (cli_option_is_set('show-ineffective-filters') or
1125                 (defined($req{$t}{'header_filter_name'}) and
1126                  $req{$t}{'header_filter_name'} =~ m/^privoxy-filter-test$/)) {
1127
1128             if ($req{$t}{'header_filter_hits'} == 0 and
1129                 not (defined($req{$t}{'header_filter_name'}) and
1130                  $req{$t}{'header_filter_name'} =~ m/^privoxy-filter-test$/)) {
1131                 return '';
1132             }
1133             # Reformat including information from the intro
1134             $c = "'" . h('filter') . $req{$t}{'header_filter_name'} . h('Standard') . "'";
1135             $c .= " hit ";
1136             # XXX: Hide behind constant, it may be interesting if LOG_LEVEL_HEADER isn't enabled as well.
1137             # $c .= $req{$t}{'filtered_header'} . " ";
1138             $c .= h('Number') . $req{$t}{'header_filter_hits'}. h('Standard');
1139             $c .= ($req{$t}{'header_filter_hits'} == 1) ? " time, " : " times, ";
1140
1141             if ($req{$t}{'old_header_size'} !=  $req{$t}{'new_header_size'}) {
1142
1143                 $c .= "changing size from ";
1144                 $c .=  h('Number') . $req{$t}{'old_header_size'} . h('Standard');
1145                 $c .= " to ";
1146                 $c .= h('Number') . $req{$t}{'new_header_size'} . h('Standard');
1147                 $c .= ".";
1148
1149             } else {
1150
1151                 $c .= "keeping the size at " . $req{$t}{'old_header_size'};
1152
1153             }
1154
1155             # Highlight from last line (XXX: What?)
1156             # $c =~ s@(?<=produced )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1157             # $c =~ s@($req{$t}{'header_filter_name'})@$h{'filter'}$1$h{'Standard'}@;
1158
1159         } else {
1160
1161            # XXX: Untested
1162            $c =~ s@(?<=produced )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1163            $c =~ s@(?<=new size )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1164
1165         }
1166         $content = $c;
1167
1168     } elsif ($c =~ m/^(Tagger|Filter) ([^\s]*) has empty joblist. Nothing to do./) {
1169
1170         # Filter privoxy-filter-test has empty joblist. Nothing to do.
1171         # Tagger variable-test has empty joblist. Nothing to do.
1172
1173         $content =~ s@(?<=$1 )([^\s]*)@$h{'filter'}$1$h{'Standard'}@;
1174
1175     } elsif ($c =~ m/^De-chunking successful. Shrunk from (\d+) to (\d+)/) {
1176
1177         $req{$t}{'chunked-size'} = $1;
1178         $req{$t}{'dechunked-size'} = $2;
1179         $req{$t}{'dechunk-change'} = $req{$t}{'dechunked-size'} - $req{$t}{'chunked-size'};
1180
1181         $content .= " (" . h('Number') . $req{$t}{'dechunk-change'} . h('Standard') . ")";
1182
1183         $content =~ s@(?<=from )($req{$t}{'chunked-size'})@$h{'Number'}$1$h{'Standard'}@;
1184         $content =~ s@(?<=to )($req{$t}{'dechunked-size'})@$h{'Number'}$1$h{'Standard'}@;
1185
1186     } elsif ($c =~ m/^Decompression successful. Old size: (\d+), new size: (\d+)./) {
1187
1188         # Decompression successful. Old size: 670, new size: 1166.
1189
1190         $req{$t}{'size-compressed'} = $1;
1191         $req{$t}{'size-decompressed'} = $2;
1192         $req{$t}{'decompression-gain'} = $req{$t}{'size-decompressed'} - $req{$t}{'size-compressed'};
1193
1194         $content =~ s@(?<=Old size: )($req{$t}{'size-compressed'})@$h{'Number'}$1$h{'Standard'}@;
1195         $content =~ s@(?<=new size: )($req{$t}{'size-decompressed'})@$h{'Number'}$1$h{'Standard'}@;
1196
1197         # XXX: Create sub get_percentage()
1198         if ($req{$t}{'size-decompressed'}) {
1199             $req{$t}{'decompression-gain-percent'} =
1200                 $req{$t}{'decompression-gain'} / $req{$t}{'size-decompressed'} * 100;
1201
1202             $content .= " (saved: ";
1203             #$content .= h('Number') . $req{$t}{'decompression-gain'} . h('Standard');
1204             #$content .= "/";
1205             $content .= h('Number') . sprintf("%.2f%%", $req{$t}{'decompression-gain-percent'}) . h('Standard');
1206             $content .= ")";
1207         }
1208
1209     } elsif ($c =~ m/^(Need to de-chunk first)/) {
1210
1211         # Need to de-chunk first
1212         return '' if SUPPRESS_NEED_TO_DE_CHUNK_FIRST;
1213
1214     } elsif ($c =~ m/^(Adding (?:dynamic )?re_filter job)/) {
1215
1216         return ''  if (SUPPRESS_SUCCEEDED_FILTER_ADDITIONS && m/succeeded/);
1217
1218         # Adding re_filter job ...
1219         # Adding dynamic re_filter job s@^(?:\w*)\s+.*\s+HTTP/\d\.\d\s*@IP-ADDRESS: $origin@D\
1220         #  to filter client-ip-address succeeded.
1221
1222     } elsif ($c =~ m/^Compressed content from /) {
1223
1224         # Compressed content from 29258 to 8630 bytes. Compression level: 3
1225         $content =~ s@(?<=from )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1226         $content =~ s@(?<=to )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1227         $content =~ s@(?<=level: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1228
1229     } elsif ($c =~ m/^Reading in filter/) {
1230
1231         return '' unless SHOW_FILTER_READIN_IN;
1232
1233     } elsif ($c =~ m/^Decompression didn't result/) {
1234
1235         # Decompression didn't result in any content.
1236
1237         # Nothing to highlight.
1238
1239     } else {
1240
1241         found_unknown_content($content);
1242
1243     }
1244
1245     return $content;
1246 }
1247
1248 sub handle_loglevel_tagging($) {
1249
1250     my $c = shift;
1251
1252     if ($c =~ /^Tagger \'([^\']*)\' added tag \'([^\']*)\'/ or
1253         $c =~ m/^Adding tag \'([^\']*)\' created by header tagger \'([^\']*)\'/) {
1254
1255         # Adding tag 'GET request' created by header tagger 'method-man' (XXX: no longer used)
1256         # Tagger 'revalidation' added tag 'REVALIDATION-REQUEST'. No action bit update necessary.
1257         # Tagger 'revalidation' added tag 'REVALIDATION-REQUEST'. Action bits updated accordingly.
1258
1259         # XXX: Save tag and tagger
1260
1261         $c =~ s@(?<=^Tagger \')([^\']*)@$h{'tagger'}$1$h{'Standard'}@;
1262         $c =~ s@(?<=added tag \')([^\']*)@$h{'tag'}$1$h{'Standard'}@;
1263         $c =~ s@(?<=Action bits )(updated)@$h{'action-bits-update'}$1$h{'Standard'}@;
1264
1265     } elsif ($c =~ /^Enlisting tag/) {
1266
1267         # Enlisting tag 'forward-directly' for client 127.0.0.1.
1268
1269         $c =~ s@(?<=tag \')([^\']*)@$h{'tag'}$1$h{'Standard'}@;
1270         $c = highlight_matched_host($c, '[^\s]+(?=\.$)');
1271
1272     } elsif ($c =~ /^Tag/) {
1273
1274         # Tag 'change-tor-socks-port' for client 127.0.0.1 expired 1 seconds ago. Deleting it.
1275
1276         $c =~ s@(?<=Tag \')([^\']*)@$h{'tag'}$1$h{'Standard'}@;
1277         $c =~ s@(?<=expired )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1278         $c = highlight_matched_host($c, '(?<=client )[^\s]+');
1279
1280     } elsif ($c =~ /^Evaluating/) {
1281
1282         # Evaluating tag 'change-tor-socks-port' for client 127.0.0.1. End of life 1613162302.
1283
1284         $c =~ s@(?<=tag \')([^\']*)@$h{'tag'}$1$h{'Standard'}@;
1285         $c = highlight_matched_host($c, '(?<=client )[^\s]+(?=\.)');
1286         $c =~ s@(?<=life )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1287
1288     } elsif ($c =~ /^Client tag/) {
1289
1290         # Client tag 'forward-directly' matches
1291
1292         $c =~ s@(?<=tag \')([^\']*)@$h{'tag'}$1$h{'Standard'}@;
1293
1294     }
1295
1296     return $c;
1297 }
1298
1299 sub handle_loglevel_redirect($) {
1300
1301     my $c = shift;
1302
1303     if ($c =~ m/^Decoding "([^""]*)"/) {
1304
1305          $req{$t}{'original-destination'} = $1;
1306          $c = highlight_matched_path($c, '(?<=Decoding ")[^"]*');
1307          $c =~ s@\"@@g;
1308
1309     } elsif ($c =~ m/^Checking/) {
1310
1311          # Checking /_ylt=A0geu.Z76BRGR9k/**http://search.yahoo.com/search?p=view+odb+presentation+on+freebsd\
1312          #  &ei=UTF-8&xargs=0&pstart=1&fr=moz2&b=11 for redirects.
1313
1314          # TODO: Change colour if really url-decoded
1315          $req{$t}{'decoded-original-destination'} = $1;
1316          $c = highlight_matched_path($c, '(?<=Checking ")[^"]*');
1317          $c =~ s@\"@@g;
1318
1319     } elsif ($c =~ m/^pcrs command "([^""]*)" changed /) {
1320
1321         # pcrs command "s@&from=rss@@" changed \
1322         #  "http://it.slashdot.org/article.pl?sid=07/03/02/1657247&from=rss"\
1323         #  to "http://it.slashdot.org/article.pl?sid=07/03/02/1657247" (1 hit).
1324         $c =~ s@(?<=pcrs command )"([^""]*)"@$h{'filter'}$1$h{'Standard'}@;
1325         $c = highlight_matched_url($c, '(?<=changed ")[^""]*');
1326         $c =~ s@(?<=changed )"([^""]*)"@$1@; # Remove quotes
1327         $c = highlight_matched_url($c, '(?<=to ")[^""]*');
1328         $c =~ s@(?<=to )"([^""]*)"@$1@; # Remove quotes
1329         $c =~ s@(\d+)(?= hits?)@$h{'hits'}$1$h{'Standard'}@;
1330
1331     } elsif ($c =~ m/^pcrs command "([^""]*)" didn\'t change/) {
1332
1333         # pcrs command "s@^http://([^.]+?)/?$@http://www.bing.com/search?q=$1@" didn't \
1334         #  change "http://www.example.org/".
1335         $c =~ s@(?<=pcrs command )"([^""]*)"@$h{'filter'}$1$h{'Standard'}@;
1336         $c = highlight_matched_url($c, '(?<=change ")[^""]*');
1337
1338     } elsif ($c =~ m/(^New URL is: )(.*)/) {
1339
1340         # New URL is: http://it.slashdot.org/article.pl?sid=07/03/04/1511210
1341         # XXX: Use URL highlighter
1342         # XXX: Save?
1343         $c = $1 . h('rewritten-URL') . $2 . h('Standard');
1344
1345     } elsif ($c =~ m/No pcrs command recognized, assuming that/) {
1346         # No pcrs command recognized, assuming that "http://config.privoxy.org/user-manual/favicon.png"\
1347         #  is already properly formatted.
1348         # XXX: assume the same?
1349         $c = highlight_matched_url($c, '(?<=assuming that \")[^"]*');
1350
1351     } elsif ($c =~ m/^Percent-encoding redirect/) {
1352
1353         # Percent-encoding redirect URL: http://www.example.org/\x02
1354         $c = highlight_matched_url($c, '(?<=redirect URL: ).*');
1355
1356     } elsif ($c =~ m/^Rewrite detected:/) {
1357
1358         # Rewrite detected: GET http://10.0.0.2:88/blah.txt HTTP/1.1
1359         # Rewrite detected: GET https://www.electrobsd.org/CommonJS/ajax/libs/jquery/3.4.1/jquery.min.js HTTP/1.1
1360         $c = highlight_matched_request_line($c, '(?<=^Rewrite detected: ).*');
1361
1362     } elsif ($c =~ m/^Rewritten request line results in downgrade to http/) {
1363
1364         # Rewritten request line results in downgrade to http
1365         $c =~ s@(downgrade)@$h{'http-downgrade'}$1$h{'Standard'}@;
1366
1367     } else {
1368
1369         found_unknown_content($c);
1370
1371     }
1372
1373     return $c;
1374 }
1375
1376 sub handle_loglevel_gif_deanimate($) {
1377
1378     my $content = shift;
1379
1380     if ($content =~ m/Success! GIF shrunk from (\d+) bytes to (\d+)\./) {
1381
1382         my $bytes_from = $1;
1383         my $bytes_to = $2;
1384         # Gif-Deanimate: Success! GIF shrunk from 205 bytes to 133.
1385         $content =~ s@$bytes_from@$h{'Number'}$bytes_from$h{'Standard'}@;
1386         # XXX: Do we need g in case of ($1 == $2)?
1387         $content =~ s@$bytes_to@$h{'Number'}$bytes_to$h{'Standard'}@;
1388
1389     } elsif ($content =~ m/GIF (not) changed/) {
1390
1391         # Gif-Deanimate: GIF not changed.
1392         return '' if SUPPRESS_GIF_NOT_CHANGED;
1393         $content =~ s@($1)@$h{'not'}$1$h{'Standard'}@;
1394
1395     } elsif ($content =~ m/^failed! \(gif parsing\)/) {
1396
1397         # failed! (gif parsing)
1398         # XXX: Replace this error message with something less stupid
1399         $content =~ s@(failed!)@$h{'error'}$1$h{'Standard'}@;
1400
1401     } elsif ($content =~ m/^Need to de-chunk first/) {
1402
1403         # Need to de-chunk first
1404         return '' if SUPPRESS_NEED_TO_DE_CHUNK_FIRST;
1405
1406     } elsif ($content =~ m/^(?:No GIF header found|failed while parsing)/) {
1407
1408         # No GIF header found (XXX: Did I ever commit this?)
1409         # failed while parsing 195 134747048 (XXX: never committed)
1410
1411         # Ignore these for now
1412
1413     } else {
1414
1415         found_unknown_content($content);
1416
1417     }
1418
1419     return $content;
1420 }
1421
1422 sub handle_loglevel_request($) {
1423
1424     my $content = shift;
1425
1426     if ($content =~ m/crunch! /) {
1427
1428         # config.privoxy.org/send-stylesheet crunch! (CGI Call)
1429
1430         # Highlight crunch reasons
1431         foreach my $reason (keys %reason_colours) {
1432             $content =~ s@\(($reason)\)@$reason_colours{$reason}($1)$h{'Standard'}@g;
1433         }
1434         # Highlight request URL domain and ditch 'crunch!'
1435         $content = highlight_matched_pattern($content, 'request_', '[^ ]*(?= crunch!)');
1436         $content =~ s@ crunch!@@;
1437
1438     } elsif ($content =~ m/\[too long, truncated\]$/) {
1439
1440         # config.privoxy.org/edit-actions-submit?f=3&v=1176116716&s=7&Submit=Submit[...]&filter... [too long, truncated]
1441         $content = highlight_matched_pattern($content, 'request_', '^.*(?=\.\.\. \[too long, truncated\]$)');
1442
1443     } elsif ($content =~ m/(.*)/) { # XXX: Pretty stupid
1444
1445         # trac.vidalia-project.net/wiki/Volunteer?format=txt
1446         $content = h('request_') . $content . h('Standard');
1447
1448     } else {  # XXX: Nop
1449
1450         found_unknown_content($content);
1451
1452     }
1453
1454     return $content;
1455 }
1456
1457 sub handle_loglevel_crunch($) {
1458
1459     my $content = shift;
1460
1461     # Highlight crunch reason
1462     foreach my $reason (keys %reason_colours) {
1463         # Crunch: Blocked: https://capture.condenastdigital.com/track?_o=cne&[...]&dim2=%7B%22adBlocked%[...]
1464         $content =~ s@($reason)@$reason_colours{$reason}$1$h{'Standard'}@;
1465     }
1466
1467     if ($content =~ m/\[too long, truncated\]$/) {
1468
1469         # Blocked: config.privoxy.org/edit-actions-submit?f=3&v=1176116716&s=7&Submit=Submit\
1470         #  [...]&filter... [too long, truncated]
1471         $content = highlight_matched_pattern($content, 'request_', '^.*(?=\.\.\. \[too long, truncated\]$)');
1472
1473     } elsif ($content =~ m/Certificate error:/) {
1474
1475         # Certificate error: ASN date error, current date after: https://expired.badssl.com/
1476         $content = highlight_matched_pattern($content, 'request_', 'https://.*');
1477
1478     } else {
1479
1480         # Blocked: http://ads.example.org/
1481         $content = highlight_matched_pattern($content, 'request_', '(?<=: ).*');
1482     }
1483
1484     return $content;
1485 }
1486
1487 sub handle_loglevel_connect($) {
1488
1489     my $c = shift;
1490
1491     if ($c =~ m/^via [^\s]+ to: [^\s]+/) {
1492
1493         # Connect: via 10.0.0.1:8123 to: www.example.org.noconnect
1494
1495         $c = highlight_matched_host($c, '(?<=via )[^\s]+');
1496         $c = highlight_matched_host($c, '(?<=to: )[^\s]+');
1497
1498     } elsif ($c =~ m/^connect to: .* failed: .*/) {
1499
1500         # connect to: www.example.org.noconnect failed: Operation not permitted
1501
1502         $c = highlight_matched_host($c, '(?<=connect to: )[^\s]+');
1503
1504         $c =~ s@(?<=failed: )(.*)@$h{'error'}$1$h{'Standard'}@;
1505
1506     } elsif ($c =~ m/^to ([^\s]*)( successful)?$/) {
1507
1508         # Connect: to www.nzherald.co.nz successful
1509         # Connect: to archiv.radiotux.de
1510
1511         return '' if SUPPRESS_SUCCESSFUL_CONNECTIONS;
1512         $c = highlight_matched_host($c, '(?<=to )[^\s]+');
1513
1514     } elsif ($c =~ m/^to ([^\s]*)$/) {
1515
1516         # Connect: to lists.sourceforge.net:443
1517
1518         $c = highlight_matched_host($c, '(?<=to )[^\s]+');
1519
1520     } elsif ($c =~ m/^[Aa]ccepted connection from .*/ or
1521              $c =~ m/^OK/) {
1522
1523         # Privoxy 3.0.20:
1524         # Accepted connection from 10.0.0.1 on socket 5
1525         # Privoxy between 3.0.20 and 3.0.6:
1526         # accepted connection from 10.0.0.1( on socket 5)?
1527         # Privoxy 3.0.6 and earlier just say:
1528         # OK
1529         $c = highlight_matched_host($c, '(?<=connection from )[^ ]*');
1530         $c = highlight_matched_pattern($c, 'Number', '(?<=socket )\d+');
1531
1532     } elsif ($c =~ m/^Closing client socket/) {
1533
1534         # Closing client socket 5. Keep-alive: 0, Socket alive: 1. Data available: 0.
1535         # Privoxy 3.0.20 and later
1536         # Closing client socket 8. Keep-alive: 1. Socket alive: 0. Data available: 0. \
1537         #  Configuration file change detected: 0. Requests received: 11.
1538
1539         $c = highlight_matched_pattern($c, 'Number', '(?<=socket )\d+');
1540         $c = highlight_matched_pattern($c, 'Number', '(?<=Keep-alive: )\d+');
1541         $c = highlight_matched_pattern($c, 'Number', '(?<=Socket alive: )\d+');
1542         $c = highlight_matched_pattern($c, 'Number', '(?<=available: )\d+');
1543         $c = highlight_matched_pattern($c, 'Number', '(?<=detected: )\d+');
1544         $c = highlight_matched_pattern($c, 'Number', '(?<=received: )\d+');
1545
1546     } elsif ($c =~ m/^write header to: .* failed:/) {
1547
1548         # write header to: 10.0.0.1 failed: Broken pipe
1549
1550         $c = highlight_matched_host($c, '(?<=write header to: )[^\s]*');
1551         $c =~ s@(?<=failed: )(.*)@$h{'Error'}$1$h{'Standard'}@;
1552
1553     } elsif ($c =~ m/^write header to client failed:/) {
1554
1555         # write header to client failed: Broken pipe
1556         # XXX: Stil in use?
1557         $c =~ s@(?<=failed: )(.*)@$h{'Error'}$1$h{'Standard'}@;
1558
1559     } elsif ($c =~ m/^socks4_connect:/) {
1560
1561         # socks4_connect: SOCKS request rejected or failed.
1562         $c =~ s@(?<=socks4_connect: )(.*)@$h{'Error'}$1$h{'Standard'}@;
1563
1564     } elsif ($c =~ m/^Listening for new connections/ or
1565              $c =~ m/^accept connection/) {
1566         # XXX: Highlight?
1567         # Privoxy versions above 3.0.6 say:
1568         # Listening for new connections ...
1569         # earlier versions say:
1570         # accept connection ...
1571         return '';
1572
1573     } elsif ($c =~ m/^accept failed:/) {
1574
1575         $c =~ s@(?<=accept failed: )(.*)@$h{'Error'}$1$h{'Standard'}@;
1576
1577     } elsif ($c =~ m/^Overriding forwarding settings/) {
1578
1579         # Overriding forwarding settings based on 'forward 10.0.0.1:8123'
1580         $c =~ s@(?<=based on \')(.*)(?=\')@$h{'configuration-line'}$1$h{'Standard'}@;
1581
1582     } elsif ($c =~ m/^Denying suspicious CONNECT request from/) {
1583
1584         # Denying suspicious CONNECT request from 10.0.0.1
1585         $c = highlight_matched_host($c, '(?<=from )[^\s]+'); # XXX: not an URL
1586
1587     } elsif ($c =~ m/^socks5_connect:/) {
1588
1589         $c =~ s@(?<=socks5_connect: )(.*)@$h{'error'}$1$h{'Standard'}@;
1590
1591     } elsif ($c =~ m/^Created new connection to/) {
1592
1593         # Created new connection to www.privoxy.org:80 on socket 11.
1594         $c = highlight_matched_host($c, '(?<=connection to )[^\s]+');
1595         $c =~ s@(?<=on socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1596
1597     } elsif ($c =~ m/^Found reusable socket/) {
1598
1599         # Found reusable socket 9 for www.privoxy.org:80 in slot 0.
1600         # 3.0.15 and later:
1601         # Found reusable socket 8 for www.privoxy.org:80 in slot 2.\
1602         #  Timestamp made 0 seconds ago. Timeout: 1. Latency: 0.
1603         $c =~ s@(?<=Found reusable socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1604         $c = highlight_matched_host($c, '(?<=for )[^\s]+');
1605         $c =~ s@(?<=in slot )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1606         $c =~ s@(?<=made )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1607         $c =~ s@(?<=Timeout: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1608         $c =~ s@(?<=Latency: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1609
1610     } elsif ($c =~ m/^Marking open socket/) {
1611
1612         # Marking open socket 9 for www.privoxy.org:80 in slot 0 as unused.
1613         $c =~ s@(?<=Marking open socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1614         $c = highlight_matched_host($c, '(?<=for )[^\s]+');
1615         $c =~ s@(?<=in slot )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1616
1617     } elsif ($c =~ m/^No reusable/) {
1618
1619         # No reusable socket for addons.mozilla.org:443 found. Opening a new one.
1620         $c = highlight_matched_host($c, '(?<=for )[^\s]+');
1621
1622     } elsif ($c =~ m/^(Remembering|Forgetting) socket/) {
1623
1624         # Remembering socket 13 for www.privoxy.org:80 in slot 0.
1625         # Forgetting socket 38 for www.privoxy.org:80 in slot 5.
1626
1627         $c =~ s@(?<=socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1628         $c = highlight_matched_host($c, '(?<=for )[^\s]+');
1629         $c =~ s@(?<=in slot )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1630
1631     } elsif ($c =~ m/^Socket \d+ (already|closed)/) {
1632
1633         # Socket 16 already forgotten or never remembered.
1634         # Socket 9 closed while waiting for client headers
1635         $c =~ s@(?<=Socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1636
1637     } elsif ($c =~ m/^The connection to/) {
1638
1639         # The connection to www.privoxy.org:80 in slot 6 timed out. Closing socket 19. Timeout is: 61.
1640         # 3.0.15 and later:
1641         # The connection to 1.bp.blogspot.com:80 in slot 0 timed out. Closing socket 5.\
1642         #  Timeout is: 1. Assumed latency: 4.
1643         # The connection to 10.0.0.1:80 in slot 0 is no longer usable. Closing socket 4.
1644         $c = highlight_matched_host($c, '(?<=connection to )[^\s]+');
1645         $c =~ s@(?<=in slot )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1646         $c =~ s@(?<=Closing socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1647         $c =~ s@(?<=Timeout is: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1648         $c =~ s@(?<=Assumed latency: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1649
1650     } elsif ($c =~ m/^Stopped waiting for the request line/ or
1651              $c =~ m/^No request line on socket \d+ received in time/ or
1652              $c =~ m/^The client side of the connection on socket \d/) {
1653
1654         # Stopped waiting for the request line. Timeout: 121.
1655         # Privoxy 3.0.19 and later:
1656         # No request line on socket 5 received in time. Timeout: 1.
1657         # The client side of the connection on socket 5 got closed \
1658         #  without sending a complete request line.
1659         $c =~ s@(?<=Timeout: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1660         $c =~ s@(?<=socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1661
1662     } elsif ($c =~ m/^Waiting for \d/) {
1663
1664         # Waiting for 1 connections to timeout.
1665         $c =~ s@(?<=^Waiting for )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1666
1667     } elsif ($c =~ m/^Initialized/) {
1668
1669         # Initialized 20 socket slots.
1670         $c =~ s@(?<=Initialized )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1671
1672     } elsif ($c =~ m/^Done reading from server/) {
1673
1674         # Done reading from server. Expected content length: 24892. \
1675         #  Actual content length: 24892. Most recently received: 4412.
1676         # 3.0.15 and later:
1677         # Done reading from server. Expected content length: 24892. \
1678         #  Actual content length: 24892. Bytes most recently read: 4412.
1679         # Done reading from server. Content length: 6018 as expected. \
1680         #  Bytes most recently read: 294.
1681         $c =~ s@(?<=ontent length: )(\d+)@$h{'Number'}$1$h{'Standard'}@g;
1682         $c =~ s@(?<=received: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1683         $c =~ s@(?<=read: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1684
1685     } elsif ($c =~ m/^Continuing buffering (?:server )?headers/) {
1686
1687         # Continuing buffering headers. byte_count: 19. header_offset: 517. len: 536.
1688         $c =~ s@(?<=byte_count: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1689         $c =~ s@(?<=header_offset: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1690         $c =~ s@(?<=len: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1691         # 3.0.15 up to 3.0.19:
1692         # Continuing buffering headers. Bytes most recently read: 498.
1693         $c =~ s@(?<=read: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1694         # 3.0.20 and later:
1695         # Continuing buffering server headers from socket 5. Bytes most recently read: 498.
1696         $c =~ s@(?<=socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1697
1698     } elsif ($c =~ m/^Received \d+ bytes while/) {
1699
1700         # Received 206 bytes while expecting 12103.
1701         $c =~ s@(?<=Received )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1702         $c =~ s@(?<=expecting )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1703
1704     } elsif ($c =~ m/^(Rejecting c|C)onnection from/) {
1705
1706         # Connection from 81.163.28.218 dropped due to ACL
1707         # Rejecting connection from 178.63.152.227. Maximum number of connections reached.
1708         # Connection from 192.168.2.1 on 127.0.1.1:8118 (socket 3) dropped due to ACL
1709         $c = highlight_matched_host($c, '(?<=onnection from )[\d.:]+');
1710         $c = highlight_matched_host($c, '(?<=on )[\d.:]+');
1711         $c =~ s@(?<=socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1712
1713     } elsif ($c =~ m/^(?:Reusing|Closing) server socket / or
1714              $c =~ m/^No additional client request/) {
1715
1716         # Reusing server socket 4. Opened for 10.0.0.1.
1717         # Closing server socket 2. Opened for 10.0.0.1.
1718         # No additional client request received in time. \
1719         #  Closing server socket 4, initially opened for 10.0.0.1.
1720         # No additional client request received in time on socket 29.
1721         # Privoxy 3.0.20 and later
1722         # Reusing server socket 7 connected to www.privoxy.org. Total requests: 2.
1723         # Closing server socket 6 connected to d.asset.soup.io. Keep-alive: 0.\
1724         #  Tainted: 1. Socket alive: 1. Timeout: 60. Configuration file change detected: 0.
1725         # Reusing server socket 35 connected to nl.wikipedia.org. Requests already sent: 5.
1726
1727         $c =~ s@(?<= socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1728         $c = highlight_matched_host($c, '(?<=for )[^\s]+(?=\.)');
1729         $c = highlight_matched_host($c, '(?<=connected to )[^\s]+(?=\.)');
1730         for my $number_pattern ('requests', 'Keep-alive', 'Tainted', ' alive', 'Timeout', 'detected') {
1731             $c = highlight_matched_pattern($c, 'Number', '(?<='. $number_pattern . ': )\d+');
1732         }
1733         $c =~ s@(?<=already sent: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1734
1735     } elsif ($c =~ m/^Connected to /) {
1736
1737         # Connected to tor-jail[10.0.0.2]:9050.
1738
1739         $c = highlight_matched_host($c, '(?<=\[)[^\]]+');
1740         $c = highlight_matched_host($c, '(?<=Connected to )[^\[\s]+');
1741         $c =~ s@(?<=\]:)(\d+)@$h{'Number'}$1$h{'Standard'}@;
1742
1743     } elsif ($c =~ m/^Could not connect to /) {
1744
1745         # Could not connect to [10.0.0.1]:80.
1746
1747         $c = highlight_matched_host($c, '(?<=\[)[^\]]+');
1748         $c =~ s@(?<=\]:)(\d+)@$h{'Number'}$1$h{'Standard'}@;
1749
1750     } elsif ($c =~ m/^Waiting for the next client request/ or
1751              $c =~ m/^The connection on server socket/ or
1752              $c =~ m/^Client request (?:\d+ )?(?:arrived in time|has been pipelined) /) {
1753
1754         # Waiting for the next client request on socket 3. Keeping the server \
1755         #  socket 12 to a.fsdn.com open.
1756         # The connection on server socket 6 to upload.wikimedia.org isn't reusable. Closing.
1757         # Privoxy 3.0.20 and later:
1758         # Client request 4 arrived in time on socket 7.
1759         # Used by Privoxy 3.0.18 and 3.0.19:
1760         # Client request arrived in time on socket 21.
1761         # Used by earlier version:
1762         # Client request arrived in time or the client closed the connection on socket 12.
1763         # Client request 8 has been pipelined on socket 7 and the socket is still alive.
1764
1765         $c =~ s@(?<=request )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1766         $c =~ s@(?<=on socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1767         $c =~ s@(?<=server socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1768         $c = highlight_matched_host($c, '(?<=to )[^\s]+');
1769
1770     } elsif ($c =~ m/^Marking the server socket/) {
1771
1772         # Marking the server socket 7 tainted.
1773
1774         $c =~ s@(?<=server socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1775
1776     } elsif ($c =~ m/^Reduced expected bytes to /) {
1777
1778         # Reduced expected bytes to 0 to account for the 1542 ones we already got.
1779         $c =~ s@(?<=bytes to )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1780         $c =~ s@(?<=for the )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1781
1782     } elsif ($c =~ m/^The client closed socket /) {
1783
1784         # The client closed socket 2 while the server socket 4 is still open.
1785         $c =~ s@(?<=closed socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1786         $c =~ s@(?<=server socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1787
1788     } elsif ($c =~ m/^Expected client content length set /) {
1789
1790         # Expected client content length set to 667325411 after reading 4999 bytes.
1791         $c =~ s@(?<=set to )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1792         $c =~ s@(?<=reading )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1793
1794     } elsif ($c =~ m/^Reducing expected bytes to /) {
1795
1796         # Reducing expected bytes to 0. Marking the server socket tainted after throwing 4 bytes away.
1797         $c =~ s@(?<=bytes to )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1798         $c =~ s@(?<=after throwing )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1799
1800     } elsif ($c =~ m/^Waiting for up to /) {
1801
1802         # Waiting for up to 4999 bytes from the client.
1803         $c =~ s@(?<=up to )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1804
1805     } elsif ($c =~ m/^Optimistically sending /) {
1806
1807         # Optimistically sending 318 bytes of client headers intended for www.privoxy.org
1808         $c =~ s@(?<=sending )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1809         $c = highlight_matched_host($c, '(?<=for )[^\s]+');
1810
1811     } elsif ($c =~ m/^Stopping to watch the client socket/) {
1812
1813         # Stopping to watch the client socket. There's already another request waiting.
1814         # Privoxy 3.0.20 and later:
1815         # Stopping to watch the client socket 5. There's already another request waiting.
1816         $c =~ s@(?<=client socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1817
1818     } elsif ($c =~ m/^Drained \d+ bytes before closing/) {
1819
1820         # Drained 180 bytes before closing socket 6
1821         $c =~ s@(?<=Drained )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1822         $c =~ s@(?<=socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1823
1824     } elsif ($c =~ m/^Tainting client socket/ or
1825              $c =~ m/^Failed to shutdown socket/) {
1826
1827         # Tainting client socket 7 due to unread data.
1828         # Failed to shutdown socket 11: Connection reset by peer
1829
1830         $c =~ s@(?<=socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1831
1832     } elsif ($c =~ m/^Shifting \d+ pipelined bytes/) {
1833
1834         # Shifting 360 pipelined bytes by 360 bytes
1835         $c =~ s@(?<=Shifting )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1836         $c =~ s@(?<=by )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1837
1838     } elsif ($c =~ m/^Flushed (\d+) bytes of request body while expecting (\d+)/) {
1839
1840         # Flushed 30 bytes of request body while expecting 30
1841         $c =~ s@(?<=Flushed )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1842         $c =~ s@(?<=expecting )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1843
1844     } elsif ($c =~ m/^Performing the TLS\/SSL handshake with client. Hash of host:/) {
1845
1846         # Performing the TLS/SSL handshake with client. Hash of host: bab5296b25e256c7b06b92b17b56bcae
1847         $c = highlight_matched_host($c, '(?<=Hash of host: ).+');
1848
1849     } elsif ($c =~ m/^Forwarding \d+ bytes of encrypted POST data/) {
1850
1851         # Forwarding 1954 bytes of encrypted POST data
1852         $c =~ s@(?<=Forwarding )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1853
1854     } elsif ($c =~ m/^Forwarded the last \d+ bytes/) {
1855
1856         # Forwarded the last 1954 bytes
1857         $c =~ s@(?<=the last )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1858
1859     } elsif ($c =~ m/^Waiting for the next client connection. Currently active threads:/) {
1860
1861         # Waiting for the next client connection. Currently active threads: 30
1862         $c =~ s@(?<=threads: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1863
1864     } elsif ($c =~ m/^Data arrived in time on client socket/) {
1865
1866         # Data arrived in time on client socket 6. Requests so far: 3
1867         $c =~ s@(?<=client socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1868         $c =~ s@(?<=Requests so far: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1869
1870     } elsif ($c =~ m/^Dropping the client connection on socket/) {
1871
1872         # Dropping the client connection on socket 71. The server connection has not been established yet.
1873         # Dropping the client connection on socket 23 with server socket 24 connected to \
1874         #  www.reddit.com. The forwarder has changed.
1875         $c =~ s@(?<=on socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1876         $c =~ s@(?<=server socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1877         $c = highlight_matched_host($c, '(?<=connected to )[^ ]+(?=\.)');
1878
1879     } elsif ($c =~ m/^The client socket \d+ has become unusable while the server/) {
1880
1881         # The client socket 16 has become unusable while the server socket 24 is still open.
1882         $c =~ s@(?<=client socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1883         $c =~ s@(?<=server socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1884
1885     } elsif ($c =~ m/^The last \d+ bytes of the request body have been read/) {
1886
1887         # The last 12078 bytes of the request body have been read
1888         $c =~ s@(?<=The last )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1889
1890     } elsif ($c =~ m/^Flushed \d+ bytes of request body/) {
1891
1892         # Flushed 3153 bytes of request body
1893         $c =~ s@(?<=Flushed )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1894
1895     } elsif ($c =~ m/^Complete client request followed by/) {
1896
1897         # Complete client request followed by 59 bytes of pipelined data received.
1898         $c =~ s@(?<=followed by )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1899
1900     } elsif ($c =~ m/^The peer notified us that the connection on socket/) {
1901
1902         # The peer notified us that the connection on socket 11 is going to be closed
1903         $c =~ s@(?<=socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1904
1905     } elsif ($c =~ m/^Client socket \d is no longer usable/) {
1906
1907         # Client socket 7 is no longer usable. The server socket has been closed.
1908         $c =~ s@(?<=socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1909
1910     } elsif ($c =~ m/^Socket timeout \d+ reached/) {
1911
1912         # Socket timeout 3 reached: http://127.0.0.1:20000/no-filter/chunked-content/36
1913         $c =~ s@(?<=timeout )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1914         $c = highlight_matched_url($c, "(?<=reached: ).*")
1915
1916     } elsif ($c =~ m/^Prepared to read up to /) {
1917
1918         # Prepared to read up to 157 bytes of encrypted request body from the client.
1919         $c =~ s@(?<=up to )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1920
1921     } elsif ($c =~ m/^Forwarding \d+ bytes /) {
1922
1923         # Forwarding 157 bytes of encrypted request body.
1924         $c =~ s@(?<=Forwarding )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1925
1926     } elsif ($c =~ m/^Buffering encrypted client body/) {
1927
1928         # Buffering encrypted client body. Prepared to read up to 2236 bytes.
1929         $c =~ s@(?<=up to )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1930
1931     } elsif ($c =~ m/^The last \d+ bytes of the encrypted request body have been read/) {
1932
1933         # The last 6945 bytes of the encrypted request body have been read.
1934         $c =~ s@(?<=The last )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1935
1936     } elsif ($c =~ m/^Reducing the chunk offset from/) {
1937
1938         # Reducing the chunk offset from 1096654 to 32704 after discarding 1063950 bytes to make room in the buffer.
1939         # Reducing the chunk offset from 16219 to 128 after flushing 16091 bytes.
1940         $c =~ s@(?<=\d to )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1941         $c =~ s@(?<=offset from )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1942         $c =~ s@(?<=after discarding )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1943         $c =~ s@(?<=after flushing )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1944
1945     } elsif ($c =~ m/^Client socket \d+ is no longer usable/) {
1946
1947         # Client socket 21 is no longer usable. The server socket has been closed.
1948         $c =~ s@(?<=Client socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1949
1950     } elsif ($c =~ m/^(Client|Server) successfully connected over/) {
1951
1952         # Server successfully connected over TLSv1.3 (TLS_AES_256_GCM_SHA384).
1953         # Client successfully connected over TLSv1.3 (TLS_AES_128_GCM_SHA256).
1954         $c =~ s@(?<=connected over )(TLSv\d\.\d)@$h{'tls-version'}$1$h{'Standard'}@;
1955         $c =~ s@(?<=\()([^)]+)@$h{'cipher-suite'}$1$h{'Standard'}@;
1956
1957     } elsif ($c =~ m/^Looks like we / or
1958              $c =~ m/^Unsetting keep-alive flag/ or
1959              $c =~ m/^No connections to wait/ or
1960              $c =~ m/^Complete client request received/ or
1961              $c =~ m/^Possible pipeline attempt detected./ or
1962              $c =~ m/^POST request detected. The connection will not be kept alive./ or
1963              $c =~ m/^The server still wants to talk, but the client hung up on us./ or
1964              $c =~ m/^The server didn't specify how long the connection will stay open/ or
1965              $c =~ m/^There might be a request body. The connection will not be kept alive/ or
1966              $c =~ m/^There better be a request body./ or
1967              $c =~ m/^Done reading from the client\.$/) {
1968
1969         # Looks like we reached the end of the last chunk. We better stop reading.
1970         # Looks like we read the end of the last chunk together with the server \
1971         #  headers. We better stop reading.
1972         # Looks like we got the last chunk together with the server headers. \
1973         #  We better stop reading.
1974         # Unsetting keep-alive flag.
1975         # No connections to wait for left.
1976         # Client request arrived in time or the client closed the connection.
1977         # Complete client request received
1978         # Possible pipeline attempt detected. The connection will not be \
1979         #  kept alive and we will only serve the first request.
1980         # POST request detected. The connection will not be kept alive.
1981         # The server still wants to talk, but the client hung up on us.
1982         # The server didn't specify how long the connection will stay open. Assume it's only a second.
1983         # There might be a request body. The connection will not be kept alive.
1984         # Privoxy 3.0.20 and later
1985         # There better be a request body.
1986         # Done reading from the client.
1987
1988     } else {
1989
1990         found_unknown_content($c);
1991
1992     }
1993
1994     return $c;
1995 }
1996
1997
1998 sub handle_loglevel_info($) {
1999
2000     my $c = shift;
2001
2002     if ($c =~ m/^Rewrite detected:/) {
2003
2004         # Rewrite detected: GET http://10.0.0.2:88/blah.txt HTTP/1.1
2005         $c = highlight_matched_request_line($c, '(?<=^Rewrite detected: ).*');
2006
2007     } elsif ($c =~ m/^Decompress(ing deflated|ion didn)/ or
2008              $c =~ m/^Compressed content detected/ or
2009              $c =~ m/^SDCH-compressed content detected/ or
2010              $c =~ m/^Tagger/
2011             ) {
2012         # Decompressing deflated iob: 117
2013         # Decompression didn't result in any content.
2014         # Compressed content detected, content filtering disabled. Consider recompiling Privoxy\
2015         #  with zlib support or enable the prevent-compression action.
2016         # SDCH-compressed content detected, content filtering disabled.\
2017         #  Consider suppressing SDCH offers made by the client.
2018         # Tagger 'complete-url' created empty tag. Ignored.
2019
2020         # Ignored for now
2021
2022     } elsif ($c =~ m/^(Re)?loading configuration file /) {
2023
2024         # loading configuration file '/usr/local/etc/privoxy/config':
2025         # Reloading configuration file '/usr/local/etc/privoxy/config'
2026         $c =~ s@(?<=loading configuration file \')([^\']*)@$h{'file'}$1$h{'Standard'}@;
2027
2028     } elsif ($c =~ m/^Loading (actions|filter|trust) file: /) {
2029
2030         # Loading actions file: /usr/local/etc/privoxy/default.action
2031         # Loading filter file: /usr/local/etc/privoxy/default.filter
2032         # Loading trust file: /usr/local/etc/privoxy/trust
2033
2034         $c =~ s@(?<= file: )(.*)$@$h{'file'}$1$h{'Standard'}@;
2035
2036     } elsif ($c =~ m/^exiting by signal/) {
2037
2038         # exiting by signal 15 .. bye
2039         $c =~ s@(?<=exiting by signal )(\d+)@$h{'signal'}$1$h{'Standard'}@;
2040
2041     } elsif ($c =~ m/^Privoxy version/) {
2042
2043         # Privoxy version 3.0.7
2044         $c =~ s@(?<=^Privoxy version )(\d+\.\d+\.\d+)$@$h{'version'}$1$h{'Standard'}@;
2045
2046     } elsif ($c =~ m/^Program name: /) {
2047
2048         # Program name: /usr/local/sbin/privoxy
2049         $c =~ s@(?<=Program name: )(.*)@$h{'program-name'}$1$h{'Standard'}@;
2050
2051     } elsif ($c =~ m/^Listening on port /) {
2052
2053         # Listening on port 8118 on IP address 10.0.0.1
2054         $c =~ s@(?<=Listening on port )(\d+)@$h{'port'}$1$h{'Standard'}@;
2055         $c =~ s@(?<=on IP address )(.*)@$h{'ip-address'}$1$h{'Standard'}@;
2056
2057     } elsif ($c =~ m/^\(Re-\)Open(?:ing)? logfile/) {
2058
2059         # (Re-)Open logfile /var/log/privoxy/privoxy.log
2060         $c =~ s@(?<=Open logfile )(.*)@$h{'file'}$1$h{'Standard'}@;
2061
2062     } elsif ($c =~ m/^(Request from|Malformed server response detected)/) {
2063
2064         # Request from 10.0.0.1 denied. limit-connect{,} doesn't allow CONNECT requests to port 443.
2065         # Request from 10.0.0.1 marked for blocking. limit-connect{,} doesn't allow CONNECT requests to port 443.
2066         # 3.0.18 and later:
2067         # Request from 10.0.0.1 marked for blocking. limit-connect{0} doesn't allow CONNECT requests to www.example.org:443
2068         # Malformed server response detected. Downgrading to HTTP/1.0 impossible.
2069
2070         $c =~ s@(?<=Request from )([^\s]*)@$h{'ip-address'}$1$h{'Standard'}@;
2071         $c =~ s@(denied|blocking)@$h{'warning'}$1$h{'Standard'}@;
2072         $c =~ s@(CONNECT)@$h{'method'}$1$h{'Standard'}@;
2073         $c =~ s@(?<=to port )(\d+)@$h{'port'}$1$h{'Standard'}@;
2074         $c =~ s@(?<=to )([^\s]+)@$h{'request_'}$1$h{'Standard'}@;
2075
2076     } elsif ($c =~ m/^Status code/) {
2077
2078         # Status code 304 implies no body.
2079         $c =~ s@(?<=Status code )(\d+)@$h{'status-code'}$1$h{'Standard'}@;
2080
2081     } elsif ($c =~ m/^Method/) {
2082
2083         # Method HEAD implies no body.
2084         $c =~ s@(?<=Method )([^\s]+)@$h{'method'}$1$h{'Standard'}@;
2085
2086     } elsif ($c =~ m/^Buffer limit reached while extending /) {
2087
2088         # Buffer limit reached while extending the buffer (iob). Needed: 4197470. Limit: 4194304
2089         $c =~ s@(?<=Needed: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
2090         $c =~ s@(?<=Limit: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
2091
2092     } elsif ($c =~ m/^File modification detected: /) {
2093
2094         # File modification detected: /usr/local/etc/privoxy/user-agent.action
2095         $c =~ s@(?<= detected: )(.*)$@$h{'file'}$1$h{'Standard'}@;
2096
2097     } elsif ($c =~ m/^No logfile configured/ or
2098              $c =~ m/^Malformerd HTTP headers detected and MS IIS5 hack enabled/ or
2099              $c =~ m/^Invalid \"chunked\" transfer/ or
2100              $c =~ m/^Support for/ or
2101              $c =~ m/^Flushing header and buffers/ or
2102              $c =~ m/^Can not resolve/
2103              ) {
2104
2105         # No logfile configured. Please enable it before reporting any problems.
2106         # Malformerd HTTP headers detected and MS IIS5 hack enabled. Expect an invalid \
2107         #  response or even no response at all.
2108         # No logfile configured. Logging disabled.
2109         # Invalid "chunked" transfer encoding detected and ignored.
2110         # Support for 'Connection: keep-alive' is experimental, incomplete and\
2111         #  known not to work properly in some situations.
2112         # Flushing header and buffers. Stepping back from filtering.
2113         # Can not resolve doesnotexist: hostname nor servname provided, or not known
2114
2115     } else {
2116
2117         found_unknown_content($c);
2118
2119     }
2120
2121     return $c;
2122 }
2123
2124 sub handle_loglevel_cgi($) {
2125
2126     my $c = shift;
2127
2128     if ($c =~ m/^Granting access to/) {
2129
2130         #Granting access to http://config.privoxy.org/send-stylesheet, referrer http://p.p/ is trustworthy.
2131
2132     } elsif ($c =~ m/^Substituting: s(.)/) {
2133
2134         # Substituting: s/@else-not-FEATURE_ZLIB@.*@endif-FEATURE_ZLIB@//sigTU
2135         # XXX: prone to span several lines
2136
2137         my $delimiter = $1;
2138         #$c =~ s@(?<=failed: )(.*)@$h{'error'}$1$h{'Standard'}@;
2139         $c =~ s@(?!<=\\)($delimiter)@$h{'pcrs-delimiter'}$1$h{'Standard'}@g; # XXX: Too aggressive
2140         #$c =~ s@(?!<=\\)($1)@$h{'pcrs-delimiter'}$1$h{'Standard'}@g;
2141     }
2142
2143     return $c;
2144 }
2145
2146 sub handle_loglevel_force($) {
2147
2148     my $c = shift;
2149
2150     if ($c =~ m/^Ignored force prefix in request:/) {
2151
2152         # Ignored force prefix in request: "GET http://10.0.0.1/PRIVOXY-FORCE/block HTTP/1.1"
2153         $c =~ s@^(Ignored)@$h{'ignored'}$1$h{'Standard'}@;
2154         $c = highlight_matched_request_line($c, '(?<=request: ")[^"]*');
2155
2156     } elsif ($c =~ m/^Enforcing request:/) {
2157
2158         # Enforcing request: "GET http://10.0.0.1/block HTTP/1.1".
2159         $c = highlight_matched_request_line($c, '(?<=request: ")[^"]*');
2160
2161     } else {
2162
2163         found_unknown_content($c);
2164
2165     }
2166
2167     return $c;
2168 }
2169
2170 sub handle_loglevel_error($) {
2171
2172     my $c = shift;
2173
2174     if ($c =~ m/^(?:Empty|No) server or forwarder response received on socket \d+\./) {
2175
2176         # Empty server or forwarder response received on socket 4.
2177         # Empty server or forwarder response received on socket 3. \
2178         #  Closing client socket 15 without sending data.
2179         # Used by Privoxy 3.0.18 and later:
2180         # No server or forwarder response received on socket 8. \
2181         #  Closing client socket 10 without sending data.
2182
2183         $c =~ s@(?<=on socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
2184         $c =~ s@(?<=client socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
2185
2186     } elsif ($c =~ m/^Didn't receive data in time:/) {
2187
2188         # Didn't receive data in time: a.fsdn.com:443
2189         $c =~ s@(?<=in time: )(.*)@$h{'destination'}$1$h{'Standard'}@;
2190
2191     } elsif ($c =~ m/^Sending data on socket \d+ over TLS/) {
2192
2193         # Sending data on socket 33 over TLS/SSL failed: no TLS/SSL errors detected
2194         $c =~ s@(?<=on socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
2195
2196     } elsif ($c =~ m/^Chunk size \d+ exceeds buffered data left/) {
2197
2198         # Chunk size 291 exceeds buffered data left. Already digested 69894 of 69957 buffered bytes.
2199         $c =~ s@(?<=size )(\d+)@$h{'Number'}$1$h{'Standard'}@;
2200         $c =~ s@(?<=digested )(\d+)@$h{'Number'}$1$h{'Standard'}@;
2201         $c =~ s@(?<=of )(\d+)@$h{'Number'}$1$h{'Standard'}@;
2202
2203     } elsif ($c =~ m/^The socks connection timed out after/) {
2204
2205         # The socks connection timed out after 60 seconds.
2206         $c =~ s@(?<=after )(\d+)@$h{'Number'}$1$h{'Standard'}@;
2207     }
2208
2209     # XXX: There are probably more messages that deserve highlighting.
2210
2211     return $c;
2212 }
2213
2214
2215 sub handle_loglevel_ignore($) {
2216     return shift;
2217 }
2218
2219 sub gather_loglevel_clf_stats($) {
2220
2221     my $content = shift;
2222     my ($method, $resource, $http_version, $status_code, $size);
2223     our %stats;
2224     our %cli_options;
2225
2226     # +0200] "GET https://www.youtube.com/watch?v=JmcA9LIIXWw HTTP/1.1" 200 68004
2227     # +0200] "VERSION-CONTROL http://p.p/ HTTP/1.1" 200 2787
2228     $content =~ m/^[+-]\d{4}\] "([^ ]+) (.+) (HTTP\/\d\.\d)" (\d+) (\d+)/;
2229     $method       = $1;
2230     $resource     = $2;
2231     $http_version = $3;
2232     $status_code  = $4;
2233     $size         = $5;
2234
2235     $stats{requests_clf}++;
2236
2237     unless (defined $method) {
2238         # +0200] "Invalid request" 400 0
2239         return if ($content =~ m/^[+-]\d{4}\] "Invalid request"/);
2240         # +0100] "Failed reading chunked client body" 400 0
2241         return if ($content =~ m/^[+-]\d{4}\] "Failed reading chunked client body"/);
2242         # +0100] "GET https://securepubads.g.doubleclick.net/gampad/ads?gd[...]... [too long, truncated]
2243         if ($content =~ m/\[too long, truncated\]$/) {
2244             print("Skipped LOG_LEVEL_CLF message that got truncated by Privoxy. Statistics will be inprecise.\n");
2245         } else {
2246             print("Failed to parse: $content\n");
2247         }
2248         return;
2249     }
2250     $stats{'method'}{$method}++;
2251     if ($cli_options{'url-statistics-threshold'} != 0) {
2252         $stats{'resource'}{$resource}++;
2253     }
2254     $stats{'http-version'}{$http_version}++;
2255
2256     if ($cli_options{'host-statistics-threshold'} != 0) {
2257         $resource =~ m@(?:https?://)?([^/]+)/?@;
2258         $stats{'hosts'}{$1}++;
2259     }
2260     $stats{'content-size-total'} += $size;
2261     $stats{'status-code'}{$status_code}++;
2262 }
2263
2264 sub gather_loglevel_request_stats($$) {
2265     my $request_url = shift;
2266     my $thread = shift;
2267     our %stats;
2268     our %cli_options;
2269
2270     $stats{requests}++;
2271     if ($cli_options{'passed-request-statistics-threshold'} != 0) {
2272         # If the request get blocked we'll decrement
2273         # in gather_loglevel_crunch_stats()
2274         chomp $request_url;
2275         $stats{'passed-request-url'}{$request_url}++;
2276     }
2277 }
2278
2279 sub gather_loglevel_crunch_stats($$) {
2280     my $c = shift;
2281     my $thread = shift;
2282     our %stats;
2283     our %cli_options;
2284
2285     $stats{crunches}++;
2286
2287     if ($c =~ m/^Redirected:/) {
2288         # Redirected: http://www.example.org/http://p.p/
2289         $stats{'fast-redirections'}++;
2290
2291     } elsif ($c =~ m/^Blocked:/) {
2292         # Blocked: blogger.googleusercontent.com:443
2293         $stats{'blocked'}++;
2294
2295     } elsif ($c =~ m/^Connection timeout:/) {
2296         # Connection timeout: http://c.tile.openstreetmap.org/18/136116/87842.png
2297         $stats{'connection-timeout'}++;
2298
2299     } elsif ($c =~ m/^Connection failure:/) {
2300         # Connection failure: http://127.0.0.1:8080/
2301         $stats{'connection-failure'}++;
2302     }
2303     if ($cli_options{'passed-request-statistics-threshold'} != 0) {
2304         $c =~ m/^[^:]+: (.*)/;
2305         if ($stats{'passed-request-url'}{$1}) {
2306             $stats{'passed-request-url'}{$1}-- ;
2307             if ($stats{'passed-request-url'}{$1} == 0) {
2308                 delete($stats{'passed-request-url'}{$1});
2309             }
2310         }
2311     }
2312 }
2313
2314
2315 sub gather_loglevel_error_stats($$) {
2316
2317     my $c = shift;
2318     my $thread = shift;
2319     our %stats;
2320     our %thread_data;
2321
2322     if ($c =~ m/^Empty server or forwarder response received on socket \d+./) {
2323
2324         # Empty server or forwarder response received on socket 4.
2325         $stats{'empty-responses'}++;
2326         if ($thread_data{$thread}{'new_connection'}) {
2327             $stats{'empty-responses-on-new-connections'}++;
2328         } else {
2329             $stats{'empty-responses-on-reused-connections'}++;
2330         }
2331     }
2332 }
2333
2334 sub gather_loglevel_connect_stats($$) {
2335
2336     my ($c, $thread) = @_;
2337     our %thread_data;
2338     our %stats;
2339
2340     if ($c =~ m/^via ([^\s]+) to: [^\s]+/) {
2341
2342         # Connect: via 10.0.0.1:8123 to: www.example.org.noconnect
2343         $thread_data{$thread}{'forwarder'} = $1; # XXX: is this missue?
2344
2345     } elsif ($c =~ m/^to ([^\s]*)$/) {
2346
2347         # Connect: to lists.sourceforge.net:443
2348
2349         $thread_data{$thread}{'forwarder'} = 'direct connection';
2350
2351     } elsif ($c =~ m/^Created new connection to/) {
2352
2353         # Created new connection to www.privoxy.org:80 on socket 11.
2354
2355         $thread_data{$thread}{'new_connection'} = 1;
2356
2357     } elsif ($c =~ m/^Reusing server socket \d./ or
2358              $c =~ m/^Found reusable socket/) {
2359
2360         # Reusing server socket 4. Opened for 10.0.0.1.
2361         # Found reusable socket 9 for www.privoxy.org:80 in slot 0.
2362
2363         $thread_data{$thread}{'new_connection'} = 0;
2364         $stats{'reused-connections'}++;
2365
2366     } elsif ($c =~ m/^Closing client socket \d+. .* Requests received: (\d+)\.$/) {
2367
2368         # Closing client socket 12. Keep-alive: 1. Socket alive: 1. Data available: 0. \
2369         #  Configuration file change detected: 0. Requests received: 14.
2370
2371         $stats{'client-requests-on-connection'}{$1}++;
2372         $stats{'closed-client-connections'}++;
2373     }
2374 }
2375
2376 sub gather_loglevel_header_stats($$) {
2377
2378     my ($c, $thread) = @_;
2379     our %stats;
2380     our %cli_options;
2381
2382     if ($c =~ m/^A HTTP\/1\.1 response without/ or
2383         $c =~ m/^Keeping the server header 'Connection: keep-alive' around./)
2384     {
2385         # A HTTP/1.1 response without Connection header implies keep-alive.
2386         # Keeping the server header 'Connection: keep-alive' around.
2387         $stats{'server-keep-alive'}++;
2388     }
2389 }
2390
2391 sub init_stats() {
2392     our %stats = (
2393         requests => 0,
2394         requests_clf => 0,
2395         crunches => 0,
2396         'server-keep-alive' => 0,
2397         'reused-connections' => 0,
2398         'empty-responses' => 0,
2399         'empty-responses-on-new-connections' => 0,
2400         'empty-responses-on-reused-connections' => 0,
2401         'fast-redirections' => 0,
2402         'blocked' => 0,
2403         'connection-failure' => 0,
2404         'connection-timeout' => 0,
2405         'reused-connections' => 0,
2406         'server-keep-alive' => 0,
2407         'closed-client-connections' => 0,
2408         'content-size-total' => 0,
2409         );
2410         $stats{'client-requests-on-connection'}{1} = 0;
2411 }
2412
2413 sub get_percentage($$) {
2414     my $big = shift;
2415     my $small = shift;
2416
2417     # If small is 0 the percentage is always 0%.
2418     # Make sure it works even if big is 0 as well.
2419     return "0.00%" if ($small eq 0);
2420
2421     # Prevent division by zero.
2422     # XXX: Is this still supposed to be reachable?
2423     return "NaN" if ($big eq 0);
2424
2425     return sprintf("%.2f%%", $small / $big * 100);
2426 }
2427
2428 sub print_stats() {
2429
2430     our %stats;
2431     our %cli_options;
2432     my $new_connections = $stats{requests} - $stats{crunches} - $stats{'reused-connections'};
2433     my $client_requests_checksum = 0;
2434     my $requests_total;
2435
2436     if ($stats{requests_clf} && $stats{requests}
2437         && $stats{requests_clf} != $stats{requests}) {
2438         print "Inconsistent request counts: " . $stats{requests} . "/" . $stats{requests_clf} . "\n";
2439     }
2440
2441     # To get the total number of requests we can use either the number
2442     # of Common-Log-Format lines or the number of "Request:" messages.
2443     # We prefer the number of CLF lines if available because using
2444     # it works when analysing old log files from Privoxy versions before 3.0.29.
2445     # In Privoxy 3.0.28 and earlier "Request:" messages excluded
2446     # crunched messages.
2447     $requests_total = $stats{requests_clf} ? $stats{requests_clf} : $stats{requests};
2448
2449     if ($requests_total eq 0) {
2450         print "No requests yet.\n";
2451         return;
2452     }
2453
2454     print "Client requests total: " . $requests_total . "\n";
2455     if ($stats{crunches}) {
2456         my $outgoing_requests = $requests_total - $stats{crunches};
2457         print "Crunches: " . $stats{crunches} . " (" .
2458             get_percentage($requests_total, $stats{crunches}) . ")\n";
2459         print "Blocks: " . $stats{'blocked'} . " (" .
2460             get_percentage($requests_total, $stats{'blocked'}) . ")\n";
2461         print "Fast redirections: " . $stats{'fast-redirections'} . " (" .
2462             get_percentage($requests_total, $stats{'fast-redirections'}) . ")\n";
2463         print "Connection timeouts: " . $stats{'connection-timeout'} . " (" .
2464             get_percentage($requests_total, $stats{'connection-timeout'}) . ")\n";
2465         print "Connection failures: " . $stats{'connection-failure'} . " (" .
2466             get_percentage($requests_total, $stats{'connection-failure'}) . ")\n";
2467         print "Outgoing requests: " . $outgoing_requests . " (" .
2468             get_percentage($requests_total, $outgoing_requests) . ")\n";
2469     } else {
2470         print "No crunches detected. Is 'debug 1024' enabled?\n";
2471     }
2472
2473     print "Server keep-alive offers: " . $stats{'server-keep-alive'} . " (" .
2474         get_percentage($requests_total, $stats{'server-keep-alive'}) . ")\n";
2475     print "New outgoing connections: " . $new_connections . " (" .
2476         get_percentage($requests_total, $new_connections) . ")\n";
2477     print "Reused server connections: " . $stats{'reused-connections'} . " (" .
2478         get_percentage($requests_total, $stats{'reused-connections'}) .
2479         "; server offers accepted: " .
2480         get_percentage($stats{'server-keep-alive'}, $stats{'reused-connections'}) . ")\n";
2481     print "Empty responses: " . $stats{'empty-responses'} . " (" .
2482         get_percentage($requests_total, $stats{'empty-responses'}) . ")\n";
2483     print "Empty responses on new connections: "
2484          . $stats{'empty-responses-on-new-connections'} . " (" .
2485         get_percentage($requests_total, $stats{'empty-responses-on-new-connections'})
2486         . ")\n";
2487     print "Empty responses on reused connections: " .
2488         $stats{'empty-responses-on-reused-connections'} . " (" .
2489         get_percentage($requests_total, $stats{'empty-responses-on-reused-connections'}) .
2490         ")\n";
2491     print "Client connections: " .  $stats{'closed-client-connections'} . "\n";
2492     if ($stats{'content-size-total'}) {
2493         print "Bytes of content transferred to the client: " .  $stats{'content-size-total'} . "\n";
2494     }
2495     my $lines_printed = 0;
2496     print "Client requests per connection distribution:\n";
2497     foreach my $client_requests (sort {
2498         $stats{'client-requests-on-connection'}{$b} <=> $stats{'client-requests-on-connection'}{$a}}
2499                                   keys %{$stats{'client-requests-on-connection'}
2500                                   })
2501     {
2502         my $count = $stats{'client-requests-on-connection'}{$client_requests};
2503         $client_requests_checksum += $count * $client_requests;
2504         if ($cli_options{'show-complete-request-distribution'} or ($lines_printed < 10)) {
2505             printf "%8d: %d\n", $count, $client_requests;
2506             $lines_printed++;
2507         }
2508     }
2509     unless ($cli_options{'show-complete-request-distribution'}) {
2510         printf "Enable --show-complete-request-distribution to get less common numbers as well.\n";
2511     }
2512     # Due to log rotation we may not have a complete picture for all the requests
2513     printf "Improperly accounted requests: ~%d\n", abs($requests_total - $client_requests_checksum);
2514
2515     if (exists $stats{method}) {
2516         print "Method distribution:\n";
2517         foreach my $method (sort {$stats{'method'}{$b} <=> $stats{'method'}{$a}} keys %{$stats{'method'}}) {
2518             printf "%8d : %-8s\n", $stats{'method'}{$method}, $method;
2519         }
2520     } else {
2521         print "Method distribution unknown. No CLF message parsed yet. Is 'debug 512' enabled?\n";
2522     }
2523     if (exists $stats{'http-version'}) {
2524         print "Client HTTP versions:\n";
2525         foreach my $http_version (sort {$stats{'http-version'}{$b} <=> $stats{'http-version'}{$a}} keys %{$stats{'http-version'}}) {
2526             printf "%8d : %-8s\n",  $stats{'http-version'}{$http_version}, $http_version;
2527         }
2528     } else {
2529         print "HTTP version distribution unknown. No CLF message parsed yet. Is 'debug 512' enabled?\n";
2530     }
2531     if (exists $stats{'status-code'}) {
2532         print "HTTP status codes according to 'debug 512' (status codes sent by the server may differ):\n";
2533         foreach my $status_code (sort {$stats{'status-code'}{$b} <=> $stats{'status-code'}{$a}} keys %{$stats{'status-code'}}) {
2534             printf "%8d : %-8d\n",  $stats{'status-code'}{$status_code}, $status_code;
2535         }
2536     } else {
2537         print "Status code distribution unknown. No CLF message parsed yet. Is 'debug 512' enabled?\n";
2538     }
2539
2540     if ($cli_options{'url-statistics-threshold'} == 0) {
2541         print "URL statistics are disabled. Increase --url-statistics-threshold to enable them.\n";
2542     } else {
2543         print "Requested URLs:\n";
2544         foreach my $resource (sort {$stats{'resource'}{$b} <=> $stats{'resource'}{$a}} keys %{$stats{'resource'}}) {
2545             if ($stats{'resource'}{$resource} < $cli_options{'url-statistics-threshold'}) {
2546                 print "Skipped statistics for URLs below the treshold.\n";
2547                 last;
2548             }
2549             printf "%d : %s\n", $stats{'resource'}{$resource}, $resource;
2550         }
2551     }
2552
2553     if ($cli_options{'passed-request-statistics-threshold'} == 0) {
2554         print "Passed request statistics are disabled. Increase --passed-request-statistics-threshold to enable them.\n";
2555     } else {
2556         print "Requested requests that were passed:\n";
2557         foreach my $passed_url (sort {$stats{'passed-request-url'}{$b} <=> $stats{'passed-request-url'}{$a}}
2558                                 keys %{$stats{'passed-request-url'}}) {
2559             if ($stats{'passed-request-url'}{$passed_url} < $cli_options{'passed-request-statistics-threshold'}) {
2560                 print "Skipped statistics for passed URLs below the treshold.\n";
2561                 last;
2562             }
2563             printf "%d : %s\n", $stats{'passed-request-url'}{$passed_url}, $passed_url;
2564         }
2565     }
2566     if ($cli_options{'host-statistics-threshold'} == 0) {
2567         print "Host statistics are disabled. Increase --host-statistics-threshold to enable them.\n";
2568     } else {
2569         print "Requested Hosts:\n";
2570         foreach my $host (sort {$stats{'hosts'}{$b} <=> $stats{'hosts'}{$a}} keys %{$stats{'hosts'}}) {
2571             if ($stats{'hosts'}{$host} < $cli_options{'host-statistics-threshold'}) {
2572                 print "Skipped statistics for Hosts below the treshold.\n";
2573                 last;
2574             }
2575             printf "%d : %s\n", $stats{'hosts'}{$host}, $host;
2576         }
2577     }
2578 }
2579
2580
2581 ################################################################################
2582 # Functions that actually print stuff
2583 ################################################################################
2584
2585 sub print_clf_message() {
2586
2587     our ($ip, $timestamp, $request_line, $status_code, $size);
2588     my $output = '';
2589
2590     return if DEBUG_SUPPRESS_LOG_MESSAGES;
2591
2592     # Rebuild highlighted
2593     $output .= $h{'Number'} . $ip . $h{'Standard'};
2594     $output .= " - - ";
2595     $output .= "[" . $h{'Timestamp'} . $timestamp . $h{'Standard'} . "]";
2596     $output .= " ";
2597     $output .= "\"" . highlight_request_line("$request_line") . "\"";
2598     $output .= " ";
2599     $output .= $h{'Status'} . $status_code . $h{'Standard'};
2600     $output .= " ";
2601     $output .= $h{'Number'} . $size . $h{'Standard'};
2602     $output .= $line_end;
2603
2604     print $output;
2605 }
2606
2607 sub print_non_clf_message($) {
2608
2609     my $content = shift;
2610     my $date_string = $keep_date_mode ? $req{$t}{'day'} . ' ' : '';
2611     my $msec_string = $no_msecs_mode ? '' : '.' . $req{$t}{'msecs'};
2612     my $line_start = $html_output_mode ? '' : $h{"Standard"};
2613
2614     return if DEBUG_SUPPRESS_LOG_MESSAGES;
2615
2616     print $line_start
2617         . $date_string
2618         . $time_colours[$time_colour_index % 2]
2619         . $req{$t}{'time-stamp'}
2620         . $msec_string
2621         . $h{Standard} . " "
2622         . $thread_colours{$t}
2623         . $t
2624         . $h{Standard}
2625         . " "
2626         . $h{$req{$t}{'log-level'}}
2627         . $req{$t}{'log-level'}
2628         . $h{Standard}
2629         . ": "
2630         . $content
2631         . $line_end;
2632 }
2633
2634 sub shorten_thread_id($) {
2635
2636     my $thread_id = shift;
2637
2638     our %short_thread_ids;
2639     our $max_threadid;
2640
2641     unless (defined $short_thread_ids{$thread_id}) {
2642         $short_thread_ids{$thread_id} = sprintf "%.3d", $max_threadid++;
2643     }
2644
2645     return $short_thread_ids{$thread_id}
2646 }
2647
2648 sub parse_loop() {
2649
2650     my ($day, $time_stamp, $thread, $log_level, $content, $c, $msecs);
2651     my $last_msecs  = 0;
2652     my $last_thread = 0;
2653     my $last_timestamp = 0;
2654     my $filters_that_did_nothing;
2655     my $key;
2656     my $time_colour;
2657     $time_colour = paint_it('white');
2658
2659     my %log_level_handlers = (
2660         'Re-Filter'         => \&handle_loglevel_re_filter,
2661         'Header'            => \&handle_loglevel_header,
2662         'Connect'           => \&handle_loglevel_connect,
2663         'Redirect'          => \&handle_loglevel_redirect,
2664         'Request'           => \&handle_loglevel_request,
2665         'Crunch'            => \&handle_loglevel_crunch,
2666         'Gif-Deanimate'     => \&handle_loglevel_gif_deanimate,
2667         'Info'              => \&handle_loglevel_info,
2668         'CGI'               => \&handle_loglevel_cgi,
2669         'Force'             => \&handle_loglevel_force,
2670         'Error'             => \&handle_loglevel_error,
2671         'Fatal error'       => \&handle_loglevel_ignore,
2672         'Writing'           => \&handle_loglevel_ignore,
2673         'Received'          => \&handle_loglevel_ignore,
2674         'Tagging'           => \&handle_loglevel_tagging,
2675         'Actions'           => \&handle_loglevel_ignore,
2676         'Unknown log level' => \&handle_loglevel_ignore,
2677     );
2678
2679     while (<>) {
2680
2681         if (m/^(\d{4}-\d{2}-\d{2}|\w{3} \d{2}) (\d\d:\d\d:\d\d)\.?(\d+)? (?:Privoxy\()?([^\)\s]*)[\)]? ([\w -]*): (.*?)\r?$/) {
2682             $thread = $t = ($shorten_thread_ids) ? shorten_thread_id($4) : $4;
2683             $req{$t}{'day'} = $day = $1;
2684             $req{$t}{'time-stamp'} = $time_stamp = $2;
2685             $req{$t}{'msecs'} = $msecs = $3 ? $3 : 0; # Only the cool kids have micro second resolution;
2686             $req{$t}{'log-level'} = $log_level = $5;
2687             $req{$t}{'content'} = $content = $c = $6;
2688             $req{$t}{'log-message'} = $_;
2689             $no_special_header_highlighting = 0;
2690
2691             if (defined($log_level_handlers{$log_level})) {
2692
2693                 $content = $log_level_handlers{$log_level}($content);
2694
2695             } else {
2696
2697                 die "No handler found for log level \"$log_level\"\n";
2698             }
2699
2700             # Highlight Truncations
2701             if (length($_) > 4000) {
2702                 $content =~ s@(too long, truncated)]$@$h{'Truncation'}$1$h{'Standard'}]@g;
2703             }
2704
2705             next unless $content;
2706
2707             # Register threads to keep the colour constant
2708             if (!defined($thread_colours{$thread})) {
2709                 $thread_colours{$thread} = $all_colours[$thread_colour_index % @all_colours];
2710                 $thread_colour_index++;
2711             }
2712
2713             # Switch timestamp colour if timestamps differ
2714             if (($msecs ne $last_msecs) || ($time_stamp ne $last_timestamp)) {
2715                debug_message("Tick tack!") if DEBUG_TICKS;
2716                $time_colour = $time_colours[$time_colour_index % 2];
2717                $time_colour_index++;
2718                $last_msecs = $msecs;
2719                $last_timestamp = $time_stamp;
2720             }
2721
2722             $last_thread = $thread;
2723
2724             print_non_clf_message($content);
2725
2726         } elsif (m/^((?:\d+\.\d+\.\d+\.\d+|[:\d]+)) - - \[(.*)\] "(.*)" (\d+) (\d+)/) {
2727
2728             # LOG_LEVEL_CLF lines look like this
2729             # 61.152.239.32 - - [04/Mar/2007:18:28:23 +0100] "GET \
2730             #  http://ad.yieldmanager.com/imp?z=1&Z=120x600&s=109339&u=http%3A%2F%2Fwww.365loan.co.uk%2F&r=1\
2731             #  HTTP/1.1" 403 1730
2732             our ($ip, $timestamp, $request_line, $status_code, $size) = ($1, $2, $3, $4, $5);
2733
2734             print_clf_message();
2735
2736         } else {
2737
2738             # Some Privoxy log messages span more than one line,
2739             # usually to dump lots of content that doesn't need any syntax highlighting.
2740             # XXX: add mechanism to forward these lines to the right handler anyway.
2741             chomp();
2742             unless (DEBUG_SUPPRESS_LOG_MESSAGES or (SUPPRESS_EMPTY_LINES and m/^\s+$/)) {
2743                 print and print get_line_end(); # unless (SUPPRESS_EMPTY_LINES and m/^\s+$/);
2744             }
2745         }
2746     }
2747 }
2748
2749 sub stats_loop() {
2750
2751     my ($day, $time_stamp, $thread, $log_level, $content);
2752     my $strict_checks = cli_option_is_set('strict-checks');
2753     my %log_level_handlers = (
2754          'Connect:'           => \&gather_loglevel_connect_stats,
2755          'Crunch:'            => \&gather_loglevel_crunch_stats,
2756          'Error:'             => \&gather_loglevel_error_stats,
2757          'Header:'            => \&gather_loglevel_header_stats,
2758          'Request:'           => \&gather_loglevel_request_stats,
2759     );
2760     my %ignored_log_levels = (
2761          'Actions:'           => \&handle_loglevel_ignore,
2762          'CGI:'               => \&handle_loglevel_ignore,
2763          'Fatal error:'       => \&handle_loglevel_ignore,
2764          'Force:'             => \&handle_loglevel_ignore,
2765          'Gif-Deanimate:'     => \&handle_loglevel_ignore,
2766          'Info:'              => \&handle_loglevel_ignore,
2767          'Re-Filter:'         => \&handle_loglevel_ignore,
2768          'Received:'          => \&handle_loglevel_ignore,
2769          'Redirect:'          => \&handle_loglevel_ignore,
2770          'Unknown log level:' => \&handle_loglevel_ignore,
2771          'Writing:'           => \&handle_loglevel_ignore,
2772          'Tagging:'           => \&handle_loglevel_ignore,
2773     );
2774
2775     while (<>) {
2776         (undef, $time_stamp, $thread, $log_level, $content) = split(/ /, $_, 5);
2777
2778
2779         next if (not defined($log_level));
2780
2781         if ($time_stamp eq "-") {
2782
2783             gather_loglevel_clf_stats($content);
2784
2785         } elsif (defined($log_level_handlers{$log_level})) {
2786
2787             $content = $log_level_handlers{$log_level}($content, $thread);
2788
2789         } elsif ($strict_checks and not defined($ignored_log_levels{$log_level})) {
2790
2791             die "No handler found for: $_";
2792         }
2793     }
2794
2795     print_stats();
2796
2797 }
2798
2799 # Convert a timestamp like 18:07:28.733 into milliseconds
2800 sub time_stamp_to_msecs($) {
2801     my $time_stamp = shift;
2802
2803     if ($time_stamp =~ /(\d\d):(\d\d):(\d\d)\.(\d{3})/) {
2804         my ($hours, $minutes, $seconds, $msecs) = ($1, $2, $3, $4);
2805
2806         $msecs += $seconds * 1000;
2807         $msecs += $minutes * 1000 * 60;
2808         $msecs += $hours   * 1000 * 60 * 60;
2809
2810         return $msecs;
2811     }
2812     return undef;
2813 }
2814
2815 sub inactivity_detection_loop() {
2816
2817     our %cli_options;
2818     my ($date, $time_stamp, $thread, $log_level, $content);
2819     my ($msecs, $previous_msecs, $inactivity);
2820     my $inactivity_threshold = $cli_options{'inactivity-threshold'};
2821     my $previous_date;
2822     my $log_messages_out_of_order = 0;
2823
2824     while (<>) {
2825         ($date, $time_stamp, $thread, $log_level, $content) = split(/ /, $_, 5);
2826
2827         next if (not defined($log_level));
2828         next if ($time_stamp eq "-");
2829         $msecs = time_stamp_to_msecs($time_stamp);
2830         unless (defined $msecs) {
2831             print "Failed to convert $time_stamp into milliseconds\n";
2832             print "$_";
2833             next;
2834         }
2835         unless (defined $previous_msecs) {
2836             $previous_msecs = $msecs;
2837             $previous_date = $date;
2838             print "$_";
2839             next;
2840         }
2841         $inactivity = $msecs - $previous_msecs;
2842         if ($inactivity < 0) {
2843             # This can happen if there's a high load in which case
2844             # a Privoxy thread may be moved off schedule between
2845             # getting the timestamp for the log message and actually
2846             # writing it.
2847             $log_messages_out_of_order++;
2848         }
2849         if ($inactivity > $inactivity_threshold) {
2850             if ($previous_date eq $date) {
2851                 print "Detected inactivity: $inactivity msecs\n";
2852             } else {
2853                 # While we could include the date in the timestamp
2854                 # we currently don't.
2855                 print "Detected date change. Timestamp difference ignored.\n";
2856             }
2857         }
2858         print "$_";
2859         $previous_msecs = $msecs;
2860         $previous_date = $date;
2861     }
2862     if ($log_messages_out_of_order) {
2863         print "At least $log_messages_out_of_order messages were written out of the chronological order.\n";
2864         print "This can result in false positives. Consider sorting the log first.\n";
2865     }
2866 }
2867
2868 sub unbreak_lines_only_loop() {
2869     my $log_messages_reached = 0;
2870     while (<>) {
2871         chomp;
2872
2873             # Log level other than LOG_LEVEL_CLF?
2874         if (m/^(\d{4}-\d{2}-\d{2}|\w{3} \d{2}) (\d\d:\d\d:\d\d)\.?(\d+)? (?:Privoxy\()?([^\)\s]*)[\)]? ([\w -]*): (.*?)\r?$/ or
2875             # LOG_LEVEL_CLF?
2876             m/^((?:\d+\.\d+\.\d+\.\d+)) - - \[(.*)\] "(.*)" (\d+) (\d+)/) {
2877             $log_messages_reached = 1;
2878             print "\n";
2879
2880         } else {
2881             # Wrapped message
2882             $_ = "\n". $_  if /^(?:\d+\.\d+\.\d+\.\d+)/;
2883             $_ = " " . $_;
2884         }
2885         s@<BR>$@@;
2886         print;
2887         print "\n" unless $log_messages_reached;
2888     }
2889     print "\n";
2890 }
2891
2892 sub VersionMessage {
2893     my $version_message;
2894
2895     $version_message .= 'Privoxy-Log-Parser ' . PRIVOXY_LOG_PARSER_VERSION  . "\n";
2896     $version_message .= 'https://www.fabiankeil.de/sourcecode/privoxy-log-parser/' . "\n";
2897
2898     print $version_message;
2899 }
2900
2901 sub get_cli_options() {
2902
2903     our %cli_options = (
2904         'detect-inactivity'        => CLI_OPTION_DETECT_INACTIVITY,
2905         'inactivity-threshold'     => CLI_OPTION_INACTIVITY_THRESHOLD,
2906         'html-output'              => CLI_OPTION_DEFAULT_TO_HTML_OUTPUT,
2907         'title'                    => CLI_OPTION_TITLE,
2908         'keep-date'                => CLI_OPTION_KEEP_DATE,
2909         'no-syntax-highlighting'   => CLI_OPTION_NO_SYNTAX_HIGHLIGHTING,
2910         'no-embedded-css'          => CLI_OPTION_NO_EMBEDDED_CSS,
2911         'no-msecs'                 => CLI_OPTION_NO_MSECS,
2912         'shorten-thread-ids'       => CLI_OPTION_SHORTEN_THREAD_IDS,
2913         'show-ineffective-filters' => CLI_OPTION_SHOW_INEFFECTIVE_FILTERS,
2914         'statistics'               => CLI_OPTION_STATISTICS,
2915         'strict-checks'            => CLI_OPTION_STRICT_CHECKS,
2916         'url-statistics-threshold' => CLI_OPTION_URL_STATISTICS_THRESHOLD,
2917         'unbreak-lines-only'       => CLI_OPTION_UNBREAK_LINES_ONLY,
2918         'host-statistics-threshold'=> CLI_OPTION_HOST_STATISTICS_THRESHOLD,
2919         'passed-request-statistics-threshold' => CLI_OPTION_PASSED_REQUEST_STATISTICS_THRESHOLD,
2920         'show-complete-request-distribution' => CLI_OPTION_SHOW_COMPLETE_REQUEST_DISTRIBUTION,
2921     );
2922
2923     GetOptions (
2924         'detect-inactivity'        => \$cli_options{'detect-inactivity'},
2925         'inactivity-threshold=i'   => \$cli_options{'inactivity-threshold'},
2926         'html-output'              => \$cli_options{'html-output'},
2927         'title'                    => \$cli_options{'title'},
2928         'keep-date'                => \$cli_options{'keep-date'},
2929         'no-syntax-highlighting'   => \$cli_options{'no-syntax-highlighting'},
2930         'no-embedded-css'          => \$cli_options{'no-embedded-css'},
2931         'no-msecs'                 => \$cli_options{'no-msecs'},
2932         'shorten-thread-ids'       => \$cli_options{'shorten-thread-ids'},
2933         'show-ineffective-filters' => \$cli_options{'show-ineffective-filters'},
2934         'statistics'               => \$cli_options{'statistics'},
2935         'strict-checks'            => \$cli_options{'strict-checks'},
2936         'unbreak-lines-only'       => \$cli_options{'unbreak-lines-only'},
2937         'url-statistics-threshold=i'=> \$cli_options{'url-statistics-threshold'},
2938         'host-statistics-threshold=i'=> \$cli_options{'host-statistics-threshold'},
2939         'passed-request-statistics-threshold=i' => \$cli_options{'passed-request-statistics-threshold'},
2940         'show-complete-request-distribution' => \$cli_options{'show-complete-request-distribution'},
2941         'version'                  => sub { VersionMessage && exit(0) },
2942         'help'                     => \&help,
2943    ) or exit(1);
2944
2945    $html_output_mode = cli_option_is_set('html-output');
2946    $no_msecs_mode = cli_option_is_set('no-msecs');
2947    $keep_date_mode = cli_option_is_set('keep-date');
2948    $shorten_thread_ids = cli_option_is_set('shorten-thread-ids');
2949    $line_end = get_line_end();
2950 }
2951
2952 sub help() {
2953
2954     our %cli_options;
2955
2956     VersionMessage();
2957
2958     print << "    EOF"
2959
2960 Options and their default values if they have any:
2961     [--detect-innactivity]
2962     [--inactivity-threshold $cli_options{'inactivity-threshold'}]
2963     [--host-statistics-threshold $cli_options{'host-statistics-threshold'}]
2964     [--html-output]
2965     [--no-embedded-css]
2966     [--no-msecs]
2967     [--no-syntax-highlighting]
2968     [--shorten-thread-ids]
2969     [--show-ineffective-filters]
2970     [--show-complete-request-distribution]
2971     [--statistics]
2972     [--unbreak-lines-only]
2973     [--url-statistics-threshold $cli_options{'url-statistics-threshold'}]
2974     [--passed-request-statistics-threshold $cli_options{'passed-request-statistics-threshold'}]
2975     [--title $cli_options{'title'}]
2976     [--version]
2977 see "perldoc $0" for more information
2978     EOF
2979     ;
2980     exit(0);
2981 }
2982
2983 ################################################################################
2984 # main
2985 ################################################################################
2986 sub main() {
2987
2988     get_cli_options();
2989     set_background(DEFAULT_BACKGROUND);
2990     prepare_our_stuff();
2991
2992     # XXX: should explicitly reject incompatible argument combinations
2993     if (cli_option_is_set('unbreak-lines-only')) {
2994         unbreak_lines_only_loop();
2995     } elsif (cli_option_is_set('statistics')) {
2996         stats_loop();
2997     } elsif (cli_option_is_set('detect-inactivity')) {
2998         inactivity_detection_loop();
2999     } else {
3000         print_intro();
3001         parse_loop();
3002         print_outro();
3003     }
3004 }
3005
3006 main();
3007
3008 =head1 NAME
3009
3010 B<privoxy-log-parser> - A parser and syntax-highlighter for Privoxy log messages
3011
3012 =head1 SYNOPSIS
3013
3014 B<privoxy-log-parser> [B<--detect-inactivity>] [B<--inactivity-threshold msecs>]
3015 [B<--html-output>]
3016 [B<--no-msecs>] [B<--no-syntax-higlighting>] [B<--statistics>]
3017 [B<--shorten-thread-ids>] [B<--show-ineffective-filters>]
3018 [B<--url-statistics-threshold>] [B<--version>]
3019
3020 =head1 DESCRIPTION
3021
3022 B<privoxy-log-parser> reads Privoxy log messages and
3023
3024 - syntax-highlights recognized lines,
3025
3026 - reformats some of them for easier comprehension,
3027
3028 - filters out less useful messages, and
3029
3030 - (in some cases) calculates additional information,
3031   like the compression ratio or how a filter affected
3032   the content size.
3033
3034 With B<privoxy-log-parser> you should be able to increase Privoxy's log level
3035 without getting confused by the resulting amount of output. For example for
3036 "debug 64" B<privoxy-log-parser> will (by default) only show messages that
3037 affect the content. If a filter doesn't cause any hits, B<privoxy-log-parser>
3038 will hide the "filter foo caused 0 hits" message.
3039
3040 =head1 OPTIONS
3041
3042 [B<--detect-inactivity>] Instead of syntax highlighting, detect periods
3043 of log inactivity of more than the amount of milliseconds specified with
3044 the B<--inactivity-threshold> option. Mainly useful for debugging.
3045
3046 [B<--host-statistics-threshold>] Only show the request count for a host
3047 if it's above or equal to the given threshold. If the threshold is 0, host
3048 statistics are disabled.
3049
3050 [B<--html-output>] Use HTML and CSS when syntax highlighting. If this option is
3051 omitted, ANSI escape sequences are used unless B<--no-syntax-highlighting> is active.
3052 This option is only intended to make embedding log excerpts in web pages easier.
3053 It does not escape any input!
3054
3055 [B<--inactivity-threshold msecs>] Specifies the number of milliseconds between
3056 log messages to consider inactivity when running in [B<--detect-inactivity>]
3057 mode.
3058
3059 [B<--keep-date>] Don't remove the date when printing highlighted log messages.
3060 Useful when parsing multiple log files at once.
3061
3062 [B<--no-msecs>] Don't expect millisecond resolution
3063
3064 [B<--no-syntax-highlighting>] Disable syntax-highlighting. Useful when
3065 the filtered output is piped into less in which case the ANSI control
3066 codes don't work, or if the terminal itself doesn't support the control
3067 codes.
3068
3069 [B<--passed-request-statistics-threshold>] Only show the request count for
3070 a passed requests if it's above or equal to the given threshold. If the
3071 threshold is 0, passed request statistics are disabled.
3072
3073 [B<--shorten-thread-ids>] Shorten the thread ids to a three-digit decimal number.
3074 Note that the mapping from thread ids to shortened ids is created at run-time
3075 and thus varies with the input.
3076
3077 [B<--show-ineffective-filters>] Don't suppress log lines for filters
3078 that didn't modify the content.
3079
3080 [B<--show-complete-request-distribution>] Show the complete client request
3081 distribution in the B<--statistics> output. Without this option only the
3082 ten most common numbers are shown.
3083
3084 [B<--statistics>] Gather various statistics instead of syntax highlighting
3085 log messages. This is an experimental feature, if the results look wrong
3086 they very well might be. Also note that the results are pretty much guaranteed
3087 to be incorrect if Privoxy and Privoxy-Log-Parser aren't in sync.
3088
3089 [B<--strict-checks>] When generating statistics, look more careful at the
3090 input data and abort if it is unexpected, even if it doesn't affect the
3091 results. Significantly slows the parsing down and is not expected to catch
3092 any problems that matter.
3093 When highlighting, print warnings in case of unknown messages which can't be
3094 properly highlighted.
3095
3096 [B<--unbreak-lines-only>] Tries to fix lines that got messed up by a broken or
3097 interestingly configured mail client and thus are no longer recognized properly.
3098 Only fixes some breakage, but may be good enough or at least better than nothing.
3099 Doesn't do anything else, so you probably want to pipe the output into
3100 B<privoxy-log-parser> again.
3101
3102 [B<--url-statistics-threshold>] Only show the request count for a resource
3103 if it's above or equal to the given threshold. If the threshold is 0, URL
3104 statistics are disabled.
3105
3106 [B<--version>] Print version and exit.
3107
3108 =head1 EXAMPLES
3109
3110 To monitor a log file:
3111
3112 tail -F /usr/jails/privoxy-jail/var/log/privoxy/privoxy.log | B<privoxy-log-parser>
3113
3114 Replace '-F' with '-f' if your tail implementation lacks '-F' support
3115 or if the log won't get rotated anyway. The log file location depends
3116 on your system (Doh!).
3117
3118 To monitor Privoxy without having it write to a log file:
3119
3120 privoxy --no-daemon /usr/jails/privoxy-jail/usr/local/etc/privoxy/config 2>&1 | B<privoxy-log-parser>
3121
3122 Again, the config file location depends on your system. Output redirection
3123 depends on your shell, the above works with bourne shells.
3124
3125 To read a processed Privoxy log file from top to bottom, letting the content
3126 scroll by slightly faster than you can read:
3127
3128 B<privoxy-log-parser> < /usr/jails/privoxy-jail/var/log/privoxy/privoxy.log
3129
3130 This is probably only useful to fill screens in the background of haxor movies.
3131
3132 =head1 CAVEATS
3133
3134 Syntax highlighting with ANSI escape sequences will look strange
3135 if your background color isn't black.
3136
3137 Some messages aren't recognized yet and will not be fully highlighted.
3138
3139 B<privoxy-log-parser> is developed with Privoxy 3.0.7 or later in mind,
3140 using earlier Privoxy versions will probably result in an increased amount
3141 of unrecognized log lines.
3142
3143 Privoxy's log files tend to be rather large. If you use HTML
3144 highlighting some browsers can't handle them, get confused and
3145 will eventually crash because of segmentation faults or unexpected
3146 exceptions. This is a problem in the browser and not B<privoxy-log-parser>'s
3147 fault.
3148
3149 =head1 BUGS
3150
3151 Many settings can't be controlled through command line options yet.
3152
3153 =head1 SEE ALSO
3154
3155 privoxy(8)
3156
3157 =head1 AUTHOR
3158
3159 Fabian Keil <fk@fabiankeil.de>
3160
3161 =cut