tools/privoxy-log-parser.pl

   1 #!/usr/bin/perl
   2
   3 ################################################################################
   4 # privoxy-log-parser
   5 #
   6 # A parser for Privoxy log messages. For incomplete documentation run
   7 # perldoc privoxy-log-parser(.pl), for fancy screenshots see:
   8 #
   9 # https://www.fabiankeil.de/sourcecode/privoxy-log-parser/
  10 #
  11 # TODO:
  12 #       - LOG_LEVEL_CGI, LOG_LEVEL_ERROR, LOG_LEVEL_WRITE content highlighting
  13 #       - create fancy statistics
  14 #       - grep through Privoxy sources to find unsupported log messages
  15 #       - hunt down substitutions that match content from variables which
  16 #         can contain stuff like ()?'[]
  17 #       - replace $h{'foo'} with h('foo') where possible
  18 #       - hunt down XXX comments instead of just creating them
  19 #       - add example log lines for every regex and mark them up for
  20 #         regression testing
  21 #       - Handle incomplete input without Perl warning about undefined variables.
  22 #       - Use generic highlighting function that takes a regex and the
  23 #         hash key as input.
  24 #       - Add --compress and --decompress options.
  25 #
  26 # Copyright (c) 2007-2020 Fabian Keil <fk@fabiankeil.de>
  27 #
  28 # Permission to use, copy, modify, and distribute this software for any
  29 # purpose with or without fee is hereby granted, provided that the above
  30 # copyright notice and this permission notice appear in all copies.
  31 #
  32 # THE SOFTWARE IS PROVIDED "AS IS" AND THE AUTHOR DISCLAIMS ALL WARRANTIES
  33 # WITH REGARD TO THIS SOFTWARE INCLUDING ALL IMPLIED WARRANTIES OF
  34 # MERCHANTABILITY AND FITNESS. IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR
  35 # ANY SPECIAL, DIRECT, INDIRECT, OR CONSEQUENTIAL DAMAGES OR ANY DAMAGES
  36 # WHATSOEVER RESULTING FROM LOSS OF USE, DATA OR PROFITS, WHETHER IN AN
  37 # ACTION OF CONTRACT, NEGLIGENCE OR OTHER TORTIOUS ACTION, ARISING OUT OF
  38 # OR IN CONNECTION WITH THE USE OR PERFORMANCE OF THIS SOFTWARE.
  39 ################################################################################
  40
  41 use strict;
  42 use warnings;
  43 use Getopt::Long;
  44
  45 use constant {
  46     PRIVOXY_LOG_PARSER_VERSION => '0.9.1',
  47     # Feel free to mess with these ...
  48     DEFAULT_BACKGROUND => 'black',  # Choose registered colour (like 'black')
  49     DEFAULT_TEXT_COLOUR => 'white', # Choose registered colour (like 'black')
  50     HEADER_DEFAULT_COLOUR => 'yellow',
  51     REGISTER_HEADERS_WITH_THE_SAME_COLOUR => 1,
  52
  53     CLI_OPTION_DEFAULT_TO_HTML_OUTPUT => 0,
  54     CLI_OPTION_TITLE => 'Privoxy-Log-Parser in da house',
  55     CLI_OPTION_NO_EMBEDDED_CSS => 0,
  56     CLI_OPTION_NO_MSECS => 0,
  57     CLI_OPTION_NO_SYNTAX_HIGHLIGHTING => 0,
  58     CLI_OPTION_SHORTEN_THREAD_IDS => 0,
  59     CLI_OPTION_SHOW_INEFFECTIVE_FILTERS => 0,
  60     CLI_OPTION_STATISTICS => 0,
  61     CLI_OPTION_STRICT_CHECKS => 0,
  62     CLI_OPTION_UNBREAK_LINES_ONLY => 0,
  63     CLI_OPTION_URL_STATISTICS_THRESHOLD => 0,
  64     CLI_OPTION_HOST_STATISTICS_THRESHOLD => 0,
  65     CLI_OPTION_SHOW_COMPLETE_REQUEST_DISTRIBUTION => 0,
  66
  67     SUPPRESS_SUCCEEDED_FILTER_ADDITIONS => 1,
  68     SHOW_SCAN_INTRO => 0,
  69     SHOW_FILTER_READIN_IN => 0,
  70     SUPPRESS_EMPTY_LINES => 1,
  71     SUPPRESS_SUCCESSFUL_CONNECTIONS => 1,
  72     SUPPRESS_GIF_NOT_CHANGED => 1,
  73     SUPPRESS_NEED_TO_DE_CHUNK_FIRST => 1,
  74
  75     DEBUG_HEADER_REGISTERING => 0,
  76     DEBUG_HEADER_HIGHLIGHTING => 0,
  77     DEBUG_TICKS => 0,
  78     DEBUG_PAINT_IT => 0,
  79     DEBUG_SUPPRESS_LOG_MESSAGES => 0,
  80
  81     PUNISH_MISSING_LOG_KNOWLEDGE_WITH_DEATH => 0,
  82     PUNISH_MISSING_HIGHLIGHT_KNOWLEDGE_WITH_DEATH => 1,
  83
  84     LOG_UNPARSED_LINES_TO_EXTRA_FILE => 0,
  85     ERROR_LOG_FILE => '/var/log/privoxy-log-parser',
  86
  87     # You better leave these alone unless you know what you're doing.
  88     COLOUR_RESET      => "\033[0;0m",
  89     ESCAPE => "\033[",
  90 };
  91
  92 # For performance reasons, these are global.
  93
  94 my $t;
  95 my %req; # request data from previous lines
  96 my %h;
  97 my %thread_colours;
  98 my @all_colours;
  99 my @time_colours;
 100 my $thread_colour_index = 0;
 101 my $header_colour_index = 0;
 102 my $time_colour_index = 0;
 103 my %header_colours;
 104 my $no_special_header_highlighting;
 105 my %reason_colours;
 106 my %h_colours;
 107 my $header_highlight_regex = '';
 108
 109 my $html_output_mode;
 110 my $no_msecs_mode; # XXX: should probably be removed
 111 my $shorten_thread_ids;
 112 my $line_end;
 113
 114 sub prepare_our_stuff() {
 115
 116     # Syntax Higlight hash
 117     @all_colours = (
 118         'red', 'green', 'brown', 'blue', 'purple', 'cyan',
 119         'light_gray', 'light_red', 'light_green', 'yellow',
 120         'light_blue', 'pink', 'light_cyan', 'white'
 121     );
 122
 123     %h = (
 124         # LOG_LEVEL
 125         Info            => 'blue',
 126         Header          => 'green',
 127         Filter          => 'purple', # XXX: Used?
 128         'Re-Filter'     => 'purple',
 129         Connect         => 'brown',
 130         Request         => 'light_cyan',
 131         CGI             => 'light_green',
 132         Redirect        => 'cyan',
 133         Error           => 'light_red',
 134         Crunch          => 'cyan',
 135         'Fatal error'   => 'light_red',
 136         'Gif-Deanimate' => 'blue',
 137         Force           => 'red',
 138         Writing         => 'light_green',
 139         Received        => 'yellow',
 140         Actions         => 'yellow',
 141         # ----------------------
 142         URL                  => 'yellow',
 143         path                 => 'brown',
 144         request_             => 'brown', # host+path but no protocol
 145         'ip-address'         => 'yellow',
 146         Number               => 'yellow',
 147         Standard             => 'reset',
 148         Truncation           => 'light_red',
 149         Status               => 'brown',
 150         Timestamp            => 'brown',
 151         Crunching            => 'light_red',
 152         crunched             => 'light_red',
 153         'Request-Line'       => 'pink',
 154         method               => 'purple',
 155         destination          => 'yellow',
 156         'http-version'       => 'pink',
 157         'crunch-pattern'     => 'pink',
 158         not                  => 'brown',
 159         file                 => 'brown',
 160         signal               => 'yellow',
 161         version              => 'green',
 162         'program-name'       => 'cyan',
 163         port                 => 'red',
 164         host                 => 'red',
 165         warning              => 'light_red',
 166         debug                => 'light_red',
 167         filter               => 'green',
 168         tag                  => 'green',
 169         tagger               => 'green',
 170         'status-message'     => 'light_cyan',
 171         'status-code'        => 'yellow',
 172         'invalid-request'    => 'light_red',
 173         'hits'               => 'yellow',
 174         error                => 'light_red',
 175         'rewritten-URL'      => 'light_red',
 176         'pcrs-delimiter'     => 'light_red',
 177         'ignored'            => 'light_red',
 178         'action-bits-update' => 'light_red',
 179         'configuration-line' => 'red',
 180         'content-type'       => 'yellow',
 181         'HOST'               => HEADER_DEFAULT_COLOUR,
 182     );
 183
 184     %h_colours = %h;
 185
 186     # Header colours need their own hash so the keys can be accessed properly
 187     %header_colours = (
 188         # Prefilled with headers that should not appear with default header colours
 189         Cookie => 'light_red',
 190         'Set-Cookie' => 'light_red',
 191         Warning => 'light_red',
 192         Default => HEADER_DEFAULT_COLOUR,
 193     );
 194
 195     # Crunch reasons need their own hash as well
 196     %reason_colours = (
 197         'Unsupported HTTP feature'               => 'light_red',
 198         Blocked                                  => 'light_red',
 199         Untrusted                                => 'light_red',
 200         Redirected                               => 'green',
 201         'CGI Call'                               => 'white',
 202         'DNS failure'                            => 'red',
 203         'Forwarding failed'                      => 'light_red',
 204         'Connection failure'                     => 'light_red',
 205         'Out of memory (may mask other reasons)' => 'light_red',
 206         'No reason recorded'                     => 'light_red',
 207     );
 208
 209     @time_colours = ('white', 'light_gray');
 210
 211     # Translate highlight strings into highlight code
 212     prepare_highlight_hash(\%header_colours);
 213     prepare_highlight_hash(\%reason_colours);
 214     prepare_highlight_hash(\%h);
 215     prepare_colour_array(\@all_colours);
 216     prepare_colour_array(\@time_colours);
 217     init_css_colours();
 218
 219     init_stats();
 220 }
 221
 222 sub paint_it($) {
 223 ###############################################################
 224 # Takes a colour string and returns an ANSI escape sequence
 225 # (unless --no-syntax-highlighting is used).
 226 # XXX: The Rolling Stones reference has to go.
 227 ###############################################################
 228
 229     my $colour = shift;
 230
 231     return "" if cli_option_is_set('no-syntax-highlighting');
 232
 233     my %light = (
 234         black       => 0,
 235         red         => 0,
 236         green       => 0,
 237         brown       => 0,
 238         blue        => 0,
 239         purple      => 0,
 240         cyan        => 0,
 241         light_gray  => 0,
 242         gray        => 0,
 243         dark_gray   => 1,
 244         light_red   => 1,
 245         light_green => 1,
 246         yellow      => 1,
 247         light_blue  => 1,
 248         pink        => 1,
 249         light_cyan  => 1,
 250         white       => 1,
 251     );
 252
 253     my %text = (
 254         black       => 30,
 255         red         => 31,
 256         green       => 32,
 257         brown       => 33,
 258         blue        => 34,
 259         purple      => 35,
 260         cyan        => 36,
 261         gray        => 37,
 262         light_gray  => 37,
 263         dark_gray   => 30,
 264         light_red   => 31,
 265         light_green => 32,
 266         yellow      => 33,
 267         light_blue  => 34,
 268         pink        => 35,
 269         light_cyan  => 36,
 270         white       => 37,
 271     );
 272
 273     my $bg_code = get_background();
 274     my $colour_code;
 275     our $default = default_colours();
 276
 277     if (defined($text{$colour})) {
 278         $colour_code  = ESCAPE;
 279         $colour_code .= $text{$colour};
 280         $colour_code .= ";";
 281         $colour_code .= $light{$colour} ? "1" : "2";
 282         $colour_code .= ";";
 283         $colour_code .= $bg_code;
 284         $colour_code .= "m";
 285         debug_message $colour . " is \'" . $colour_code . $colour . $default . "\'" if DEBUG_PAINT_IT;
 286
 287     } elsif ($colour =~ /reset/) {
 288
 289         $colour_code = default_colours();
 290
 291     } else {
 292
 293         die "What's $colour supposed to mean?\n";
 294     }
 295
 296     return $colour_code;
 297 }
 298
 299 sub get_semantic_html_markup($) {
 300 ###############################################################
 301 # Takes a string and returns a span element
 302 ###############################################################
 303
 304     my $type = shift;
 305     my $code;
 306
 307     if ($type =~ /Standard/) {
 308         $code = '</span>';
 309     } else {
 310         $type = lc($type);
 311         $code = '<span title="' . $type . '" class="' . $type . '">';
 312     }
 313
 314     return $code;
 315 }
 316
 317 sub cli_option_is_set($) {
 318
 319     our %cli_options;
 320     my $cli_option = shift;
 321
 322     die "Unknown CLI option: $cli_option" unless defined $cli_options{$cli_option};
 323
 324     return $cli_options{$cli_option};
 325 }
 326
 327 sub get_html_title() {
 328
 329     our %cli_options;
 330     return $cli_options{'title'};
 331
 332 }
 333
 334 sub init_css_colours() {
 335
 336     our %css_colours = (
 337         black       => "000",
 338         red         => "F00",
 339         green       => "0F0",
 340         brown       => "C90",
 341         blue        => "0F0",
 342         purple      => "F06", # XXX: wrong
 343         cyan        => "F09", # XXX: wrong
 344         light_gray  => "999",
 345         gray        => "333",
 346         dark_gray   => "222",
 347         light_red   => "F33",
 348         light_green => "33F",
 349         yellow      => "FF0",
 350         light_blue  => "30F",
 351         pink        => "F0F",
 352         light_cyan  => "66F",
 353         white       => "FFF",
 354     );
 355 }
 356
 357 sub get_css_colour($) {
 358
 359    our %css_colours;
 360    my $colour = shift;
 361
 362    die "What's $colour supposed to mean?\n" unless defined($css_colours{$colour});
 363
 364    return '#' . $css_colours{$colour};
 365 }
 366
 367 sub get_css_line($) {
 368
 369     my $class = shift;
 370     my $css_line;
 371
 372     $css_line .= '.' . lc($class) . ' {'; # XXX: lc() shouldn't be necessary
 373     die "What's $class supposed to mean?\n" unless defined($h_colours{$class});
 374     $css_line .= 'color:' . get_css_colour($h_colours{$class}) . ';';
 375     $css_line .= 'background-color:' . get_css_colour(DEFAULT_BACKGROUND) . ';';
 376     $css_line .= '}' . "\n";
 377
 378     return $css_line;
 379 }
 380
 381 sub get_css_line_for_colour($) {
 382
 383     my $colour = shift;
 384     my $css_line;
 385
 386     $css_line .= '.' . lc($colour) . ' {'; # XXX: lc() shouldn't be necessary
 387     $css_line .= 'color:' . get_css_colour($colour) . ';';
 388     $css_line .= 'background-color:' . get_css_colour(DEFAULT_BACKGROUND) . ';';
 389     $css_line .= '}' . "\n";
 390
 391     return $css_line;
 392 }
 393
 394 # XXX: Wrong solution
 395 sub get_missing_css_lines() {
 396
 397     my $css_line;
 398
 399     $css_line .= '.' . 'default' . ' {';
 400     $css_line .= 'color:' . HEADER_DEFAULT_COLOUR . ';';
 401     $css_line .= 'background-color:' . get_css_colour(DEFAULT_BACKGROUND) . ';';
 402     $css_line .= '}' . "\n";
 403
 404     return $css_line;
 405 }
 406
 407 sub get_css() {
 408
 409     our %css_colours; #XXX: Wrong solution
 410
 411     my $css = '';
 412
 413     $css .= '.privoxy-log {';
 414     $css .= 'color:' . get_css_colour(DEFAULT_TEXT_COLOUR) . ';';
 415     $css .= 'background-color:' . get_css_colour(DEFAULT_BACKGROUND) . ';';
 416     $css .= '}' . "\n";
 417
 418     foreach my $key (keys %h_colours) {
 419
 420         next if ($h_colours{$key} =~ m/reset/); #XXX: Wrong solution.
 421         $css .= get_css_line($key);
 422
 423     }
 424
 425     foreach my $colour (keys %css_colours) {
 426
 427         $css .= get_css_line_for_colour($colour);
 428
 429     }
 430
 431     $css .= get_missing_css_lines(); #XXX: Wrong solution
 432
 433     return $css;
 434 }
 435
 436 sub print_intro() {
 437
 438     my $intro = '';
 439
 440     if (cli_option_is_set('html-output')) {
 441
 442         my $title = get_html_title();
 443
 444         $intro .= '<html><head>';
 445         $intro .= '<title>' . $title . '</title>';
 446         $intro .= '<style>' . get_css() . '</style>' unless cli_option_is_set('no-embedded-css');
 447         $intro .= '</head><body>';
 448         $intro .= '<h1>' . $title . '</h1><p class="privoxy-log">';
 449
 450         print $intro;
 451     }
 452 }
 453
 454 sub print_outro() {
 455
 456     my $outro = '';
 457
 458     if (cli_option_is_set('html-output')) {
 459
 460         $outro = '</p></body></html>';
 461         print $outro;
 462
 463     }
 464 }
 465
 466 sub get_line_end() {
 467     return cli_option_is_set('html-output') ? "<br>\n" : "\n";
 468 }
 469
 470 sub get_colour_html_markup($) {
 471 ###############################################################
 472 # Takes a colour string a span element. XXX: WHAT?
 473 # XXX: This function shouldn't be necessary, the
 474 # markup should always be semantically correct.
 475 ###############################################################
 476
 477     my $type = shift;
 478     my $code;
 479
 480     if ($type =~ /Standard/) {
 481         $code = '</span>';
 482     } else {
 483         $code = '<span class="' . lc($type) . '">';
 484     }
 485
 486     return $code;
 487 }
 488
 489 sub default_colours() {
 490     # XXX: Properly
 491     our $bg_code;
 492     return reset_colours();
 493 }
 494
 495 sub show_colours() {
 496     # XXX: Implement
 497 }
 498
 499 sub reset_colours() {
 500     return ESCAPE . "0m";
 501 }
 502
 503 sub set_background($) {
 504
 505     my $colour = shift;
 506     our $bg_code;
 507     my %backgrounds = (
 508               black       => "40",
 509               red         => "41",
 510               green       => "42",
 511               brown       => "43",
 512               blue        => "44",
 513               magenta     => "45",
 514               cyan        => "46",
 515               white       => "47",
 516               default     => "49",
 517     );
 518
 519     if (defined($backgrounds{$colour})) {
 520         $bg_code = $backgrounds{$colour};
 521     } else {
 522         die "Invalid background colour: " . $colour;
 523     }
 524 }
 525
 526 sub get_background() {
 527     return our $bg_code;
 528 }
 529
 530 sub prepare_highlight_hash($) {
 531     my $ref = shift;
 532
 533     foreach my $key (keys %$ref) {
 534         $$ref{$key} = $html_output_mode ?
 535             get_semantic_html_markup($key) :
 536             paint_it($$ref{$key});
 537     }
 538 }
 539
 540 sub prepare_colour_array($) {
 541     my $ref = shift;
 542
 543     foreach my $i (0 ... @$ref - 1) {
 544         $$ref[$i] = $html_output_mode ?
 545             get_colour_html_markup($$ref[$i]) :
 546             paint_it($$ref[$i]);
 547     }
 548 }
 549
 550 sub found_unknown_content($) {
 551
 552     my $unknown = shift;
 553     my $message;
 554
 555     return unless cli_option_is_set('strict-checks');
 556
 557     return if ($unknown =~ /\[too long, truncated\]$/);
 558
 559     $message = "found_unknown_content: Don't know how to highlight: ";
 560     # Break line so the log file can later be parsed as Privoxy log file again
 561     $message .= '"' . $unknown . '"' . " in:\n";
 562     $message .= $req{$t}{'log-message'};
 563     debug_message($message);
 564     log_parse_error($req{$t}{'log-message'});
 565
 566     die "Unworthy content parser" if PUNISH_MISSING_LOG_KNOWLEDGE_WITH_DEATH;
 567 }
 568
 569 sub log_parse_error($) {
 570
 571     my $message = shift;
 572
 573     if (LOG_UNPARSED_LINES_TO_EXTRA_FILE) {
 574         open(my $errorlog_fd, ">>", ERROR_LOG_FILE) || die "Writing " . ERROR_LOG_FILE . " failed";
 575         print $errorlog_fd $message;
 576         close($errorlog_fd);
 577     }
 578 }
 579
 580 sub debug_message(@) {
 581     my @message = @_;
 582
 583     print $h{'debug'} . "@message" . $h{'Standard'} . "\n";
 584 }
 585
 586 ################################################################################
 587 # highlighter functions that aren't loglevel-specific
 588 ################################################################################
 589
 590 sub h($) {
 591
 592     # Get highlight marker
 593     my $highlight = shift; # XXX: Stupid name;
 594     my $result = '';
 595     my $message;
 596
 597     if (defined($highlight)) {
 598
 599         $result = $h{$highlight};
 600
 601     } else {
 602
 603         $message = "h: Don't recognize highlighter $highlight.";
 604         debug_message($message);
 605         log_parser_error($message);
 606         die "Unworthy highlighter function" if PUNISH_MISSING_HIGHLIGHT_KNOWLEDGE_WITH_DEATH;
 607     }
 608
 609     return $result;
 610 }
 611
 612 sub highlight_known_headers($) {
 613
 614     my $content = shift;
 615
 616     debug_message("Searching $content for things to highlight.") if DEBUG_HEADER_HIGHLIGHTING;
 617
 618     if ($content =~ m/(?<=\s)($header_highlight_regex):/) {
 619         my $header = $1;
 620         $content =~ s@(?<=[\s|'])($header)(?=:)@$header_colours{$header}$1$h{'Standard'}@ig;
 621         debug_message("Highlighted '$header' in '$content'") if DEBUG_HEADER_HIGHLIGHTING;
 622     }
 623
 624     return $content;
 625 }
 626
 627 sub highlight_matched_request_line($$) {
 628
 629     my $result = shift; # XXX: Stupid name;
 630     my $regex = shift;
 631     if ($result =~ m@(.*)($regex)(.*)@) {
 632         $result = $1 . highlight_request_line($2) . $3
 633     }
 634     return $result;
 635 }
 636
 637 sub highlight_request_line($) {
 638
 639     my $rl = shift;
 640     my ($method, $url, $http_version);
 641
 642     #GET http://images.sourceforge.net/sfx/icon_warning.gif HTTP/1.1
 643     if ($rl =~ m/Invalid request/) {
 644
 645         $rl = h('invalid-request') . $rl . h('Standard');
 646
 647     } elsif ($rl =~ m/^([-\w]+) (.*) (HTTP\/\d+\.\d+)/) {
 648
 649         # XXX: might not match in case of HTTP method fuzzing.
 650         # XXX: save these: ($method, $path, $http_version) = ($1, $2, $3);
 651         $rl =~ s@^(\w+)@$h{'method'}$1$h{'Standard'}@;
 652         if ($rl =~ /http:\/\//) {
 653             $rl = highlight_matched_url($rl, '[^\s]*(?=\sHTTP)');
 654         } else {
 655             $rl = highlight_matched_pattern($rl, 'request_', '[^\s]*(?=\sHTTP)');
 656         }
 657
 658         $rl =~ s@(HTTP\/\d\.\d)$@$h{'http-version'}$1$h{'Standard'}@;
 659
 660     } elsif ($rl =~ m/\.\.\. \[too long, truncated\]$/) {
 661
 662         $rl =~ s@^(\w+)@$h{'method'}$1$h{'Standard'}@;
 663         $rl = highlight_matched_url($rl, '[^\s]*(?=\.\.\.)');
 664
 665     } elsif ($rl =~ m/^ $/) {
 666
 667         $rl = h('error') . "No request line specified!" . h('Standard');
 668
 669     } else {
 670
 671         debug_message ("Can't parse request line: $rl");
 672
 673     }
 674
 675     return $rl;
 676 }
 677
 678 sub highlight_response_line($) {
 679
 680     my $rl = shift;
 681     my ($http_version, $status_code, $status_message);
 682
 683     #HTTP/1.1 200 OK
 684     #ICY 200 OK
 685
 686     # TODO: Mark different status codes differently
 687
 688     if ($rl =~ m/((?:HTTP\/\d\.\d|ICY)) (\d+) (.*)/) {
 689         ($http_version, $status_code, $status_message) = ($1, $2, $3);
 690     } else {
 691         debug_message ("Can't parse response line: $rl") and die 'Fix this';
 692     }
 693
 694     # Rebuild highlighted
 695     $rl= "";
 696     $rl .= h('http-version') . $http_version . h('Standard');
 697     $rl .= " ";
 698     $rl .= h('status-code') . $status_code . h('Standard');
 699     $rl .= " ";
 700     $rl .= h('status-message') . $status_message . h('Standard');
 701
 702     return $rl;
 703 }
 704
 705 sub highlight_matched_url($$) {
 706
 707     my $result = shift; # XXX: Stupid name;
 708     my $regex = shift;
 709
 710     #print "Got $result, regex ($regex)\n";
 711
 712     if ($result =~ m@(.*?)($regex)(.*)@) {
 713         $result = $1 . highlight_url($2) . $3;
 714         #print "Now the result is $result\n";
 715     }
 716
 717     return $result;
 718 }
 719
 720 sub highlight_matched_host($$) {
 721
 722     my ($result, $regex) = @_; # XXX: result ist stupid name;
 723
 724     if ($result =~ m@(.*?)($regex)(.*)@) {
 725         $result = $1 . $h{host} . $2 . $h{Standard} . $3;
 726     }
 727
 728     return $result;
 729 }
 730
 731 sub highlight_matched_pattern($$$) {
 732
 733     my $result = shift; # XXX: Stupid name;
 734     my $key = shift;
 735     my $regex = shift;
 736
 737     die "Unknown key $key" unless defined $h{$key};
 738
 739     if ($result =~ m@(.*?)($regex)(.*)@) {
 740         $result = $1 . h($key) . $2 . h('Standard') . $3;
 741     }
 742
 743     return $result;
 744 }
 745
 746 sub highlight_matched_path($$) {
 747
 748     my $result = shift; # XXX: Stupid name;
 749     my $regex = shift;
 750
 751     if ($result =~ m@(.*?)($regex)(.*)@) {
 752         $result = $1 . h('path') . $2 . h('Standard') . $3;
 753     }
 754
 755     return $result;
 756 }
 757
 758 sub highlight_url($) {
 759
 760     my $url = shift;
 761
 762     if ($html_output_mode) {
 763
 764         $url = '<a href="' . $url . '">' . $url . '</a>';
 765
 766     } else {
 767
 768         $url = h('URL') . $url . h('Standard');
 769
 770     }
 771
 772     return $url;
 773 }
 774
 775 sub update_header_highlight_regex($) {
 776
 777     my $header = shift;
 778     my $headers = join ('|', keys %header_colours);
 779
 780     $header_highlight_regex = qr/$headers/;
 781     print "Registering '$header'\n" if DEBUG_HEADER_HIGHLIGHTING;
 782 }
 783
 784 ################################################################################
 785 # loglevel-specific highlighter functions
 786 ################################################################################
 787
 788 sub handle_loglevel_header($) {
 789
 790     my $c = shift;
 791
 792     if ($c =~ /^scan:/) {
 793
 794         if ($c =~ m/^scan: ([^: ]+):/) {
 795
 796             # Register new headers
 797             # scan: Accept: image/png,image/*;q=0.8,*/*;q=0.5
 798             my $header = $1;
 799             if (!defined($header_colours{$header}) and $header =~ /^[\d\w-]*$/) {
 800                 debug_message "Registering previously unknown header $1" if DEBUG_HEADER_REGISTERING;
 801
 802                 if (REGISTER_HEADERS_WITH_THE_SAME_COLOUR) {
 803                     $header_colours{$header} =  $header_colours{'Default'};
 804                 } else {
 805                     $header_colours{$header} = $all_colours[$header_colour_index % @all_colours];
 806                     $header_colour_index++;
 807                 }
 808                 update_header_highlight_regex($header);
 809             }
 810
 811         } elsif ($c =~ m/^(scan: )(\w+ .+ HTTP\/\d\.\d)/) {
 812
 813             # scan: GET http://p.p/ HTTP/1.1
 814             $c = $1 . highlight_request_line($2);
 815
 816         } elsif ($c =~ m/^(scan: )((?:HTTP\/\d\.\d|ICY) (\d+) (.*))/) {
 817
 818             # scan: HTTP/1.1 200 OK
 819             $req{$t}{'response_line'} = $2;
 820             $req{$t}{'status_code'} = $3;
 821             $req{$t}{'status_message'} = $4;
 822             $c = $1 . highlight_response_line($req{$t}{'response_line'});
 823         }
 824
 825     } elsif ($c =~ m/^Crunching (?:server|client) header: .* \(contains: ([^\)]*)\)/) {
 826
 827         # Crunching server header: Set-Cookie: trac_form_token=d5308c34e16d15e9e301a456; (contains: Cookie:)
 828         $c =~ s@(?<=contains: )($1)@$h{'crunch-pattern'}$1$h{'Standard'}@;
 829         $c =~ s@(Crunching)@$h{$1}$1$h{'Standard'}@;
 830
 831     } elsif ($c =~ m/^New host is: ([^\s]*)\./) {
 832
 833         # New host is: trac.vidalia-project.net. Crunching Referer: http://www.vidalia-project.net/!
 834         $c = highlight_matched_host($c, '(?<=New host is: )[^\s]+(?=\.)');
 835         $c = highlight_matched_url($c, '(?<=Crunching Referer: )[^\s!]+');
 836
 837     } elsif ($c =~ m/^Text mode enabled by force. (Take cover)!/) {
 838
 839         # Text mode enabled by force. Take cover!
 840         $c =~ s@($1)@$h{'warning'}$1$h{'Standard'}@;
 841
 842     } elsif ($c =~ m/^(New HTTP Request-Line: )(.*)/) {
 843
 844         # New HTTP Request-Line: GET http://www.privoxy.org/ HTTP/1.1
 845         $c = $1 . highlight_request_line($2);
 846
 847     } elsif ($c =~ m/^Adjust(ed)? Content-Length to \d+/) {
 848
 849         # Adjusted Content-Length to 2132
 850         # Adjust Content-Length to 33533
 851         $c =~ s@(?<=Content-Length to )(\d+)@$h{'Number'}$1$h{'Standard'}@;
 852         $c = highlight_known_headers($c);
 853
 854     } elsif ($c =~ m/^Destination extracted from "Host:" header. New request URL:/) {
 855
 856         # Destination extracted from "Host:" header. New request URL: http://www.cccmz.de/~ridcully/blog/
 857         $c = highlight_matched_url($c, '(?<=New request URL: ).*');
 858
 859     } elsif ($c =~ m/^Couldn\'t parse:/) {
 860
 861         # XXX: These should probable be logged with LOG_LEVEL_ERROR
 862         # Couldn't parse: If-Modified-Since: Wed, 21 Mar 2007 16:34:50 GMT (crunching!)
 863         # Couldn't parse: at, 24 Mar 2007 13:46:21 GMT in If-Modified-Since: Sat, 24 Mar 2007 13:46:21 GMT (crunching!)
 864         $c =~ s@^(Couldn\'t parse)@$h{'error'}$1$h{'Standard'}@;
 865
 866     } elsif ($c =~ /^Tagger \'([^\']*)\' added tag \'([^\']*)\'/ or
 867              $c =~ m/^Adding tag \'([^\']*)\' created by header tagger \'([^\']*)\'/) {
 868
 869         # Adding tag 'GET request' created by header tagger 'method-man' (XXX: no longer used)
 870         # Tagger 'revalidation' added tag 'REVALIDATION-REQUEST'. No action bit update necessary.
 871         # Tagger 'revalidation' added tag 'REVALIDATION-REQUEST'. Action bits updated accordingly.
 872
 873         # XXX: Save tag and tagger
 874
 875         $c =~ s@(?<=^Tagger \')([^\']*)@$h{'tagger'}$1$h{'Standard'}@;
 876         $c =~ s@(?<=added tag \')([^\']*)@$h{'tag'}$1$h{'Standard'}@;
 877         $c =~ s@(?<=Action bits )(updated)@$h{'action-bits-update'}$1$h{'Standard'}@;
 878         $no_special_header_highlighting = 1;
 879
 880     } elsif ($c =~ /^Tagger \'([^\']*)\' didn['']t add tag \'([^\']*)\'/) {
 881
 882         # Tagger 'revalidation' didn't add tag 'REVALIDATION-REQUEST'. Tag already present
 883         # XXX: Save tag and tagger
 884
 885         $c =~ s@(?<=^Tagger \')([^\']*)@$h{'tag'}$1$h{'Standard'}@;
 886         $c =~ s@(?<=didn['']t add tag \')([^\']*)@$h{'tagger'}$1$h{'Standard'}@;
 887
 888     } elsif ($c =~ m/^(?:scan:|Randomiz|addh:|Adding:|Removing:|Referer:|Modified:|Accept-Language header|[Cc]ookie)/
 889           or $c =~ m/^(Text mode is already enabled|Denied request with NULL byte|Replaced:|add-unique:)/
 890           or $c =~ m/^(Crunched (incoming|outgoing) cookie|Suppressed offer|Accepted the client)/
 891           or $c =~ m/^(addh-unique|Referer forged to)/
 892           or $c =~ m/^Downgraded answer to HTTP\/1.0/
 893           or $c =~ m/^Parameter: \+hide-referrer\{[^\}]*\} is a bad idea, but I don\'t care./
 894           or $c =~ m/^Referer (?:overwritten|replaced) with: Referer: / #XXX: should this be highlighted?
 895           or $c =~ m/^Referer crunched!/
 896           or $c =~ m/^crunched x-forwarded-for!/
 897           or $c =~ m/^crunched From!/
 898           or $c =~ m/^ modified$/
 899           or $c =~ m/^Content filtering is enabled. Crunching:/
 900           or $c =~ m/^force-text-mode overruled the client/
 901           or $c =~ m/^Server time in the future\./
 902           or $c =~ m/^content-disposition header crunched and replaced with:/i
 903           or $c =~ m/^Reducing white space in /
 904           or $c =~ m/^Ignoring single quote in /
 905           or $c =~ m/^Converting tab to space in /
 906           or $c =~ m/A HTTP\/1\.1 response without/
 907           or $c =~ m/Disabled filter mode on behalf of the client/
 908           or $c =~ m/Keeping the (?:server|client) header /
 909           or $c =~ m/Content modified with no Content-Length header set/
 910           or $c =~ m/^Appended client IP address to/
 911           or $c =~ m/^Removing 'Connection: close' to imply keep-alive./
 912           or $c =~ m/^keep-alive support is disabled/
 913           or $c =~ m/^Continue hack in da house/
 914           or $c =~ m/^Merged multiple header lines to:/
 915           or $c =~ m/^Added header: /
 916           or $c =~ m/^Enlisting (?:sorted|left-over) header/
 917           or $c =~ m/^Multiple Content-Type headers detected. Removing and ignoring: Content-Type:/
 918             )
 919     {
 920         # XXX: Some of these may need highlighting
 921
 922         # Modified: User-Agent: Mozilla/5.0 (X11; U; SunOS i86pc; pl-PL; rv:1.8.1.1) Gecko/20070214 Firefox/2.0.0.1
 923         # Accept-Language header crunched and replaced with: Accept-Language: pl-pl
 924         # cookie 'Set-Cookie: eZSessionCookie=07bfec287c197440d299f81580593c3d; \
 925         #  expires=Thursday, 12-Apr-07 15:16:18 GMT; path=/' send by \
 926         #  http://wirres.net/article/articleview/4265/1/6/ appears to be using time format 1 (XXX: gone with the wind)
 927         # Cookie rewritten to a temporary one: Set-Cookie: NSC_gffe-iuuq-mc-wtfswfs=8efb33a53660;path=/
 928         # Text mode is already enabled
 929         # Denied request with NULL byte(s) turned into line break(s)
 930         # Replaced: 'Connection: Yo, home to Bel Air' with 'Connection: close'
 931         # addh-unique: Host: people.freebsd.org
 932         # Suppressed offer to compress content
 933         # Crunched incoming cookie -- yum!
 934         # Accepted the client's request to fetch without filtering.
 935         # Crunched outgoing cookie: Cookie: PREF=ID=6cf0abd347b30262:TM=1173357617:LM=1173357617:S=jZypyyJ7LPiwFi1_
 936         # addh-unique: Host: subkeys.pgp.net:11371
 937         # Referer forged to: Referer: http://10.0.0.1/
 938         # Downgraded answer to HTTP/1.0
 939         # Parameter: +hide-referrer{pille-palle} is a bad idea, but I don't care.
 940         # Referer overwritten with: Referer: pille-palle
 941         # Referer replaced with: Referer: pille-palle
 942         # crunched x-forwarded-for!
 943         # crunched From!
 944         #  modified # XXX: pretty stupid log message
 945         # Content filtering is enabled. Crunching: 'Range: 1234-5678' to prevent range-mismatch problems
 946         # force-text-mode overruled the client's request to fetch without filtering!
 947         # Server time in the future.
 948         # content-disposition header crunched and replaced with: content-disposition: filename=baz
 949         # Content-Disposition header crunched and replaced with: content-disposition: filename=baz
 950         # Reducing white space in 'X-LWS-Test: "This  is  quoted" this is not "this  is  " but " this again   is  not'
 951         # Ignoring single quote in 'X-LWS-Test: "This  is  quoted" this is not "this  is  " but "  this again   is  not'
 952         # Converting tab to space in 'X-LWS-Test:   "This  is  quoted" this   is  not "this  is  "  but  "\
 953         #  this again   is  not'
 954         # A HTTP/1.1 response without Connection header implies keep-alive.
 955         # Disabled filter mode on behalf of the client.
 956         # Keeping the server header 'Connection: keep-alive' around.
 957         # Keeping the client header 'Connection: close' around. The connection will not be kept alive.
 958         # Keeping the client header 'Connection: keep-alive' around. The connection will be kept alive if possible.
 959         # Content modified with no Content-Length header set. Creating a fake one for adjustment later on.
 960         # Appended client IP address to X-Forwarded-For: 10.0.0.2, 10.0.0.1
 961         # Removing 'Connection: close' to imply keep-alive.
 962         # keep-alive support is disabled. Crunching: Keep-Alive: 300.
 963         # Continue hack in da house.
 964         # Merged multiple header lines to: 'X-FORWARDED-PROTO: http X-HOST: 127.0.0.1'
 965         # Added header: Content-Encoding: deflate
 966         # Enlisting sorted header User-Agent: Mozilla/5.0 (X11; SunOS i86pc; rv:10.0.3) Gecko/20100101 Firefox/10.0.3
 967         # Enlisting left-over header Connection: close
 968         # Multiple Content-Type headers detected. Removing and ignoring: Content-Type: text/html
 969
 970     } elsif ($c =~ m/^scanning headers for:/) {
 971
 972         return '' unless SHOW_SCAN_INTRO;
 973
 974     } elsif ($c =~ m/^[Cc]runch(ing|ed)|crumble crunched:/) {
 975         # crunched User-Agent!
 976         # Crunching: Content-Encoding: gzip
 977
 978         $c =~ s@(Crunching|crunched)@$h{$1}$1$h{'Standard'}@;
 979
 980     } elsif ($c =~ m/^Offending request data with NULL bytes turned into \'°\' characters:/) {
 981
 982         # Offending request data with NULL bytes turned into '°' characters: °°n°°(°°°
 983
 984         $c = h('warning') . $c . h('Standard');
 985
 986     } elsif ($c =~ m/^(Transforming \")(.*?)(\" to \")(.*?)(\")/) {
 987
 988         # Transforming "Proxy-Authenticate: Basic realm="Correos Proxy Server"" to\
 989         #  "Proxy-Authenticate: Basic realm="Correos Proxy Server""
 990
 991        $c =~ s@(?<=^Transforming \")(.*)(?=\" to)@$h{'Header'}$1$h{'Standard'}@;
 992        $c =~ s@(?<=to \")(.*)(?=\")@$h{'Header'}$1$h{'Standard'}@;
 993
 994     } elsif ($c =~ m/^Removing empty header/) {
 995
 996         # Removing empty header
 997         # Ignore for now
 998
 999     } elsif ($c =~ m/^Content-Type: .* not replaced/) {
1000
1001         # Content-Type: application/octet-stream not replaced. It doesn't look like text.\
1002         #  Enable force-text-mode if you know what you're doing.
1003         # XXX: Could highlight more here.
1004         $c =~ s@(?<=^Content-Type: )(.*)(?= not replaced)@$h{'content-type'}$1$h{'Standard'}@;
1005
1006     } elsif ($c =~ m/^(Server|Client) keep-alive timeout is/) {
1007
1008        # Server keep-alive timeout is 5. Sticking with 10.
1009        # Client keep-alive timeout is 20. Sticking with 10.
1010
1011        $c =~ s@(?<=timeout is )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1012        $c =~ s@(?<=Sticking with )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1013
1014     } elsif ($c =~ m/^Reducing keep-alive timeout/) {
1015
1016        # Reducing keep-alive timeout from 60 to 10.
1017
1018        $c =~ s@(?<= from )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1019        $c =~ s@(?<= to )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1020
1021     } elsif ($c =~ m/^Killed all-caps Host header line: HOST:/) {
1022
1023        # Killed all-caps Host header line: HOST: bestproxydb.com
1024        $c = highlight_matched_host($c, '(?<=HOST: )[^\s]+');
1025        $c = highlight_matched_pattern($c, 'HOST', 'HOST');
1026
1027     } else {
1028
1029         found_unknown_content($c);
1030     }
1031
1032     # Highlight headers
1033     unless ($c =~ m/^Transforming/) {
1034         $c = highlight_known_headers($c) unless $no_special_header_highlighting;
1035     }
1036
1037     return $c;
1038 }
1039
1040 sub handle_loglevel_re_filter($) {
1041
1042     my $content = shift;
1043     my $c = $content;
1044     my $key;
1045
1046     if ($c =~ m/^(?:re_)?filtering ([^\s]+) \(size (\d+)\) with (?:filter )?\'?([^\s]+?)\'? produced (\d+) hits \(new size (\d+)\)/) {
1047
1048         # XXX: only the second version gets highlighted properly.
1049         # re_filtering www.lfk.de/favicon.ico (size 209) with filter untrackable-hulk produced 0 hits (new size 209).
1050         # filtering aci.blogg.de/ (size 37988) with 'blogg.de' produced 3 hits (new size 38057)
1051         $req{$t}{'content_source'} = $1;
1052         $req{$t}{'content_size'}   = $2;
1053         $req{$t}{'content_filter'} = $3;
1054         $req{$t}{'content_hits'}   = $4;
1055         $req{$t}{'new_content_size'} = $5;
1056         $req{$t}{'content_size_change'} = $req{$t}{'new_content_size'} - $req{$t}{'content_size'};
1057         #return '' if ($req{$t}{'content_hits'} == 0 && !cli_option_is_set('show-ineffective-filters'));
1058         if ($req{$t}{'content_hits'} == 0 and
1059             not (cli_option_is_set('show-ineffective-filters')
1060                  or ($req{$t}{'content_filter'} =~ m/^privoxy-filter-test$/))) {
1061                 return '';
1062         }
1063
1064         $c =~ s@(?<=\(size )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1065         $c =~ s@(?<=\(new size )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1066         $c =~ s@(?<=produced )(\d+)(?= hits)@$h{'Number'}$1$h{'Standard'}@;
1067
1068         $c =~ s@([^\s]+?)(\'? produced)@$h{'filter'}$1$h{'Standard'}$2@;
1069         $c = highlight_matched_host($c, '(?<=filtering )[^\s]+');
1070
1071         $c =~ s@\.$@ @;
1072         $c .= "(" . $h{'Number'};
1073         $c .= "+" if ($req{$t}{'content_size_change'} >= 0);
1074         $c .= $req{$t}{'content_size_change'} . $h{'Standard'} . ")";
1075         $content = $c;
1076
1077   } elsif ($c =~ /\.{3}$/
1078         and $c =~ m/^(?:re_)?filtering \'?(.*?)\'? \(size (\d*)\) with (?:filter )?\'?([^\s]*?)\'? ?\.{3}$/) {
1079
1080         # Used by Privoxy 3.0.5 and 3.0.6:
1081         # XXX: Fill in ...
1082         # Used by Privoxy 3.0.7:
1083         # filtering 'Connection: close' (size 17) with 'generic-content-ads' ...
1084
1085         $req{$t}{'filtered_header'} = $1;
1086         $req{$t}{'old_header_size'} = $2;
1087         $req{$t}{'header_filter_name'} = $3;
1088
1089         unless (cli_option_is_set('show-ineffective-filters') or
1090                 $req{$t}{'header_filter_name'} =~ m/^privoxy-filter-test$/) {
1091             return '';
1092         }
1093         $content =~ s@(?<=\(size )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1094         $content =~ s@($req{$t}{'header_filter_name'})@$h{'filter'}$1$h{'Standard'}@;
1095
1096     } elsif ($c =~ m/^ ?\.\.\. ?produced (\d*) hits \(new size (\d*)\)\./) {
1097
1098         # ...produced 0 hits (new size 23).
1099         #... produced 1 hits (new size 54).
1100
1101         $req{$t}{'header_filter_hits'} = $1;
1102         $req{$t}{'new_header_size'} = $2;
1103
1104         unless (cli_option_is_set('show-ineffective-filters') or
1105                 (defined($req{$t}{'header_filter_name'}) and
1106                  $req{$t}{'header_filter_name'} =~ m/^privoxy-filter-test$/)) {
1107
1108             if ($req{$t}{'header_filter_hits'} == 0 and
1109                 not (defined($req{$t}{'header_filter_name'}) and
1110                  $req{$t}{'header_filter_name'} =~ m/^privoxy-filter-test$/)) {
1111                 return '';
1112             }
1113             # Reformat including information from the intro
1114             $c = "'" . h('filter') . $req{$t}{'header_filter_name'} . h('Standard') . "'";
1115             $c .= " hit ";
1116             # XXX: Hide behind constant, it may be interesting if LOG_LEVEL_HEADER isn't enabled as well.
1117             # $c .= $req{$t}{'filtered_header'} . " ";
1118             $c .= h('Number') . $req{$t}{'header_filter_hits'}. h('Standard');
1119             $c .= ($req{$t}{'header_filter_hits'} == 1) ? " time, " : " times, ";
1120
1121             if ($req{$t}{'old_header_size'} !=  $req{$t}{'new_header_size'}) {
1122
1123                 $c .= "changing size from ";
1124                 $c .=  h('Number') . $req{$t}{'old_header_size'} . h('Standard');
1125                 $c .= " to ";
1126                 $c .= h('Number') . $req{$t}{'new_header_size'} . h('Standard');
1127                 $c .= ".";
1128
1129             } else {
1130
1131                 $c .= "keeping the size at " . $req{$t}{'old_header_size'};
1132
1133             }
1134
1135             # Highlight from last line (XXX: What?)
1136             # $c =~ s@(?<=produced )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1137             # $c =~ s@($req{$t}{'header_filter_name'})@$h{'filter'}$1$h{'Standard'}@;
1138
1139         } else {
1140
1141            # XXX: Untested
1142            $c =~ s@(?<=produced )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1143            $c =~ s@(?<=new size )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1144
1145         }
1146         $content = $c;
1147
1148     } elsif ($c =~ m/^(Tagger|Filter) ([^\s]*) has empty joblist. Nothing to do./) {
1149
1150         # Filter privoxy-filter-test has empty joblist. Nothing to do.
1151         # Tagger variable-test has empty joblist. Nothing to do.
1152
1153         $content =~ s@(?<=$1 )([^\s]*)@$h{'filter'}$1$h{'Standard'}@;
1154
1155     } elsif ($c =~ m/^De-chunking successful. Shrunk from (\d+) to (\d+)/) {
1156
1157         $req{$t}{'chunked-size'} = $1;
1158         $req{$t}{'dechunked-size'} = $2;
1159         $req{$t}{'dechunk-change'} = $req{$t}{'dechunked-size'} - $req{$t}{'chunked-size'};
1160
1161         $content .= " (" . h('Number') . $req{$t}{'dechunk-change'} . h('Standard') . ")";
1162
1163         $content =~ s@(?<=from )($req{$t}{'chunked-size'})@$h{'Number'}$1$h{'Standard'}@;
1164         $content =~ s@(?<=to )($req{$t}{'dechunked-size'})@$h{'Number'}$1$h{'Standard'}@;
1165
1166     } elsif ($c =~ m/^Decompression successful. Old size: (\d+), new size: (\d+)./) {
1167
1168         # Decompression successful. Old size: 670, new size: 1166.
1169
1170         $req{$t}{'size-compressed'} = $1;
1171         $req{$t}{'size-decompressed'} = $2;
1172         $req{$t}{'decompression-gain'} = $req{$t}{'size-decompressed'} - $req{$t}{'size-compressed'};
1173
1174         $content =~ s@(?<=Old size: )($req{$t}{'size-compressed'})@$h{'Number'}$1$h{'Standard'}@;
1175         $content =~ s@(?<=new size: )($req{$t}{'size-decompressed'})@$h{'Number'}$1$h{'Standard'}@;
1176
1177         # XXX: Create sub get_percentage()
1178         if ($req{$t}{'size-decompressed'}) {
1179             $req{$t}{'decompression-gain-percent'} =
1180                 $req{$t}{'decompression-gain'} / $req{$t}{'size-decompressed'} * 100;
1181
1182             $content .= " (saved: ";
1183             #$content .= h('Number') . $req{$t}{'decompression-gain'} . h('Standard');
1184             #$content .= "/";
1185             $content .= h('Number') . sprintf("%.2f%%", $req{$t}{'decompression-gain-percent'}) . h('Standard');
1186             $content .= ")";
1187         }
1188
1189     } elsif ($c =~ m/^(Need to de-chunk first)/) {
1190
1191         # Need to de-chunk first
1192         return '' if SUPPRESS_NEED_TO_DE_CHUNK_FIRST;
1193
1194     } elsif ($c =~ m/^(Adding (?:dynamic )?re_filter job)/) {
1195
1196         return ''  if (SUPPRESS_SUCCEEDED_FILTER_ADDITIONS && m/succeeded/);
1197
1198         # Adding re_filter job ...
1199         # Adding dynamic re_filter job s@^(?:\w*)\s+.*\s+HTTP/\d\.\d\s*@IP-ADDRESS: $origin@D\
1200         #  to filter client-ip-address succeeded.
1201
1202     } elsif ($c =~ m/^Compressed content from /) {
1203
1204         # Compressed content from 29258 to 8630 bytes. Compression level: 3
1205         $content =~ s@(?<=from )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1206         $content =~ s@(?<=to )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1207         $content =~ s@(?<=level: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1208
1209     } elsif ($c =~ m/^Reading in filter/) {
1210
1211         return '' unless SHOW_FILTER_READIN_IN;
1212
1213     } elsif ($c =~ m/^Decompression didn't result/) {
1214
1215         # Decompression didn't result in any content.
1216
1217         # Nothing to highlight.
1218
1219     } else {
1220
1221         found_unknown_content($content);
1222
1223     }
1224
1225     return $content;
1226 }
1227
1228 sub handle_loglevel_redirect($) {
1229
1230     my $c = shift;
1231
1232     if ($c =~ m/^Decoding "([^""]*)"/) {
1233
1234          $req{$t}{'original-destination'} = $1;
1235          $c = highlight_matched_path($c, '(?<=Decoding ")[^"]*');
1236          $c =~ s@\"@@g;
1237
1238     } elsif ($c =~ m/^Checking/) {
1239
1240          # Checking /_ylt=A0geu.Z76BRGR9k/**http://search.yahoo.com/search?p=view+odb+presentation+on+freebsd\
1241          #  &ei=UTF-8&xargs=0&pstart=1&fr=moz2&b=11 for redirects.
1242
1243          # TODO: Change colour if really url-decoded
1244          $req{$t}{'decoded-original-destination'} = $1;
1245          $c = highlight_matched_path($c, '(?<=Checking ")[^"]*');
1246          $c =~ s@\"@@g;
1247
1248     } elsif ($c =~ m/^pcrs command "([^""]*)" changed /) {
1249
1250         # pcrs command "s@&from=rss@@" changed \
1251         #  "http://it.slashdot.org/article.pl?sid=07/03/02/1657247&from=rss"\
1252         #  to "http://it.slashdot.org/article.pl?sid=07/03/02/1657247" (1 hit).
1253         $c =~ s@(?<=pcrs command )"([^""]*)"@$h{'filter'}$1$h{'Standard'}@;
1254         $c = highlight_matched_url($c, '(?<=changed ")[^""]*');
1255         $c =~ s@(?<=changed )"([^""]*)"@$1@; # Remove quotes
1256         $c = highlight_matched_url($c, '(?<=to ")[^""]*');
1257         $c =~ s@(?<=to )"([^""]*)"@$1@; # Remove quotes
1258         $c =~ s@(\d+)(?= hits?)@$h{'hits'}$1$h{'Standard'}@;
1259
1260     } elsif ($c =~ m/^pcrs command "([^""]*)" didn\'t change/) {
1261
1262         # pcrs command "s@^http://([^.]+?)/?$@http://www.bing.com/search?q=$1@" didn't \
1263         #  change "http://www.example.org/".
1264         $c =~ s@(?<=pcrs command )"([^""]*)"@$h{'filter'}$1$h{'Standard'}@;
1265         $c = highlight_matched_url($c, '(?<=change ")[^""]*');
1266
1267     } elsif ($c =~ m/(^New URL is: )(.*)/) {
1268
1269         # New URL is: http://it.slashdot.org/article.pl?sid=07/03/04/1511210
1270         # XXX: Use URL highlighter
1271         # XXX: Save?
1272         $c = $1 . h('rewritten-URL') . $2 . h('Standard');
1273
1274     } elsif ($c =~ m/No pcrs command recognized, assuming that/) {
1275         # No pcrs command recognized, assuming that "http://config.privoxy.org/user-manual/favicon.png"\
1276         #  is already properly formatted.
1277         # XXX: assume the same?
1278         $c = highlight_matched_url($c, '(?<=assuming that \")[^"]*');
1279
1280     } elsif ($c =~ m/^Percent-encoding redirect/) {
1281
1282         # Percent-encoding redirect URL: http://www.example.org/\x02
1283         $c = highlight_matched_url($c, '(?<=redirect URL: ).*');
1284
1285     } else {
1286
1287         found_unknown_content($c);
1288
1289     }
1290
1291     return $c;
1292 }
1293
1294 sub handle_loglevel_gif_deanimate($) {
1295
1296     my $content = shift;
1297
1298     if ($content =~ m/Success! GIF shrunk from (\d+) bytes to (\d+)\./) {
1299
1300         my $bytes_from = $1;
1301         my $bytes_to = $2;
1302         # Gif-Deanimate: Success! GIF shrunk from 205 bytes to 133.
1303         $content =~ s@$bytes_from@$h{'Number'}$bytes_from$h{'Standard'}@;
1304         # XXX: Do we need g in case of ($1 == $2)?
1305         $content =~ s@$bytes_to@$h{'Number'}$bytes_to$h{'Standard'}@;
1306
1307     } elsif ($content =~ m/GIF (not) changed/) {
1308
1309         # Gif-Deanimate: GIF not changed.
1310         return '' if SUPPRESS_GIF_NOT_CHANGED;
1311         $content =~ s@($1)@$h{'not'}$1$h{'Standard'}@;
1312
1313     } elsif ($content =~ m/^failed! \(gif parsing\)/) {
1314
1315         # failed! (gif parsing)
1316         # XXX: Replace this error message with something less stupid
1317         $content =~ s@(failed!)@$h{'error'}$1$h{'Standard'}@;
1318
1319     } elsif ($content =~ m/^Need to de-chunk first/) {
1320
1321         # Need to de-chunk first
1322         return '' if SUPPRESS_NEED_TO_DE_CHUNK_FIRST;
1323
1324     } elsif ($content =~ m/^(?:No GIF header found|failed while parsing)/) {
1325
1326         # No GIF header found (XXX: Did I ever commit this?)
1327         # failed while parsing 195 134747048 (XXX: never committed)
1328
1329         # Ignore these for now
1330
1331     } else {
1332
1333         found_unknown_content($content);
1334
1335     }
1336
1337     return $content;
1338 }
1339
1340 sub handle_loglevel_request($) {
1341
1342     my $content = shift;
1343
1344     if ($content =~ m/crunch! /) {
1345
1346         # config.privoxy.org/send-stylesheet crunch! (CGI Call)
1347
1348         # Highlight crunch reasons
1349         foreach my $reason (keys %reason_colours) {
1350             $content =~ s@\(($reason)\)@$reason_colours{$reason}($1)$h{'Standard'}@g;
1351         }
1352         # Highlight request URL domain and ditch 'crunch!'
1353         $content = highlight_matched_pattern($content, 'request_', '[^ ]*(?= crunch!)');
1354         $content =~ s@ crunch!@@;
1355
1356     } elsif ($content =~ m/\[too long, truncated\]$/) {
1357
1358         # config.privoxy.org/edit-actions-submit?f=3&v=1176116716&s=7&Submit=Submit[...]&filter... [too long, truncated]
1359         $content = highlight_matched_pattern($content, 'request_', '^.*(?=\.\.\. \[too long, truncated\]$)');
1360
1361     } elsif ($content =~ m/(.*)/) { # XXX: Pretty stupid
1362
1363         # trac.vidalia-project.net/wiki/Volunteer?format=txt
1364         $content = h('request_') . $content . h('Standard');
1365
1366     } else {  # XXX: Nop
1367
1368         found_unknown_content($content);
1369
1370     }
1371
1372     return $content;
1373 }
1374
1375 sub handle_loglevel_crunch($) {
1376
1377     my $content = shift;
1378
1379     # Highlight crunch reason
1380     foreach my $reason (keys %reason_colours) {
1381         $content =~ s@($reason)@$reason_colours{$reason}$1$h{'Standard'}@g;
1382     }
1383
1384     if ($content =~ m/\[too long, truncated\]$/) {
1385
1386         # Blocked: config.privoxy.org/edit-actions-submit?f=3&v=1176116716&s=7&Submit=Submit\
1387         #  [...]&filter... [too long, truncated]
1388         $content = highlight_matched_pattern($content, 'request_', '^.*(?=\.\.\. \[too long, truncated\]$)');
1389
1390     } else {
1391
1392         # Blocked: http://ads.example.org/
1393         $content = highlight_matched_pattern($content, 'request_', '(?<=: ).*');
1394     }
1395
1396     return $content;
1397 }
1398
1399 sub handle_loglevel_connect($) {
1400
1401     my $c = shift;
1402
1403     if ($c =~ m/^via [^\s]+ to: [^\s]+/) {
1404
1405         # Connect: via 10.0.0.1:8123 to: www.example.org.noconnect
1406
1407         $c = highlight_matched_host($c, '(?<=via )[^\s]+');
1408         $c = highlight_matched_host($c, '(?<=to: )[^\s]+');
1409
1410     } elsif ($c =~ m/^connect to: .* failed: .*/) {
1411
1412         # connect to: www.example.org.noconnect failed: Operation not permitted
1413
1414         $c = highlight_matched_host($c, '(?<=connect to: )[^\s]+');
1415
1416         $c =~ s@(?<=failed: )(.*)@$h{'error'}$1$h{'Standard'}@;
1417
1418     } elsif ($c =~ m/^to ([^\s]*)( successful)?$/) {
1419
1420         # Connect: to www.nzherald.co.nz successful
1421         # Connect: to archiv.radiotux.de
1422
1423         return '' if SUPPRESS_SUCCESSFUL_CONNECTIONS;
1424         $c = highlight_matched_host($c, '(?<=to )[^\s]+');
1425
1426     } elsif ($c =~ m/^to ([^\s]*)$/) {
1427
1428         # Connect: to lists.sourceforge.net:443
1429
1430         $c = highlight_matched_host($c, '(?<=to )[^\s]+');
1431
1432     } elsif ($c =~ m/^[Aa]ccepted connection from .*/ or
1433              $c =~ m/^OK/) {
1434
1435         # Privoxy 3.0.20:
1436         # Accepted connection from 10.0.0.1 on socket 5
1437         # Privoxy between 3.0.20 and 3.0.6:
1438         # accepted connection from 10.0.0.1( on socket 5)?
1439         # Privoxy 3.0.6 and earlier just say:
1440         # OK
1441         $c = highlight_matched_host($c, '(?<=connection from )[^ ]*');
1442         $c = highlight_matched_pattern($c, 'Number', '(?<=socket )\d+');
1443
1444     } elsif ($c =~ m/^Closing client socket/) {
1445
1446         # Closing client socket 5. Keep-alive: 0, Socket alive: 1. Data available: 0.
1447         # Privoxy 3.0.20 and later
1448         # Closing client socket 8. Keep-alive: 1. Socket alive: 0. Data available: 0. \
1449         #  Configuration file change detected: 0. Requests received: 11.
1450
1451         $c = highlight_matched_pattern($c, 'Number', '(?<=socket )\d+');
1452         $c = highlight_matched_pattern($c, 'Number', '(?<=Keep-alive: )\d+');
1453         $c = highlight_matched_pattern($c, 'Number', '(?<=Socket alive: )\d+');
1454         $c = highlight_matched_pattern($c, 'Number', '(?<=available: )\d+');
1455         $c = highlight_matched_pattern($c, 'Number', '(?<=detected: )\d+');
1456         $c = highlight_matched_pattern($c, 'Number', '(?<=received: )\d+');
1457
1458     } elsif ($c =~ m/^write header to: .* failed:/) {
1459
1460         # write header to: 10.0.0.1 failed: Broken pipe
1461
1462         $c = highlight_matched_host($c, '(?<=write header to: )[^\s]*');
1463         $c =~ s@(?<=failed: )(.*)@$h{'Error'}$1$h{'Standard'}@;
1464
1465     } elsif ($c =~ m/^write header to client failed:/) {
1466
1467         # write header to client failed: Broken pipe
1468         # XXX: Stil in use?
1469         $c =~ s@(?<=failed: )(.*)@$h{'Error'}$1$h{'Standard'}@;
1470
1471     } elsif ($c =~ m/^socks4_connect:/) {
1472
1473         # socks4_connect: SOCKS request rejected or failed.
1474         $c =~ s@(?<=socks4_connect: )(.*)@$h{'Error'}$1$h{'Standard'}@;
1475
1476     } elsif ($c =~ m/^Listening for new connections/ or
1477              $c =~ m/^accept connection/) {
1478         # XXX: Highlight?
1479         # Privoxy versions above 3.0.6 say:
1480         # Listening for new connections ...
1481         # earlier versions say:
1482         # accept connection ...
1483         return '';
1484
1485     } elsif ($c =~ m/^accept failed:/) {
1486
1487         $c =~ s@(?<=accept failed: )(.*)@$h{'Error'}$1$h{'Standard'}@;
1488
1489     } elsif ($c =~ m/^Overriding forwarding settings/) {
1490
1491         # Overriding forwarding settings based on 'forward 10.0.0.1:8123'
1492         $c =~ s@(?<=based on \')(.*)(?=\')@$h{'configuration-line'}$1$h{'Standard'}@;
1493
1494     } elsif ($c =~ m/^Denying suspicious CONNECT request from/) {
1495
1496         # Denying suspicious CONNECT request from 10.0.0.1
1497         $c = highlight_matched_host($c, '(?<=from )[^\s]+'); # XXX: not an URL
1498
1499     } elsif ($c =~ m/^socks5_connect:/) {
1500
1501         $c =~ s@(?<=socks5_connect: )(.*)@$h{'error'}$1$h{'Standard'}@;
1502
1503     } elsif ($c =~ m/^Created new connection to/) {
1504
1505         # Created new connection to www.privoxy.org:80 on socket 11.
1506         $c = highlight_matched_host($c, '(?<=connection to )[^\s]+');
1507         $c =~ s@(?<=on socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1508
1509     } elsif ($c =~ m/^Found reusable socket/) {
1510
1511         # Found reusable socket 9 for www.privoxy.org:80 in slot 0.
1512         # 3.0.15 and later:
1513         # Found reusable socket 8 for www.privoxy.org:80 in slot 2.\
1514         #  Timestamp made 0 seconds ago. Timeout: 1. Latency: 0.
1515         $c =~ s@(?<=Found reusable socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1516         $c = highlight_matched_host($c, '(?<=for )[^\s]+');
1517         $c =~ s@(?<=in slot )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1518         $c =~ s@(?<=made )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1519         $c =~ s@(?<=Timeout: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1520         $c =~ s@(?<=Latency: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1521
1522     } elsif ($c =~ m/^Marking open socket/) {
1523
1524         # Marking open socket 9 for www.privoxy.org:80 in slot 0 as unused.
1525         $c =~ s@(?<=Marking open socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1526         $c = highlight_matched_host($c, '(?<=for )[^\s]+');
1527         $c =~ s@(?<=in slot )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1528
1529     } elsif ($c =~ m/^No reusable/) {
1530
1531         # No reusable socket for addons.mozilla.org:443 found. Opening a new one.
1532         $c = highlight_matched_host($c, '(?<=for )[^\s]+');
1533
1534     } elsif ($c =~ m/^(Remembering|Forgetting) socket/) {
1535
1536         # Remembering socket 13 for www.privoxy.org:80 in slot 0.
1537         # Forgetting socket 38 for www.privoxy.org:80 in slot 5.
1538
1539         $c =~ s@(?<=socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1540         $c = highlight_matched_host($c, '(?<=for )[^\s]+');
1541         $c =~ s@(?<=in slot )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1542
1543     } elsif ($c =~ m/^Socket/) {
1544
1545         # Socket 16 already forgotten or never remembered.
1546         $c =~ s@(?<=Socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1547
1548     } elsif ($c =~ m/^The connection to/) {
1549
1550         # The connection to www.privoxy.org:80 in slot 6 timed out. Closing socket 19. Timeout is: 61.
1551         # 3.0.15 and later:
1552         # The connection to 1.bp.blogspot.com:80 in slot 0 timed out. Closing socket 5.\
1553         #  Timeout is: 1. Assumed latency: 4.
1554         # The connection to 10.0.0.1:80 in slot 0 is no longer usable. Closing socket 4.
1555         $c = highlight_matched_host($c, '(?<=connection to )[^\s]+');
1556         $c =~ s@(?<=in slot )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1557         $c =~ s@(?<=Closing socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1558         $c =~ s@(?<=Timeout is: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1559         $c =~ s@(?<=Assumed latency: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1560
1561     } elsif ($c =~ m/^Stopped waiting for the request line/ or
1562              $c =~ m/^No request line on socket \d received in time/ or
1563              $c =~ m/^The client side of the connection on socket \d/) {
1564
1565         # Stopped waiting for the request line. Timeout: 121.
1566         # Privoxy 3.0.19 and later:
1567         # No request line on socket 5 received in time. Timeout: 1.
1568         # The client side of the connection on socket 5 got closed \
1569         #  without sending a complete request line.
1570         $c =~ s@(?<=Timeout: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1571         $c =~ s@(?<=socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1572
1573     } elsif ($c =~ m/^Waiting for \d/) {
1574
1575         # Waiting for 1 connections to timeout.
1576         $c =~ s@(?<=^Waiting for )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1577
1578     } elsif ($c =~ m/^Initialized/) {
1579
1580         # Initialized 20 socket slots.
1581         $c =~ s@(?<=Initialized )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1582
1583     } elsif ($c =~ m/^Done reading from server/) {
1584
1585         # Done reading from server. Expected content length: 24892. \
1586         #  Actual content length: 24892. Most recently received: 4412.
1587         # 3.0.15 and later:
1588         # Done reading from server. Expected content length: 24892. \
1589         #  Actual content length: 24892. Bytes most recently read: 4412.
1590         # Done reading from server. Content length: 6018 as expected. \
1591         #  Bytes most recently read: 294.
1592         $c =~ s@(?<=ontent length: )(\d+)@$h{'Number'}$1$h{'Standard'}@g;
1593         $c =~ s@(?<=received: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1594         $c =~ s@(?<=read: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1595
1596     } elsif ($c =~ m/^Continuing buffering (?:server )?headers/) {
1597
1598         # Continuing buffering headers. byte_count: 19. header_offset: 517. len: 536.
1599         $c =~ s@(?<=byte_count: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1600         $c =~ s@(?<=header_offset: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1601         $c =~ s@(?<=len: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1602         # 3.0.15 up to 3.0.19:
1603         # Continuing buffering headers. Bytes most recently read: 498.
1604         $c =~ s@(?<=read: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1605         # 3.0.20 and later:
1606         # Continuing buffering server headers from socket 5. Bytes most recently read: 498.
1607         $c =~ s@(?<=socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1608
1609     } elsif ($c =~ m/^Received \d+ bytes while/) {
1610
1611         # Received 206 bytes while expecting 12103.
1612         $c =~ s@(?<=Received )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1613         $c =~ s@(?<=expecting )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1614
1615     } elsif ($c =~ m/^(Rejecting c|C)onnection from/) {
1616
1617         # Connection from 81.163.28.218 dropped due to ACL
1618         # Rejecting connection from 178.63.152.227. Maximum number of connections reached.
1619         # Connection from 192.168.2.1 on 127.0.1.1:8118 (socket 3) dropped due to ACL
1620         $c = highlight_matched_host($c, '(?<=onnection from )[\d.:]+');
1621         $c = highlight_matched_host($c, '(?<=on )[\d.:]+');
1622         $c =~ s@(?<=socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1623
1624     } elsif ($c =~ m/^(?:Reusing|Closing) server socket / or
1625              $c =~ m/^No additional client request/) {
1626
1627         # Reusing server socket 4. Opened for 10.0.0.1.
1628         # Closing server socket 2. Opened for 10.0.0.1.
1629         # No additional client request received in time. \
1630         #  Closing server socket 4, initially opened for 10.0.0.1.
1631         # No additional client request received in time on socket 29.
1632         # Privoxy 3.0.20 and later
1633         # Reusing server socket 7 connected to www.privoxy.org. Total requests: 2.
1634         # Closing server socket 6 connected to d.asset.soup.io. Keep-alive: 0.\
1635         #  Tainted: 1. Socket alive: 1. Timeout: 60. Configuration file change detected: 0.
1636
1637         $c =~ s@(?<= socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1638         $c = highlight_matched_host($c, '(?<=for )[^\s]+(?=\.)');
1639         $c = highlight_matched_host($c, '(?<=connected to )[^\s]+(?=\.)');
1640         for my $number_pattern ('requests', 'Keep-alive', 'Tainted', ' alive', 'Timeout', 'detected') {
1641             $c = highlight_matched_pattern($c, 'Number', '(?<='. $number_pattern . ': )\d+');
1642         }
1643
1644     } elsif ($c =~ m/^Connected to /) {
1645
1646         # Connected to tor-jail[10.0.0.2]:9050.
1647
1648         $c = highlight_matched_host($c, '(?<=\[)[^\]]+');
1649         $c = highlight_matched_host($c, '(?<=Connected to )[^\[\s]+');
1650         $c =~ s@(?<=\]:)(\d+)@$h{'Number'}$1$h{'Standard'}@;
1651
1652     } elsif ($c =~ m/^Could not connect to /) {
1653
1654         # Could not connect to [10.0.0.1]:80.
1655
1656         $c = highlight_matched_host($c, '(?<=\[)[^\]]+');
1657         $c =~ s@(?<=\]:)(\d+)@$h{'Number'}$1$h{'Standard'}@;
1658
1659     } elsif ($c =~ m/^Waiting for the next client request/ or
1660              $c =~ m/^The connection on server socket/ or
1661              $c =~ m/^Client request (?:\d+ )?(?:arrived in time|has been pipelined) /) {
1662
1663         # Waiting for the next client request on socket 3. Keeping the server \
1664         #  socket 12 to a.fsdn.com open.
1665         # The connection on server socket 6 to upload.wikimedia.org isn't reusable. Closing.
1666         # Privoxy 3.0.20 and later:
1667         # Client request 4 arrived in time on socket 7.
1668         # Used by Privoxy 3.0.18 and 3.0.19:
1669         # Client request arrived in time on socket 21.
1670         # Used by earlier version:
1671         # Client request arrived in time or the client closed the connection on socket 12.
1672         # Client request 8 has been pipelined on socket 7 and the socket is still alive.
1673
1674         $c =~ s@(?<=request )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1675         $c =~ s@(?<=on socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1676         $c =~ s@(?<=server socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1677         $c = highlight_matched_host($c, '(?<=to )[^\s]+');
1678
1679     } elsif ($c =~ m/^Marking the server socket/) {
1680
1681         # Marking the server socket 7 tainted.
1682
1683         $c =~ s@(?<=server socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1684
1685     } elsif ($c =~ m/^Reduced expected bytes to /) {
1686
1687         # Reduced expected bytes to 0 to account for the 1542 ones we already got.
1688         $c =~ s@(?<=bytes to )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1689         $c =~ s@(?<=for the )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1690
1691     } elsif ($c =~ m/^The client closed socket /) {
1692
1693         # The client closed socket 2 while the server socket 4 is still open.
1694         $c =~ s@(?<=closed socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1695         $c =~ s@(?<=server socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1696
1697     } elsif ($c =~ m/^Expected client content length set /) {
1698
1699         # Expected client content length set to 667325411 after reading 4999 bytes.
1700         $c =~ s@(?<=set to )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1701         $c =~ s@(?<=reading )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1702
1703     } elsif ($c =~ m/^Reducing expected bytes to /) {
1704
1705         # Reducing expected bytes to 0. Marking the server socket tainted after throwing 4 bytes away.
1706         $c =~ s@(?<=bytes to )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1707         $c =~ s@(?<=after throwing )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1708
1709     } elsif ($c =~ m/^Waiting for up to /) {
1710
1711         # Waiting for up to 4999 bytes from the client.
1712         $c =~ s@(?<=up to )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1713
1714     } elsif ($c =~ m/^Optimistically sending /) {
1715
1716         # Optimistically sending 318 bytes of client headers intended for www.privoxy.org
1717         $c =~ s@(?<=sending )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1718         $c = highlight_matched_host($c, '(?<=for )[^\s]+');
1719
1720     } elsif ($c =~ m/^Stopping to watch the client socket/) {
1721
1722         # Stopping to watch the client socket. There's already another request waiting.
1723         # Privoxy 3.0.20 and later:
1724         # Stopping to watch the client socket 5. There's already another request waiting.
1725         $c =~ s@(?<=client socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1726
1727     } elsif ($c =~ m/^Drained \d+ bytes before closing/) {
1728
1729         # Drained 180 bytes before closing socket 6
1730         $c =~ s@(?<=Drained )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1731         $c =~ s@(?<=socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1732
1733     } elsif ($c =~ m/^Tainting client socket/ or
1734              $c =~ m/^Failed to shutdown socket/) {
1735
1736         # Tainting client socket 7 due to unread data.
1737         # Failed to shutdown socket 11: Connection reset by peer
1738
1739         $c =~ s@(?<=socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1740
1741     } elsif ($c =~ m/^Shifting \d+ pipelined bytes/) {
1742
1743         # Shifting 360 pipelined bytes by 360 bytes
1744         $c =~ s@(?<=Shifting )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1745         $c =~ s@(?<=by )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1746
1747     } elsif ($c =~ m/^Flushed (\d+) bytes of request body while expecting (\d+)/) {
1748
1749         # Flushed 30 bytes of request body while expecting 30
1750         $c =~ s@(?<=Flushed )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1751         $c =~ s@(?<=expecting )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1752
1753     } elsif ($c =~ m/^Performing the TLS\/SSL handshake with client. Hash of host:/) {
1754
1755         # Performing the TLS/SSL handshake with client. Hash of host: bab5296b25e256c7b06b92b17b56bcae
1756         $c = highlight_matched_host($c, '(?<=Hash of host: ).+');
1757
1758     } elsif ($c =~ m/^Forwarding \d+ bytes of encrypted POST data/) {
1759
1760         # Forwarding 1954 bytes of encrypted POST data
1761         $c =~ s@(?<=Forwarding )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1762
1763     } elsif ($c =~ m/^Forwarded the last \d+ bytes/) {
1764
1765         # Forwarded the last 1954 bytes
1766         $c =~ s@(?<=the last )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1767
1768     } elsif ($c =~ m/^Waiting for the next client connection. Currently active threads:/) {
1769
1770         # Waiting for the next client connection. Currently active threads: 30
1771         $c =~ s@(?<=threads: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1772
1773     } elsif ($c =~ m/^Data arrived in time on client socket/) {
1774
1775         # Data arrived in time on client socket 6. Requests so far: 3
1776         $c =~ s@(?<=client socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1777         $c =~ s@(?<=Requests so far: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1778
1779     } elsif ($c =~ m/^Looks like we / or
1780              $c =~ m/^Unsetting keep-alive flag/ or
1781              $c =~ m/^No connections to wait/ or
1782              $c =~ m/^Complete client request received/ or
1783              $c =~ m/^Possible pipeline attempt detected./ or
1784              $c =~ m/^POST request detected. The connection will not be kept alive./ or
1785              $c =~ m/^The server still wants to talk, but the client hung up on us./ or
1786              $c =~ m/^The server didn't specify how long the connection will stay open/ or
1787              $c =~ m/^There might be a request body. The connection will not be kept alive/ or
1788              $c =~ m/^There better be a request body./ or
1789              $c =~ m/^Done reading from the client\.$/) {
1790
1791         # Looks like we reached the end of the last chunk. We better stop reading.
1792         # Looks like we read the end of the last chunk together with the server \
1793         #  headers. We better stop reading.
1794         # Looks like we got the last chunk together with the server headers. \
1795         #  We better stop reading.
1796         # Unsetting keep-alive flag.
1797         # No connections to wait for left.
1798         # Client request arrived in time or the client closed the connection.
1799         # Complete client request received
1800         # Possible pipeline attempt detected. The connection will not be \
1801         #  kept alive and we will only serve the first request.
1802         # POST request detected. The connection will not be kept alive.
1803         # The server still wants to talk, but the client hung up on us.
1804         # The server didn't specify how long the connection will stay open. Assume it's only a second.
1805         # There might be a request body. The connection will not be kept alive.
1806         # Privoxy 3.0.20 and later
1807         # There better be a request body.
1808         # Done reading from the client.
1809
1810     } else {
1811
1812         found_unknown_content($c);
1813
1814     }
1815
1816     return $c;
1817 }
1818
1819
1820 sub handle_loglevel_info($) {
1821
1822     my $c = shift;
1823
1824     if ($c =~ m/^Rewrite detected:/) {
1825
1826         # Rewrite detected: GET http://10.0.0.2:88/blah.txt HTTP/1.1
1827         $c = highlight_matched_request_line($c, '(?<=^Rewrite detected: ).*');
1828
1829     } elsif ($c =~ m/^Decompress(ing deflated|ion didn)/ or
1830              $c =~ m/^Compressed content detected/ or
1831              $c =~ m/^SDCH-compressed content detected/ or
1832              $c =~ m/^Tagger/
1833             ) {
1834         # Decompressing deflated iob: 117
1835         # Decompression didn't result in any content.
1836         # Compressed content detected, content filtering disabled. Consider recompiling Privoxy\
1837         #  with zlib support or enable the prevent-compression action.
1838         # SDCH-compressed content detected, content filtering disabled.\
1839         #  Consider suppressing SDCH offers made by the client.
1840         # Tagger 'complete-url' created empty tag. Ignored.
1841
1842         # Ignored for now
1843
1844     } elsif ($c =~ m/^(Re)?loading configuration file /) {
1845
1846         # loading configuration file '/usr/local/etc/privoxy/config':
1847         # Reloading configuration file '/usr/local/etc/privoxy/config'
1848         $c =~ s@(?<=loading configuration file \')([^\']*)@$h{'file'}$1$h{'Standard'}@;
1849
1850     } elsif ($c =~ m/^Loading (actions|filter|trust) file: /) {
1851
1852         # Loading actions file: /usr/local/etc/privoxy/default.action
1853         # Loading filter file: /usr/local/etc/privoxy/default.filter
1854         # Loading trust file: /usr/local/etc/privoxy/trust
1855
1856         $c =~ s@(?<= file: )(.*)$@$h{'file'}$1$h{'Standard'}@;
1857
1858     } elsif ($c =~ m/^exiting by signal/) {
1859
1860         # exiting by signal 15 .. bye
1861         $c =~ s@(?<=exiting by signal )(\d+)@$h{'signal'}$1$h{'Standard'}@;
1862
1863     } elsif ($c =~ m/^Privoxy version/) {
1864
1865         # Privoxy version 3.0.7
1866         $c =~ s@(?<=^Privoxy version )(\d+\.\d+\.\d+)$@$h{'version'}$1$h{'Standard'}@;
1867
1868     } elsif ($c =~ m/^Program name: /) {
1869
1870         # Program name: /usr/local/sbin/privoxy
1871         $c =~ s@(?<=Program name: )(.*)@$h{'program-name'}$1$h{'Standard'}@;
1872
1873     } elsif ($c =~ m/^Listening on port /) {
1874
1875         # Listening on port 8118 on IP address 10.0.0.1
1876         $c =~ s@(?<=Listening on port )(\d+)@$h{'port'}$1$h{'Standard'}@;
1877         $c =~ s@(?<=on IP address )(.*)@$h{'ip-address'}$1$h{'Standard'}@;
1878
1879     } elsif ($c =~ m/^\(Re-\)Open(?:ing)? logfile/) {
1880
1881         # (Re-)Open logfile /var/log/privoxy/privoxy.log
1882         $c =~ s@(?<=Open logfile )(.*)@$h{'file'}$1$h{'Standard'}@;
1883
1884     } elsif ($c =~ m/^(Request from|Malformed server response detected)/) {
1885
1886         # Request from 10.0.0.1 denied. limit-connect{,} doesn't allow CONNECT requests to port 443.
1887         # Request from 10.0.0.1 marked for blocking. limit-connect{,} doesn't allow CONNECT requests to port 443.
1888         # 3.0.18 and later:
1889         # Request from 10.0.0.1 marked for blocking. limit-connect{0} doesn't allow CONNECT requests to www.example.org:443
1890         # Malformed server response detected. Downgrading to HTTP/1.0 impossible.
1891
1892         $c =~ s@(?<=Request from )([^\s]*)@$h{'ip-address'}$1$h{'Standard'}@;
1893         $c =~ s@(denied|blocking)@$h{'warning'}$1$h{'Standard'}@;
1894         $c =~ s@(CONNECT)@$h{'method'}$1$h{'Standard'}@;
1895         $c =~ s@(?<=to port )(\d+)@$h{'port'}$1$h{'Standard'}@;
1896         $c =~ s@(?<=to )([^\s]+)@$h{'request_'}$1$h{'Standard'}@;
1897
1898     } elsif ($c =~ m/^Status code/) {
1899
1900         # Status code 304 implies no body.
1901         $c =~ s@(?<=Status code )(\d+)@$h{'status-code'}$1$h{'Standard'}@;
1902
1903     } elsif ($c =~ m/^Method/) {
1904
1905         # Method HEAD implies no body.
1906         $c =~ s@(?<=Method )([^\s]+)@$h{'method'}$1$h{'Standard'}@;
1907
1908     } elsif ($c =~ m/^Buffer limit reached while extending /) {
1909
1910         # Buffer limit reached while extending the buffer (iob). Needed: 4197470. Limit: 4194304
1911         $c =~ s@(?<=Needed: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1912         $c =~ s@(?<=Limit: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1913
1914     } elsif ($c =~ m/^File modification detected: /) {
1915
1916         # File modification detected: /usr/local/etc/privoxy/user-agent.action
1917         $c =~ s@(?<= detected: )(.*)$@$h{'file'}$1$h{'Standard'}@;
1918
1919     } elsif ($c =~ m/^No logfile configured/ or
1920              $c =~ m/^Malformerd HTTP headers detected and MS IIS5 hack enabled/ or
1921              $c =~ m/^Invalid \"chunked\" transfer/ or
1922              $c =~ m/^Support for/ or
1923              $c =~ m/^Flushing header and buffers/ or
1924              $c =~ m/^Can not resolve/
1925              ) {
1926
1927         # No logfile configured. Please enable it before reporting any problems.
1928         # Malformerd HTTP headers detected and MS IIS5 hack enabled. Expect an invalid \
1929         #  response or even no response at all.
1930         # No logfile configured. Logging disabled.
1931         # Invalid "chunked" transfer encoding detected and ignored.
1932         # Support for 'Connection: keep-alive' is experimental, incomplete and\
1933         #  known not to work properly in some situations.
1934         # Flushing header and buffers. Stepping back from filtering.
1935         # Can not resolve doesnotexist: hostname nor servname provided, or not known
1936
1937     } else {
1938
1939         found_unknown_content($c);
1940
1941     }
1942
1943     return $c;
1944 }
1945
1946 sub handle_loglevel_cgi($) {
1947
1948     my $c = shift;
1949
1950     if ($c =~ m/^Granting access to/) {
1951
1952         #Granting access to http://config.privoxy.org/send-stylesheet, referrer http://p.p/ is trustworthy.
1953
1954     } elsif ($c =~ m/^Substituting: s(.)/) {
1955
1956         # Substituting: s/@else-not-FEATURE_ZLIB@.*@endif-FEATURE_ZLIB@//sigTU
1957         # XXX: prone to span several lines
1958
1959         my $delimiter = $1;
1960         #$c =~ s@(?<=failed: )(.*)@$h{'error'}$1$h{'Standard'}@;
1961         $c =~ s@(?!<=\\)($delimiter)@$h{'pcrs-delimiter'}$1$h{'Standard'}@g; # XXX: Too aggressive
1962         #$c =~ s@(?!<=\\)($1)@$h{'pcrs-delimiter'}$1$h{'Standard'}@g;
1963     }
1964
1965     return $c;
1966 }
1967
1968 sub handle_loglevel_force($) {
1969
1970     my $c = shift;
1971
1972     if ($c =~ m/^Ignored force prefix in request:/) {
1973
1974         # Ignored force prefix in request: "GET http://10.0.0.1/PRIVOXY-FORCE/block HTTP/1.1"
1975         $c =~ s@^(Ignored)@$h{'ignored'}$1$h{'Standard'}@;
1976         $c = highlight_matched_request_line($c, '(?<=request: ")[^"]*');
1977
1978     } elsif ($c =~ m/^Enforcing request:/) {
1979
1980         # Enforcing request: "GET http://10.0.0.1/block HTTP/1.1".
1981         $c = highlight_matched_request_line($c, '(?<=request: ")[^"]*');
1982
1983     } else {
1984
1985         found_unknown_content($c);
1986
1987     }
1988
1989     return $c;
1990 }
1991
1992 sub handle_loglevel_error($) {
1993
1994     my $c = shift;
1995
1996     if ($c =~ m/^(?:Empty|No) server or forwarder response received on socket \d+\./) {
1997
1998         # Empty server or forwarder response received on socket 4.
1999         # Empty server or forwarder response received on socket 3. \
2000         #  Closing client socket 15 without sending data.
2001         # Used by Privoxy 3.0.18 and later:
2002         # No server or forwarder response received on socket 8. \
2003         #  Closing client socket 10 without sending data.
2004
2005         $c =~ s@(?<=on socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
2006         $c =~ s@(?<=client socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
2007
2008     } elsif ($c =~ m/^Didn't receive data in time:/) {
2009
2010         # Didn't receive data in time: a.fsdn.com:443
2011         $c =~ s@(?<=in time: )(.*)@$h{'destination'}$1$h{'Standard'}@;
2012     }
2013
2014     # XXX: There are probably more messages that deserve highlighting.
2015
2016     return $c;
2017 }
2018
2019
2020 sub handle_loglevel_ignore($) {
2021     return shift;
2022 }
2023
2024 sub gather_loglevel_clf_stats($) {
2025
2026     my $content = shift;
2027     my ($method, $resource, $http_version, $status_code, $size);
2028     our %stats;
2029     our %cli_options;
2030
2031     # +0200] "GET https://www.youtube.com/watch?v=JmcA9LIIXWw HTTP/1.1" 200 68004
2032     # +0200] "VERSION-CONTROL http://p.p/ HTTP/1.1" 200 2787
2033     $content =~ m/^[+-]\d{4}\] "([^ ]+) (.+) (HTTP\/\d\.\d)" (\d+) (\d+)/;
2034     $method       = $1;
2035     $resource     = $2;
2036     $http_version = $3;
2037     $status_code  = $4;
2038     $size         = $5;
2039
2040     $stats{requests_clf}++;
2041
2042     unless (defined $method) {
2043         # +0200] "Invalid request" 400 0
2044         return if ($content =~ m/^[+-]\d{4}\] "Invalid request"/);
2045         print("Failed to parse: $content\n");
2046         return;
2047     }
2048     $stats{'method'}{$method}++;
2049     if ($cli_options{'url-statistics-threshold'} != 0) {
2050         $stats{'resource'}{$resource}++;
2051     }
2052     $stats{'http-version'}{$http_version}++;
2053
2054     if ($cli_options{'host-statistics-threshold'} != 0) {
2055         $resource =~ m@(?:https?://)?([^/]+)/?@;
2056         $stats{'hosts'}{$1}++;
2057     }
2058     $stats{'content-size-total'} += $size;
2059     $stats{'status-code'}{$status_code}++;
2060 }
2061
2062 sub gather_loglevel_request_stats($$) {
2063     my $c = shift;
2064     my $thread = shift;
2065     our %stats;
2066
2067     $stats{requests}++;
2068 }
2069
2070 sub gather_loglevel_crunch_stats($$) {
2071     my $c = shift;
2072     my $thread = shift;
2073     our %stats;
2074
2075     $stats{crunches}++;
2076
2077     if ($c =~ m/^Redirected:/) {
2078         # Redirected: http://www.example.org/http://p.p/
2079         $stats{'fast-redirections'}++;
2080
2081     } elsif ($c =~ m/^Blocked:/) {
2082         # Blocked: blogger.googleusercontent.com:443
2083         $stats{'blocked'}++;
2084
2085     } elsif ($c =~ m/^Connection timeout:/) {
2086         # Connection timeout: http://c.tile.openstreetmap.org/18/136116/87842.png
2087         $stats{'connection-timeout'}++;
2088
2089     } elsif ($c =~ m/^Connection failure:/) {
2090         # Connection failure: http://127.0.0.1:8080/
2091         $stats{'connection-failure'}++;
2092     }
2093 }
2094
2095
2096 sub gather_loglevel_error_stats($$) {
2097
2098     my $c = shift;
2099     my $thread = shift;
2100     our %stats;
2101     our %thread_data;
2102
2103     if ($c =~ m/^Empty server or forwarder response received on socket \d+./) {
2104
2105         # Empty server or forwarder response received on socket 4.
2106         $stats{'empty-responses'}++;
2107         if ($thread_data{$thread}{'new_connection'}) {
2108             $stats{'empty-responses-on-new-connections'}++;
2109         } else {
2110             $stats{'empty-responses-on-reused-connections'}++;
2111         }
2112     }
2113 }
2114
2115 sub gather_loglevel_connect_stats($$) {
2116
2117     my ($c, $thread) = @_;
2118     our %thread_data;
2119     our %stats;
2120
2121     if ($c =~ m/^via ([^\s]+) to: [^\s]+/) {
2122
2123         # Connect: via 10.0.0.1:8123 to: www.example.org.noconnect
2124         $thread_data{$thread}{'forwarder'} = $1; # XXX: is this missue?
2125
2126     } elsif ($c =~ m/^to ([^\s]*)$/) {
2127
2128         # Connect: to lists.sourceforge.net:443
2129
2130         $thread_data{$thread}{'forwarder'} = 'direct connection';
2131
2132     } elsif ($c =~ m/^Created new connection to/) {
2133
2134         # Created new connection to www.privoxy.org:80 on socket 11.
2135
2136         $thread_data{$thread}{'new_connection'} = 1;
2137
2138     } elsif ($c =~ m/^Reusing server socket \d./ or
2139              $c =~ m/^Found reusable socket/) {
2140
2141         # Reusing server socket 4. Opened for 10.0.0.1.
2142         # Found reusable socket 9 for www.privoxy.org:80 in slot 0.
2143
2144         $thread_data{$thread}{'new_connection'} = 0;
2145         $stats{'reused-connections'}++;
2146
2147     } elsif ($c =~ m/^Closing client socket \d+. .* Requests received: (\d+)\.$/) {
2148
2149         # Closing client socket 12. Keep-alive: 1. Socket alive: 1. Data available: 0. \
2150         #  Configuration file change detected: 0. Requests received: 14.
2151
2152         $stats{'client-requests-on-connection'}{$1}++;
2153         $stats{'closed-client-connections'}++;
2154     }
2155 }
2156
2157 sub gather_loglevel_header_stats($$) {
2158
2159     my ($c, $thread) = @_;
2160     our %stats;
2161     our %cli_options;
2162
2163     if ($c =~ m/^A HTTP\/1\.1 response without/ or
2164         $c =~ m/^Keeping the server header 'Connection: keep-alive' around./)
2165     {
2166         # A HTTP/1.1 response without Connection header implies keep-alive.
2167         # Keeping the server header 'Connection: keep-alive' around.
2168         $stats{'server-keep-alive'}++;
2169     }
2170 }
2171
2172 sub init_stats() {
2173     our %stats = (
2174         requests => 0,
2175         requests_clf => 0,
2176         crunches => 0,
2177         'server-keep-alive' => 0,
2178         'reused-connections' => 0,
2179         'empty-responses' => 0,
2180         'empty-responses-on-new-connections' => 0,
2181         'empty-responses-on-reused-connections' => 0,
2182         'fast-redirections' => 0,
2183         'blocked' => 0,
2184         'connection-failure' => 0,
2185         'connection-timeout' => 0,
2186         'reused-connections' => 0,
2187         'server-keep-alive' => 0,
2188         'closed-client-connections' => 0,
2189         'content-size-total' => 0,
2190         );
2191         $stats{'client-requests-on-connection'}{1} = 0;
2192 }
2193
2194 sub get_percentage($$) {
2195     my $big = shift;
2196     my $small = shift;
2197
2198     # If small is 0 the percentage is always 0%.
2199     # Make sure it works even if big is 0 as well.
2200     return "0.00%" if ($small eq 0);
2201
2202     # Prevent division by zero.
2203     # XXX: Is this still supposed to be reachable?
2204     return "NaN" if ($big eq 0);
2205
2206     return sprintf("%.2f%%", $small / $big * 100);
2207 }
2208
2209 sub print_stats() {
2210
2211     our %stats;
2212     our %cli_options;
2213     my $new_connections = $stats{requests} - $stats{crunches} - $stats{'reused-connections'};
2214     my $client_requests_checksum = 0;
2215     my $requests_total;
2216
2217     if ($stats{requests_clf} && $stats{requests}
2218         && $stats{requests_clf} != $stats{requests}) {
2219         print "Inconsistent request counts: " . $stats{requests} . "/" . $stats{requests_clf} . "\n";
2220     }
2221
2222     # To get the total number of requests we can use either the number
2223     # of Common-Log-Format lines or the number of "Request:" messages.
2224     # We prefer the number of CLF lines if available because using
2225     # it works when analysing old log files from Privoxy versions before 3.0.29.
2226     # In Privoxy 3.0.28 and earlier "Request:" messages excluded
2227     # crunched messages.
2228     $requests_total = $stats{requests_clf} ? $stats{requests_clf} : $stats{requests};
2229
2230     if ($requests_total eq 0) {
2231         print "No requests yet.\n";
2232         return;
2233     }
2234
2235     print "Client requests total: " . $requests_total . "\n";
2236     if ($stats{crunches}) {
2237         my $outgoing_requests = $requests_total - $stats{crunches};
2238         print "Crunches: " . $stats{crunches} . " (" .
2239             get_percentage($requests_total, $stats{crunches}) . ")\n";
2240         print "Blocks: " . $stats{'blocked'} . " (" .
2241             get_percentage($requests_total, $stats{'blocked'}) . ")\n";
2242         print "Fast redirections: " . $stats{'fast-redirections'} . " (" .
2243             get_percentage($requests_total, $stats{'fast-redirections'}) . ")\n";
2244         print "Connection timeouts: " . $stats{'connection-timeout'} . " (" .
2245             get_percentage($requests_total, $stats{'connection-timeout'}) . ")\n";
2246         print "Connection failures: " . $stats{'connection-failure'} . " (" .
2247             get_percentage($requests_total, $stats{'connection-failure'}) . ")\n";
2248         print "Outgoing requests: " . $outgoing_requests . " (" .
2249             get_percentage($requests_total, $outgoing_requests) . ")\n";
2250     } else {
2251         print "No crunches detected. Is 'debug 1024' enabled?\n";
2252     }
2253
2254     print "Server keep-alive offers: " . $stats{'server-keep-alive'} . " (" .
2255         get_percentage($requests_total, $stats{'server-keep-alive'}) . ")\n";
2256     print "New outgoing connections: " . $new_connections . " (" .
2257         get_percentage($requests_total, $new_connections) . ")\n";
2258     print "Reused connections: " . $stats{'reused-connections'} . " (" .
2259         get_percentage($requests_total, $stats{'reused-connections'}) .
2260         "; server offers accepted: " .
2261         get_percentage($stats{'server-keep-alive'}, $stats{'reused-connections'}) . ")\n";
2262     print "Empty responses: " . $stats{'empty-responses'} . " (" .
2263         get_percentage($requests_total, $stats{'empty-responses'}) . ")\n";
2264     print "Empty responses on new connections: "
2265          . $stats{'empty-responses-on-new-connections'} . " (" .
2266         get_percentage($requests_total, $stats{'empty-responses-on-new-connections'})
2267         . ")\n";
2268     print "Empty responses on reused connections: " .
2269         $stats{'empty-responses-on-reused-connections'} . " (" .
2270         get_percentage($requests_total, $stats{'empty-responses-on-reused-connections'}) .
2271         ")\n";
2272     print "Client connections: " .  $stats{'closed-client-connections'} . "\n";
2273     if ($stats{'content-size-total'}) {
2274         print "Bytes of content transfered to the client: " .  $stats{'content-size-total'} . "\n";
2275     }
2276     my $lines_printed = 0;
2277     print "Client requests per connection distribution:\n";
2278     foreach my $client_requests (sort {
2279         $stats{'client-requests-on-connection'}{$b} <=> $stats{'client-requests-on-connection'}{$a}}
2280                                   keys %{$stats{'client-requests-on-connection'}
2281                                   })
2282     {
2283         my $count = $stats{'client-requests-on-connection'}{$client_requests};
2284         $client_requests_checksum += $count * $client_requests;
2285         if ($cli_options{'show-complete-request-distribution'} or ($lines_printed < 10)) {
2286             printf "%8d: %d\n", $count, $client_requests;
2287             $lines_printed++;
2288         }
2289     }
2290     unless ($cli_options{'show-complete-request-distribution'}) {
2291         printf "Enable --show-complete-request-distribution to get less common numbers as well.\n";
2292     }
2293     # Due to log rotation we may not have a complete picture for all the requests
2294     printf "Improperly accounted requests: ~%d\n", abs($requests_total - $client_requests_checksum);
2295
2296     if (exists $stats{method}) {
2297         print "Method distribution:\n";
2298         foreach my $method (sort {$stats{'method'}{$b} <=> $stats{'method'}{$a}} keys %{$stats{'method'}}) {
2299             printf "%8d : %-8s\n", $stats{'method'}{$method}, $method;
2300         }
2301     } else {
2302         print "Method distribution unknown. No CLF message parsed yet. Is 'debug 512' enabled?\n";
2303     }
2304     if (exists $stats{'http-version'}) {
2305         print "Client HTTP versions:\n";
2306         foreach my $http_version (sort {$stats{'http-version'}{$b} <=> $stats{'http-version'}{$a}} keys %{$stats{'http-version'}}) {
2307             printf "%8d : %-8s\n",  $stats{'http-version'}{$http_version}, $http_version;
2308         }
2309     } else {
2310         print "HTTP version distribution unknown. No CLF message parsed yet. Is 'debug 512' enabled?\n";
2311     }
2312     if (exists $stats{'status-code'}) {
2313         print "HTTP status codes:\n";
2314         foreach my $status_code (sort {$stats{'status-code'}{$b} <=> $stats{'status-code'}{$a}} keys %{$stats{'status-code'}}) {
2315             printf "%8d : %-8d\n",  $stats{'status-code'}{$status_code}, $status_code;
2316         }
2317     } else {
2318         print "Status code distribution unknown. No CLF message parsed yet. Is 'debug 512' enabled?\n";
2319     }
2320
2321     if ($cli_options{'url-statistics-threshold'} == 0) {
2322         print "URL statistics are disabled. Increase --url-statistics-threshold to enable them.\n";
2323     } else {
2324         print "Requested URLs:\n";
2325         foreach my $resource (sort {$stats{'resource'}{$b} <=> $stats{'resource'}{$a}} keys %{$stats{'resource'}}) {
2326             if ($stats{'resource'}{$resource} < $cli_options{'url-statistics-threshold'}) {
2327                 print "Skipped statistics for URLs below the treshold.\n";
2328                 last;
2329             }
2330             printf "%d : %s\n", $stats{'resource'}{$resource}, $resource;
2331         }
2332     }
2333
2334     if ($cli_options{'host-statistics-threshold'} == 0) {
2335         print "Host statistics are disabled. Increase --host-statistics-threshold to enable them.\n";
2336     } else {
2337         print "Requested Hosts:\n";
2338         foreach my $host (sort {$stats{'hosts'}{$b} <=> $stats{'hosts'}{$a}} keys %{$stats{'hosts'}}) {
2339             if ($stats{'hosts'}{$host} < $cli_options{'host-statistics-threshold'}) {
2340                 print "Skipped statistics for Hosts below the treshold.\n";
2341                 last;
2342             }
2343             printf "%d : %s\n", $stats{'hosts'}{$host}, $host;
2344         }
2345     }
2346 }
2347
2348
2349 ################################################################################
2350 # Functions that actually print stuff
2351 ################################################################################
2352
2353 sub print_clf_message() {
2354
2355     our ($ip, $timestamp, $request_line, $status_code, $size);
2356     my $output = '';
2357
2358     return if DEBUG_SUPPRESS_LOG_MESSAGES;
2359
2360     # Rebuild highlighted
2361     $output .= $h{'Number'} . $ip . $h{'Standard'};
2362     $output .= " - - ";
2363     $output .= "[" . $h{'Timestamp'} . $timestamp . $h{'Standard'} . "]";
2364     $output .= " ";
2365     $output .= "\"" . highlight_request_line("$request_line") . "\"";
2366     $output .= " ";
2367     $output .= $h{'Status'} . $status_code . $h{'Standard'};
2368     $output .= " ";
2369     $output .= $h{'Number'} . $size . $h{'Standard'};
2370     $output .= $line_end;
2371
2372     print $output;
2373 }
2374
2375 sub print_non_clf_message($) {
2376
2377     my $content = shift;
2378     my $msec_string = $no_msecs_mode ? '' : '.' . $req{$t}{'msecs'};
2379     my $line_start = $html_output_mode ? '' : $h{"Standard"};
2380
2381     return if DEBUG_SUPPRESS_LOG_MESSAGES;
2382
2383     print $line_start
2384         . $time_colours[$time_colour_index % 2]
2385         . $req{$t}{'time-stamp'}
2386         . $msec_string
2387         . $h{Standard} . " "
2388         . $thread_colours{$t}
2389         . $t
2390         . $h{Standard}
2391         . " "
2392         . $h{$req{$t}{'log-level'}}
2393         . $req{$t}{'log-level'}
2394         . $h{Standard}
2395         . ": "
2396         . $content
2397         . $line_end;
2398 }
2399
2400 sub shorten_thread_id($) {
2401
2402     my $thread_id = shift;
2403
2404     our %short_thread_ids;
2405     our $max_threadid;
2406
2407     unless (defined $short_thread_ids{$thread_id}) {
2408         $short_thread_ids{$thread_id} = sprintf "%.3d", $max_threadid++;
2409     }
2410
2411     return $short_thread_ids{$thread_id}
2412 }
2413
2414 sub parse_loop() {
2415
2416     my ($day, $time_stamp, $thread, $log_level, $content, $c, $msecs);
2417     my $last_msecs  = 0;
2418     my $last_thread = 0;
2419     my $last_timestamp = 0;
2420     my $filters_that_did_nothing;
2421     my $key;
2422     my $time_colour;
2423     $time_colour = paint_it('white');
2424
2425     my %log_level_handlers = (
2426         'Re-Filter'         => \&handle_loglevel_re_filter,
2427         'Header'            => \&handle_loglevel_header,
2428         'Connect'           => \&handle_loglevel_connect,
2429         'Redirect'          => \&handle_loglevel_redirect,
2430         'Request'           => \&handle_loglevel_request,
2431         'Crunch'            => \&handle_loglevel_crunch,
2432         'Gif-Deanimate'     => \&handle_loglevel_gif_deanimate,
2433         'Info'              => \&handle_loglevel_info,
2434         'CGI'               => \&handle_loglevel_cgi,
2435         'Force'             => \&handle_loglevel_force,
2436         'Error'             => \&handle_loglevel_error,
2437         'Fatal error'       => \&handle_loglevel_ignore,
2438         'Writing'           => \&handle_loglevel_ignore,
2439         'Received'          => \&handle_loglevel_ignore,
2440         'Actions'           => \&handle_loglevel_ignore,
2441         'Unknown log level' => \&handle_loglevel_ignore,
2442     );
2443
2444     while (<>) {
2445
2446         if (m/^(\d{4}-\d{2}-\d{2}|\w{3} \d{2}) (\d\d:\d\d:\d\d)\.?(\d+)? (?:Privoxy\()?([^\)\s]*)[\)]? ([\w -]*): (.*?)\r?$/) {
2447             $thread = $t = ($shorten_thread_ids) ? shorten_thread_id($4) : $4;
2448             $req{$t}{'day'} = $day = $1;
2449             $req{$t}{'time-stamp'} = $time_stamp = $2;
2450             $req{$t}{'msecs'} = $msecs = $3 ? $3 : 0; # Only the cool kids have micro second resolution;
2451             $req{$t}{'log-level'} = $log_level = $5;
2452             $req{$t}{'content'} = $content = $c = $6;
2453             $req{$t}{'log-message'} = $_;
2454             $no_special_header_highlighting = 0;
2455
2456             if (defined($log_level_handlers{$log_level})) {
2457
2458                 $content = $log_level_handlers{$log_level}($content);
2459
2460             } else {
2461
2462                 die "No handler found for log level \"$log_level\"\n";
2463             }
2464
2465             # Highlight Truncations
2466             if (length($_) > 4000) {
2467                 $content =~ s@(too long, truncated)]$@$h{'Truncation'}$1$h{'Standard'}]@g;
2468             }
2469
2470             next unless $content;
2471
2472             # Register threads to keep the colour constant
2473             if (!defined($thread_colours{$thread})) {
2474                 $thread_colours{$thread} = $all_colours[$thread_colour_index % @all_colours];
2475                 $thread_colour_index++;
2476             }
2477
2478             # Switch timestamp colour if timestamps differ
2479             if (($msecs ne $last_msecs) || ($time_stamp ne $last_timestamp)) {
2480                debug_message("Tick tack!") if DEBUG_TICKS;
2481                $time_colour = $time_colours[$time_colour_index % 2];
2482                $time_colour_index++;
2483                $last_msecs = $msecs;
2484                $last_timestamp = $time_stamp;
2485             }
2486
2487             $last_thread = $thread;
2488
2489             print_non_clf_message($content);
2490
2491         } elsif (m/^((?:\d+\.\d+\.\d+\.\d+|[:\d]+)) - - \[(.*)\] "(.*)" (\d+) (\d+)/) {
2492
2493             # LOG_LEVEL_CLF lines look like this
2494             # 61.152.239.32 - - [04/Mar/2007:18:28:23 +0100] "GET \
2495             #  http://ad.yieldmanager.com/imp?z=1&Z=120x600&s=109339&u=http%3A%2F%2Fwww.365loan.co.uk%2F&r=1\
2496             #  HTTP/1.1" 403 1730
2497             our ($ip, $timestamp, $request_line, $status_code, $size) = ($1, $2, $3, $4, $5);
2498
2499             print_clf_message();
2500
2501         } else {
2502
2503             # Some Privoxy log messages span more than one line,
2504             # usually to dump lots of content that doesn't need any syntax highlighting.
2505             # XXX: add mechanism to forward these lines to the right handler anyway.
2506             chomp();
2507             unless (DEBUG_SUPPRESS_LOG_MESSAGES or (SUPPRESS_EMPTY_LINES and m/^\s+$/)) {
2508                 print and print get_line_end(); # unless (SUPPRESS_EMPTY_LINES and m/^\s+$/);
2509             }
2510         }
2511     }
2512 }
2513
2514 sub stats_loop() {
2515
2516     my ($day, $time_stamp, $msecs, $thread, $log_level, $content);
2517     my $strict_checks = cli_option_is_set('strict-checks');
2518     my %log_level_handlers = (
2519          'Connect:'           => \&gather_loglevel_connect_stats,
2520          'Crunch:'            => \&gather_loglevel_crunch_stats,
2521          'Error:'             => \&gather_loglevel_error_stats,
2522          'Header:'            => \&gather_loglevel_header_stats,
2523          'Request:'           => \&gather_loglevel_request_stats,
2524     );
2525     my %ignored_log_levels = (
2526          'Actions:'           => \&handle_loglevel_ignore,
2527          'CGI:'               => \&handle_loglevel_ignore,
2528          'Fatal error:'       => \&handle_loglevel_ignore,
2529          'Force:'             => \&handle_loglevel_ignore,
2530          'Gif-Deanimate:'     => \&handle_loglevel_ignore,
2531          'Info:'              => \&handle_loglevel_ignore,
2532          'Re-Filter:'         => \&handle_loglevel_ignore,
2533          'Received:'          => \&handle_loglevel_ignore,
2534          'Redirect:'          => \&handle_loglevel_ignore,
2535          'Unknown log level:' => \&handle_loglevel_ignore,
2536          'Writing:'           => \&handle_loglevel_ignore,
2537     );
2538
2539     while (<>) {
2540         (undef, $time_stamp, $thread, $log_level, $content) = split(/ /, $_, 5);
2541
2542
2543         next if (not defined($log_level));
2544
2545         if ($time_stamp eq "-") {
2546
2547             gather_loglevel_clf_stats($content);
2548
2549         } elsif (defined($log_level_handlers{$log_level})) {
2550
2551             $content = $log_level_handlers{$log_level}($content, $thread);
2552
2553         } elsif ($strict_checks and not defined($ignored_log_levels{$log_level})) {
2554
2555             die "No handler found for: $_";
2556         }
2557     }
2558
2559     print_stats();
2560
2561 }
2562
2563 sub unbreak_lines_only_loop() {
2564     my $log_messages_reached = 0;
2565     while (<>) {
2566         chomp;
2567
2568             # Log level other than LOG_LEVEL_CLF?
2569         if (m/^(\d{4}-\d{2}-\d{2}|\w{3} \d{2}) (\d\d:\d\d:\d\d)\.?(\d+)? (?:Privoxy\()?([^\)\s]*)[\)]? ([\w -]*): (.*?)\r?$/ or
2570             # LOG_LEVEL_CLF?
2571             m/^((?:\d+\.\d+\.\d+\.\d+)) - - \[(.*)\] "(.*)" (\d+) (\d+)/) {
2572             $log_messages_reached = 1;
2573             print "\n";
2574
2575         } else {
2576             # Wrapped message
2577             $_ = "\n". $_  if /^(?:\d+\.\d+\.\d+\.\d+)/;
2578             $_ = " " . $_;
2579         }
2580         s@<BR>$@@;
2581         print;
2582         print "\n" unless $log_messages_reached;
2583     }
2584     print "\n";
2585 }
2586
2587 sub VersionMessage {
2588     my $version_message;
2589
2590     $version_message .= 'Privoxy-Log-Parser ' . PRIVOXY_LOG_PARSER_VERSION  . "\n";
2591     $version_message .= 'https://www.fabiankeil.de/sourcecode/privoxy-log-parser/' . "\n";
2592
2593     print $version_message;
2594 }
2595
2596 sub get_cli_options() {
2597
2598     our %cli_options = (
2599         'html-output'              => CLI_OPTION_DEFAULT_TO_HTML_OUTPUT,
2600         'title'                    => CLI_OPTION_TITLE,
2601         'no-syntax-highlighting'   => CLI_OPTION_NO_SYNTAX_HIGHLIGHTING,
2602         'no-embedded-css'          => CLI_OPTION_NO_EMBEDDED_CSS,
2603         'no-msecs'                 => CLI_OPTION_NO_MSECS,
2604         'shorten-thread-ids'       => CLI_OPTION_SHORTEN_THREAD_IDS,
2605         'show-ineffective-filters' => CLI_OPTION_SHOW_INEFFECTIVE_FILTERS,
2606         'statistics'               => CLI_OPTION_STATISTICS,
2607         'strict-checks'            => CLI_OPTION_STRICT_CHECKS,
2608         'url-statistics-threshold' => CLI_OPTION_URL_STATISTICS_THRESHOLD,
2609         'unbreak-lines-only'       => CLI_OPTION_UNBREAK_LINES_ONLY,
2610         'host-statistics-threshold'=> CLI_OPTION_HOST_STATISTICS_THRESHOLD,
2611         'show-complete-request-distribution' => CLI_OPTION_SHOW_COMPLETE_REQUEST_DISTRIBUTION,
2612     );
2613
2614     GetOptions (
2615         'html-output'              => \$cli_options{'html-output'},
2616         'title'                    => \$cli_options{'title'},
2617         'no-syntax-highlighting'   => \$cli_options{'no-syntax-highlighting'},
2618         'no-embedded-css'          => \$cli_options{'no-embedded-css'},
2619         'no-msecs'                 => \$cli_options{'no-msecs'},
2620         'shorten-thread-ids'       => \$cli_options{'shorten-thread-ids'},
2621         'show-ineffective-filters' => \$cli_options{'show-ineffective-filters'},
2622         'statistics'               => \$cli_options{'statistics'},
2623         'strict-checks'            => \$cli_options{'strict-checks'},
2624         'unbreak-lines-only'       => \$cli_options{'unbreak-lines-only'},
2625         'url-statistics-threshold=i'=> \$cli_options{'url-statistics-threshold'},
2626         'host-statistics-threshold=i'=> \$cli_options{'host-statistics-threshold'},
2627         'show-complete-request-distribution' => \$cli_options{'show-complete-request-distribution'},
2628         'version'                  => sub { VersionMessage && exit(0) },
2629         'help'                     => \&help,
2630    ) or exit(1);
2631
2632    $html_output_mode = cli_option_is_set('html-output');
2633    $no_msecs_mode = cli_option_is_set('no-msecs');
2634    $shorten_thread_ids = cli_option_is_set('shorten-thread-ids');
2635    $line_end = get_line_end();
2636 }
2637
2638 sub help() {
2639
2640     our %cli_options;
2641
2642     VersionMessage();
2643
2644     print << "    EOF"
2645
2646 Options and their default values if they have any:
2647     [--host-statistics-threshold $cli_options{'host-statistics-threshold'}]
2648     [--html-output]
2649     [--no-embedded-css]
2650     [--no-msecs]
2651     [--no-syntax-highlighting]
2652     [--shorten-thread-ids]
2653     [--show-ineffective-filters]
2654     [--show-complete-request-distribution]
2655     [--statistics]
2656     [--unbreak-lines-only]
2657     [--url-statistics-threshold $cli_options{'url-statistics-threshold'}]
2658     [--title $cli_options{'title'}]
2659     [--version]
2660 see "perldoc $0" for more information
2661     EOF
2662     ;
2663     exit(0);
2664 }
2665
2666 ################################################################################
2667 # main
2668 ################################################################################
2669 sub main() {
2670
2671     get_cli_options();
2672     set_background(DEFAULT_BACKGROUND);
2673     prepare_our_stuff();
2674
2675     print_intro();
2676
2677     # XXX: should explicitly reject incompatible argument combinations
2678     if (cli_option_is_set('unbreak-lines-only')) {
2679         unbreak_lines_only_loop();
2680     } elsif (cli_option_is_set('statistics')) {
2681         stats_loop();
2682     } else {
2683         parse_loop();
2684     }
2685
2686     print_outro();
2687 }
2688
2689 main();
2690
2691 =head1 NAME
2692
2693 B<privoxy-log-parser> - A parser and syntax-highlighter for Privoxy log messages
2694
2695 =head1 SYNOPSIS
2696
2697 B<privoxy-log-parser> [B<--html-output>]
2698 [B<--no-msecs>] [B<--no-syntax-higlighting>] [B<--statistics>]
2699 [B<--shorten-thread-ids>] [B<--show-ineffective-filters>]
2700 [B<--url-statistics-threshold>] [B<--version>]
2701
2702 =head1 DESCRIPTION
2703
2704 B<privoxy-log-parser> reads Privoxy log messages and
2705
2706 - syntax-highlights recognized lines,
2707
2708 - reformats some of them for easier comprehension,
2709
2710 - filters out less useful messages, and
2711
2712 - (in some cases) calculates additional information,
2713   like the compression ratio or how a filter affected
2714   the content size.
2715
2716 With B<privoxy-log-parser> you should be able to increase Privoxy's log level
2717 without getting confused by the resulting amount of output. For example for
2718 "debug 64" B<privoxy-log-parser> will (by default) only show messages that
2719 affect the content. If a filter doesn't cause any hits, B<privoxy-log-parser>
2720 will hide the "filter foo caused 0 hits" message.
2721
2722 =head1 OPTIONS
2723
2724 [B<--host-statistics-threshold>] Only show the request count for a host
2725 if it's above or equal to the given threshold. If the threshold is 0, host
2726 statistics are disabled.
2727
2728 [B<--html-output>] Use HTML and CSS for the syntax highlighting. If this option is
2729 omitted, ANSI escape sequences are used unless B<--no-syntax-highlighting> is active.
2730 This option is only intended to make embedding log excerpts in web pages easier.
2731 It does not escape any input!
2732
2733 [B<--no-msecs>] Don't expect milisecond resolution
2734
2735 [B<--no-syntax-highlighting>] Disable syntax-highlighting. Useful when
2736 the filtered output is piped into less in which case the ANSI control
2737 codes don't work, or if the terminal itself doesn't support the control
2738 codes.
2739
2740 [B<--shorten-thread-ids>] Shorten the thread ids to a three-digit decimal number.
2741 Note that the mapping from thread ids to shortened ids is created at run-time
2742 and thus varies with the input.
2743
2744 [B<--show-ineffective-filters>] Don't suppress log lines for filters
2745 that didn't modify the content.
2746
2747 [B<--show-complete-request-distribution>] Show the complete client request
2748 distribution in the B<--statistics> output. Without this option only the
2749 ten most common numbers are shown.
2750
2751 [B<--statistics>] Gather various statistics instead of syntax highlighting
2752 log messages. This is an experimental feature, if the results look wrong
2753 they very well might be. Also note that the results are pretty much guaranteed
2754 to be incorrect if Privoxy and Privoxy-Log-Parser aren't in sync.
2755
2756 [B<--strict-checks>] When generating statistics, look more careful at the
2757 input data and abort if it is unexpected, even if it doesn't affect the
2758 results. Significantly slows the parsing down and is not expected to catch
2759 any problems that matter.
2760 When highlighting, print warnings in case of unknown messages which can't be
2761 properly highlighted.
2762
2763 [B<--unbreak-lines-only>] Tries to fix lines that got messed up by a broken or
2764 interestingly configured mail client and thus are no longer recognized properly.
2765 Only fixes some breakage, but may be good enough or at least better than nothing.
2766 Doesn't do anything else, so you probably want to pipe the output into
2767 B<privoxy-log-parser> again.
2768
2769 [B<--url-statistics-threshold>] Only show the request count for a resource
2770 if it's above or equal to the given threshold. If the threshold is 0, URL
2771 statistics are disabled.
2772
2773 [B<--version>] Print version and exit.
2774
2775 =head1 EXAMPLES
2776
2777 To monitor a log file:
2778
2779 tail -F /usr/jails/privoxy-jail/var/log/privoxy/privoxy.log | B<privoxy-log-parser>
2780
2781 Replace '-F' with '-f' if your tail implementation lacks '-F' support
2782 or if the log won't get rotated anyway. The log file location depends
2783 on your system (Doh!).
2784
2785 To monitor Privoxy without having it write to a log file:
2786
2787 privoxy --no-daemon /usr/jails/privoxy-jail/usr/local/etc/privoxy/config 2>&1 | B<privoxy-log-parser>
2788
2789 Again, the config file location depends on your system. Output redirection
2790 depends on your shell, the above works with bourne shells.
2791
2792 To read a processed Privoxy log file from top to bottom, letting the content
2793 scroll by slightly faster than you can read:
2794
2795 B<privoxy-log-parser> < /usr/jails/privoxy-jail/var/log/privoxy/privoxy.log
2796
2797 This is probably only useful to fill screens in the background of haxor movies.
2798
2799 =head1 CAVEATS
2800
2801 Syntax highlighting with ANSI escape sequences will look strange
2802 if your background color isn't black.
2803
2804 Some messages aren't recognized yet and will not be fully highlighted.
2805
2806 B<privoxy-log-parser> is developed with Privoxy 3.0.7 or later in mind,
2807 using earlier Privoxy versions will probably result in an increased amount
2808 of unrecognized log lines.
2809
2810 Privoxy's log files tend to be rather large. If you use HTML
2811 highlighting some browsers can't handle them, get confused and
2812 will eventually crash because of segmentation faults or unexpected
2813 exceptions. This is a problem in the browser and not B<privoxy-log-parser>'s
2814 fault.
2815
2816 =head1 BUGS
2817
2818 Many settings can't be controlled through command line options yet.
2819
2820 =head1 SEE ALSO
2821
2822 privoxy(1)
2823
2824 =head1 AUTHOR
2825
2826 Fabian Keil <fk@fabiankeil.de>
2827
2828 =cut