tools/privoxy-log-parser.pl

   1 #!/usr/bin/perl
   2
   3 ################################################################################
   4 # privoxy-log-parser
   5 #
   6 # A parser for Privoxy log messages. For incomplete documentation run
   7 # perldoc privoxy-log-parser(.pl), for fancy screenshots see:
   8 #
   9 # http://www.fabiankeil.de/sourcecode/privoxy-log-parser/
  10 #
  11 # $Id: privoxy-log-parser.pl,v 1.102 2010/11/08 17:53:14 fabiankeil Exp $
  12 #
  13 # TODO:
  14 #       - LOG_LEVEL_CGI, LOG_LEVEL_ERROR, LOG_LEVEL_WRITE content highlighting
  15 #       - create fancy statistics
  16 #       - grep through Privoxy sources to find unsupported log messages
  17 #       - hunt down substitutions that match content from variables which
  18 #         can contain stuff like ()?'[]
  19 #       - replace $h{'foo'} with h('foo') where possible
  20 #       - hunt down XXX comments instead of just creating them
  21 #       - add example log lines for every regex and mark them up for
  22 #         regression testing
  23 #       - Handle incomplete input without Perl warning about undefined variables.
  24 #       - Use generic highlighting function that takes a regex and the
  25 #         hash key as input.
  26 #       - Add --compress and --decompress options.
  27 #
  28 # Copyright (c) 2007-2010 Fabian Keil <fk@fabiankeil.de>
  29 #
  30 # Permission to use, copy, modify, and distribute this software for any
  31 # purpose with or without fee is hereby granted, provided that the above
  32 # copyright notice and this permission notice appear in all copies.
  33 #
  34 # THE SOFTWARE IS PROVIDED "AS IS" AND THE AUTHOR DISCLAIMS ALL WARRANTIES
  35 # WITH REGARD TO THIS SOFTWARE INCLUDING ALL IMPLIED WARRANTIES OF
  36 # MERCHANTABILITY AND FITNESS. IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR
  37 # ANY SPECIAL, DIRECT, INDIRECT, OR CONSEQUENTIAL DAMAGES OR ANY DAMAGES
  38 # WHATSOEVER RESULTING FROM LOSS OF USE, DATA OR PROFITS, WHETHER IN AN
  39 # ACTION OF CONTRACT, NEGLIGENCE OR OTHER TORTIOUS ACTION, ARISING OUT OF
  40 # OR IN CONNECTION WITH THE USE OR PERFORMANCE OF THIS SOFTWARE.
  41 ################################################################################
  42
  43 use strict;
  44 use warnings;
  45 use Getopt::Long;
  46
  47 use constant {
  48     PRIVOXY_LOG_PARSER_VERSION => '0.6',
  49     # Feel free to mess with these ...
  50     DEFAULT_BACKGROUND => 'black',  # Choose registered colour (like 'black')
  51     DEFAULT_TEXT_COLOUR => 'white', # Choose registered colour (like 'black')
  52     HEADER_DEFAULT_COLOUR => 'yellow',
  53     REGISTER_HEADERS_WITH_THE_SAME_COLOUR => 1,
  54
  55     CLI_OPTION_DEFAULT_TO_HTML_OUTPUT => 0,
  56     CLI_OPTION_TITLE => 'Privoxy-Log-Parser in da house',
  57     CLI_OPTION_NO_EMBEDDED_CSS => 0,
  58     CLI_OPTION_NO_MSECS => 0,
  59     CLI_OPTION_NO_SYNTAX_HIGHLIGHTING => 0,
  60     CLI_OPTION_SHORTEN_THREAD_IDS => 0,
  61     CLI_OPTION_SHOW_INEFFECTIVE_FILTERS => 0,
  62     CLI_OPTION_ACCEPT_UNKNOWN_MESSAGES => 0,
  63     CLI_OPTION_STATISTICS => 0,
  64     CLI_OPTION_URL_STATISTICS_THRESHOLD => 0,
  65     CLI_OPTION_HOST_STATISTICS_THRESHOLD => 0,
  66
  67     SUPPRESS_SUCCEEDED_FILTER_ADDITIONS => 1,
  68     SHOW_SCAN_INTRO => 0,
  69     SHOW_FILTER_READIN_IN => 0,
  70     SUPPRESS_EMPTY_LINES => 1,
  71     SUPPRESS_SUCCESSFUL_CONNECTIONS => 1,
  72     SUPPRESS_ACCEPTED_CONNECTIONS => 1,
  73     SUPPRESS_GIF_NOT_CHANGED => 1,
  74     SUPPRESS_NEED_TO_DE_CHUNK_FIRST => 1,
  75
  76     DEBUG_HEADER_REGISTERING => 0,
  77     DEBUG_HEADER_HIGHLIGHTING => 0,
  78     DEBUG_TICKS => 0,
  79     DEBUG_PAINT_IT => 0,
  80     DEBUG_SUPPRESS_LOG_MESSAGES => 0,
  81
  82     PUNISH_MISSING_LOG_KNOWLEDGE_WITH_DEATH => 0,
  83     PUNISH_MISSING_HIGHLIGHT_KNOWLEDGE_WITH_DEATH => 1,
  84
  85     LOG_UNPARSED_LINES_TO_EXTRA_FILE => 0,
  86     ERROR_LOG_FILE => '/var/log/privoxy-log-parser',
  87
  88     # You better leave these alone unless you know what you're doing.
  89     COLOUR_RESET      => "\033[0;0m",
  90     ESCAPE => "\033[",
  91 };
  92
  93 # For performance reasons, these are global.
  94
  95 my $t;
  96 my %req; # request data from previous lines
  97 my %h;
  98 my %thread_colours;
  99 my @all_colours;
 100 my @time_colours;
 101 my $thread_colour_index = 0;
 102 my $header_colour_index = 0;
 103 my $time_colour_index = 0;
 104 my %header_colours;
 105 my $no_special_header_highlighting;
 106 my %reason_colours;
 107 my %h_colours;
 108 my $header_highlight_regex = '';
 109
 110 my $html_output_mode;
 111 my $no_msecs_mode; # XXX: should probably be removed
 112 my $shorten_thread_ids;
 113 my $line_end;
 114
 115 sub prepare_our_stuff () {
 116
 117     # Syntax Higlight hash
 118     @all_colours = (
 119         'red', 'green', 'brown', 'blue', 'purple', 'cyan',
 120         'light_gray', 'light_red', 'light_green', 'yellow',
 121         'light_blue', 'pink', 'light_cyan', 'white'
 122     );
 123
 124     %h = (
 125         # LOG_LEVEL
 126         Info            => 'blue',
 127         Header          => 'green',
 128         Filter          => 'purple', # XXX: Used?
 129         'Re-Filter'     => 'purple',
 130         Connect         => 'brown',
 131         Request         => 'light_cyan',
 132         CGI             => 'light_green',
 133         Redirect        => 'cyan',
 134         Error           => 'light_red',
 135         Crunch          => 'cyan',
 136         'Fatal error'   => 'light_red',
 137         'Gif-Deanimate' => 'blue',
 138         Force           => 'red',
 139         Writing         => 'light_green',
 140         Received        => 'yellow',
 141         # ----------------------
 142         URL                  => 'yellow',
 143         path                 => 'brown',
 144         request_             => 'brown', # host+path but no protocol
 145         'ip-address'         => 'yellow',
 146         Number               => 'yellow',
 147         Standard             => 'reset',
 148         Truncation           => 'light_red',
 149         Status               => 'brown',
 150         Timestamp            => 'brown',
 151         Crunching            => 'light_red',
 152         crunched             => 'light_red',
 153         'Request-Line'       => 'pink',
 154         method               => 'purple',
 155         destination          => 'yellow',
 156         'http-version'       => 'pink',
 157         'crunch-pattern'     => 'pink',
 158         not                  => 'brown',
 159         file                 => 'brown',
 160         signal               => 'yellow',
 161         version              => 'green',
 162         'program-name'       => 'cyan',
 163         port                 => 'red',
 164         host                 => 'red',
 165         warning              => 'light_red',
 166         debug                => 'light_red',
 167         filter               => 'green',
 168         tag                  => 'green',
 169         tagger               => 'green',
 170         'status-message'     => 'light_cyan',
 171         'status-code'        => 'yellow',
 172         'invalid-request'    => 'light_red',
 173         'hits'               => 'yellow',
 174         error                => 'light_red',
 175         'rewritten-URL'      => 'light_red',
 176         'pcrs-delimiter'     => 'light_red',
 177         'ignored'            => 'light_red',
 178         'action-bits-update' => 'light_red',
 179         'configuration-line' => 'red',
 180         'content-type'       => 'yellow',
 181         'HOST'               => HEADER_DEFAULT_COLOUR,
 182     );
 183
 184     %h_colours = %h;
 185
 186     # Header colours need their own hash so the keys can be accessed properly
 187     %header_colours = (
 188         # Prefilled with headers that should not appear with default header colours
 189         Cookie => 'light_red',
 190         'Set-Cookie' => 'light_red',
 191         Warning => 'light_red',
 192         Default => HEADER_DEFAULT_COLOUR,
 193     );
 194
 195     # Crunch reasons need their own hash as well
 196     %reason_colours = (
 197         'Unsupported HTTP feature'               => 'light_red',
 198         Blocked                                  => 'light_red',
 199         Untrusted                                => 'light_red',
 200         Redirected                               => 'green',
 201         'CGI Call'                               => 'white',
 202         'DNS failure'                            => 'red',
 203         'Forwarding failed'                      => 'light_red',
 204         'Connection failure'                     => 'light_red',
 205         'Out of memory (may mask other reasons)' => 'light_red',
 206         'No reason recorded'                     => 'light_red',
 207     );
 208
 209     @time_colours = ('white', 'light_gray');
 210
 211     # Translate highlight strings into highlight code
 212     prepare_highlight_hash(\%header_colours);
 213     prepare_highlight_hash(\%reason_colours);
 214     prepare_highlight_hash(\%h);
 215     prepare_colour_array(\@all_colours);
 216     prepare_colour_array(\@time_colours);
 217     init_css_colours();
 218
 219     init_stats();
 220 }
 221
 222 sub paint_it ($) {
 223 ###############################################################
 224 # Takes a colour string and returns an ANSI escape sequence
 225 # (unless --no-syntax-highlighting is used).
 226 # XXX: The Rolling Stones reference has to go.
 227 ###############################################################
 228
 229     my $colour = shift @_;
 230
 231     return "" if cli_option_is_set('no-syntax-highlighting');
 232
 233     my %light = (
 234         black       => 0,
 235         red         => 0,
 236         green       => 0,
 237         brown       => 0,
 238         blue        => 0,
 239         purple      => 0,
 240         cyan        => 0,
 241         light_gray  => 0,
 242         gray        => 0,
 243         dark_gray   => 1,
 244         light_red   => 1,
 245         light_green => 1,
 246         yellow      => 1,
 247         light_blue  => 1,
 248         pink        => 1,
 249         light_cyan  => 1,
 250         white       => 1,
 251     );
 252
 253     my %text = (
 254         black       => 30,
 255         red         => 31,
 256         green       => 32,
 257         brown       => 33,
 258         blue        => 34,
 259         purple      => 35,
 260         cyan        => 36,
 261         gray        => 37,
 262         light_gray  => 37,
 263         dark_gray   => 30,
 264         light_red   => 31,
 265         light_green => 32,
 266         yellow      => 33,
 267         light_blue  => 34,
 268         pink        => 35,
 269         light_cyan  => 36,
 270         white       => 37,
 271     );
 272
 273     my $bg_code = get_background();
 274     my $colour_code;
 275     our $default = default_colours();
 276
 277     if (defined($text{$colour})) {
 278         $colour_code  = ESCAPE;
 279         $colour_code .= $text{$colour};
 280         $colour_code .= ";";
 281         $colour_code .= $light{$colour} ? "1" : "2";
 282         $colour_code .= ";";
 283         $colour_code .= $bg_code;
 284         $colour_code .= "m";
 285         debug_message $colour . " is \'" . $colour_code . $colour . $default . "\'" if DEBUG_PAINT_IT;
 286
 287     } elsif ($colour =~ /reset/) {
 288
 289         $colour_code = default_colours();
 290
 291     } else {
 292
 293         die "What's $colour supposed to mean?\n";
 294     }
 295
 296     return $colour_code;
 297 }
 298
 299 sub get_semantic_html_markup ($) {
 300 ###############################################################
 301 # Takes a string and returns a span element
 302 ###############################################################
 303
 304     my $type = shift @_;
 305     my $code;
 306
 307     if ($type =~ /Standard/) {
 308         $code = '</span>';
 309     } else {
 310         $type = lc($type);
 311         $code = '<span title="' . $type . '" class="' . $type . '">';
 312     }
 313
 314     return $code;
 315 }
 316
 317 sub cli_option_is_set ($) {
 318
 319     our %cli_options;
 320     my $cli_option = shift;
 321
 322     die "Unknown CLI option: $cli_option" unless defined $cli_options{$cli_option};
 323
 324     return $cli_options{$cli_option};
 325 }
 326
 327 sub get_html_title () {
 328
 329     our %cli_options;
 330     return $cli_options{'title'};
 331
 332 }
 333
 334 sub init_css_colours() {
 335
 336     our %css_colours = (
 337         black       => "000",
 338         red         => "F00",
 339         green       => "0F0",
 340         brown       => "C90",
 341         blue        => "0F0",
 342         purple      => "F06", # XXX: wrong
 343         cyan        => "F09", # XXX: wrong
 344         light_gray  => "999",
 345         gray        => "333",
 346         dark_gray   => "222",
 347         light_red   => "F33",
 348         light_green => "33F",
 349         yellow      => "FF0",
 350         light_blue  => "30F",
 351         pink        => "F0F",
 352         light_cyan  => "66F",
 353         white       => "FFF",
 354     );
 355 }
 356
 357 sub get_css_colour ($) {
 358
 359    our %css_colours;
 360    my $colour = shift;
 361
 362    die "What's $colour supposed to mean?\n" unless defined($css_colours{$colour});
 363
 364    return '#' . $css_colours{$colour};
 365 }
 366
 367 sub get_css_line ($) {
 368
 369     my $class = shift;
 370     my $css_line;
 371
 372     $css_line .= '.' . lc($class) . ' {'; # XXX: lc() shouldn't be necessary
 373     die "What's $class supposed to mean?\n" unless defined($h_colours{$class});
 374     $css_line .= 'color:' . get_css_colour($h_colours{$class}) . ';';
 375     $css_line .= 'background-color:' . get_css_colour(DEFAULT_BACKGROUND) . ';';
 376     $css_line .= '}' . "\n";
 377
 378     return $css_line;
 379 }
 380
 381 sub get_css_line_for_colour ($) {
 382
 383     my $colour = shift;
 384     my $css_line;
 385
 386     $css_line .= '.' . lc($colour) . ' {'; # XXX: lc() shouldn't be necessary
 387     $css_line .= 'color:' . get_css_colour($colour) . ';';
 388     $css_line .= 'background-color:' . get_css_colour(DEFAULT_BACKGROUND) . ';';
 389     $css_line .= '}' . "\n";
 390
 391     return $css_line;
 392 }
 393
 394 # XXX: Wrong solution
 395 sub get_missing_css_lines () {
 396
 397     my $css_line;
 398
 399     $css_line .= '.' . 'default' . ' {';
 400     $css_line .= 'color:' . HEADER_DEFAULT_COLOUR . ';';
 401     $css_line .= 'background-color:' . get_css_colour(DEFAULT_BACKGROUND) . ';';
 402     $css_line .= '}' . "\n";
 403
 404     return $css_line;
 405 }
 406
 407 sub get_css () {
 408
 409     our %css_colours; #XXX: Wrong solution
 410
 411     my $css = '';
 412
 413     $css .= '.privoxy-log {';
 414     $css .= 'color:' . get_css_colour(DEFAULT_TEXT_COLOUR) . ';';
 415     $css .= 'background-color:' . get_css_colour(DEFAULT_BACKGROUND) . ';';
 416     $css .= '}' . "\n";
 417
 418     foreach my $key (keys %h_colours) {
 419
 420         next if ($h_colours{$key} =~ m/reset/); #XXX: Wrong solution.
 421         $css .= get_css_line($key);
 422
 423     }
 424
 425     foreach my $colour (keys %css_colours) {
 426
 427         $css .= get_css_line_for_colour($colour);
 428
 429     }
 430
 431     $css .= get_missing_css_lines(); #XXX: Wrong solution
 432
 433     return $css;
 434 }
 435
 436 sub print_intro () {
 437
 438     my $intro = '';
 439
 440     if (cli_option_is_set('html-output')) {
 441
 442         my $title = get_html_title();
 443
 444         $intro .= '<html><head>';
 445         $intro .= '<title>' . $title . '</title>';
 446         $intro .= '<style>' . get_css() . '</style>' unless cli_option_is_set('no-embedded-css');
 447         $intro .= '</head><body>';
 448         $intro .= '<h1>' . $title . '</h1><p class="privoxy-log">';
 449
 450         print $intro;
 451     }
 452 }
 453
 454 sub print_outro () {
 455
 456     my $outro = '';
 457
 458     if (cli_option_is_set('html-output')) {
 459
 460         $outro = '</p></body></html>';
 461         print $outro;
 462
 463     }
 464 }
 465
 466 sub get_line_end () {
 467     return cli_option_is_set('html-output') ? "<br>\n" : "\n";
 468 }
 469
 470 sub get_colour_html_markup ($) {
 471 ###############################################################
 472 # Takes a colour string a span element. XXX: WHAT?
 473 # XXX: This function shouldn't be necessary, the
 474 # markup should always be semantically correct.
 475 ###############################################################
 476
 477     my $type = shift @_;
 478     my $code;
 479
 480     if ($type =~ /Standard/) {
 481         $code = '</span>';
 482     } else {
 483         $code = '<span class="' . lc($type) . '">';
 484     }
 485
 486     return $code;
 487 }
 488
 489 sub default_colours () {
 490     # XXX: Properly
 491     our $bg_code;
 492     return reset_colours();
 493 }
 494
 495 sub show_colours () {
 496     # XXX: Implement
 497 }
 498
 499 sub reset_colours () {
 500     return ESCAPE . "0m";
 501 }
 502
 503 sub set_background ($){
 504
 505     my $colour = shift;
 506     our $bg_code;
 507     my %backgrounds = (
 508               black       => "40",
 509               red         => "41",
 510               green       => "42",
 511               brown       => "43",
 512               blue        => "44",
 513               magenta     => "45",
 514               cyan        => "46",
 515               white       => "47",
 516               default     => "49",
 517     );
 518
 519     if (defined($backgrounds{$colour})) {
 520         $bg_code = $backgrounds{$colour};
 521     } else {
 522         die "Invalid background colour: " . $colour;
 523     }
 524 }
 525
 526 sub get_background (){
 527     return our $bg_code;
 528 }
 529
 530 sub prepare_highlight_hash ($) {
 531     my $ref = shift;
 532
 533     foreach my $key (keys %$ref) {
 534         $$ref{$key} = $html_output_mode ?
 535             get_semantic_html_markup($key) :
 536             paint_it($$ref{$key});
 537     }
 538 }
 539
 540 sub prepare_colour_array ($) {
 541     my $ref = shift;
 542
 543     foreach my $i (0 ... @$ref - 1) {
 544         $$ref[$i] = $html_output_mode ?
 545             get_colour_html_markup($$ref[$i]) :
 546             paint_it($$ref[$i]);
 547     }
 548 }
 549
 550 sub found_unknown_content ($) {
 551
 552     my $unknown = shift;
 553     my $message;
 554
 555     return if cli_option_is_set('accept-unknown-messages');
 556
 557     return if ($unknown =~ /\[too long, truncated\]$/);
 558
 559     $message = "found_unknown_content: Don't know how to highlight: ";
 560     # Break line so the log file can later be parsed as Privoxy log file again
 561     $message .= '"' . $unknown . '"' . " in:\n";
 562     $message .= $req{$t}{'log-message'};
 563     debug_message($message);
 564     log_parse_error($req{$t}{'log-message'});
 565
 566     die "Unworthy content parser" if PUNISH_MISSING_LOG_KNOWLEDGE_WITH_DEATH;
 567 }
 568
 569 sub log_parse_error ($) {
 570
 571     my $message = shift;
 572
 573     if (LOG_UNPARSED_LINES_TO_EXTRA_FILE) {
 574         open(ERRORLOG, ">>" . ERROR_LOG_FILE) || die "Writing " . ERROR_LOG_FILE . " failed";
 575         print ERRORLOG $message;
 576         close(ERRORLOG);
 577     }
 578 }
 579
 580 sub debug_message (@) {
 581     my @message = @_;
 582
 583     print $h{'debug'} . "@message" . $h{'Standard'} . "\n";
 584 }
 585
 586 ################################################################################
 587 # highlighter functions that aren't loglevel-specific
 588 ################################################################################
 589
 590 sub h ($) {
 591
 592     # Get highlight marker
 593     my $highlight = shift; # XXX: Stupid name;
 594     my $result = '';
 595     my $message;
 596
 597     if (defined($highlight)) {
 598
 599         $result = $h{$highlight};
 600
 601     } else {
 602
 603         $message = "h: Don't recognize highlighter $highlight.";
 604         debug_message($message);
 605         log_parser_error($message);
 606         die "Unworthy highlighter function" if PUNISH_MISSING_HIGHLIGHT_KNOWLEDGE_WITH_DEATH;
 607     }
 608
 609     return $result;
 610 }
 611
 612 sub highlight_known_headers ($) {
 613
 614     my $content = shift;
 615
 616     debug_message("Searching $content for things to highlight.") if DEBUG_HEADER_HIGHLIGHTING;
 617
 618     if ($content =~ m/(?<=\s)($header_highlight_regex):/) {
 619         my $header = $1;
 620         $content =~ s@(?<=[\s|'])($header)(?=:)@$header_colours{$header}$1$h{'Standard'}@ig;
 621         debug_message("Highlighted '$header' in '$content'") if DEBUG_HEADER_HIGHLIGHTING;
 622     }
 623
 624     return $content;
 625 }
 626
 627 sub highlight_matched_request_line ($$) {
 628
 629     my $result = shift; # XXX: Stupid name;
 630     my $regex = shift;
 631     if ($result =~ m@(.*)($regex)(.*)@) {
 632         $result = $1 . highlight_request_line($2) . $3
 633     }
 634     return $result;
 635 }
 636
 637 sub highlight_request_line ($) {
 638
 639     my $rl = shift;
 640     my ($method, $url, $http_version);
 641
 642     #GET http://images.sourceforge.net/sfx/icon_warning.gif HTTP/1.1
 643     if ($rl =~ m/Invalid request/) {
 644
 645         $rl = h('invalid-request') . $rl . h('Standard');
 646
 647     } elsif ($rl =~ m/^([-\w]+) (.*) (HTTP\/\d\.\d)/) {
 648
 649         # XXX: might not match in case of HTTP method fuzzing.
 650         # XXX: save these: ($method, $path, $http_version) = ($1, $2, $3);
 651         $rl =~ s@^(\w+)@$h{'method'}$1$h{'Standard'}@;
 652         if ($rl =~ /http:\/\//) {
 653             $rl = highlight_matched_url($rl, '[^\s]*(?=\sHTTP)');
 654         } else {
 655             $rl = highlight_matched_pattern($rl, 'request_', '[^\s]*(?=\sHTTP)');
 656         }
 657
 658         $rl =~ s@(HTTP\/\d\.\d)$@$h{'http-version'}$1$h{'Standard'}@;
 659
 660     } elsif ($rl =~ m/\.\.\. \[too long, truncated\]$/) {
 661
 662         $rl =~ s@^(\w+)@$h{'method'}$1$h{'Standard'}@;
 663         $rl = highlight_matched_url($rl, '[^\s]*(?=\.\.\.)');
 664
 665     } elsif ($rl =~ m/^ $/) {
 666
 667         $rl = h('error') . "No request line specified!" . h('Standard');
 668
 669     } else {
 670
 671         debug_message ("Can't parse request line: $rl");
 672
 673     }
 674
 675     return $rl;
 676 }
 677
 678 sub highlight_response_line ($) {
 679
 680     my $rl = shift;
 681     my ($http_version, $status_code, $status_message);
 682
 683     #HTTP/1.1 200 OK
 684     #ICY 200 OK
 685
 686     # TODO: Mark different status codes differently
 687
 688     if ($rl =~ m/((?:HTTP\/\d\.\d|ICY)) (\d+) (.*)/) {
 689         ($http_version, $status_code, $status_message) = ($1, $2, $3);
 690     } else {
 691         debug_message ("Can't parse response line: $rl") and die 'Fix this';
 692     }
 693
 694     # Rebuild highlighted
 695     $rl= "";
 696     $rl .= h('http-version') . $http_version . h('Standard');
 697     $rl .= " ";
 698     $rl .= h('status-code') . $status_code . h('Standard');
 699     $rl .= " ";
 700     $rl .= h('status-message') . $status_message . h('Standard');
 701
 702     return $rl;
 703 }
 704
 705 sub highlight_matched_url ($$) {
 706
 707     my $result = shift; # XXX: Stupid name;
 708     my $regex = shift;
 709
 710     #print "Got $result, regex ($regex)\n";
 711
 712     if ($result =~ m@(.*?)($regex)(.*)@) {
 713         $result = $1 . highlight_url($2) . $3;
 714         #print "Now the result is $result\n";
 715     }
 716
 717     return $result;
 718 }
 719
 720 sub highlight_matched_host ($$) {
 721
 722     my ($result, $regex) = @_; # XXX: result ist stupid name;
 723
 724     if ($result =~ m@(.*?)($regex)(.*)@) {
 725         $result = $1 . $h{host} . $2 . $h{Standard} . $3;
 726     }
 727
 728     return $result;
 729 }
 730
 731 sub highlight_matched_pattern ($$$) {
 732
 733     my $result = shift; # XXX: Stupid name;
 734     my $key = shift;
 735     my $regex = shift;
 736
 737     die "Unknown key $key" unless defined $h{$key};
 738
 739     if ($result =~ m@(.*?)($regex)(.*)@) {
 740         $result = $1 . h($key) . $2 . h('Standard') . $3;
 741     }
 742
 743     return $result;
 744 }
 745
 746 sub highlight_matched_path ($$) {
 747
 748     my $result = shift; # XXX: Stupid name;
 749     my $regex = shift;
 750
 751     if ($result =~ m@(.*?)($regex)(.*)@) {
 752         $result = $1 . h('path') . $2 . h('Standard') . $3;
 753     }
 754
 755     return $result;
 756 }
 757
 758 sub highlight_url ($) {
 759
 760     my $url = shift;
 761
 762     if ($html_output_mode) {
 763
 764         $url = '<a href="' . $url . '">' . $url . '</a>';
 765
 766     } else {
 767
 768         $url = h('URL') . $url . h('Standard');
 769
 770     }
 771
 772     return $url;
 773 }
 774
 775 sub update_header_highlight_regex ($) {
 776
 777     my $header = shift;
 778     my $headers = join ('|', keys %header_colours);
 779
 780     $header_highlight_regex = qr/$headers/;
 781     print "Registering '$header'\n" if DEBUG_HEADER_HIGHLIGHTING;
 782 }
 783
 784 ################################################################################
 785 # loglevel-specific highlighter functions
 786 ################################################################################
 787
 788 sub handle_loglevel_header ($) {
 789
 790     my $c = shift;
 791
 792     if ($c =~ /^scan:/) {
 793
 794         if ($c =~ m/^scan: ([^: ]+):/) {
 795
 796             # Register new headers
 797             # scan: Accept: image/png,image/*;q=0.8,*/*;q=0.5
 798             my $header = $1;
 799             if (!defined($header_colours{$header}) and $header =~ /^[\d\w-]*$/) {
 800                 debug_message "Registering previously unknown header $1" if DEBUG_HEADER_REGISTERING;
 801
 802                 if (REGISTER_HEADERS_WITH_THE_SAME_COLOUR) {
 803                     $header_colours{$header} =  $header_colours{'Default'};
 804                 } else {
 805                     $header_colours{$header} = $all_colours[$header_colour_index % @all_colours];
 806                     $header_colour_index++;
 807                 }
 808                 update_header_highlight_regex($header);
 809             }
 810
 811         } elsif ($c =~ m/^(scan: )(\w+ .+ HTTP\/\d\.\d)/) {
 812
 813             # scan: GET http://p.p/ HTTP/1.1
 814             $c = $1 . highlight_request_line($2);
 815
 816         } elsif ($c =~ m/^(scan: )((?:HTTP\/\d\.\d|ICY) (\d+) (.*))/) {
 817
 818             # scan: HTTP/1.1 200 OK
 819             $req{$t}{'response_line'} = $2;
 820             $req{$t}{'status_code'} = $3;
 821             $req{$t}{'status_message'} = $4;
 822             $c = $1 . highlight_response_line($req{$t}{'response_line'});
 823         }
 824
 825     } elsif ($c =~ m/^Crunching (?:server|client) header: .* \(contains: ([^\)]*)\)/) {
 826
 827         # Crunching server header: Set-Cookie: trac_form_token=d5308c34e16d15e9e301a456; (contains: Cookie:)
 828         $c =~ s@(?<=contains: )($1)@$h{'crunch-pattern'}$1$h{'Standard'}@;
 829         $c =~ s@(Crunching)@$h{$1}$1$h{'Standard'}@;
 830
 831     } elsif ($c =~ m/^New host is: ([^\s]*)\./) {
 832
 833         # New host is: trac.vidalia-project.net. Crunching Referer: http://www.vidalia-project.net/!
 834         $c = highlight_matched_host($c, '(?<=New host is: )[^\s]+(?=\.)');
 835         $c = highlight_matched_url($c, '(?<=Crunching Referer: )[^\s!]+');
 836
 837     } elsif ($c =~ m/^Text mode enabled by force. (Take cover)!/) {
 838
 839         # Text mode enabled by force. Take cover!
 840         $c =~ s@($1)@$h{'warning'}$1$h{'Standard'}@;
 841
 842     } elsif ($c =~ m/^(New HTTP Request-Line: )(.*)/) {
 843
 844         # New HTTP Request-Line: GET http://www.privoxy.org/ HTTP/1.1
 845         $c = $1 . highlight_request_line($2);
 846
 847     } elsif ($c =~ m/^Adjust(ed)? Content-Length to \d+/) {
 848
 849         # Adjusted Content-Length to 2132
 850         # Adjust Content-Length to 33533
 851         $c =~ s@(?<=Content-Length to )(\d+)@$h{'Number'}$1$h{'Standard'}@;
 852         $c = highlight_known_headers($c);
 853
 854     } elsif ($c =~ m/^Destination extracted from "Host:" header. New request URL:/) {
 855
 856         # Destination extracted from "Host:" header. New request URL: http://www.cccmz.de/~ridcully/blog/
 857         $c = highlight_matched_url($c, '(?<=New request URL: ).*');
 858
 859     } elsif ($c =~ m/^Couldn\'t parse:/) {
 860
 861         # XXX: These should probable be logged with LOG_LEVEL_ERROR
 862         # Couldn't parse: If-Modified-Since: Wed, 21 Mar 2007 16:34:50 GMT (crunching!)
 863         # Couldn't parse: at, 24 Mar 2007 13:46:21 GMT in If-Modified-Since: Sat, 24 Mar 2007 13:46:21 GMT (crunching!)
 864         $c =~ s@^(Couldn\'t parse)@$h{'error'}$1$h{'Standard'}@;
 865
 866     } elsif ($c =~ /^Tagger \'([^\']*)\' added tag \'([^\']*)\'/ or
 867              $c =~ m/^Adding tag \'([^\']*)\' created by header tagger \'([^\']*)\'/) {
 868
 869         # Adding tag 'GET request' created by header tagger 'method-man' (XXX: no longer used)
 870         # Tagger 'revalidation' added tag 'REVALIDATION-REQUEST'. No action bit update necessary.
 871         # Tagger 'revalidation' added tag 'REVALIDATION-REQUEST'. Action bits updated accordingly.
 872
 873         # XXX: Save tag and tagger
 874
 875         $c =~ s@(?<=^Tagger \')([^\']*)@$h{'tagger'}$1$h{'Standard'}@;
 876         $c =~ s@(?<=added tag \')([^\']*)@$h{'tag'}$1$h{'Standard'}@;
 877         $c =~ s@(?<=Action bits )(updated)@$h{'action-bits-update'}$1$h{'Standard'}@;
 878         $no_special_header_highlighting = 1;
 879
 880     } elsif ($c =~ /^Tagger \'([^\']*)\' didn['']t add tag \'([^\']*)\'/) {
 881
 882         # Tagger 'revalidation' didn't add tag 'REVALIDATION-REQUEST'. Tag already present
 883         # XXX: Save tag and tagger
 884
 885         $c =~ s@(?<=^Tagger \')([^\']*)@$h{'tag'}$1$h{'Standard'}@;
 886         $c =~ s@(?<=didn['']t add tag \')([^\']*)@$h{'tagger'}$1$h{'Standard'}@;
 887
 888     } elsif ($c =~ m/^(?:scan:|Randomiz|addh:|Adding:|Removing:|Referer:|Modified:|Accept-Language header|[Cc]ookie)/
 889           or $c =~ m/^(Text mode is already enabled|Denied request with NULL byte|Replaced:|add-unique:)/
 890           or $c =~ m/^(Crunched (incoming|outgoing) cookie|Suppressed offer|Accepted the client)/
 891           or $c =~ m/^(addh-unique|Referer forged to)/
 892           or $c =~ m/^Downgraded answer to HTTP\/1.0/
 893           or $c =~ m/^Parameter: \+hide-referrer\{[^\}]*\} is a bad idea, but I don\'t care./
 894           or $c =~ m/^Referer (?:overwritten|replaced) with: Referer: / #XXX: should this be highlighted?
 895           or $c =~ m/^Referer crunched!/
 896           or $c =~ m/^crunched x-forwarded-for!/
 897           or $c =~ m/^crunched From!/
 898           or $c =~ m/^ modified$/
 899           or $c =~ m/^Content filtering is enabled. Crunching:/
 900           or $c =~ m/^force-text-mode overruled the client/
 901           or $c =~ m/^Server time in the future\./
 902           or $c =~ m/^content-disposition header crunched and replaced with:/i
 903           or $c =~ m/^Reducing white space in /
 904           or $c =~ m/^Ignoring single quote in /
 905           or $c =~ m/^Converting tab to space in /
 906           or $c =~ m/A HTTP\/1\.1 response without/
 907           or $c =~ m/Disabled filter mode on behalf of the client/
 908           or $c =~ m/Keeping the (?:server|client) header /
 909           or $c =~ m/Content modified with no Content-Length header set/
 910           or $c =~ m/^Appended client IP address to/
 911           or $c =~ m/^Removing 'Connection: close' to imply keep-alive./
 912           or $c =~ m/^keep-alive support is disabled/
 913           or $c =~ m/^Continue hack in da house/
 914           or $c =~ m/^Merged multiple header lines to:/
 915             )
 916     {
 917         # XXX: Some of these may need highlighting
 918
 919         # Modified: User-Agent: Mozilla/5.0 (X11; U; SunOS i86pc; pl-PL; rv:1.8.1.1) Gecko/20070214 Firefox/2.0.0.1
 920         # Accept-Language header crunched and replaced with: Accept-Language: pl-pl
 921         # cookie 'Set-Cookie: eZSessionCookie=07bfec287c197440d299f81580593c3d; \
 922         #  expires=Thursday, 12-Apr-07 15:16:18 GMT; path=/' send by \
 923         #  http://wirres.net/article/articleview/4265/1/6/ appears to be using time format 1 (XXX: gone with the wind)
 924         # Cookie rewritten to a temporary one: Set-Cookie: NSC_gffe-iuuq-mc-wtfswfs=8efb33a53660;path=/
 925         # Text mode is already enabled
 926         # Denied request with NULL byte(s) turned into line break(s)
 927         # Replaced: 'Connection: Yo, home to Bel Air' with 'Connection: close'
 928         # addh-unique: Host: people.freebsd.org
 929         # Suppressed offer to compress content
 930         # Crunched incoming cookie -- yum!
 931         # Accepted the client's request to fetch without filtering.
 932         # Crunched outgoing cookie: Cookie: PREF=ID=6cf0abd347b30262:TM=1173357617:LM=1173357617:S=jZypyyJ7LPiwFi1_
 933         # addh-unique: Host: subkeys.pgp.net:11371
 934         # Referer forged to: Referer: http://10.0.0.1/
 935         # Downgraded answer to HTTP/1.0
 936         # Parameter: +hide-referrer{pille-palle} is a bad idea, but I don't care.
 937         # Referer overwritten with: Referer: pille-palle
 938         # Referer replaced with: Referer: pille-palle
 939         # crunched x-forwarded-for!
 940         # crunched From!
 941         #  modified # XXX: pretty stupid log message
 942         # Content filtering is enabled. Crunching: 'Range: 1234-5678' to prevent range-mismatch problems
 943         # force-text-mode overruled the client's request to fetch without filtering!
 944         # Server time in the future.
 945         # content-disposition header crunched and replaced with: content-disposition: filename=baz
 946         # Content-Disposition header crunched and replaced with: content-disposition: filename=baz
 947         # Reducing white space in 'X-LWS-Test: "This  is  quoted" this is not "this  is  " but " this again   is  not'
 948         # Ignoring single quote in 'X-LWS-Test: "This  is  quoted" this is not "this  is  " but "  this again   is  not'
 949         # Converting tab to space in 'X-LWS-Test:   "This  is  quoted" this   is  not "this  is  "  but  "\
 950         #  this again   is  not'
 951         # A HTTP/1.1 response without Connection header implies keep-alive.
 952         # Disabled filter mode on behalf of the client.
 953         # Keeping the server header 'Connection: keep-alive' around.
 954         # Keeping the client header 'Connection: close' around. The connection will not be kept alive.
 955         # Keeping the client header 'Connection: keep-alive' around. The connection will be kept alive if possible.
 956         # Content modified with no Content-Length header set. Creating a fake one for adjustment later on.
 957         # Appended client IP address to X-Forwarded-For: 10.0.0.2, 10.0.0.1
 958         # Removing 'Connection: close' to imply keep-alive.
 959         # keep-alive support is disabled. Crunching: Keep-Alive: 300.
 960         # Continue hack in da house.
 961         # Merged multiple header lines to: 'X-FORWARDED-PROTO: http X-HOST: 127.0.0.1'
 962
 963     } elsif ($c =~ m/^scanning headers for:/) {
 964
 965         return '' unless SHOW_SCAN_INTRO;
 966
 967     } elsif ($c =~ m/^[Cc]runch(ing|ed)|crumble crunched:/) {
 968         # crunched User-Agent!
 969         # Crunching: Content-Encoding: gzip
 970
 971         $c =~ s@(Crunching|crunched)@$h{$1}$1$h{'Standard'}@;
 972
 973     } elsif ($c =~ m/^Offending request data with NULL bytes turned into \'°\' characters:/) {
 974
 975         # Offending request data with NULL bytes turned into '°' characters: °°n°°(°°°
 976
 977         $c = h('warning') . $c . h('Standard');
 978
 979     } elsif ($c =~ m/^(Transforming \")(.*?)(\" to \")(.*?)(\")/) {
 980
 981         # Transforming "Proxy-Authenticate: Basic realm="Correos Proxy Server"" to\
 982         #  "Proxy-Authenticate: Basic realm="Correos Proxy Server""
 983
 984        $c =~ s@(?<=^Transforming \")(.*)(?=\" to)@$h{'Header'}$1$h{'Standard'}@;
 985        $c =~ s@(?<=to \")(.*)(?=\")@$h{'Header'}$1$h{'Standard'}@;
 986
 987     } elsif ($c =~ m/^Removing empty header/) {
 988
 989         # Removing empty header
 990         # Ignore for now
 991
 992     } elsif ($c =~ m/^Content-Type: .* not replaced/) {
 993
 994         # Content-Type: application/octet-stream not replaced. It doesn't look like text.\
 995         #  Enable force-text-mode if you know what you're doing.
 996         # XXX: Could highlight more here.
 997         $c =~ s@(?<=^Content-Type: )(.*)(?= not replaced)@$h{'content-type'}$1$h{'Standard'}@;
 998
 999     } elsif ($c =~ m/^(Server|Client) keep-alive timeout is/) {
1000
1001        # Server keep-alive timeout is 5. Sticking with 10.
1002        # Client keep-alive timeout is 20. Sticking with 10.
1003
1004        $c =~ s@(?<=timeout is )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1005        $c =~ s@(?<=Sticking with )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1006
1007     } elsif ($c =~ m/^Reducing keep-alive timeout/) {
1008
1009        # Reducing keep-alive timeout from 60 to 10.
1010
1011        $c =~ s@(?<= from )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1012        $c =~ s@(?<= to )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1013
1014     } elsif ($c =~ m/^Killed all-caps Host header line: HOST:/) {
1015
1016        # Killed all-caps Host header line: HOST: bestproxydb.com
1017        $c = highlight_matched_host($c, '(?<=HOST: )[^\s]+');
1018        $c = highlight_matched_pattern($c, 'HOST', 'HOST');
1019
1020     } else {
1021
1022         found_unknown_content($c);
1023     }
1024
1025     # Highlight headers
1026     unless ($c =~ m/^Transforming/) {
1027         $c = highlight_known_headers($c) unless $no_special_header_highlighting;
1028     }
1029
1030     return $c;
1031 }
1032
1033 sub handle_loglevel_re_filter ($) {
1034
1035     my $content = shift;
1036     my $c = $content;
1037     my $key;
1038
1039     if ($c =~ m/^(?:re_)?filtering ([^\s]+) \(size (\d+)\) with (?:filter )?\'?([^\s]+?)\'? produced (\d+) hits \(new size (\d+)\)/) {
1040
1041         # XXX: only the second version gets highlighted properly.
1042         # re_filtering www.lfk.de/favicon.ico (size 209) with filter untrackable-hulk produced 0 hits (new size 209).
1043         # filtering aci.blogg.de/ (size 37988) with 'blogg.de' produced 3 hits (new size 38057)
1044         $req{$t}{'content_source'} = $1;
1045         $req{$t}{'content_size'}   = $2;
1046         $req{$t}{'content_filter'} = $3;
1047         $req{$t}{'content_hits'}   = $4;
1048         $req{$t}{'new_content_size'} = $5;
1049         $req{$t}{'content_size_change'} = $req{$t}{'new_content_size'} - $req{$t}{'content_size'};
1050         #return '' if ($req{$t}{'content_hits'} == 0 && !cli_option_is_set('show-ineffective-filters'));
1051         if ($req{$t}{'content_hits'} == 0 and
1052             not (cli_option_is_set('show-ineffective-filters')
1053                  or ($req{$t}{'content_filter'} =~ m/^privoxy-filter-test$/))) {
1054                 return '';
1055         }
1056
1057         $c =~ s@(?<=\(size )(\d+)\)(?= with)@$h{'Number'}$1$h{'Standard'}@;
1058         $c =~ s@(?<=\(new size )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1059         $c =~ s@(?<=produced )(\d+)(?= hits)@$h{'Number'}$1$h{'Standard'}@;
1060
1061         $c =~ s@([^\s]+?)(\'? produced)@$h{'filter'}$1$h{'Standard'}$2@;
1062         $c = highlight_matched_host($c, '(?<=filtering )[^\s]+');
1063
1064         $c =~ s@\.$@ @;
1065         $c .= "(" . $h{'Number'};
1066         $c .= "+" if ($req{$t}{'content_size_change'} >= 0);
1067         $c .= $req{$t}{'content_size_change'} . $h{'Standard'} . ")";
1068         $content = $c;
1069
1070   } elsif ($c =~ /\.{3}$/
1071         and $c =~ m/^(?:re_)?filtering \'?(.*?)\'? \(size (\d*)\) with (?:filter )?\'?([^\s]*?)\'? ?\.{3}$/) {
1072
1073         # Used by Privoxy 3.0.5 and 3.0.6:
1074         # XXX: Fill in ...
1075         # Used by Privoxy 3.0.7:
1076         # filtering 'Connection: close' (size 17) with 'generic-content-ads' ...
1077
1078         $req{$t}{'filtered_header'} = $1;
1079         $req{$t}{'old_header_size'} = $2;
1080         $req{$t}{'header_filter_name'} = $3;
1081
1082         unless (cli_option_is_set('show-ineffective-filters') or
1083                 $req{$t}{'header_filter_name'} =~ m/^privoxy-filter-test$/) {
1084             return '';
1085         }
1086         $content =~ s@(?<=\(size )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1087         $content =~ s@($req{$t}{'header_filter_name'})@$h{'filter'}$1$h{'Standard'}@;
1088
1089     } elsif ($c =~ m/^ ?\.\.\. ?produced (\d*) hits \(new size (\d*)\)\./) {
1090
1091         # ...produced 0 hits (new size 23).
1092         #... produced 1 hits (new size 54).
1093
1094         $req{$t}{'header_filter_hits'} = $1;
1095         $req{$t}{'new_header_size'} = $2;
1096
1097         unless (cli_option_is_set('show-ineffective-filters') or
1098                 (defined($req{$t}{'header_filter_name'}) and
1099                  $req{$t}{'header_filter_name'} =~ m/^privoxy-filter-test$/)) {
1100
1101             if ($req{$t}{'header_filter_hits'} == 0 and
1102                 not (defined($req{$t}{'header_filter_name'}) and
1103                  $req{$t}{'header_filter_name'} =~ m/^privoxy-filter-test$/)) {
1104                 return '';
1105             }
1106             # Reformat including information from the intro
1107             $c = "'" . h('filter') . $req{$t}{'header_filter_name'} . h('Standard') . "'";
1108             $c .= " hit ";
1109             # XXX: Hide behind constant, it may be interesting if LOG_LEVEL_HEADER isn't enabled as well.
1110             # $c .= $req{$t}{'filtered_header'} . " ";
1111             $c .= h('Number') . $req{$t}{'header_filter_hits'}. h('Standard');
1112             $c .= ($req{$t}{'header_filter_hits'} == 1) ? " time, " : " times, ";
1113
1114             if ($req{$t}{'old_header_size'} !=  $req{$t}{'new_header_size'}) {
1115
1116                 $c .= "changing size from ";
1117                 $c .=  h('Number') . $req{$t}{'old_header_size'} . h('Standard');
1118                 $c .= " to ";
1119                 $c .= h('Number') . $req{$t}{'new_header_size'} . h('Standard');
1120                 $c .= ".";
1121
1122             } else {
1123
1124                 $c .= "keeping the size at " . $req{$t}{'old_header_size'};
1125
1126             }
1127
1128             # Highlight from last line (XXX: What?)
1129             # $c =~ s@(?<=produced )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1130             # $c =~ s@($req{$t}{'header_filter_name'})@$h{'filter'}$1$h{'Standard'}@;
1131
1132         } else {
1133
1134            # XXX: Untested
1135            $c =~ s@(?<=produced )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1136            $c =~ s@(?<=new size )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1137
1138         }
1139         $content = $c;
1140
1141     } elsif ($c =~ m/^(Tagger|Filter) ([^\s]*) has empty joblist. Nothing to do./) {
1142
1143         # Filter privoxy-filter-test has empty joblist. Nothing to do.
1144         # Tagger variable-test has empty joblist. Nothing to do.
1145
1146         $content =~ s@(?<=$1 )([^\s]*)@$h{'filter'}$1$h{'Standard'}@;
1147
1148     } elsif ($c =~ m/^De-chunking successful. Shrunk from (\d+) to (\d+)/) {
1149
1150         $req{$t}{'chunked-size'} = $1;
1151         $req{$t}{'dechunked-size'} = $2;
1152         $req{$t}{'dechunk-change'} = $req{$t}{'dechunked-size'} - $req{$t}{'chunked-size'};
1153
1154         $content .= " (" . h('Number') . $req{$t}{'dechunk-change'} . h('Standard') . ")";
1155
1156         $content =~ s@(?<=from )($req{$t}{'chunked-size'})@$h{'Number'}$1$h{'Standard'}@;
1157         $content =~ s@(?<=to )($req{$t}{'dechunked-size'})@$h{'Number'}$1$h{'Standard'}@;
1158
1159     } elsif ($c =~ m/^Decompression successful. Old size: (\d+), new size: (\d+)./) {
1160
1161         # Decompression successful. Old size: 670, new size: 1166.
1162
1163         $req{$t}{'size-compressed'} = $1;
1164         $req{$t}{'size-decompressed'} = $2;
1165         $req{$t}{'decompression-gain'} = $req{$t}{'size-decompressed'} - $req{$t}{'size-compressed'};
1166
1167         $content =~ s@(?<=Old size: )($req{$t}{'size-compressed'})@$h{'Number'}$1$h{'Standard'}@;
1168         $content =~ s@(?<=new size: )($req{$t}{'size-decompressed'})@$h{'Number'}$1$h{'Standard'}@;
1169
1170         # XXX: Create sub get_percentage()
1171         if ($req{$t}{'size-decompressed'}) {
1172             $req{$t}{'decompression-gain-percent'} =
1173                 $req{$t}{'decompression-gain'} / $req{$t}{'size-decompressed'} * 100;
1174
1175             $content .= " (saved: ";
1176             #$content .= h('Number') . $req{$t}{'decompression-gain'} . h('Standard');
1177             #$content .= "/";
1178             $content .= h('Number') . sprintf("%.2f%%", $req{$t}{'decompression-gain-percent'}) . h('Standard');
1179             $content .= ")";
1180         }
1181
1182     } elsif ($c =~ m/^(Need to de-chunk first)/) {
1183
1184         # Need to de-chunk first
1185         return '' if SUPPRESS_NEED_TO_DE_CHUNK_FIRST;
1186
1187     } elsif ($c =~ m/^(Adding (?:dynamic )?re_filter job)/) {
1188
1189         return ''  if (SUPPRESS_SUCCEEDED_FILTER_ADDITIONS && m/succeeded/);
1190
1191         # Adding re_filter job ...
1192         # Adding dynamic re_filter job s@^(?:\w*)\s+.*\s+HTTP/\d\.\d\s*@IP-ADDRESS: $origin@D\
1193         #  to filter client-ip-address succeeded.
1194
1195     } elsif ($c =~ m/^Reading in filter/) {
1196
1197         return '' unless SHOW_FILTER_READIN_IN;
1198
1199     } else {
1200
1201         found_unknown_content($content);
1202
1203     }
1204
1205     return $content;
1206 }
1207
1208 sub handle_loglevel_redirect ($) {
1209
1210     my $c = shift;
1211
1212     if ($c =~ m/^Decoding "([^""]*)"/) {
1213
1214          $req{$t}{'original-destination'} = $1;
1215          $c = highlight_matched_path($c, '(?<=Decoding ")[^"]*');
1216          $c =~ s@\"@@g;
1217
1218     } elsif ($c =~ m/^Checking/) {
1219
1220          # Checking /_ylt=A0geu.Z76BRGR9k/**http://search.yahoo.com/search?p=view+odb+presentation+on+freebsd\
1221          #  &ei=UTF-8&xargs=0&pstart=1&fr=moz2&b=11 for redirects.
1222
1223          # TODO: Change colour if really url-decoded
1224          $req{$t}{'decoded-original-destination'} = $1;
1225          $c = highlight_matched_path($c, '(?<=Checking ")[^"]*');
1226          $c =~ s@\"@@g;
1227
1228     } elsif ($c =~ m/^pcrs command "([^""]*)" changed /) {
1229
1230         # pcrs command "s@&from=rss@@" changed \
1231         #  "http://it.slashdot.org/article.pl?sid=07/03/02/1657247&from=rss"\
1232         #  to "http://it.slashdot.org/article.pl?sid=07/03/02/1657247" (1 hit).
1233         $c =~ s@(?<=pcrs command )"([^""]*)"@$h{'filter'}$1$h{'Standard'}@;
1234         $c = highlight_matched_url($c, '(?<=changed ")[^""]*');
1235         $c =~ s@(?<=changed )"([^""]*)"@$1@; # Remove quotes
1236         $c = highlight_matched_url($c, '(?<=to ")[^""]*');
1237         $c =~ s@(?<=to )"([^""]*)"@$1@; # Remove quotes
1238         $c =~ s@(\d+)(?= hits?)@$h{'hits'}$1$h{'Standard'}@;
1239
1240     } elsif ($c =~ m/^pcrs command "([^""]*)" didn\'t change/) {
1241
1242         # pcrs command "s@^http://([^.]+?)/?$@http://www.bing.com/search?q=$1@" didn't \
1243         #  change "http://www.example.org/".
1244         $c =~ s@(?<=pcrs command )"([^""]*)"@$h{'filter'}$1$h{'Standard'}@;
1245         $c = highlight_matched_url($c, '(?<=change ")[^""]*');
1246
1247     } elsif ($c =~ m/(^New URL is: )(.*)/) {
1248
1249         # New URL is: http://it.slashdot.org/article.pl?sid=07/03/04/1511210
1250         # XXX: Use URL highlighter
1251         # XXX: Save?
1252         $c = $1 . h('rewritten-URL') . $2 . h('Standard');
1253
1254     } elsif ($c =~ m/No pcrs command recognized, assuming that/) {
1255         # No pcrs command recognized, assuming that "http://config.privoxy.org/user-manual/favicon.png"\
1256         #  is already properly formatted.
1257         # XXX: assume the same?
1258         $c = highlight_matched_url($c, '(?<=assuming that \")[^"]*');
1259
1260     } else {
1261
1262         found_unknown_content($c);
1263
1264     }
1265
1266     return $c;
1267 }
1268
1269 sub handle_loglevel_gif_deanimate ($) {
1270
1271     my $content = shift;
1272
1273     if ($content =~ m/Success! GIF shrunk from (\d+) bytes to (\d+)\./) {
1274
1275         my $bytes_from = $1;
1276         my $bytes_to = $2;
1277         # Gif-Deanimate: Success! GIF shrunk from 205 bytes to 133.
1278         $content =~ s@$bytes_from@$h{'Number'}$bytes_from$h{'Standard'}@;
1279         # XXX: Do we need g in case of ($1 == $2)?
1280         $content =~ s@$bytes_to@$h{'Number'}$bytes_to$h{'Standard'}@;
1281
1282     } elsif ($content =~ m/GIF (not) changed/) {
1283
1284         # Gif-Deanimate: GIF not changed.
1285         return '' if SUPPRESS_GIF_NOT_CHANGED;
1286         $content =~ s@($1)@$h{'not'}$1$h{'Standard'}@;
1287
1288     } elsif ($content =~ m/^failed! \(gif parsing\)/) {
1289
1290         # failed! (gif parsing)
1291         # XXX: Replace this error message with something less stupid
1292         $content =~ s@(failed!)@$h{'error'}$1$h{'Standard'}@;
1293
1294     } elsif ($content =~ m/^Need to de-chunk first/) {
1295
1296         # Need to de-chunk first
1297         return '' if SUPPRESS_NEED_TO_DE_CHUNK_FIRST;
1298
1299     } elsif ($content =~ m/^(?:No GIF header found|failed while parsing)/) {
1300
1301         # No GIF header found (XXX: Did I ever commit this?)
1302         # failed while parsing 195 134747048 (XXX: never commited)
1303
1304         # Ignore these for now
1305
1306     } else {
1307
1308         found_unknown_content($content);
1309
1310     }
1311
1312     return $content;
1313 }
1314
1315 sub handle_loglevel_request ($) {
1316
1317     my $content = shift;
1318
1319     if ($content =~ m/crunch! /) {
1320
1321         # config.privoxy.org/send-stylesheet crunch! (CGI Call)
1322
1323         # Highlight crunch reasons
1324         foreach my $reason (keys %reason_colours) {
1325             $content =~ s@\(($reason)\)@$reason_colours{$reason}($1)$h{'Standard'}@g;
1326         }
1327         # Highlight request URL domain and ditch 'crunch!'
1328         $content = highlight_matched_pattern($content, 'request_', '[^ ]*(?= crunch!)');
1329         $content =~ s@ crunch!@@;
1330
1331     } elsif ($content =~ m/\[too long, truncated\]$/) {
1332
1333         # config.privoxy.org/edit-actions-submit?f=3&v=1176116716&s=7&Submit=Submit[...]&filter... [too long, truncated]
1334         $content = highlight_matched_pattern($content, 'request_', '^.*(?=\.\.\. \[too long, truncated\]$)');
1335
1336     } elsif ($content =~ m/(.*)/) { # XXX: Pretty stupid
1337
1338         # trac.vidalia-project.net/wiki/Volunteer?format=txt
1339         $content = h('request_') . $content . h('Standard');
1340
1341     } else {  # XXX: Nop
1342
1343         found_unknown_content($content);
1344
1345     }
1346
1347     return $content;
1348 }
1349
1350 sub handle_loglevel_crunch ($) {
1351
1352     my $content = shift;
1353
1354     # Highlight crunch reason
1355     foreach my $reason (keys %reason_colours) {
1356         $content =~ s@($reason)@$reason_colours{$reason}$1$h{'Standard'}@g;
1357     }
1358
1359     if ($content =~ m/\[too long, truncated\]$/) {
1360
1361         # Blocked: config.privoxy.org/edit-actions-submit?f=3&v=1176116716&s=7&Submit=Submit\
1362         #  [...]&filter... [too long, truncated]
1363         $content = highlight_matched_pattern($content, 'request_', '^.*(?=\.\.\. \[too long, truncated\]$)');
1364
1365     } else {
1366
1367         # Blocked: http://ads.example.org/
1368         $content = highlight_matched_pattern($content, 'request_', '(?<=: ).*');
1369     }
1370
1371     return $content;
1372 }
1373
1374 sub handle_loglevel_connect ($) {
1375
1376     my $c = shift;
1377
1378     if ($c =~ m/^via [^\s]+ to: [^\s]+/) {
1379
1380         # Connect: via 10.0.0.1:8123 to: www.example.org.noconnect
1381
1382         $c = highlight_matched_host($c, '(?<=via )[^\s]+');
1383         $c = highlight_matched_host($c, '(?<=to: )[^\s]+');
1384
1385     } elsif ($c =~ m/^connect to: .* failed: .*/) {
1386
1387         # connect to: www.example.org.noconnect failed: Operation not permitted
1388
1389         $c = highlight_matched_host($c, '(?<=connect to: )[^\s]+');
1390
1391         $c =~ s@(?<=failed: )(.*)@$h{'error'}$1$h{'Standard'}@;
1392
1393     } elsif ($c =~ m/^to ([^\s]*)( successful)?$/) {
1394
1395         # Connect: to www.nzherald.co.nz successful
1396         # Connect: to archiv.radiotux.de
1397
1398         return '' if SUPPRESS_SUCCESSFUL_CONNECTIONS;
1399         $c = highlight_matched_host($c, '(?<=to )[^\s]+');
1400
1401     } elsif ($c =~ m/^to ([^\s]*)$/) {
1402
1403         # Connect: to lists.sourceforge.net:443
1404
1405         $c = highlight_matched_host($c, '(?<=to )[^\s]+');
1406
1407     } elsif ($c =~ m/^accepted connection from .*/ or
1408              $c =~ m/^OK/) {
1409
1410         # accepted connection from 10.0.0.1
1411         # Privoxy 3.0.6 and earlier just say:
1412         # OK
1413         return '' if SUPPRESS_ACCEPTED_CONNECTIONS;
1414         $c = highlight_matched_host($c, '(?<=connection from ).*');
1415
1416     } elsif ($c =~ m/^write header to: .* failed:/) {
1417
1418         # write header to: 10.0.0.1 failed: Broken pipe
1419
1420         $c = highlight_matched_host($c, '(?<=write header to: )[^\s]*');
1421         $c =~ s@(?<=failed: )(.*)@$h{'Error'}$1$h{'Standard'}@;
1422
1423     } elsif ($c =~ m/^write header to client failed:/) {
1424
1425         # write header to client failed: Broken pipe
1426         # XXX: Stil in use?
1427         $c =~ s@(?<=failed: )(.*)@$h{'Error'}$1$h{'Standard'}@;
1428
1429     } elsif ($c =~ m/^socks4_connect:/) {
1430
1431         # socks4_connect: SOCKS request rejected or failed.
1432         $c =~ s@(?<=socks4_connect: )(.*)@$h{'Error'}$1$h{'Standard'}@;
1433
1434     } elsif ($c =~ m/^Listening for new connections/ or
1435              $c =~ m/^accept connection/) {
1436         # XXX: Highlight?
1437         # Privoxy versions above 3.0.6 say:
1438         # Listening for new connections ...
1439         # earlier versions say:
1440         # accept connection ...
1441         return '';
1442
1443     } elsif ($c =~ m/^accept failed:/) {
1444
1445         $c =~ s@(?<=accept failed: )(.*)@$h{'Error'}$1$h{'Standard'}@;
1446
1447     } elsif ($c =~ m/^Overriding forwarding settings/) {
1448
1449         # Overriding forwarding settings based on 'forward 10.0.0.1:8123'
1450         $c =~ s@(?<=based on \')(.*)(?=\')@$h{'configuration-line'}$1$h{'Standard'}@;
1451
1452     } elsif ($c =~ m/^Denying suspicious CONNECT request from/) {
1453
1454         # Denying suspicious CONNECT request from 10.0.0.1
1455         $c = highlight_matched_host($c, '(?<=from )[^\s]+'); # XXX: not an URL
1456
1457     } elsif ($c =~ m/^socks5_connect:/) {
1458
1459         $c =~ s@(?<=socks5_connect: )(.*)@$h{'error'}$1$h{'Standard'}@;
1460
1461     } elsif ($c =~ m/^Created new connection to/) {
1462
1463         # Created new connection to www.privoxy.org:80 on socket 11.
1464         $c = highlight_matched_host($c, '(?<=connection to )[^\s]+');
1465         $c =~ s@(?<=on socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1466
1467     } elsif ($c =~ m/^Found reusable socket/) {
1468
1469         # Found reusable socket 9 for www.privoxy.org:80 in slot 0.
1470         # 3.0.15 and later:
1471         # Found reusable socket 8 for www.privoxy.org:80 in slot 2.\
1472         #  Timestamp made 0 seconds ago. Timeout: 1. Latency: 0.
1473         $c =~ s@(?<=Found reusable socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1474         $c = highlight_matched_host($c, '(?<=for )[^\s]+');
1475         $c =~ s@(?<=in slot )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1476         $c =~ s@(?<=made )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1477         $c =~ s@(?<=Timeout: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1478         $c =~ s@(?<=Latency: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1479
1480     } elsif ($c =~ m/^Marking open socket/) {
1481
1482         # Marking open socket 9 for www.privoxy.org:80 in slot 0 as unused.
1483         $c =~ s@(?<=Marking open socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1484         $c = highlight_matched_host($c, '(?<=for )[^\s]+');
1485         $c =~ s@(?<=in slot )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1486
1487     } elsif ($c =~ m/^No reusable/) {
1488
1489         # No reusable socket for addons.mozilla.org:443 found. Opening a new one.
1490         $c = highlight_matched_host($c, '(?<=for )[^\s]+');
1491
1492     } elsif ($c =~ m/^(Remembering|Forgetting) socket/) {
1493
1494         # Remembering socket 13 for www.privoxy.org:80 in slot 0.
1495         # Forgetting socket 38 for www.privoxy.org:80 in slot 5.
1496
1497         $c =~ s@(?<=socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1498         $c = highlight_matched_host($c, '(?<=for )[^\s]+');
1499         $c =~ s@(?<=in slot )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1500
1501     } elsif ($c =~ m/^Socket/) {
1502
1503         # Socket 16 already forgotten or never remembered.
1504         $c =~ s@(?<=Socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1505
1506     } elsif ($c =~ m/^The connection to/) {
1507
1508         # The connection to www.privoxy.org:80 in slot 6 timed out. Closing socket 19. Timeout is: 61.
1509         # 3.0.15 and later:
1510         # The connection to 1.bp.blogspot.com:80 in slot 0 timed out. Closing socket 5.\
1511         #  Timeout is: 1. Assumed latency: 4.
1512         # The connection to 10.0.0.1:80 in slot 0 is no longer usable. Closing socket 4.
1513         $c = highlight_matched_host($c, '(?<=connection to )[^\s]+');
1514         $c =~ s@(?<=in slot )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1515         $c =~ s@(?<=Closing socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1516         $c =~ s@(?<=Timeout is: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1517         $c =~ s@(?<=Assumed latency: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1518
1519     } elsif ($c =~ m/^Stopped waiting for the request line./) {
1520
1521         # Stopped waiting for the request line. Timeout: 121.
1522         $c =~ s@(?<=Timeout: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1523
1524     } elsif ($c =~ m/^Waiting for \d/) {
1525
1526         # Waiting for 1 connections to timeout.
1527         $c =~ s@(?<=^Waiting for )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1528
1529     } elsif ($c =~ m/^Initialized/) {
1530
1531         # Initialized 20 socket slots.
1532         $c =~ s@(?<=Initialized )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1533
1534     } elsif ($c =~ m/^Done reading from server/) {
1535
1536         # Done reading from server. Expected content length: 24892. \
1537         #  Actual content length: 24892. Most recently received: 4412.
1538         # 3.0.15 and later:
1539         # Done reading from server. Expected content length: 24892. \
1540         #  Actual content length: 24892. Bytes most recently read: 4412.
1541         # Done reading from server. Content length: 6018 as expected. \
1542         #  Bytes most recently read: 294.
1543         $c =~ s@(?<=ontent length: )(\d+)@$h{'Number'}$1$h{'Standard'}@g;
1544         $c =~ s@(?<=received: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1545         $c =~ s@(?<=read: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1546
1547     } elsif ($c =~ m/^Continuing buffering headers/) {
1548
1549         # Continuing buffering headers. byte_count: 19. header_offset: 517. len: 536.
1550         $c =~ s@(?<=byte_count: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1551         $c =~ s@(?<=header_offset: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1552         $c =~ s@(?<=len: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1553         # 3.0.15 and later:
1554         # Continuing buffering headers. Bytes most recently read: %d.
1555         $c =~ s@(?<=read: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1556
1557     } elsif ($c =~ m/^Received \d+ bytes while/) {
1558
1559         # Received 206 bytes while expecting 12103.
1560         $c =~ s@(?<=Received )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1561         $c =~ s@(?<=expecting )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1562
1563     } elsif ($c =~ m/^(Rejecting c|C)onnection from/) {
1564
1565         # Connection from 81.163.28.218 dropped due to ACL
1566         # Rejecting connection from 178.63.152.227. Maximum number of connections reached.
1567         $c =~ s@(?<=onnection from )((?:\d+\.?){3}\d+)@$h{'Number'}$1$h{'Standard'}@;
1568
1569     } elsif ($c =~ m/^(?:Reusing|Closing) server socket \d./ or
1570              $c =~ m/^No additional client request/) {
1571
1572         # Reusing server socket 4. Opened for 10.0.0.1.
1573         # Closing server socket 2. Opened for 10.0.0.1.
1574         # No additional client request received in time. \
1575         #  Closing server socket 4, initially opened for 10.0.0.1.
1576         # No additional client request received in time on socket 29.
1577
1578         $c =~ s@(?<= socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1579         $c = highlight_matched_host($c, '(?<=for )[^\s]+(?=\.$)');
1580
1581     } elsif ($c =~ m/^Connected to /) {
1582
1583         # Connected to tor-jail[10.0.0.2]:9050.
1584
1585         $c = highlight_matched_host($c, '(?<=\[)[^\]]+');
1586         $c = highlight_matched_host($c, '(?<=Connected to )[^\[\s]+');
1587         $c =~ s@(?<=\]:)(\d+)@$h{'Number'}$1$h{'Standard'}@;
1588
1589     } elsif ($c =~ m/^Could not connect to /) {
1590
1591         # Could not connect to [10.0.0.1]:80.
1592
1593         $c = highlight_matched_host($c, '(?<=\[)[^\]]+');
1594         $c =~ s@(?<=\]:)(\d+)@$h{'Number'}$1$h{'Standard'}@;
1595
1596     } elsif ($c =~ m/^Waiting for the next client request/ or
1597              $c =~ m/^The connection on server socket/ or
1598              $c =~ m/^Client request arrived in time or the client closed the connection/) {
1599
1600         # Waiting for the next client request on socket 3. Keeping the server \
1601         #  socket 12 to a.fsdn.com open.
1602         # The connection on server socket 6 to upload.wikimedia.org isn't reusable. Closing.
1603         # Client request arrived in time or the client closed the connection on socket 12.
1604
1605         $c =~ s@(?<=on socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1606         $c =~ s@(?<=server socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1607         $c = highlight_matched_host($c, '(?<=to )[^\s]+');
1608
1609     } elsif ($c =~ m/^Marking the server socket/) {
1610
1611         # Marking the server socket 7 tainted.
1612
1613         $c =~ s@(?<=server socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1614
1615     } elsif ($c =~ m/^Reduced expected bytes to /) {
1616
1617         # Reduced expected bytes to 0 to account for the 1542 ones we already got.
1618         $c =~ s@(?<=bytes to )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1619         $c =~ s@(?<=for the )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1620
1621     } elsif ($c =~ m/^The client closed socket /) {
1622
1623         # The client closed socket 2 while the server socket 4 is still open.
1624         $c =~ s@(?<=closed socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1625         $c =~ s@(?<=server socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1626
1627     } elsif ($c =~ m/^Expected client content length set /) {
1628
1629         # Expected client content length set to 667325411 after reading 4999 bytes.
1630         $c =~ s@(?<=set to )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1631         $c =~ s@(?<=reading )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1632
1633     } elsif ($c =~ m/^Waiting for up to /) {
1634
1635         # Waiting for up to 4999 bytes from the client.
1636         $c =~ s@(?<=up to )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1637
1638     } elsif ($c =~ m/^Looks like we / or
1639              $c =~ m/^Unsetting keep-alive flag/ or
1640              $c =~ m/^No connections to wait/ or
1641              $c =~ m/^Complete client request received/ or
1642              $c =~ m/^Possible pipeline attempt detected./ or
1643              $c =~ m/^POST request detected. The connection will not be kept alive./ or
1644              $c =~ m/^The server still wants to talk, but the client hung up on us./ or
1645              $c =~ m/^The server didn't specify how long the connection will stay open/ or
1646              $c =~ m/^There might be a request body. The connection will not be kept alive/ or
1647              $c =~ m/^Stopping to watch the client socket. There's already another request waiting./ or
1648              $c =~ m/^Done reading from the client\.$/) {
1649
1650         # Looks like we reached the end of the last chunk. We better stop reading.
1651         # Looks like we read the end of the last chunk together with the server \
1652         #  headers. We better stop reading.
1653         # Looks like we got the last chunk together with the server headers. \
1654         #  We better stop reading.
1655         # Unsetting keep-alive flag.
1656         # No connections to wait for left.
1657         # Client request arrived in time or the client closed the connection.
1658         # Complete client request received
1659         # Possible pipeline attempt detected. The connection will not be \
1660         #  kept alive and we will only serve the first request.
1661         # POST request detected. The connection will not be kept alive.
1662         # The server still wants to talk, but the client hung up on us.
1663         # The server didn't specify how long the connection will stay open. Assume it's only a second.
1664         # There might be a request body. The connection will not be kept alive.
1665         # Stopping to watch the client socket. There's already another request waiting.
1666         # Done reading from the client\.
1667
1668     } else {
1669
1670         found_unknown_content($c);
1671
1672     }
1673
1674     return $c;
1675 }
1676
1677
1678 sub handle_loglevel_info ($) {
1679
1680     my $c = shift;
1681
1682     if ($c =~ m/^Rewrite detected:/) {
1683
1684         # Rewrite detected: GET http://10.0.0.2:88/blah.txt HTTP/1.1
1685         $c = highlight_matched_request_line($c, '(?<=^Rewrite detected: ).*');
1686
1687     } elsif ($c =~ m/^Decompress(ing deflated|ion didn)/ or
1688              $c =~ m/^Compressed content detected/ or
1689              $c =~ m/^Tagger/
1690             ) {
1691         # Decompressing deflated iob: 117
1692         # Decompression didn't result in any content.
1693         # Compressed content detected, content filtering disabled. Consider recompiling Privoxy\
1694         #  with zlib support or enable the prevent-compression action.
1695         # Tagger 'complete-url' created empty tag. Ignored.
1696
1697         # Ignored for now
1698
1699     } elsif ($c =~ m/^(Re)?loading configuration file /) {
1700
1701         # loading configuration file '/usr/local/etc/privoxy/config':
1702         # Reloading configuration file '/usr/local/etc/privoxy/config'
1703         $c =~ s@(?<=loading configuration file \')([^\']*)@$h{'file'}$1$h{'Standard'}@;
1704
1705     } elsif ($c =~ m/^Loading (actions|filter) file: /) {
1706
1707         # Loading actions file: /usr/local/etc/privoxy/default.action
1708         # Loading filter file: /usr/local/etc/privoxy/default.filter
1709         $c =~ s@(?<= file: )(.*)$@$h{'file'}$1$h{'Standard'}@;
1710
1711     } elsif ($c =~ m/^exiting by signal/) {
1712
1713         # exiting by signal 15 .. bye
1714         $c =~ s@(?<=exiting by signal )(\d+)@$h{'signal'}$1$h{'Standard'}@;
1715
1716     } elsif ($c =~ m/^Privoxy version/) {
1717
1718         # Privoxy version 3.0.7
1719         $c =~ s@(?<=^Privoxy version )(\d+\.\d+\.\d+)$@$h{'version'}$1$h{'Standard'}@;
1720
1721     } elsif ($c =~ m/^Program name: /) {
1722
1723         # Program name: /usr/local/sbin/privoxy
1724         $c =~ s@(?<=Program name: )(.*)@$h{'program-name'}$1$h{'Standard'}@;
1725
1726     } elsif ($c =~ m/^Listening on port /) {
1727
1728         # Listening on port 8118 on IP address 10.0.0.1
1729         $c =~ s@(?<=Listening on port )(\d+)@$h{'port'}$1$h{'Standard'}@;
1730         $c =~ s@(?<=on IP address )(.*)@$h{'ip-address'}$1$h{'Standard'}@;
1731
1732     } elsif ($c =~ m/^\(Re-\)Open(?:ing)? logfile/) {
1733
1734         # (Re-)Open logfile /var/log/privoxy/privoxy.log
1735         $c =~ s@(?<=Open logfile )(.*)@$h{'file'}$1$h{'Standard'}@;
1736
1737     } elsif ($c =~ m/^(Request from|Malformed server response detected)/) {
1738
1739         # Request from 10.0.0.1 denied. limit-connect{,} doesn't allow CONNECT requests to port 443.
1740         # Request from 10.0.0.1 marked for blocking. limit-connect{,} doesn't allow CONNECT requests to port 443.
1741         # Malformed server response detected. Downgrading to HTTP/1.0 impossible.
1742
1743         $c =~ s@(?<=Request from )([^\s]*)@$h{'ip-address'}$1$h{'Standard'}@;
1744         $c =~ s@(denied|blocking)@$h{'warning'}$1$h{'Standard'}@;
1745         $c =~ s@(CONNECT)@$h{'method'}$1$h{'Standard'}@;
1746         $c =~ s@(?<=to port )(\d+)@$h{'port'}$1$h{'Standard'}@;
1747
1748     } elsif ($c =~ m/^Status code/) {
1749
1750         # Status code 304 implies no body.
1751         $c =~ s@(?<=Status code )(\d+)@$h{'status-code'}$1$h{'Standard'}@;
1752
1753     } elsif ($c =~ m/^Method/) {
1754
1755         # Method HEAD implies no body.
1756         $c =~ s@(?<=Method )([^\s]+)@$h{'method'}$1$h{'Standard'}@;
1757
1758     } elsif ($c =~ m/^Buffer limit reached while extending /) {
1759
1760         # Buffer limit reached while extending the buffer (iob). Needed: 4197470. Limit: 4194304
1761         $c =~ s@(?<=Needed: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1762         $c =~ s@(?<=Limit: )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1763
1764     } elsif ($c =~ m/^No logfile configured/ or
1765              $c =~ m/^Malformerd HTTP headers detected and MS IIS5 hack enabled/ or
1766              $c =~ m/^Invalid \"chunked\" transfer/ or
1767              $c =~ m/^Support for/ or
1768              $c =~ m/^Flushing header and buffers/ or
1769              $c =~ m/^Can not resolve/
1770              ) {
1771
1772         # No logfile configured. Please enable it before reporting any problems.
1773         # Malformerd HTTP headers detected and MS IIS5 hack enabled. Expect an invalid \
1774         #  response or even no response at all.
1775         # No logfile configured. Logging disabled.
1776         # Invalid "chunked" transfer encoding detected and ignored.
1777         # Support for 'Connection: keep-alive' is experimental, incomplete and\
1778         #  known not to work properly in some situations.
1779         # Flushing header and buffers. Stepping back from filtering.
1780         # Can not resolve doesnotexist: hostname nor servname provided, or not known
1781
1782     } else {
1783
1784         found_unknown_content($c);
1785
1786     }
1787
1788     return $c;
1789 }
1790
1791 sub handle_loglevel_cgi ($) {
1792
1793     my $c = shift;
1794
1795     if ($c =~ m/^Granting access to/) {
1796
1797         #Granting access to http://config.privoxy.org/send-stylesheet, referrer http://p.p/ is trustworthy.
1798
1799     } elsif ($c =~ m/^Substituting: s(.)/) {
1800
1801         # Substituting: s/@else-not-FEATURE_ZLIB@.*@endif-FEATURE_ZLIB@//sigTU
1802         # XXX: prone to span several lines
1803
1804         my $delimiter = $1;
1805         #$c =~ s@(?<=failed: )(.*)@$h{'error'}$1$h{'Standard'}@;
1806         $c =~ s@(?!<=\\)($delimiter)@$h{'pcrs-delimiter'}$1$h{'Standard'}@g; # XXX: Too aggressive
1807         #$c =~ s@(?!<=\\)($1)@$h{'pcrs-delimiter'}$1$h{'Standard'}@g;
1808     }
1809
1810     return $c;
1811 }
1812
1813 sub handle_loglevel_force ($) {
1814
1815     my $c = shift;
1816
1817     if ($c =~ m/^Ignored force prefix in request:/) {
1818
1819         # Ignored force prefix in request: "GET http://10.0.0.1/PRIVOXY-FORCE/block HTTP/1.1"
1820         $c =~ s@^(Ignored)@$h{'ignored'}$1$h{'Standard'}@;
1821         $c = highlight_matched_request_line($c, '(?<=request: ")[^"]*');
1822
1823     } elsif ($c =~ m/^Enforcing request:/) {
1824
1825         # Enforcing request: "GET http://10.0.0.1/block HTTP/1.1".
1826         $c = highlight_matched_request_line($c, '(?<=request: ")[^"]*');
1827
1828     } else {
1829
1830         found_unknown_content($c);
1831
1832     }
1833
1834     return $c;
1835 }
1836
1837 sub handle_loglevel_error ($) {
1838
1839     my $c = shift;
1840
1841     if ($c =~ m/^Empty server or forwarder response received on socket \d+./) {
1842
1843         # Empty server or forwarder response received on socket 4.
1844         # Empty server or forwarder response received on socket 3. \
1845         #  Closing client socket 15 without sending data.
1846         $c =~ s@(?<=on socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1847         $c =~ s@(?<=client socket )(\d+)@$h{'Number'}$1$h{'Standard'}@;
1848     }
1849     # XXX: There are probably more messages that deserve highlighting.
1850
1851     return $c;
1852 }
1853
1854
1855 sub handle_loglevel_ignore ($) {
1856     return shift;
1857 }
1858
1859 sub gather_loglevel_request_stats ($$) {
1860     my $c = shift;
1861     my $thread = shift;
1862     our %stats;
1863
1864     $stats{requests}++;
1865 }
1866
1867 sub gather_loglevel_crunch_stats ($$) {
1868     my $c = shift;
1869     my $thread = shift;
1870     our %stats;
1871
1872     $stats{requests}++;
1873     $stats{crunches}++;
1874
1875     if ($c =~ m/^Redirected:/) {
1876         # Redirected: http://www.example.org/http://p.p/
1877         $stats{'fast-redirections'}++;
1878
1879     } elsif ($c =~ m/^Blocked:/) {
1880         # Blocked: blogger.googleusercontent.com:443
1881         $stats{'blocked'}++;
1882     }
1883 }
1884
1885
1886 sub gather_loglevel_error_stats ($$) {
1887
1888     my $c = shift;
1889     my $thread = shift;
1890     our %stats;
1891     our %thread_data;
1892
1893     if ($c =~ m/^Empty server or forwarder response received on socket \d+./) {
1894
1895         # Empty server or forwarder response received on socket 4.
1896         $stats{'empty-responses'}++;
1897         if ($thread_data{$thread}{'new_connection'}) {
1898             $stats{'empty-responses-on-new-connections'}++;
1899         } else {
1900             $stats{'empty-responses-on-reused-connections'}++;
1901         }
1902     }
1903 }
1904
1905 sub gather_loglevel_connect_stats ($$) {
1906
1907     my ($c, $thread) = @_;
1908     our %thread_data;
1909     our %stats;
1910
1911     if ($c =~ m/^via ([^\s]+) to: [^\s]+/) {
1912
1913         # Connect: via 10.0.0.1:8123 to: www.example.org.noconnect
1914         $thread_data{$thread}{'forwarder'} = $1; # XXX: is this missue?
1915
1916     } elsif ($c =~ m/^to ([^\s]*)$/) {
1917
1918         # Connect: to lists.sourceforge.net:443
1919
1920         $thread_data{$thread}{'forwarder'} = 'direct connection';
1921
1922     } elsif ($c =~ m/^Created new connection to/) {
1923
1924         # Created new connection to www.privoxy.org:80 on socket 11.
1925
1926         $thread_data{$thread}{'new_connection'} = 1;
1927
1928     } elsif ($c =~ m/^Reusing server socket \d./ or
1929              $c =~ m/^Found reusable socket/) {
1930
1931         # Reusing server socket 4. Opened for 10.0.0.1.
1932         # Found reusable socket 9 for www.privoxy.org:80 in slot 0.
1933
1934         $thread_data{$thread}{'new_connection'} = 0;
1935         $stats{'reused-connections'}++;
1936     }
1937 }
1938
1939 sub gather_loglevel_header_stats ($$) {
1940
1941     my ($c, $thread) = @_;
1942     our %stats;
1943
1944     if ($c =~ m/^A HTTP\/1\.1 response without/ or
1945         $c =~ m/^Keeping the server header 'Connection: keep-alive' around./)
1946     {
1947         # A HTTP/1.1 response without Connection header implies keep-alive.
1948         # Keeping the server header 'Connection: keep-alive' around.
1949         $stats{'server-keep-alive'}++;
1950
1951     } elsif ($c =~ m/^scan: ((\w+) (.+) (HTTP\/\d\.\d))/) {
1952
1953         # scan: HTTP/1.1 200 OK
1954         $stats{'method'}{$2}++;
1955         $stats{'ressource'}{$3}++;
1956         $stats{'http-version'}{$4}++;
1957
1958     } elsif ($c =~ m/^scan: Host: ([^\s]+)/) {
1959
1960         # scan: Host: p.p
1961         $stats{'hosts'}{$1}++;
1962     }
1963 }
1964
1965 sub init_stats () {
1966     our %stats = (
1967         requests => 0,
1968         crunches => 0,
1969         'server-keep-alive' => 0,
1970         'reused-connections' => 0,
1971         'empty-responses' => 0,
1972         'empty-responses-on-new-connections' => 0,
1973         'empty-responses-on-reused-connections' => 0,
1974         'fast-redirections' => 0,
1975         'blocked' => 0,
1976         'reused-connections' => 0,
1977         'server-keep-alive' => 0,
1978         );
1979 }
1980
1981 sub get_percentage ($$) {
1982     my $big = shift;
1983     my $small = shift;
1984     return "NaN" if ($big eq 0);
1985     return sprintf("%.2f%%", $small / $big * 100);
1986 }
1987
1988 sub print_stats () {
1989
1990     our %stats;
1991     our %cli_options;
1992     my $new_connections = $stats{requests} - $stats{crunches} - $stats{'reused-connections'};
1993     my $outgoing_requests = $stats{requests} - $stats{crunches};
1994
1995     if ($stats{requests} eq 0) {
1996         print "No requests yet.\n";
1997         return;
1998     }
1999
2000     print "Client requests total: " . $stats{requests} . "\n";
2001     print "Crunches: " . $stats{crunches} . " (" .
2002         get_percentage($stats{requests}, $stats{crunches}) . ")\n";
2003     print "Blocks: " . $stats{'blocked'} . " (" .
2004         get_percentage($stats{requests}, $stats{'blocked'}) . ")\n";
2005     print "Fast redirections: " . $stats{'fast-redirections'} . " (" .
2006         get_percentage($stats{requests}, $stats{'fast-redirections'}) . ")\n";
2007     print "Outgoing requests: " . $outgoing_requests . " (" .
2008         get_percentage($stats{requests}, $outgoing_requests) . ")\n";
2009     print "Server keep-alive offers: " . $stats{'server-keep-alive'} . " (" .
2010         get_percentage($stats{requests}, $stats{'server-keep-alive'}) . ")\n";
2011     print "New outgoing connections: " . $new_connections . " (" .
2012         get_percentage($stats{requests}, $new_connections) . ")\n";
2013     print "Reused connections: " . $stats{'reused-connections'} . " (" .
2014         get_percentage($stats{requests}, $stats{'reused-connections'}) .
2015         "; server offers accepted: " .
2016         get_percentage($stats{'server-keep-alive'}, $stats{'reused-connections'}) . ")\n";
2017     print "Empty responses: " . $stats{'empty-responses'} . " (" .
2018         get_percentage($stats{requests}, $stats{'empty-responses'}) . ")\n";
2019     print "Empty responses on new connections: "
2020          . $stats{'empty-responses-on-new-connections'} . " (" .
2021         get_percentage($stats{requests}, $stats{'empty-responses-on-new-connections'})
2022         . ")\n";
2023     print "Empty responses on reused connections: " .
2024         $stats{'empty-responses-on-reused-connections'} . " (" .
2025         get_percentage($stats{requests}, $stats{'empty-responses-on-reused-connections'}) .
2026         ")\n";
2027
2028     if ($stats{method} eq 0) {
2029         print "No response lines parsed yet yet.\n";
2030         return;
2031     }
2032     print "Method distribution:\n";
2033     foreach my $method (sort {$stats{'method'}{$b} <=> $stats{'method'}{$a}} keys %{$stats{'method'}}) {
2034         printf "%8d : %-8s\n", $stats{'method'}{$method}, $method;
2035     }
2036     print "Client HTTP versions:\n";
2037     foreach my $http_version (sort {$stats{'http-version'}{$b} <=> $stats{'http-version'}{$a}} keys %{$stats{'http-version'}}) {
2038         printf "%d : %s\n",  $stats{'http-version'}{$http_version}, $http_version;
2039     }
2040
2041     if ($cli_options{'url-statistics-threshold'} == 0) {
2042         print "URL statistics are disabled. Increase --url-statistics-threshold to enable them.\n";
2043     } else {
2044         print "Requested URLs:\n";
2045         foreach my $ressource (sort {$stats{'ressource'}{$b} <=> $stats{'ressource'}{$a}} keys %{$stats{'ressource'}}) {
2046             if ($stats{'ressource'}{$ressource} < $cli_options{'url-statistics-threshold'}) {
2047                 print "Skipped statistics for URLs below the treshold.\n";
2048                 last;
2049             }
2050             printf "%d : %s\n", $stats{'ressource'}{$ressource}, $ressource;
2051         }
2052     }
2053
2054     if ($cli_options{'host-statistics-threshold'} == 0) {
2055         print "Host statistics are disabled. Increase --host-statistics-threshold to enable them.\n";
2056     } else {
2057         print "Requested Hosts:\n";
2058         foreach my $host (sort {$stats{'hosts'}{$b} <=> $stats{'hosts'}{$a}} keys %{$stats{'hosts'}}) {
2059             if ($stats{'hosts'}{$host} < $cli_options{'host-statistics-threshold'}) {
2060                 print "Skipped statistics for Hosts below the treshold.\n";
2061                 last;
2062             }
2063             printf "%d : %s\n", $stats{'hosts'}{$host}, $host;
2064         }
2065     }
2066 }
2067
2068
2069 ################################################################################
2070 # Functions that actually print stuff
2071 ################################################################################
2072
2073 sub print_clf_message () {
2074
2075     our ($ip, $timestamp, $request_line, $status_code, $size);
2076     my $output = '';
2077
2078     return if DEBUG_SUPPRESS_LOG_MESSAGES;
2079
2080     # Rebuild highlighted
2081     $output .= $h{'Number'} . $ip . $h{'Standard'};
2082     $output .= " - - ";
2083     $output .= "[" . $h{'Timestamp'} . $timestamp . $h{'Standard'} . "]";
2084     $output .= " ";
2085     $output .= "\"" . highlight_request_line("$request_line") . "\"";
2086     $output .= " ";
2087     $output .= $h{'Status'} . $status_code . $h{'Standard'};
2088     $output .= " ";
2089     $output .= $h{'Number'} . $size . $h{'Standard'};
2090     $output .= $line_end;
2091
2092     print $output;
2093 }
2094
2095 sub print_non_clf_message ($) {
2096
2097     my $content = shift;
2098     my $msec_string = "." . $req{$t}{'msecs'} unless $no_msecs_mode;
2099     my $line_start = $html_output_mode ? '' : $h{"Standard"};
2100
2101     return if DEBUG_SUPPRESS_LOG_MESSAGES;
2102
2103     print $line_start
2104         . $time_colours[$time_colour_index % 2]
2105         . $req{$t}{'time-stamp'}
2106         . $msec_string
2107         . $h{Standard} . " "
2108         . $thread_colours{$t}
2109         . $t
2110         . $h{Standard}
2111         . " "
2112         . $h{$req{$t}{'log-level'}}
2113         . $req{$t}{'log-level'}
2114         . $h{Standard}
2115         . ": "
2116         . $content
2117         . $line_end;
2118 }
2119
2120 sub shorten_thread_id ($) {
2121
2122     my $thread_id = shift;
2123
2124     our %short_thread_ids;
2125     our $max_threadid;
2126
2127     unless (defined $short_thread_ids{$thread_id}) {
2128         $short_thread_ids{$thread_id} = sprintf "%.3d", $max_threadid++;
2129     }
2130
2131     return $short_thread_ids{$thread_id}
2132 }
2133
2134 sub parse_loop () {
2135
2136     my ($day, $time_stamp, $thread, $log_level, $content, $c, $msecs);
2137     my $last_msecs  = 0;
2138     my $last_thread = 0;
2139     my $last_timestamp = 0;
2140     my $filters_that_did_nothing;
2141     my $key;
2142     my $time_colour;
2143     $time_colour = paint_it('white');
2144
2145     my %log_level_handlers = (
2146         'Re-Filter'         => \&handle_loglevel_re_filter,
2147         'Header'            => \&handle_loglevel_header,
2148         'Connect'           => \&handle_loglevel_connect,
2149         'Redirect'          => \&handle_loglevel_redirect,
2150         'Request'           => \&handle_loglevel_request,
2151         'Crunch'            => \&handle_loglevel_crunch,
2152         'Gif-Deanimate'     => \&handle_loglevel_gif_deanimate,
2153         'Info'              => \&handle_loglevel_info,
2154         'CGI'               => \&handle_loglevel_cgi,
2155         'Force'             => \&handle_loglevel_force,
2156         'Error'             => \&handle_loglevel_error,
2157         'Fatal error'       => \&handle_loglevel_ignore,
2158         'Writing'           => \&handle_loglevel_ignore,
2159         'Received'          => \&handle_loglevel_ignore,
2160         'Unknown log level' => \&handle_loglevel_ignore,
2161     );
2162
2163     while (<>) {
2164
2165         if (m/^(\w{3} \d{2}) (\d\d:\d\d:\d\d)\.?(\d+)? (?:Privoxy\()?([^\)\s]*)[\)]? ([\w -]*): (.*?)\r?$/) {
2166             $thread = $t = ($shorten_thread_ids) ? shorten_thread_id($4) : $4;
2167             $req{$t}{'day'} = $day = $1;
2168             $req{$t}{'time-stamp'} = $time_stamp = $2;
2169             $req{$t}{'msecs'} = $msecs = $3 ? $3 : 0; # Only the cool kids have micro second resolution;
2170             $req{$t}{'log-level'} = $log_level = $5;
2171             $req{$t}{'content'} = $content = $c = $6;
2172             $req{$t}{'log-message'} = $_;
2173             $no_special_header_highlighting = 0;
2174
2175             if (defined($log_level_handlers{$log_level})) {
2176
2177                 $content = $log_level_handlers{$log_level}($content);
2178
2179             } else {
2180
2181                 die "No handler found for log level \"$log_level\"\n";
2182             }
2183
2184             # Highlight Truncations
2185             if (length($_) > 4000) {
2186                 $content =~ s@(too long, truncated)]$@$h{'Truncation'}$1$h{'Standard'}]@g;
2187             }
2188
2189             next unless $content;
2190
2191             # Register threads to keep the colour constant
2192             if (!defined($thread_colours{$thread})) {
2193                 $thread_colours{$thread} = $all_colours[$thread_colour_index % @all_colours];
2194                 $thread_colour_index++;
2195             }
2196
2197             # Switch timestamp colour if timestamps differ
2198             if (($msecs ne $last_msecs) || ($time_stamp ne $last_timestamp)) {
2199                debug_message("Tick tack!") if DEBUG_TICKS;
2200                $time_colour = $time_colours[$time_colour_index % 2];
2201                $time_colour_index++;
2202                $last_msecs = $msecs;
2203                $last_timestamp = $time_stamp;
2204             }
2205
2206             $last_thread = $thread;
2207
2208             print_non_clf_message($content);
2209
2210         } elsif (m/^((?:\d+\.\d+\.\d+\.\d+|[:\d]+)) - - \[(.*)\] "(.*)" (\d+) (\d+)/) {
2211
2212             # LOG_LEVEL_CLF lines look like this
2213             # 61.152.239.32 - - [04/Mar/2007:18:28:23 +0100] "GET \
2214             #  http://ad.yieldmanager.com/imp?z=1&Z=120x600&s=109339&u=http%3A%2F%2Fwww.365loan.co.uk%2F&r=1\
2215             #  HTTP/1.1" 403 1730
2216             our ($ip, $timestamp, $request_line, $status_code, $size) = ($1, $2, $3, $4, $5);
2217
2218             print_clf_message();
2219
2220         } else {
2221
2222             # Some Privoxy log messages span more than one line,
2223             # usually to dump lots of content that doesn't need any syntax highlighting.
2224             # XXX: add mechanism to forward these lines to the right handler anyway.
2225             chomp();
2226             unless (DEBUG_SUPPRESS_LOG_MESSAGES or (SUPPRESS_EMPTY_LINES and m/^\s+$/)) {
2227                 print and print get_line_end(); # unless (SUPPRESS_EMPTY_LINES and m/^\s+$/);
2228             }
2229         }
2230     }
2231 }
2232
2233 sub stats_loop () {
2234
2235     my ($day, $time_stamp, $msecs, $thread, $log_level, $content);
2236     my %log_level_handlers = (
2237          'Re-Filter'         => \&handle_loglevel_ignore,
2238          'Header'            => \&gather_loglevel_header_stats,
2239          'Connect'           => \&gather_loglevel_connect_stats,
2240          'Redirect'          => \&handle_loglevel_ignore,
2241          'Request'           => \&gather_loglevel_request_stats,
2242          'Crunch'            => \&gather_loglevel_crunch_stats,
2243          'Gif-Deanimate'     => \&handle_loglevel_ignore,
2244          'Info'              => \&handle_loglevel_ignore,
2245          'CGI'               => \&handle_loglevel_ignore,
2246          'Force'             => \&handle_loglevel_ignore,
2247          'Error'             => \&gather_loglevel_error_stats,
2248          'Fatal error'       => \&handle_loglevel_ignore,
2249          'Writing'           => \&handle_loglevel_ignore,
2250          'Received'          => \&handle_loglevel_ignore,
2251          'Unknown log level' => \&handle_loglevel_ignore
2252     );
2253
2254     while (<>) {
2255         if (m/^(\w{3} \d{2}) (\d\d:\d\d:\d\d)\.?(\d+)? (?:Privoxy\()?([^\)\s]*)[\)]? ([\w -]*): (.*?)\r?$/) {
2256             $day = $1;
2257             $time_stamp = $2;
2258             $msecs = $3 ? $3 : 0;
2259             $thread = $4;
2260             $log_level = $5;
2261             $content = $6;
2262
2263             if (defined($log_level_handlers{$log_level})) {
2264
2265                 $content = $log_level_handlers{$log_level}($content, $thread);
2266
2267             } else {
2268
2269                 die "No handler found for log level \"$log_level\"\n";
2270
2271             }
2272         }
2273     }
2274
2275     print_stats();
2276
2277 }
2278
2279 sub VersionMessage {
2280     my $version_message;
2281
2282     $version_message .= 'Privoxy-Log-Parser ' . PRIVOXY_LOG_PARSER_VERSION  . "\n";
2283     $version_message .= 'Copyright (C) 2007-2010 Fabian Keil <fk@fabiankeil.de>' . "\n";
2284     $version_message .= 'http://www.fabiankeil.de/sourcecode/privoxy-log-parser/' . "\n";
2285
2286     print $version_message;
2287 }
2288
2289 sub get_cli_options () {
2290
2291     our %cli_options = (
2292         'html-output'              => CLI_OPTION_DEFAULT_TO_HTML_OUTPUT,
2293         'title'                    => CLI_OPTION_TITLE,
2294         'no-syntax-highlighting'   => CLI_OPTION_NO_SYNTAX_HIGHLIGHTING,
2295         'no-embedded-css'          => CLI_OPTION_NO_EMBEDDED_CSS,
2296         'no-msecs'                 => CLI_OPTION_NO_MSECS,
2297         'shorten-thread-ids'       => CLI_OPTION_SHORTEN_THREAD_IDS,
2298         'show-ineffective-filters' => CLI_OPTION_SHOW_INEFFECTIVE_FILTERS,
2299         'accept-unknown-messages'  => CLI_OPTION_ACCEPT_UNKNOWN_MESSAGES,
2300         'statistics'               => CLI_OPTION_STATISTICS,
2301         'url-statistics-threshold' => CLI_OPTION_URL_STATISTICS_THRESHOLD,
2302         'host-statistics-threshold'=> CLI_OPTION_HOST_STATISTICS_THRESHOLD,
2303     );
2304
2305     GetOptions (
2306         'html-output'              => \$cli_options{'html-output'},
2307         'title'                    => \$cli_options{'title'},
2308         'no-syntax-highlighting'   => \$cli_options{'no-syntax-highlighting'},
2309         'no-embedded-css'          => \$cli_options{'no-embedded-css'},
2310         'no-msecs'                 => \$cli_options{'no-msecs'},
2311         'shorten-thread-ids'       => \$cli_options{'shorten-thread-ids'},
2312         'show-ineffective-filters' => \$cli_options{'show-ineffective-filters'},
2313         'accept-unknown-messages'  => \$cli_options{'accept-unknown-messages'},
2314         'statistics'               => \$cli_options{'statistics'},
2315         'url-statistics-threshold=s'=> \$cli_options{'url-statistics-threshold'},
2316         'host-statistics-threshold=s'=> \$cli_options{'host-statistics-threshold'},
2317         'version'                  => sub { VersionMessage && exit(0) },
2318         'help'                     => \&help,
2319    ) or exit(1);
2320
2321    $html_output_mode = cli_option_is_set('html-output');
2322    $no_msecs_mode = cli_option_is_set('no-msecs');
2323    $shorten_thread_ids = cli_option_is_set('shorten-thread-ids');
2324    $line_end = get_line_end();
2325 }
2326
2327 sub help () {
2328
2329     our %cli_options;
2330
2331     VersionMessage();
2332
2333     print << "    EOF"
2334
2335 Options and their default values if they have any:
2336     [--accept-unknown-messages]
2337     [--host-statistics-threshold $cli_options{'host-statistics-threshold'}]
2338     [--html-output]
2339     [--no-embedded-css]
2340     [--no-msecs]
2341     [--no-syntax-highlighting]
2342     [--shorten-thread-ids]
2343     [--show-ineffective-filters]
2344     [--statistics]
2345     [--url-statistics-threshold $cli_options{'url-statistics-threshold'}]
2346     [--title $cli_options{'title'}]
2347     [--version]
2348 see "perldoc $0" for more information
2349     EOF
2350     ;
2351     exit(0);
2352 }
2353
2354 ################################################################################
2355 # main
2356 ################################################################################
2357 sub main () {
2358
2359     get_cli_options();
2360     set_background(DEFAULT_BACKGROUND);
2361     prepare_our_stuff();
2362
2363     print_intro();
2364
2365     if (cli_option_is_set('statistics')) {
2366         stats_loop();
2367     } else {
2368         parse_loop();
2369     }
2370
2371     print_outro();
2372 }
2373
2374 main();
2375
2376 =head1 NAME
2377
2378 B<privoxy-log-parser> - A parser and syntax-highlighter for Privoxy log messages
2379
2380 =head1 SYNOPSIS
2381
2382 B<privoxy-log-parser> [B<--accept-unknown-messages>] [B<--html-output>]
2383 [B<--no-msecs>] [B<--no-syntax-higlighting>] [B<--statistics>]
2384 [B<--shorten-thread-ids>] [B<--show-ineffective-filters>]
2385 [B<--url-statistics-threshold>] [B<--version>]
2386
2387 =head1 DESCRIPTION
2388
2389 B<privoxy-log-parser> reads Privoxy log messages and
2390
2391 - syntax-highlights recognized lines,
2392
2393 - reformats some of them for easier comprehension,
2394
2395 - filters out less useful messages, and
2396
2397 - (in some cases) calculates additional information,
2398   like the compression ratio or how a filter affected
2399   the content size.
2400
2401 With B<privoxy-log-parser> you should be able to increase Privoxy's log level
2402 without getting confused by the resulting amount of output. For example for
2403 "debug 64" B<privoxy-log-parser> will (by default) only show messages that
2404 affect the content. If a filter doesn't cause any hits, B<privoxy-log-parser>
2405 will hide the "filter foo caused 0 hits" message.
2406
2407 =head1 OPTIONS
2408
2409 [B<--accept-unknown-messages>] Don't print warnings in case of unknown messages,
2410 just don't highlight them.
2411
2412 [B<--host-statistics-threshold>] Only show the request count for a host
2413 if it's above or equal to the given threshold. If the threshold is 0, host
2414 statistics are disabled.
2415
2416 [B<--html-output>] Use HTML and CSS for the syntax highlighting. If this option is
2417 omitted, ANSI escape sequences are used unless B<--no-syntax-highlighting> is active.
2418 This option is only intended to make embedding log excerpts in web pages easier.
2419 It does not escape any input!
2420
2421 [B<--no-msecs>] Don't expect milisecond resolution
2422
2423 [B<--no-syntax-highlighting>] Disable syntax-highlighting. Useful when
2424 the filtered output is piped into less in which case the ANSI control
2425 codes don't work, or if the terminal itself doesn't support the control
2426 codes.
2427
2428 [B<--shorten-thread-ids>] Shorten the thread ids to a three-digit decimal number.
2429 Note that the mapping from thread ids to shortened ids is created at run-time
2430 and thus varies with the input.
2431
2432 [B<--show-ineffective-filters>] Don't suppress log lines for filters
2433 that didn't modify the content.
2434
2435 [B<--statistics>] Gather various statistics instead of syntax highlighting
2436 log messages. This is an experimental feature, if the results look wrong
2437 they very well might be. Also note that the results are pretty much guaranteed
2438 to be incorrect if Privoxy and Privoxy-Log-Parser aren't in sync.
2439
2440 [B<--url-statistics-threshold>] Only show the request count for a ressource
2441 if it's above or equal to the given threshold. If the threshold is 0, URL
2442 statistics are disabled.
2443
2444 [B<--version>] Print version and exit.
2445
2446 =head1 EXAMPLES
2447
2448 To monitor a log file:
2449
2450 tail -F /usr/jails/privoxy-jail/var/log/privoxy/privoxy.log | B<privoxy-log-parser>
2451
2452 Replace '-F' with '-f' if your tail implementation lacks '-F' support
2453 or if the log won't get rotated anyway. The log file location depends
2454 on your system (Doh!).
2455
2456 To monitor Privoxy without having it write to a log file:
2457
2458 privoxy --no-daemon /usr/jails/privoxy-jail/usr/local/etc/privoxy/config 2>&1 | B<privoxy-log-parser>
2459
2460 Again, the config file location depends on your system. Output redirection
2461 depends on your shell, the above works with bourne shells.
2462
2463 To read a processed Privoxy log file from top to bottom, letting the content
2464 scroll by slightly faster than you can read:
2465
2466 B<privoxy-log-parser> < /usr/jails/privoxy-jail/var/log/privoxy/privoxy.log
2467
2468 This is probably only useful to fill screens in the background of haxor movies.
2469
2470 =head1 CAVEATS
2471
2472 Syntax highlighting with ANSI escape sequences will look strange
2473 if your background color isn't black.
2474
2475 Some messages aren't recognized yet and will not be fully highlighted.
2476
2477 B<privoxy-log-parser> is developed with Privoxy 3.0.7 or later in mind,
2478 using earlier Privoxy versions will probably result in an increased amount
2479 of unrecognized log lines.
2480
2481 Privoxy's log files tend to be rather large. If you use HTML
2482 highlighting some browsers can't handle them, get confused and
2483 will eventually crash because of segmentation faults or unexpected
2484 exceptions. This is a problem in the browser and not B<privoxy-log-parser>'s
2485 fault.
2486
2487 =head1 BUGS
2488
2489 Many settings can't be controlled through command line options yet.
2490
2491 =head1 SEE ALSO
2492
2493 privoxy(1)
2494
2495 =head1 AUTHOR
2496
2497 Fabian Keil <fk@fabiankeil.de>
2498
2499 =cut